lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use v5.10.1;
   8 use List::Util qw(min max);
   9 use URI::Escape qw(uri_unescape);
  10 use PublicInbox::Smsg;
  11 use PublicInbox::Hval qw(ascii_html obfuscate_addrs mid_href fmt_ts);
  12 use PublicInbox::View;
  13 use PublicInbox::WwwAtomStream;
  14 use PublicInbox::WwwStream qw(html_oneshot);
  15 use PublicInbox::SearchThread;
  16 use PublicInbox::SearchQuery;
  17 use PublicInbox::Search qw(get_pct);
  18 my %rmap_inc;
  19
  20 sub mbox_results {
  21         my ($ctx) = @_;
  22         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  23         if ($ctx->{env}->{'psgi.input'}->read(my $buf, 3)) {
  24                 $q->{t} = 1 if $buf =~ /\Ax=[^0]/;
  25         }
  26         require PublicInbox::Mbox;
  27         $q->{x} eq 'm' ? PublicInbox::Mbox::mbox_all($ctx, $q) :
  28                         sres_top_html($ctx);
  29 }
  30
  31 sub sres_top_html {
  32         my ($ctx) = @_;
  33         my $srch = $ctx->{ibx}->isrch or
  34                 return PublicInbox::WWW::need($ctx, 'Search');
  35         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  36         my $x = $q->{x};
  37         my $o = $q->{o};
  38         my $asc;
  39         if ($o < 0) {
  40                 $asc = 1;
  41                 $o = -($o + 1); # so [-1] is the last element, like Perl lists
  42         }
  43
  44         my $code = 200;
  45         # double the limit for expanded views:
  46         my $opts = {
  47                 limit => $q->{l},
  48                 offset => $o,
  49                 relevance => $q->{r},
  50                 threads => $q->{t},
  51                 asc => $asc,
  52         };
  53         my ($mset, $total, $err, $html);
  54 retry:
  55         eval {
  56                 my $query = $q->{'q'};
  57                 $srch->query_approxidate($ctx->{ibx}->git, $query);
  58                 $mset = $srch->mset($query, $opts);
  59                 $total = $mset->get_matches_estimated;
  60         };
  61         $err = $@;
  62         ctx_prepare($q, $ctx);
  63         if ($err) {
  64                 $code = 400;
  65                 $html = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  66         } elsif ($total == 0) {
  67                 if (defined($ctx->{-uxs_retried})) {
  68                         # undo retry damage:
  69                         $q->{'q'} = $ctx->{-uxs_retried};
  70                 } elsif (index($q->{'q'}, '%') >= 0) {
  71                         $ctx->{-uxs_retried} = $q->{'q'};
  72                         $q->{'q'} = uri_unescape($q->{'q'});
  73                         goto retry;
  74                 }
  75                 $code = 404;
  76                 $html = "<pre>\n[No results found]</pre><hr>";
  77         } else {
  78                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  79
  80                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx);
  81                 return mset_thread($ctx, $mset, $q) if $x eq 't';
  82                 mset_summary($ctx, $mset, $q); # appends to {-html_tip}
  83                 $html = '';
  84         }
  85         html_oneshot($ctx, $code);
  86 }
  87
  88 # display non-nested search results similar to what users expect from
  89 # regular WWW search engines:
  90 sub mset_summary {
  91         my ($ctx, $mset, $q) = @_;
  92
  93         my $total = $mset->get_matches_estimated;
  94         my $pad = length("$total");
  95         my $pfx = ' ' x $pad;
  96         my $res = \($ctx->{-html_tip});
  97         my $ibx = $ctx->{ibx};
  98         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
  99         my @nums = @{$ibx->isrch->mset_to_artnums($mset)};
 100         my %num2msg = map { $_->{num} => $_ } @{$ibx->over->get_all(@nums)};
 101         my ($min, $max, %seen);
 102
 103         foreach my $m ($mset->items) {
 104                 my $num = shift @nums;
 105                 my $smsg = delete($num2msg{$num}) or do {
 106                         eval {
 107                                 $m = "$m $num expired\n";
 108                                 $ctx->{env}->{'psgi.errors'}->print($m);
 109                         };
 110                         next;
 111                 };
 112                 my $mid = $smsg->{mid};
 113                 next if $seen{$mid}++;
 114                 $mid = mid_href($mid);
 115                 $ctx->{-t_max} //= $smsg->{ts};
 116                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
 117                 my $pct = get_pct($m);
 118
 119                 # only when sorting by relevance, ->items is always
 120                 # ordered descending:
 121                 $max //= $pct;
 122                 $min = $pct;
 123
 124                 my $s = ascii_html($smsg->{subject});
 125                 my $f = ascii_html($smsg->{from_name});
 126                 if ($obfs_ibx) {
 127                         obfuscate_addrs($obfs_ibx, $s);
 128                         obfuscate_addrs($obfs_ibx, $f);
 129                 }
 130                 my $date = fmt_ts($smsg->{ds});
 131                 $s = '(no subject)' if $s eq '';
 132                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 133                         $s . "</a></b>\n";
 134                 $$res .= "$pfx  - by $f @ $date UTC [$pct%]\n\n";
 135         }
 136         if ($q->{r}) { # for descriptions in search_nav_bot
 137                 $q->{-min_pct} = $min;
 138                 $q->{-max_pct} = $max;
 139         }
 140         $$res .= search_nav_bot($mset, $q);
 141         undef;
 142 }
 143
 144 # shorten "/full/path/to/Foo/Bar.pm" to "Foo/Bar.pm" so error
 145 # messages don't reveal FS layout info in case people use non-standard
 146 # installation paths
 147 sub path2inc ($) {
 148         my $full = $_[0];
 149         if (my $short = $rmap_inc{$full}) {
 150                 return $short;
 151         } elsif (!scalar(keys %rmap_inc) && -e $full) {
 152                 %rmap_inc = map {; "$INC{$_}" => $_ } keys %INC;
 153                 # fall back to basename as last resort
 154                 $rmap_inc{$full} // (split('/', $full))[-1];
 155         } else {
 156                 $full;
 157         }
 158 }
 159
 160 sub err_txt {
 161         my ($ctx, $err) = @_;
 162         my $u = $ctx->{ibx}->base_url($ctx->{env}) . '_/text/help/';
 163         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 164         $err =~ s!(\S+)!path2inc($1)!sge;
 165         $err = ascii_html($err);
 166         "\nBad query: <b>$err</b>\n" .
 167                 qq{See <a\nhref="$u">$u</a> for help on using search};
 168 }
 169
 170 sub search_nav_top {
 171         my ($mset, $q, $ctx) = @_;
 172         my $m = $q->qs_html(x => 'm', r => undef, t => undef);
 173         my $rv = qq{<form\naction="?$m"\nmethod="post"><pre>};
 174         my $initial_q = $ctx->{-uxs_retried};
 175         if (defined $initial_q) {
 176                 my $rewritten = $q->{'q'};
 177                 utf8::decode($initial_q);
 178                 utf8::decode($rewritten);
 179                 $initial_q = ascii_html($initial_q);
 180                 $rewritten = ascii_html($rewritten);
 181                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 182                 $rv .= " returned no results, used:\n";
 183                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 184         }
 185
 186         $rv .= 'Search results ordered by [';
 187         if ($q->{r}) {
 188                 my $d = $q->qs_html(r => 0);
 189                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 190         } else {
 191                 my $d = $q->qs_html(r => 1);
 192                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 193         }
 194
 195         $rv .= ']  view[';
 196
 197         my $x = $q->{x};
 198         if ($x eq '') {
 199                 my $t = $q->qs_html(x => 't');
 200                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 201         } elsif ($q->{x} eq 't') {
 202                 my $s = $q->qs_html(x => '');
 203                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 204         }
 205         my $A = $q->qs_html(x => 'A', r => undef);
 206         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 207         if ($ctx->{ibx}->isrch->has_threadid) {
 208                 $rv .= qq{\n\t\t\tdownload mbox.gz: } .
 209                         # we set name=z w/o using it since it seems required for
 210                         # lynx (but works fine for w3m).
 211                         qq{<input\ntype=submit\nname=z\n} .
 212                                 q{value="results only"/>} .
 213                         qq{|<input\ntype=submit\nname=x\n} .
 214                                 q{value="full threads"/>};
 215         } else { # BOFH needs to --reindex
 216                 $rv .= qq{\n\t\t\t\t\t\tdownload: } .
 217                         qq{<input\ntype=submit\nname=z\nvalue="mbox.gz"/>}
 218         }
 219         $rv .= qq{</pre></form><pre>};
 220 }
 221
 222 sub search_nav_bot { # also used by WwwListing for searching extindex miscidx
 223         my ($mset, $q) = @_;
 224         my $total = $mset->get_matches_estimated;
 225         my $l = $q->{l};
 226         my $rv = '</pre><hr><pre id=t>';
 227         my $o = $q->{o};
 228         my $off = $o < 0 ? -($o + 1) : $o;
 229         my $end = $off + $mset->size;
 230         my $beg = $off + 1;
 231
 232         if ($beg <= $end) {
 233                 my $approx = $end == $total ? '' : '~';
 234                 $rv .= "Results $beg-$end of $approx$total";
 235         } else {
 236                 $rv .= "No more results, only $total";
 237         }
 238         my ($next, $join, $prev, $nd, $pd);
 239
 240         if ($o >= 0) { # sort descending
 241                 my $n = $o + $l;
 242                 if ($n < $total) {
 243                         $next = $q->qs_html(o => $n, l => $l);
 244                         $nd = $q->{r} ? "[&lt;= $q->{-min_pct}%]" : '(older)';
 245                 }
 246                 if ($o > 0) {
 247                         $join = $n < $total ? ' | ' : "\t";
 248                         my $p = $o - $l;
 249                         $prev = $q->qs_html(o => ($p > 0 ? $p : 0));
 250                         $pd = $q->{r} ? "[&gt;= $q->{-max_pct}%]" : '(newer)';
 251                 }
 252         } else { # o < 0, sort ascending
 253                 my $n = $o - $l;
 254
 255                 if (-$n < $total) {
 256                         $next = $q->qs_html(o => $n, l => $l);
 257                         $nd = $q->{r} ? "[&lt;= $q->{-min_pct}%]" : '(newer)';
 258                 }
 259                 if ($o < -1) {
 260                         $join = -$n < $total ? ' | ' : "\t";
 261                         my $p = $o + $l;
 262                         $prev = $q->qs_html(o => ($p < 0 ? $p : 0));
 263                         $pd = $q->{r} ? "[&gt;= $q->{-max_pct}%]" : '(older)';
 264                 }
 265         }
 266
 267         $rv .= qq{  <a\nhref="?$next"\nrel=next>next $nd</a>} if $next;
 268         $rv .= $join if $join;
 269         $rv .= qq{<a\nhref="?$prev"\nrel=prev>prev $pd</a>} if $prev;
 270
 271         my $rev = $q->qs_html(o => $o < 0 ? 0 : -1);
 272         $rv .= qq{ | <a\nhref="?$rev">reverse</a></pre>};
 273 }
 274
 275 sub sort_relevance {
 276         [ sort {
 277                 (eval { $b->topmost->{pct} } // 0) <=>
 278                 (eval { $a->topmost->{pct} } // 0)
 279         } @{$_[0]} ]
 280 }
 281
 282 sub mset_thread {
 283         my ($ctx, $mset, $q) = @_;
 284         my $ibx = $ctx->{ibx};
 285         my @pct = map { get_pct($_) } $mset->items;
 286         my $msgs = $ibx->isrch->mset_to_smsg($ibx, $mset);
 287         my $i = 0;
 288         $_->{pct} = $pct[$i++] for @$msgs;
 289         my $r = $q->{r};
 290         if ($r) { # for descriptions in search_nav_bot
 291                 $q->{-min_pct} = min(@pct);
 292                 $q->{-max_pct} = max(@pct);
 293         }
 294         my $rootset = PublicInbox::SearchThread::thread($msgs,
 295                 $r ? \&sort_relevance : \&PublicInbox::View::sort_ds,
 296                 $ctx);
 297         my $skel = search_nav_bot($mset, $q). "<pre>";
 298         $ctx->{-upfx} = '';
 299         $ctx->{anchor_idx} = 1;
 300         $ctx->{cur_level} = 0;
 301         $ctx->{skel} = \$skel;
 302         $ctx->{mapping} = {};
 303         $ctx->{searchview} = 1;
 304         $ctx->{prev_attr} = '';
 305         $ctx->{prev_level} = 0;
 306         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 307
 308         # reduce hash lookups in skel_dump
 309         $ctx->{-obfs_ibx} = $ibx->{obfuscate} ? $ibx : undef;
 310         PublicInbox::View::walk_thread($rootset, $ctx,
 311                 \&PublicInbox::View::pre_thread);
 312
 313         # link $INBOX_DIR/description text to "recent" view around
 314         # the newest message in this result set:
 315         $ctx->{-t_max} = max(map { delete $_->{ts} } @$msgs);
 316
 317         @$msgs = reverse @$msgs if $r;
 318         $ctx->{msgs} = $msgs;
 319         PublicInbox::WwwStream::aresponse($ctx, 200, \&mset_thread_i);
 320 }
 321
 322 # callback for PublicInbox::WwwStream::getline
 323 sub mset_thread_i {
 324         my ($ctx, $eml) = @_;
 325         $ctx->zmore($ctx->html_top) if exists $ctx->{-html_tip};
 326         $eml and return PublicInbox::View::eml_entry($ctx, $eml);
 327         my $smsg = shift @{$ctx->{msgs}} or
 328                 $ctx->zmore(${delete($ctx->{skel})});
 329         $smsg;
 330 }
 331
 332 sub ctx_prepare {
 333         my ($q, $ctx) = @_;
 334         my $qh = $q->{'q'};
 335         utf8::decode($qh);
 336         $qh = ascii_html($qh);
 337         $ctx->{-q_value_html} = $qh;
 338         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 339         $ctx->{-title_html} = "$qh - search results";
 340         my $extra = '';
 341         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 342         if (my $x = $q->{x}) {
 343                 $x = ascii_html($x);
 344                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 345         }
 346         $ctx->{-extra_form_html} = $extra;
 347 }
 348
 349 sub adump {
 350         my ($cb, $mset, $q, $ctx) = @_;
 351         $ctx->{ids} = $ctx->{ibx}->isrch->mset_to_artnums($mset);
 352         $ctx->{search_query} = $q; # used by WwwAtomStream::atom_header
 353         PublicInbox::WwwAtomStream->response($ctx, 200, \&adump_i);
 354 }
 355
 356 # callback for PublicInbox::WwwAtomStream::getline
 357 sub adump_i {
 358         my ($ctx) = @_;
 359         while (my $num = shift @{$ctx->{ids}}) {
 360                 my $smsg = eval { $ctx->{ibx}->over->get_art($num) } or next;
 361                 return $smsg;
 362         }
 363 }
 364
 365 1;