lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use URI::Escape qw(uri_unescape uri_escape);
   9 use PublicInbox::SearchMsg;
  10 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  11 use PublicInbox::View;
  12 use PublicInbox::WwwAtomStream;
  13 use PublicInbox::MID qw(mid2path mid_mime mid_clean mid_escape MID_ESC);
  14 use PublicInbox::MIME;
  15 require PublicInbox::Git;
  16 require PublicInbox::SearchThread;
  17 our $LIM = 200;
  18
  19 sub noop {}
  20
  21 sub sres_top_html {
  22         my ($ctx) = @_;
  23         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  24         my $code = 200;
  25
  26         # double the limit for expanded views:
  27         my $opts = {
  28                 limit => $LIM,
  29                 offset => $q->{o},
  30                 mset => 1,
  31                 relevance => $q->{r},
  32         };
  33         my ($mset, $total, $err, $cb);
  34 retry:
  35         eval {
  36                 $mset = $ctx->{srch}->query($q->{'q'}, $opts);
  37                 $total = $mset->get_matches_estimated;
  38         };
  39         $err = $@;
  40         ctx_prepare($q, $ctx);
  41         if ($err) {
  42                 $code = 400;
  43                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  44                 $cb = *noop;
  45         } elsif ($total == 0) {
  46                 if (defined($ctx->{-uxs_retried})) {
  47                         # undo retry damage:
  48                         $q->{'q'} = $ctx->{-uxs_retried};
  49                 } elsif (index($q->{'q'}, '%') >= 0) {
  50                         $ctx->{-uxs_retried} = $q->{'q'};
  51                         $q->{'q'} = uri_unescape($q->{'q'});
  52                         goto retry;
  53                 }
  54                 $code = 404;
  55                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  56                 $cb = *noop;
  57         } else {
  58                 my $x = $q->{x};
  59                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  60
  61                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx) . "\n\n";
  62                 if ($x eq 't') {
  63                         $cb = mset_thread($ctx, $mset, $q);
  64                 } else {
  65                         $cb = mset_summary($ctx, $mset, $q);
  66                 }
  67         }
  68         PublicInbox::WwwStream->response($ctx, $code, $cb);
  69 }
  70
  71 # allow undef for individual doc loads...
  72 sub load_doc_retry {
  73         my ($srch, $mitem) = @_;
  74
  75         eval {
  76                 $srch->retry_reopen(sub {
  77                         PublicInbox::SearchMsg->load_doc($mitem->get_document)
  78                 });
  79         }
  80 }
  81
  82 # display non-threaded search results similar to what users expect from
  83 # regular WWW search engines:
  84 sub mset_summary {
  85         my ($ctx, $mset, $q) = @_;
  86
  87         my $total = $mset->get_matches_estimated;
  88         my $pad = length("$total");
  89         my $pfx = ' ' x $pad;
  90         my $res = \($ctx->{-html_tip});
  91         my $srch = $ctx->{srch};
  92         my $ibx = $ctx->{-inbox};
  93         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
  94         foreach my $m ($mset->items) {
  95                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
  96                 my $pct = $m->get_percent;
  97                 my $smsg = load_doc_retry($srch, $m);
  98                 unless ($smsg) {
  99                         eval {
 100                                 $m = "$m ".$m->get_docid . " expired\n";
 101                                 $ctx->{env}->{'psgi.errors'}->print($m);
 102                         };
 103                         next;
 104                 }
 105                 my $s = ascii_html($smsg->subject);
 106                 my $f = ascii_html($smsg->from_name);
 107                 if ($obfs_ibx) {
 108                         obfuscate_addrs($obfs_ibx, $s);
 109                         obfuscate_addrs($obfs_ibx, $f);
 110                 }
 111                 my $ts = PublicInbox::View::fmt_ts($smsg->ts);
 112                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
 113                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 114                         $s . "</a></b>\n";
 115                 $$res .= "$pfx  - by $f @ $ts UTC [$pct%]\n\n";
 116         }
 117         $$res .= search_nav_bot($mset, $q);
 118         *noop;
 119 }
 120
 121 sub err_txt {
 122         my ($ctx, $err) = @_;
 123         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 124         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 125         $err = ascii_html($err);
 126         "\nBad query: <b>$err</b>\n" .
 127                 qq{See <a\nhref="$u">$u</a> for help on using search};
 128 }
 129
 130 sub search_nav_top {
 131         my ($mset, $q, $ctx) = @_;
 132
 133         my $rv = '<pre>';
 134         my $initial_q = $ctx->{-uxs_retried};
 135         if (defined $initial_q) {
 136                 my $rewritten = $q->{'q'};
 137                 utf8::decode($initial_q);
 138                 utf8::decode($rewritten);
 139                 $initial_q = ascii_html($initial_q);
 140                 $rewritten = ascii_html($rewritten);
 141                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 142                 $rv .= " returned no results, used:\n";
 143                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 144         }
 145
 146         $rv .= 'Search results ordered by [';
 147         if ($q->{r}) {
 148                 my $d = $q->qs_html(r => 0);
 149                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 150         } else {
 151                 my $d = $q->qs_html(r => 1);
 152                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 153         }
 154
 155         $rv .= ']  view[';
 156
 157         my $x = $q->{x};
 158         if ($x eq '') {
 159                 my $t = $q->qs_html(x => 't');
 160                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">threaded</a>}
 161         } elsif ($q->{x} eq 't') {
 162                 my $s = $q->qs_html(x => '');
 163                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>threaded</b>};
 164         }
 165         my $A = $q->qs_html(x => 'A', r => undef);
 166         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 167 }
 168
 169 sub search_nav_bot {
 170         my ($mset, $q) = @_;
 171         my $total = $mset->get_matches_estimated;
 172         my $nr = scalar $mset->items;
 173         my $o = $q->{o};
 174         my $end = $o + $nr;
 175         my $beg = $o + 1;
 176         my $rv = '</pre><hr><pre id=t>';
 177         if ($beg <= $end) {
 178                 $rv .= "Results $beg-$end of $total";
 179                 $rv .= ' (estimated)' if $end != $total;
 180         } else {
 181                 $rv .= "No more results, only $total";
 182         }
 183         my $n = $o + $LIM;
 184
 185         if ($n < $total) {
 186                 my $qs = $q->qs_html(o => $n);
 187                 $rv .= qq{  <a\nhref="?$qs"\nrel=next>next</a>}
 188         }
 189         if ($o > 0) {
 190                 $rv .= $n < $total ? '/' : '       ';
 191                 my $p = $o - $LIM;
 192                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 193                 $rv .= qq{<a\nhref="?$qs"\nrel=prev>prev</a>};
 194         }
 195         $rv .= '</pre>';
 196 }
 197
 198 sub sort_relevance {
 199         my ($pct) = @_;
 200         sub {
 201                 [ sort { (eval { $pct->{$b->topmost->{id}} } || 0)
 202                                 <=>
 203                         (eval { $pct->{$a->topmost->{id}} } || 0)
 204         } @{$_[0]} ] };
 205 }
 206
 207 sub mset_thread {
 208         my ($ctx, $mset, $q) = @_;
 209         my %pct;
 210         my $srch = $ctx->{srch};
 211         my $msgs = $srch->retry_reopen(sub { [ map {
 212                 my $i = $_;
 213                 my $smsg = PublicInbox::SearchMsg->load_doc($i->get_document);
 214                 $pct{$smsg->mid} = $i->get_percent;
 215                 $smsg;
 216         } ($mset->items) ]});
 217         my $r = $q->{r};
 218         my $rootset = PublicInbox::SearchThread::thread($msgs,
 219                 $r ? sort_relevance(\%pct) : *PublicInbox::View::sort_ts,
 220                 $srch);
 221         my $skel = search_nav_bot($mset, $q). "<pre>";
 222         my $inbox = $ctx->{-inbox};
 223         $ctx->{-upfx} = '';
 224         $ctx->{anchor_idx} = 1;
 225         $ctx->{cur_level} = 0;
 226         $ctx->{dst} = \$skel;
 227         $ctx->{mapping} = {};
 228         $ctx->{pct} = \%pct;
 229         $ctx->{prev_attr} = '';
 230         $ctx->{prev_level} = 0;
 231         $ctx->{seen} = {};
 232         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 233
 234         # reduce hash lookups in skel_dump
 235         $ctx->{-obfuscate} = $ctx->{-inbox}->{obfuscate};
 236         PublicInbox::View::walk_thread($rootset, $ctx,
 237                 *PublicInbox::View::pre_thread);
 238
 239         @$msgs = reverse @$msgs if $r;
 240         my $mime;
 241         sub {
 242                 return unless $msgs;
 243                 while ($mime = pop @$msgs) {
 244                         $mime = $inbox->msg_by_smsg($mime) and last;
 245                 }
 246                 if ($mime) {
 247                         $mime = PublicInbox::MIME->new($mime);
 248                         return PublicInbox::View::index_entry($mime, $ctx,
 249                                 scalar @$msgs);
 250                 }
 251                 $msgs = undef;
 252                 $skel .= "\n</pre>";
 253         };
 254 }
 255
 256 sub ctx_prepare {
 257         my ($q, $ctx) = @_;
 258         my $qh = $q->{'q'};
 259         utf8::decode($qh);
 260         $qh = ascii_html($qh);
 261         $ctx->{-q_value_html} = $qh;
 262         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 263         $ctx->{-title_html} = "$qh - search results";
 264         my $extra = '';
 265         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 266         if (my $x = $q->{x}) {
 267                 $x = ascii_html($x);
 268                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 269         }
 270         $ctx->{-extra_form_html} = $extra;
 271 }
 272
 273 sub adump {
 274         my ($cb, $mset, $q, $ctx) = @_;
 275         my $ibx = $ctx->{-inbox};
 276         my @items = $mset->items;
 277         $ctx->{search_query} = $q;
 278         my $srch = $ctx->{srch};
 279         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
 280                 while (my $x = shift @items) {
 281                         $x = load_doc_retry($srch, $x);
 282                         $x = $ibx->msg_by_smsg($x) and
 283                                         return PublicInbox::MIME->new($x);
 284                 }
 285                 return undef;
 286         });
 287 }
 288
 289 package PublicInbox::SearchQuery;
 290 use strict;
 291 use warnings;
 292 use URI::Escape qw(uri_escape);
 293 use PublicInbox::Hval;
 294 use PublicInbox::MID qw(MID_ESC);
 295
 296 sub new {
 297         my ($class, $qp) = @_;
 298
 299         my $r = $qp->{r};
 300         bless {
 301                 q => $qp->{'q'},
 302                 x => $qp->{x} || '',
 303                 o => (($qp->{o} || '0') =~ /(\d+)/),
 304                 r => (defined $r && $r ne '0'),
 305         }, $class;
 306 }
 307
 308 sub qs_html {
 309         my ($self, %over) = @_;
 310
 311         if (keys %over) {
 312                 my $tmp = bless { %$self }, ref($self);
 313                 foreach my $k (keys %over) {
 314                         $tmp->{$k} = $over{$k};
 315                 }
 316                 $self = $tmp;
 317         }
 318
 319         my $q = uri_escape($self->{'q'}, MID_ESC);
 320         $q =~ s/%20/+/g; # improve URL readability
 321         my $qs = "q=$q";
 322
 323         if (my $o = $self->{o}) { # ignore o == 0
 324                 $qs .= "&amp;o=$o";
 325         }
 326         if (my $r = $self->{r}) {
 327                 $qs .= "&amp;r";
 328         }
 329         if (my $x = $self->{x}) {
 330                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A');
 331         }
 332         $qs;
 333 }
 334
 335 1;