lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use URI::Escape qw(uri_unescape uri_escape);
   9 use PublicInbox::SearchMsg;
  10 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  11 use PublicInbox::View;
  12 use PublicInbox::WwwAtomStream;
  13 use PublicInbox::MID qw(MID_ESC);
  14 use PublicInbox::MIME;
  15 require PublicInbox::Git;
  16 require PublicInbox::SearchThread;
  17 our $LIM = 200;
  18
  19 sub noop {}
  20
  21 sub mbox_results {
  22         my ($ctx) = @_;
  23         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  24         my $x = $q->{x};
  25         return PublicInbox::Mbox::mbox_all($ctx, $q->{'q'}) if $x eq 'm';
  26         sres_top_html($ctx);
  27 }
  28
  29 sub sres_top_html {
  30         my ($ctx) = @_;
  31         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  32         my $x = $q->{x};
  33         my $query = $q->{'q'};
  34
  35         my $code = 200;
  36         # double the limit for expanded views:
  37         my $opts = {
  38                 limit => $LIM,
  39                 offset => $q->{o},
  40                 mset => 1,
  41                 relevance => $q->{r},
  42         };
  43         my ($mset, $total, $err, $cb);
  44 retry:
  45         eval {
  46                 $mset = $ctx->{srch}->query($query, $opts);
  47                 $total = $mset->get_matches_estimated;
  48         };
  49         $err = $@;
  50         ctx_prepare($q, $ctx);
  51         if ($err) {
  52                 $code = 400;
  53                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  54                 $cb = *noop;
  55         } elsif ($total == 0) {
  56                 if (defined($ctx->{-uxs_retried})) {
  57                         # undo retry damage:
  58                         $q->{'q'} = $ctx->{-uxs_retried};
  59                 } elsif (index($q->{'q'}, '%') >= 0) {
  60                         $ctx->{-uxs_retried} = $q->{'q'};
  61                         $q->{'q'} = uri_unescape($q->{'q'});
  62                         goto retry;
  63                 }
  64                 $code = 404;
  65                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  66                 $cb = *noop;
  67         } else {
  68                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  69
  70                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx);
  71                 if ($x eq 't') {
  72                         $cb = mset_thread($ctx, $mset, $q);
  73                 } else {
  74                         $cb = mset_summary($ctx, $mset, $q);
  75                 }
  76         }
  77         PublicInbox::WwwStream->response($ctx, $code, $cb);
  78 }
  79
  80 # allow undef for individual doc loads...
  81 sub load_doc_retry {
  82         my ($srch, $mitem) = @_;
  83
  84         eval {
  85                 $srch->retry_reopen(sub {
  86                         PublicInbox::SearchMsg->load_doc($mitem->get_document)
  87                 });
  88         }
  89 }
  90
  91 # display non-nested search results similar to what users expect from
  92 # regular WWW search engines:
  93 sub mset_summary {
  94         my ($ctx, $mset, $q) = @_;
  95
  96         my $total = $mset->get_matches_estimated;
  97         my $pad = length("$total");
  98         my $pfx = ' ' x $pad;
  99         my $res = \($ctx->{-html_tip});
 100         my $srch = $ctx->{srch};
 101         my $ibx = $ctx->{-inbox};
 102         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
 103         foreach my $m ($mset->items) {
 104                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
 105                 my $pct = $m->get_percent;
 106                 my $smsg = load_doc_retry($srch, $m);
 107                 unless ($smsg) {
 108                         eval {
 109                                 $m = "$m ".$m->get_docid . " expired\n";
 110                                 $ctx->{env}->{'psgi.errors'}->print($m);
 111                         };
 112                         next;
 113                 }
 114                 my $s = ascii_html($smsg->subject);
 115                 my $f = ascii_html($smsg->from_name);
 116                 if ($obfs_ibx) {
 117                         obfuscate_addrs($obfs_ibx, $s);
 118                         obfuscate_addrs($obfs_ibx, $f);
 119                 }
 120                 my $date = PublicInbox::View::fmt_ts($smsg->ds);
 121                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
 122                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 123                         $s . "</a></b>\n";
 124                 $$res .= "$pfx  - by $f @ $date UTC [$pct%]\n\n";
 125         }
 126         $$res .= search_nav_bot($mset, $q);
 127         *noop;
 128 }
 129
 130 sub err_txt {
 131         my ($ctx, $err) = @_;
 132         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 133         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 134         $err = ascii_html($err);
 135         "\nBad query: <b>$err</b>\n" .
 136                 qq{See <a\nhref="$u">$u</a> for help on using search};
 137 }
 138
 139 sub search_nav_top {
 140         my ($mset, $q, $ctx) = @_;
 141         my $m = $q->qs_html(x => 'm', r => undef);
 142         my $rv = qq{<form\naction="?$m"\nmethod="post"><pre>};
 143         my $initial_q = $ctx->{-uxs_retried};
 144         if (defined $initial_q) {
 145                 my $rewritten = $q->{'q'};
 146                 utf8::decode($initial_q);
 147                 utf8::decode($rewritten);
 148                 $initial_q = ascii_html($initial_q);
 149                 $rewritten = ascii_html($rewritten);
 150                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 151                 $rv .= " returned no results, used:\n";
 152                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 153         }
 154
 155         $rv .= 'Search results ordered by [';
 156         if ($q->{r}) {
 157                 my $d = $q->qs_html(r => 0);
 158                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 159         } else {
 160                 my $d = $q->qs_html(r => 1);
 161                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 162         }
 163
 164         $rv .= ']  view[';
 165
 166         my $x = $q->{x};
 167         if ($x eq '') {
 168                 my $t = $q->qs_html(x => 't');
 169                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 170         } elsif ($q->{x} eq 't') {
 171                 my $s = $q->qs_html(x => '');
 172                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 173         }
 174         my $A = $q->qs_html(x => 'A', r => undef);
 175         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 176         $rv .= qq{\n\t\t\t\t\t\tdownload: };
 177         $rv .= qq{<input\ntype=submit\nvalue="mbox.gz"/></pre></form><pre>};
 178 }
 179
 180 sub search_nav_bot {
 181         my ($mset, $q) = @_;
 182         my $total = $mset->get_matches_estimated;
 183         my $nr = scalar $mset->items;
 184         my $o = $q->{o};
 185         my $end = $o + $nr;
 186         my $beg = $o + 1;
 187         my $rv = '</pre><hr><pre id=t>';
 188         if ($beg <= $end) {
 189                 $rv .= "Results $beg-$end of $total";
 190                 $rv .= ' (estimated)' if $end != $total;
 191         } else {
 192                 $rv .= "No more results, only $total";
 193         }
 194         my $n = $o + $LIM;
 195
 196         if ($n < $total) {
 197                 my $qs = $q->qs_html(o => $n);
 198                 $rv .= qq{  <a\nhref="?$qs"\nrel=next>next</a>}
 199         }
 200         if ($o > 0) {
 201                 $rv .= $n < $total ? '/' : '       ';
 202                 my $p = $o - $LIM;
 203                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 204                 $rv .= qq{<a\nhref="?$qs"\nrel=prev>prev</a>};
 205         }
 206         $rv .= '</pre>';
 207 }
 208
 209 sub sort_relevance {
 210         my ($pct) = @_;
 211         sub {
 212                 [ sort { (eval { $pct->{$b->topmost->{id}} } || 0)
 213                                 <=>
 214                         (eval { $pct->{$a->topmost->{id}} } || 0)
 215         } @{$_[0]} ] };
 216 }
 217
 218 sub mset_thread {
 219         my ($ctx, $mset, $q) = @_;
 220         my %pct;
 221         my $srch = $ctx->{srch};
 222         my $msgs = $srch->retry_reopen(sub { [ map {
 223                 my $i = $_;
 224                 my $smsg = PublicInbox::SearchMsg->load_doc($i->get_document);
 225                 $pct{$smsg->mid} = $i->get_percent;
 226                 $smsg;
 227         } ($mset->items) ]});
 228         my $r = $q->{r};
 229         my $rootset = PublicInbox::SearchThread::thread($msgs,
 230                 $r ? sort_relevance(\%pct) : *PublicInbox::View::sort_ds,
 231                 $ctx);
 232         my $skel = search_nav_bot($mset, $q). "<pre>";
 233         my $inbox = $ctx->{-inbox};
 234         $ctx->{-upfx} = '';
 235         $ctx->{anchor_idx} = 1;
 236         $ctx->{cur_level} = 0;
 237         $ctx->{dst} = \$skel;
 238         $ctx->{mapping} = {};
 239         $ctx->{pct} = \%pct;
 240         $ctx->{prev_attr} = '';
 241         $ctx->{prev_level} = 0;
 242         $ctx->{seen} = {};
 243         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 244
 245         # reduce hash lookups in skel_dump
 246         $ctx->{-obfuscate} = $ctx->{-inbox}->{obfuscate};
 247         PublicInbox::View::walk_thread($rootset, $ctx,
 248                 *PublicInbox::View::pre_thread);
 249
 250         @$msgs = reverse @$msgs if $r;
 251         sub {
 252                 return unless $msgs;
 253                 my $smsg;
 254                 while (my $m = pop @$msgs) {
 255                         $smsg = $inbox->smsg_mime($m) and last;
 256                 }
 257                 if ($smsg) {
 258                         return PublicInbox::View::index_entry($smsg, $ctx,
 259                                 scalar @$msgs);
 260                 }
 261                 $msgs = undef;
 262                 $skel .= "\n</pre>";
 263         };
 264 }
 265
 266 sub ctx_prepare {
 267         my ($q, $ctx) = @_;
 268         my $qh = $q->{'q'};
 269         utf8::decode($qh);
 270         $qh = ascii_html($qh);
 271         $ctx->{-q_value_html} = $qh;
 272         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 273         $ctx->{-title_html} = "$qh - search results";
 274         my $extra = '';
 275         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 276         if (my $x = $q->{x}) {
 277                 $x = ascii_html($x);
 278                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 279         }
 280         $ctx->{-extra_form_html} = $extra;
 281 }
 282
 283 sub adump {
 284         my ($cb, $mset, $q, $ctx) = @_;
 285         my $ibx = $ctx->{-inbox};
 286         my @items = $mset->items;
 287         $ctx->{search_query} = $q;
 288         my $srch = $ctx->{srch};
 289         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
 290                 while (my $x = shift @items) {
 291                         $x = load_doc_retry($srch, $x);
 292                         $x = $ibx->smsg_mime($x) and return $x;
 293                 }
 294                 return undef;
 295         });
 296 }
 297
 298 package PublicInbox::SearchQuery;
 299 use strict;
 300 use warnings;
 301 use URI::Escape qw(uri_escape);
 302 use PublicInbox::Hval;
 303 use PublicInbox::MID qw(MID_ESC);
 304
 305 sub new {
 306         my ($class, $qp) = @_;
 307
 308         my $r = $qp->{r};
 309         bless {
 310                 q => $qp->{'q'},
 311                 x => $qp->{x} || '',
 312                 o => (($qp->{o} || '0') =~ /(\d+)/),
 313                 r => (defined $r && $r ne '0'),
 314         }, $class;
 315 }
 316
 317 sub qs_html {
 318         my ($self, %over) = @_;
 319
 320         if (keys %over) {
 321                 my $tmp = bless { %$self }, ref($self);
 322                 foreach my $k (keys %over) {
 323                         $tmp->{$k} = $over{$k};
 324                 }
 325                 $self = $tmp;
 326         }
 327
 328         my $q = uri_escape($self->{'q'}, MID_ESC);
 329         $q =~ s/%20/+/g; # improve URL readability
 330         my $qs = "q=$q";
 331
 332         if (my $o = $self->{o}) { # ignore o == 0
 333                 $qs .= "&amp;o=$o";
 334         }
 335         if (my $r = $self->{r}) {
 336                 $qs .= "&amp;r";
 337         }
 338         if (my $x = $self->{x}) {
 339                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A' || $x eq 'm');
 340         }
 341         $qs;
 342 }
 343
 344 1;