lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use URI::Escape qw(uri_unescape uri_escape);
   9 use PublicInbox::SearchMsg;
  10 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  11 use PublicInbox::View;
  12 use PublicInbox::WwwAtomStream;
  13 use PublicInbox::MID qw(MID_ESC);
  14 use PublicInbox::MIME;
  15 require PublicInbox::Git;
  16 require PublicInbox::SearchThread;
  17 our $LIM = 200;
  18
  19 sub noop {}
  20
  21 sub mbox_results {
  22         my ($ctx) = @_;
  23         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  24         my $x = $q->{x};
  25         return PublicInbox::Mbox::mbox_all($ctx, $q->{'q'}) if $x eq 'm';
  26         sres_top_html($ctx);
  27 }
  28
  29 sub sres_top_html {
  30         my ($ctx) = @_;
  31         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  32         my $x = $q->{x};
  33         my $query = $q->{'q'};
  34
  35         my $code = 200;
  36         # double the limit for expanded views:
  37         my $opts = {
  38                 limit => $LIM,
  39                 offset => $q->{o},
  40                 mset => 1,
  41                 relevance => $q->{r},
  42         };
  43         my ($mset, $total, $err, $cb);
  44 retry:
  45         eval {
  46                 $mset = $ctx->{srch}->query($query, $opts);
  47                 $total = $mset->get_matches_estimated;
  48         };
  49         $err = $@;
  50         ctx_prepare($q, $ctx);
  51         if ($err) {
  52                 $code = 400;
  53                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  54                 $cb = *noop;
  55         } elsif ($total == 0) {
  56                 if (defined($ctx->{-uxs_retried})) {
  57                         # undo retry damage:
  58                         $q->{'q'} = $ctx->{-uxs_retried};
  59                 } elsif (index($q->{'q'}, '%') >= 0) {
  60                         $ctx->{-uxs_retried} = $q->{'q'};
  61                         $q->{'q'} = uri_unescape($q->{'q'});
  62                         goto retry;
  63                 }
  64                 $code = 404;
  65                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  66                 $cb = *noop;
  67         } else {
  68                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  69
  70                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx);
  71                 if ($x eq 't') {
  72                         $cb = mset_thread($ctx, $mset, $q);
  73                 } else {
  74                         $cb = mset_summary($ctx, $mset, $q);
  75                 }
  76         }
  77         PublicInbox::WwwStream->response($ctx, $code, $cb);
  78 }
  79
  80 # allow undef for individual doc loads...
  81 sub load_doc_retry {
  82         my ($srch, $mitem) = @_;
  83
  84         eval {
  85                 $srch->retry_reopen(sub {
  86                         PublicInbox::SearchMsg->load_doc($mitem->get_document)
  87                 });
  88         }
  89 }
  90
  91 # display non-nested search results similar to what users expect from
  92 # regular WWW search engines:
  93 sub mset_summary {
  94         my ($ctx, $mset, $q) = @_;
  95
  96         my $total = $mset->get_matches_estimated;
  97         my $pad = length("$total");
  98         my $pfx = ' ' x $pad;
  99         my $res = \($ctx->{-html_tip});
 100         my $srch = $ctx->{srch};
 101         my $ibx = $ctx->{-inbox};
 102         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
 103         foreach my $m ($mset->items) {
 104                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
 105                 my $pct = $m->get_percent;
 106                 my $smsg = load_doc_retry($srch, $m);
 107                 unless ($smsg) {
 108                         eval {
 109                                 $m = "$m ".$m->get_docid . " expired\n";
 110                                 $ctx->{env}->{'psgi.errors'}->print($m);
 111                         };
 112                         next;
 113                 }
 114                 my $s = ascii_html($smsg->subject);
 115                 my $f = ascii_html($smsg->from_name);
 116                 if ($obfs_ibx) {
 117                         obfuscate_addrs($obfs_ibx, $s);
 118                         obfuscate_addrs($obfs_ibx, $f);
 119                 }
 120                 my $date = PublicInbox::View::fmt_ts($smsg->ds);
 121                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
 122                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 123                         $s . "</a></b>\n";
 124                 $$res .= "$pfx  - by $f @ $date UTC [$pct%]\n\n";
 125         }
 126         $$res .= search_nav_bot($mset, $q);
 127         *noop;
 128 }
 129
 130 sub err_txt {
 131         my ($ctx, $err) = @_;
 132         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 133         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 134         $err = ascii_html($err);
 135         "\nBad query: <b>$err</b>\n" .
 136                 qq{See <a\nhref="$u">$u</a> for help on using search};
 137 }
 138
 139 sub search_nav_top {
 140         my ($mset, $q, $ctx) = @_;
 141         my $m = $q->qs_html(x => 'm', r => undef);
 142         my $rv = qq{<form\naction="?$m"\nmethod="post"><pre>};
 143         my $initial_q = $ctx->{-uxs_retried};
 144         if (defined $initial_q) {
 145                 my $rewritten = $q->{'q'};
 146                 utf8::decode($initial_q);
 147                 utf8::decode($rewritten);
 148                 $initial_q = ascii_html($initial_q);
 149                 $rewritten = ascii_html($rewritten);
 150                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 151                 $rv .= " returned no results, used:\n";
 152                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 153         }
 154
 155         $rv .= 'Search results ordered by [';
 156         if ($q->{r}) {
 157                 my $d = $q->qs_html(r => 0);
 158                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 159         } else {
 160                 my $d = $q->qs_html(r => 1);
 161                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 162         }
 163
 164         $rv .= ']  view[';
 165
 166         my $x = $q->{x};
 167         if ($x eq '') {
 168                 my $t = $q->qs_html(x => 't');
 169                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 170         } elsif ($q->{x} eq 't') {
 171                 my $s = $q->qs_html(x => '');
 172                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 173         }
 174         my $A = $q->qs_html(x => 'A', r => undef);
 175         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 176         $rv .= qq{\n\t\t\t\t\t\tdownload: };
 177         $rv .= qq{<input\ntype=submit\nvalue="mbox.gz"/></pre></form><pre>};
 178 }
 179
 180 sub search_nav_bot {
 181         my ($mset, $q) = @_;
 182         my $total = $mset->get_matches_estimated;
 183         my $o = $q->{o};
 184         my $end = $o + $mset->size;
 185         my $beg = $o + 1;
 186         my $rv = '</pre><hr><pre id=t>';
 187         if ($beg <= $end) {
 188                 $rv .= "Results $beg-$end of $total";
 189                 $rv .= ' (estimated)' if $end != $total;
 190         } else {
 191                 $rv .= "No more results, only $total";
 192         }
 193         my $n = $o + $LIM;
 194
 195         if ($n < $total) {
 196                 my $qs = $q->qs_html(o => $n);
 197                 $rv .= qq{  <a\nhref="?$qs"\nrel=next>next</a>}
 198         }
 199         if ($o > 0) {
 200                 $rv .= $n < $total ? '/' : '       ';
 201                 my $p = $o - $LIM;
 202                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 203                 $rv .= qq{<a\nhref="?$qs"\nrel=prev>prev</a>};
 204         }
 205         $rv .= '</pre>';
 206 }
 207
 208 sub sort_relevance {
 209         my ($pct) = @_;
 210         sub {
 211                 [ sort { (eval { $pct->{$b->topmost->{id}} } || 0)
 212                                 <=>
 213                         (eval { $pct->{$a->topmost->{id}} } || 0)
 214         } @{$_[0]} ] };
 215 }
 216
 217 sub mset_thread {
 218         my ($ctx, $mset, $q) = @_;
 219         my %pct;
 220         my $srch = $ctx->{srch};
 221         my $msgs = $srch->retry_reopen(sub { [ map {
 222                 my $i = $_;
 223                 my $smsg = PublicInbox::SearchMsg->load_doc($i->get_document);
 224                 $pct{$smsg->mid} = $i->get_percent;
 225                 $smsg;
 226         } ($mset->items) ]});
 227         my $r = $q->{r};
 228         my $rootset = PublicInbox::SearchThread::thread($msgs,
 229                 $r ? sort_relevance(\%pct) : *PublicInbox::View::sort_ds,
 230                 $ctx);
 231         my $skel = search_nav_bot($mset, $q). "<pre>";
 232         my $inbox = $ctx->{-inbox};
 233         $ctx->{-upfx} = '';
 234         $ctx->{anchor_idx} = 1;
 235         $ctx->{cur_level} = 0;
 236         $ctx->{dst} = \$skel;
 237         $ctx->{mapping} = {};
 238         $ctx->{pct} = \%pct;
 239         $ctx->{prev_attr} = '';
 240         $ctx->{prev_level} = 0;
 241         $ctx->{seen} = {};
 242         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 243
 244         # reduce hash lookups in skel_dump
 245         $ctx->{-obfuscate} = $ctx->{-inbox}->{obfuscate};
 246         PublicInbox::View::walk_thread($rootset, $ctx,
 247                 *PublicInbox::View::pre_thread);
 248
 249         @$msgs = reverse @$msgs if $r;
 250         sub {
 251                 return unless $msgs;
 252                 my $smsg;
 253                 while (my $m = pop @$msgs) {
 254                         $smsg = $inbox->smsg_mime($m) and last;
 255                 }
 256                 if ($smsg) {
 257                         return PublicInbox::View::index_entry($smsg, $ctx,
 258                                 scalar @$msgs);
 259                 }
 260                 $msgs = undef;
 261                 $skel .= "\n</pre>";
 262         };
 263 }
 264
 265 sub ctx_prepare {
 266         my ($q, $ctx) = @_;
 267         my $qh = $q->{'q'};
 268         utf8::decode($qh);
 269         $qh = ascii_html($qh);
 270         $ctx->{-q_value_html} = $qh;
 271         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 272         $ctx->{-title_html} = "$qh - search results";
 273         my $extra = '';
 274         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 275         if (my $x = $q->{x}) {
 276                 $x = ascii_html($x);
 277                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 278         }
 279         $ctx->{-extra_form_html} = $extra;
 280 }
 281
 282 sub adump {
 283         my ($cb, $mset, $q, $ctx) = @_;
 284         my $ibx = $ctx->{-inbox};
 285         my @items = $mset->items;
 286         $ctx->{search_query} = $q;
 287         my $srch = $ctx->{srch};
 288         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
 289                 while (my $x = shift @items) {
 290                         $x = load_doc_retry($srch, $x);
 291                         $x = $ibx->smsg_mime($x) and return $x;
 292                 }
 293                 return undef;
 294         });
 295 }
 296
 297 package PublicInbox::SearchQuery;
 298 use strict;
 299 use warnings;
 300 use URI::Escape qw(uri_escape);
 301 use PublicInbox::Hval;
 302 use PublicInbox::MID qw(MID_ESC);
 303
 304 sub new {
 305         my ($class, $qp) = @_;
 306
 307         my $r = $qp->{r};
 308         bless {
 309                 q => $qp->{'q'},
 310                 x => $qp->{x} || '',
 311                 o => (($qp->{o} || '0') =~ /(\d+)/),
 312                 r => (defined $r && $r ne '0'),
 313         }, $class;
 314 }
 315
 316 sub qs_html {
 317         my ($self, %over) = @_;
 318
 319         if (keys %over) {
 320                 my $tmp = bless { %$self }, ref($self);
 321                 foreach my $k (keys %over) {
 322                         $tmp->{$k} = $over{$k};
 323                 }
 324                 $self = $tmp;
 325         }
 326
 327         my $q = uri_escape($self->{'q'}, MID_ESC);
 328         $q =~ s/%20/+/g; # improve URL readability
 329         my $qs = "q=$q";
 330
 331         if (my $o = $self->{o}) { # ignore o == 0
 332                 $qs .= "&amp;o=$o";
 333         }
 334         if (my $r = $self->{r}) {
 335                 $qs .= "&amp;r";
 336         }
 337         if (my $x = $self->{x}) {
 338                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A' || $x eq 'm');
 339         }
 340         $qs;
 341 }
 342
 343 1;