lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::SearchMsg;
   9 use PublicInbox::Hval qw/ascii_html/;
  10 use PublicInbox::View;
  11 use PublicInbox::WwwAtomStream;
  12 use PublicInbox::MID qw(mid2path mid_mime mid_clean mid_escape);
  13 use PublicInbox::MIME;
  14 require PublicInbox::Git;
  15 require PublicInbox::SearchThread;
  16 our $LIM = 200;
  17
  18 sub noop {}
  19
  20 sub sres_top_html {
  21         my ($ctx) = @_;
  22         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  23         my $code = 200;
  24
  25         # double the limit for expanded views:
  26         my $opts = {
  27                 limit => $LIM,
  28                 offset => $q->{o},
  29                 mset => 1,
  30                 relevance => $q->{r},
  31         };
  32         my ($mset, $total);
  33         eval {
  34                 $mset = $ctx->{srch}->query($q->{'q'}, $opts);
  35                 $total = $mset->get_matches_estimated;
  36         };
  37         my $err = $@;
  38         ctx_prepare($q, $ctx);
  39         my $cb;
  40         if ($err) {
  41                 $code = 400;
  42                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  43                 $cb = *noop;
  44         } elsif ($total == 0) {
  45                 $code = 404;
  46                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  47                 $cb = *noop;
  48         } else {
  49                 my $x = $q->{x};
  50                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  51
  52                 $ctx->{-html_tip} = search_nav_top($mset, $q) . "\n\n";
  53                 if ($x eq 't') {
  54                         $cb = mset_thread($ctx, $mset, $q);
  55                 } else {
  56                         $cb = mset_summary($ctx, $mset, $q);
  57                 }
  58         }
  59         PublicInbox::WwwStream->response($ctx, $code, $cb);
  60 }
  61
  62 # allow undef for individual doc loads...
  63 sub load_doc_retry {
  64         my ($srch, $mitem) = @_;
  65
  66         eval {
  67                 $srch->retry_reopen(sub {
  68                         PublicInbox::SearchMsg->load_doc($mitem->get_document)
  69                 });
  70         }
  71 }
  72
  73 # display non-threaded search results similar to what users expect from
  74 # regular WWW search engines:
  75 sub mset_summary {
  76         my ($ctx, $mset, $q) = @_;
  77
  78         my $total = $mset->get_matches_estimated;
  79         my $pad = length("$total");
  80         my $pfx = ' ' x $pad;
  81         my $res = \($ctx->{-html_tip});
  82         my $srch = $ctx->{srch};
  83         foreach my $m ($mset->items) {
  84                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
  85                 my $pct = $m->get_percent;
  86                 my $smsg = load_doc_retry($srch, $m);
  87                 unless ($smsg) {
  88                         eval {
  89                                 $m = "$m ".$m->get_docid . " expired\n";
  90                                 $ctx->{env}->{'psgi.errors'}->print($m);
  91                         };
  92                         next;
  93                 }
  94                 my $s = ascii_html($smsg->subject);
  95                 my $f = ascii_html($smsg->from_name);
  96                 my $ts = PublicInbox::View::fmt_ts($smsg->ts);
  97                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
  98                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
  99                         $s . "</a></b>\n";
 100                 $$res .= "$pfx  - by $f @ $ts UTC [$pct%]\n\n";
 101         }
 102         $$res .= search_nav_bot($mset, $q);
 103         *noop;
 104 }
 105
 106 sub err_txt {
 107         my ($ctx, $err) = @_;
 108         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 109         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 110         $err = ascii_html($err);
 111         "\nBad query: <b>$err</b>\n" .
 112                 qq{See <a\nhref="$u">$u</a> for help on using search};
 113 }
 114
 115 sub search_nav_top {
 116         my ($mset, $q) = @_;
 117
 118         my $rv = "<pre>Search results ordered by [";
 119         if ($q->{r}) {
 120                 my $d = $q->qs_html(r => 0);
 121                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 122         } else {
 123                 my $d = $q->qs_html(r => 1);
 124                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 125         }
 126
 127         $rv .= ']  view[';
 128
 129         my $x = $q->{x};
 130         if ($x eq '') {
 131                 my $t = $q->qs_html(x => 't');
 132                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">threaded</a>}
 133         } elsif ($q->{x} eq 't') {
 134                 my $s = $q->qs_html(x => '');
 135                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>threaded</b>};
 136         }
 137         my $A = $q->qs_html(x => 'A', r => undef);
 138         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 139 }
 140
 141 sub search_nav_bot {
 142         my ($mset, $q) = @_;
 143         my $total = $mset->get_matches_estimated;
 144         my $nr = scalar $mset->items;
 145         my $o = $q->{o};
 146         my $end = $o + $nr;
 147         my $beg = $o + 1;
 148         my $rv = '</pre><hr><pre>';
 149         if ($beg <= $end) {
 150                 $rv .= "Results $beg-$end of $total";
 151                 $rv .= ' (estimated)' if $end != $total;
 152         } else {
 153                 $rv .= "No more results, only $total";
 154         }
 155         my $n = $o + $LIM;
 156
 157         if ($n < $total) {
 158                 my $qs = $q->qs_html(o => $n);
 159                 $rv .= qq{  <a\nhref="?$qs"\nrel=next>next</a>}
 160         }
 161         if ($o > 0) {
 162                 $rv .= $n < $total ? '/' : '       ';
 163                 my $p = $o - $LIM;
 164                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 165                 $rv .= qq{<a\nhref="?$qs"\nrel=prev>prev</a>};
 166         }
 167         $rv .= '</pre>';
 168 }
 169
 170 sub sort_relevance {
 171         my ($pct) = @_;
 172         sub {
 173                 [ sort { (eval { $pct->{$b->topmost->{id}} } || 0)
 174                                 <=>
 175                         (eval { $pct->{$a->topmost->{id}} } || 0)
 176         } @{$_[0]} ] };
 177 }
 178
 179 sub mset_thread {
 180         my ($ctx, $mset, $q) = @_;
 181         my %pct;
 182         my $msgs = $ctx->{srch}->retry_reopen(sub { [ map {
 183                 my $i = $_;
 184                 my $smsg = PublicInbox::SearchMsg->load_doc($i->get_document);
 185                 $pct{$smsg->mid} = $i->get_percent;
 186                 $smsg;
 187         } ($mset->items) ]});
 188
 189         my $rootset = PublicInbox::SearchThread::thread($msgs,
 190                 $q->{r} ? sort_relevance(\%pct) : *PublicInbox::View::sort_ts);
 191         my $skel = search_nav_bot($mset, $q). "<pre>";
 192         my $inbox = $ctx->{-inbox};
 193         $ctx->{-upfx} = '';
 194         $ctx->{anchor_idx} = 1;
 195         $ctx->{cur_level} = 0;
 196         $ctx->{dst} = \$skel;
 197         $ctx->{mapping} = {};
 198         $ctx->{pct} = \%pct;
 199         $ctx->{prev_attr} = '';
 200         $ctx->{prev_level} = 0;
 201         $ctx->{seen} = {};
 202         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 203
 204         PublicInbox::View::walk_thread($rootset, $ctx,
 205                 *PublicInbox::View::pre_thread);
 206
 207         my $mime;
 208         sub {
 209                 return unless $msgs;
 210                 while ($mime = shift @$msgs) {
 211                         $mime = $inbox->msg_by_smsg($mime) and last;
 212                 }
 213                 if ($mime) {
 214                         $mime = PublicInbox::MIME->new($mime);
 215                         return PublicInbox::View::index_entry($mime, $ctx,
 216                                 scalar @$msgs);
 217                 }
 218                 $msgs = undef;
 219                 $skel .= "\n</pre>";
 220         };
 221 }
 222
 223 sub ctx_prepare {
 224         my ($q, $ctx) = @_;
 225         my $qh = ascii_html($q->{'q'});
 226         $ctx->{-q_value_html} = $qh;
 227         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 228         $ctx->{-title_html} = "$qh - search results";
 229         my $extra = '';
 230         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 231         if (my $x = $q->{x}) {
 232                 $x = ascii_html($x);
 233                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 234         }
 235         $ctx->{-extra_form_html} = $extra;
 236 }
 237
 238 sub adump {
 239         my ($cb, $mset, $q, $ctx) = @_;
 240         my $ibx = $ctx->{-inbox};
 241         my @items = $mset->items;
 242         $ctx->{search_query} = $q;
 243         my $srch = $ctx->{srch};
 244         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
 245                 while (my $x = shift @items) {
 246                         $x = load_doc_retry($srch, $x);
 247                         $x = $ibx->msg_by_smsg($x) and
 248                                         return PublicInbox::MIME->new($x);
 249                 }
 250                 return undef;
 251         });
 252 }
 253
 254 package PublicInbox::SearchQuery;
 255 use strict;
 256 use warnings;
 257 use PublicInbox::Hval;
 258 use PublicInbox::MID qw(mid_escape);
 259
 260 sub new {
 261         my ($class, $qp) = @_;
 262
 263         my $r = $qp->{r};
 264         bless {
 265                 q => $qp->{'q'},
 266                 x => $qp->{x} || '',
 267                 o => (($qp->{o} || '0') =~ /(\d+)/),
 268                 r => (defined $r && $r ne '0'),
 269         }, $class;
 270 }
 271
 272 sub qs_html {
 273         my ($self, %over) = @_;
 274
 275         if (keys %over) {
 276                 my $tmp = bless { %$self }, ref($self);
 277                 foreach my $k (keys %over) {
 278                         $tmp->{$k} = $over{$k};
 279                 }
 280                 $self = $tmp;
 281         }
 282
 283         my $q = mid_escape($self->{'q'});
 284         $q =~ s/%20/+/g; # improve URL readability
 285         my $qs = "q=$q";
 286
 287         if (my $o = $self->{o}) { # ignore o == 0
 288                 $qs .= "&amp;o=$o";
 289         }
 290         if (my $r = $self->{r}) {
 291                 $qs .= "&amp;r";
 292         }
 293         if (my $x = $self->{x}) {
 294                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A');
 295         }
 296         $qs;
 297 }
 298
 299 1;