lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use URI::Escape qw(uri_unescape uri_escape);
   9 use PublicInbox::SearchMsg;
  10 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  11 use PublicInbox::View;
  12 use PublicInbox::WwwAtomStream;
  13 use PublicInbox::MID qw(MID_ESC);
  14 use PublicInbox::MIME;
  15 require PublicInbox::Git;
  16 require PublicInbox::SearchThread;
  17 our $LIM = 200;
  18
  19 sub noop {}
  20
  21 sub mbox_results {
  22         my ($ctx) = @_;
  23         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  24         my $x = $q->{x};
  25         require PublicInbox::Mbox;
  26         return PublicInbox::Mbox::mbox_all($ctx, $q->{'q'}) if $x eq 'm';
  27         sres_top_html($ctx);
  28 }
  29
  30 sub sres_top_html {
  31         my ($ctx) = @_;
  32         my $srch = $ctx->{-inbox}->search or
  33                 return PublicInbox::WWW::need($ctx, 'Search');
  34         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  35         my $x = $q->{x};
  36         my $query = $q->{'q'};
  37         my $o = $q->{o};
  38         my $asc;
  39         if ($o < 0) {
  40                 $asc = 1;
  41                 $o = -($o + 1); # so [-1] is the last element, like Perl lists
  42         }
  43
  44         my $code = 200;
  45         # double the limit for expanded views:
  46         my $opts = {
  47                 limit => $q->{l},
  48                 offset => $o,
  49                 mset => 1,
  50                 relevance => $q->{r},
  51                 asc => $asc,
  52         };
  53         my ($mset, $total, $err, $cb);
  54 retry:
  55         eval {
  56                 $mset = $srch->query($query, $opts);
  57                 $total = $mset->get_matches_estimated;
  58         };
  59         $err = $@;
  60         ctx_prepare($q, $ctx);
  61         if ($err) {
  62                 $code = 400;
  63                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  64                 $cb = *noop;
  65         } elsif ($total == 0) {
  66                 if (defined($ctx->{-uxs_retried})) {
  67                         # undo retry damage:
  68                         $q->{'q'} = $ctx->{-uxs_retried};
  69                 } elsif (index($q->{'q'}, '%') >= 0) {
  70                         $ctx->{-uxs_retried} = $q->{'q'};
  71                         $q->{'q'} = uri_unescape($q->{'q'});
  72                         goto retry;
  73                 }
  74                 $code = 404;
  75                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  76                 $cb = *noop;
  77         } else {
  78                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  79
  80                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx);
  81                 if ($x eq 't') {
  82                         $cb = mset_thread($ctx, $mset, $q);
  83                 } else {
  84                         $cb = mset_summary($ctx, $mset, $q);
  85                 }
  86         }
  87         PublicInbox::WwwStream->response($ctx, $code, $cb);
  88 }
  89
  90 # allow undef for individual doc loads...
  91 sub load_doc_retry {
  92         my ($srch, $mitem) = @_;
  93
  94         eval {
  95                 $srch->retry_reopen(sub {
  96                         PublicInbox::SearchMsg->load_doc($mitem->get_document)
  97                 });
  98         }
  99 }
 100
 101 # display non-nested search results similar to what users expect from
 102 # regular WWW search engines:
 103 sub mset_summary {
 104         my ($ctx, $mset, $q) = @_;
 105
 106         my $total = $mset->get_matches_estimated;
 107         my $pad = length("$total");
 108         my $pfx = ' ' x $pad;
 109         my $res = \($ctx->{-html_tip});
 110         my $ibx = $ctx->{-inbox};
 111         my $srch = $ibx->search;
 112         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
 113         foreach my $m ($mset->items) {
 114                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
 115                 my $pct = $m->get_percent;
 116                 my $smsg = load_doc_retry($srch, $m);
 117                 unless ($smsg) {
 118                         eval {
 119                                 $m = "$m ".$m->get_docid . " expired\n";
 120                                 $ctx->{env}->{'psgi.errors'}->print($m);
 121                         };
 122                         next;
 123                 }
 124                 my $s = ascii_html($smsg->subject);
 125                 my $f = ascii_html($smsg->from_name);
 126                 if ($obfs_ibx) {
 127                         obfuscate_addrs($obfs_ibx, $s);
 128                         obfuscate_addrs($obfs_ibx, $f);
 129                 }
 130                 my $date = PublicInbox::View::fmt_ts($smsg->ds);
 131                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
 132                 $s = '(no subject)' if $s eq '';
 133                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 134                         $s . "</a></b>\n";
 135                 $$res .= "$pfx  - by $f @ $date UTC [$pct%]\n\n";
 136         }
 137         $$res .= search_nav_bot($mset, $q);
 138         *noop;
 139 }
 140
 141 sub err_txt {
 142         my ($ctx, $err) = @_;
 143         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 144         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 145         $err = ascii_html($err);
 146         "\nBad query: <b>$err</b>\n" .
 147                 qq{See <a\nhref="$u">$u</a> for help on using search};
 148 }
 149
 150 sub search_nav_top {
 151         my ($mset, $q, $ctx) = @_;
 152         my $m = $q->qs_html(x => 'm', r => undef);
 153         my $rv = qq{<form\naction="?$m"\nmethod="post"><pre>};
 154         my $initial_q = $ctx->{-uxs_retried};
 155         if (defined $initial_q) {
 156                 my $rewritten = $q->{'q'};
 157                 utf8::decode($initial_q);
 158                 utf8::decode($rewritten);
 159                 $initial_q = ascii_html($initial_q);
 160                 $rewritten = ascii_html($rewritten);
 161                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 162                 $rv .= " returned no results, used:\n";
 163                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 164         }
 165
 166         $rv .= 'Search results ordered by [';
 167         if ($q->{r}) {
 168                 my $d = $q->qs_html(r => 0);
 169                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 170         } else {
 171                 my $d = $q->qs_html(r => 1);
 172                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 173         }
 174
 175         $rv .= ']  view[';
 176
 177         my $x = $q->{x};
 178         if ($x eq '') {
 179                 my $t = $q->qs_html(x => 't');
 180                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 181         } elsif ($q->{x} eq 't') {
 182                 my $s = $q->qs_html(x => '');
 183                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 184         }
 185         my $A = $q->qs_html(x => 'A', r => undef);
 186         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 187         $rv .= qq{\n\t\t\t\t\t\tdownload: };
 188         $rv .= qq{<input\ntype=submit\nvalue="mbox.gz"/></pre></form><pre>};
 189 }
 190
 191 sub search_nav_bot {
 192         my ($mset, $q) = @_;
 193         my $total = $mset->get_matches_estimated;
 194         my $l = $q->{l};
 195         my $rv = '</pre><hr><pre id=t>';
 196         my $o = $q->{o};
 197         my $off = $o < 0 ? -($o + 1) : $o;
 198         my $end = $off + $mset->size;
 199         my $beg = $off + 1;
 200
 201         if ($beg <= $end) {
 202                 $rv .= "Results $beg-$end of $total";
 203                 $rv .= ' (estimated)' if $end != $total;
 204         } else {
 205                 $rv .= "No more results, only $total";
 206         }
 207         my ($next, $join, $prev);
 208
 209         if ($o >= 0) { # sort descending
 210                 my $n = $o + $l;
 211                 if ($n < $total) {
 212                         $next = $q->qs_html(o => $n, l => $l);
 213                 }
 214                 if ($o > 0) {
 215                         $join = $n < $total ? '/' : '       ';
 216                         my $p = $o - $l;
 217                         $prev = $q->qs_html(o => ($p > 0 ? $p : 0));
 218                 }
 219         } else { # o < 0, sort ascending
 220                 my $n = $o - $l;
 221
 222                 if (-$n < $total) {
 223                         $next = $q->qs_html(o => $n, l => $l);
 224                 }
 225                 if ($o < -1) {
 226                         $join = -$n < $total ? '/' : '       ';
 227                         my $p = $o + $l;
 228                         $prev = $q->qs_html(o => ($p < 0 ? $p : 0));
 229                 }
 230         }
 231
 232         $rv .= qq{  <a\nhref="?$next"\nrel=next>next</a>} if $next;
 233         $rv .= $join if $join;
 234         $rv .= qq{<a\nhref="?$prev"\nrel=prev>prev</a>} if $prev;
 235         $rv .= '</pre>';
 236 }
 237
 238 sub sort_relevance {
 239         my ($pct) = @_;
 240         sub {
 241                 [ sort { (eval { $pct->{$b->topmost->{id}} } || 0)
 242                                 <=>
 243                         (eval { $pct->{$a->topmost->{id}} } || 0)
 244         } @{$_[0]} ] };
 245 }
 246
 247 sub mset_thread {
 248         my ($ctx, $mset, $q) = @_;
 249         my %pct;
 250         my $ibx = $ctx->{-inbox};
 251         my $msgs = $ibx->search->retry_reopen(sub { [ map {
 252                 my $i = $_;
 253                 my $smsg = PublicInbox::SearchMsg->load_doc($i->get_document);
 254                 $pct{$smsg->mid} = $i->get_percent;
 255                 $smsg;
 256         } ($mset->items) ]});
 257         my $r = $q->{r};
 258         my $rootset = PublicInbox::SearchThread::thread($msgs,
 259                 $r ? sort_relevance(\%pct) : *PublicInbox::View::sort_ds,
 260                 $ctx);
 261         my $skel = search_nav_bot($mset, $q). "<pre>";
 262         $ctx->{-upfx} = '';
 263         $ctx->{anchor_idx} = 1;
 264         $ctx->{cur_level} = 0;
 265         $ctx->{dst} = \$skel;
 266         $ctx->{mapping} = {};
 267         $ctx->{pct} = \%pct;
 268         $ctx->{prev_attr} = '';
 269         $ctx->{prev_level} = 0;
 270         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 271
 272         # reduce hash lookups in skel_dump
 273         $ctx->{-obfuscate} = $ctx->{-inbox}->{obfuscate};
 274         PublicInbox::View::walk_thread($rootset, $ctx,
 275                 *PublicInbox::View::pre_thread);
 276
 277         @$msgs = reverse @$msgs if $r;
 278         sub {
 279                 return unless $msgs;
 280                 my $smsg;
 281                 while (my $m = pop @$msgs) {
 282                         $smsg = $ibx->smsg_mime($m) and last;
 283                 }
 284                 if ($smsg) {
 285                         return PublicInbox::View::index_entry($smsg, $ctx,
 286                                 scalar @$msgs);
 287                 }
 288                 $msgs = undef;
 289                 $skel .= "\n</pre>";
 290         };
 291 }
 292
 293 sub ctx_prepare {
 294         my ($q, $ctx) = @_;
 295         my $qh = $q->{'q'};
 296         utf8::decode($qh);
 297         $qh = ascii_html($qh);
 298         $ctx->{-q_value_html} = $qh;
 299         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 300         $ctx->{-title_html} = "$qh - search results";
 301         my $extra = '';
 302         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 303         if (my $x = $q->{x}) {
 304                 $x = ascii_html($x);
 305                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 306         }
 307         $ctx->{-extra_form_html} = $extra;
 308 }
 309
 310 sub adump {
 311         my ($cb, $mset, $q, $ctx) = @_;
 312         my $ibx = $ctx->{-inbox};
 313         my @items = $mset->items;
 314         $ctx->{search_query} = $q;
 315         my $srch = $ibx->search;
 316         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
 317                 while (my $x = shift @items) {
 318                         $x = load_doc_retry($srch, $x);
 319                         $x = $ibx->smsg_mime($x) and return $x;
 320                 }
 321                 return undef;
 322         });
 323 }
 324
 325 package PublicInbox::SearchQuery;
 326 use strict;
 327 use warnings;
 328 use URI::Escape qw(uri_escape);
 329 use PublicInbox::Hval;
 330 use PublicInbox::MID qw(MID_ESC);
 331
 332 sub new {
 333         my ($class, $qp) = @_;
 334
 335         my $r = $qp->{r};
 336         my ($l) = (($qp->{l} || '') =~ /([0-9]+)/);
 337         $l = $LIM if !$l || $l > $LIM;
 338         bless {
 339                 q => $qp->{'q'},
 340                 x => $qp->{x} || '',
 341                 o => (($qp->{o} || '0') =~ /(-?[0-9]+)/),
 342                 l => $l,
 343                 r => (defined $r && $r ne '0'),
 344         }, $class;
 345 }
 346
 347 sub qs_html {
 348         my ($self, %over) = @_;
 349
 350         if (keys %over) {
 351                 my $tmp = bless { %$self }, ref($self);
 352                 foreach my $k (keys %over) {
 353                         $tmp->{$k} = $over{$k};
 354                 }
 355                 $self = $tmp;
 356         }
 357
 358         my $q = uri_escape($self->{'q'}, MID_ESC);
 359         $q =~ s/%20/+/g; # improve URL readability
 360         my $qs = "q=$q";
 361
 362         if (my $o = $self->{o}) { # ignore o == 0
 363                 $qs .= "&amp;o=$o";
 364         }
 365         if (my $l = $self->{l}) {
 366                 $qs .= "&amp;l=$l" unless $l == $LIM;
 367         }
 368         if (my $r = $self->{r}) {
 369                 $qs .= "&amp;r";
 370         }
 371         if (my $x = $self->{x}) {
 372                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A' || $x eq 'm');
 373         }
 374         $qs;
 375 }
 376
 377 1;