lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::SearchMsg;
   9 use PublicInbox::Hval;
  10 use PublicInbox::View;
  11 use PublicInbox::MID qw(mid2path mid_clean);
  12 use Email::MIME;
  13 require PublicInbox::Git;
  14 our $LIM = 50;
  15
  16 sub sres_top_html {
  17         my ($ctx) = @_;
  18         my $q = PublicInbox::SearchQuery->new($ctx->{cgi});
  19         my $code = 200;
  20
  21         # double the limit for expanded views:
  22         my $opts = {
  23                 limit => $LIM,
  24                 offset => $q->{o},
  25                 mset => 1,
  26                 relevance => $q->{r},
  27         };
  28         my ($mset, $total);
  29
  30         eval {
  31                 $mset = $ctx->{srch}->query($q->{q}, $opts);
  32                 $total = $mset->get_matches_estimated;
  33         };
  34         my $err = $@;
  35         my $res = html_start($q, $ctx) . '<pre>';
  36         if ($err) {
  37                 $code = 400;
  38                 $res .= err_txt($err) . "</pre><hr /><pre>" . foot($ctx);
  39         } elsif ($total == 0) {
  40                 $code = 404;
  41                 $res .= "\n\n[No results found]</pre><hr /><pre>".foot($ctx);
  42         } else {
  43                 my $x = $q->{x};
  44                 return sub { adump($_[0], $mset, $q, $ctx) } if ($x eq 'A');
  45
  46                 $res .= search_nav_top($mset, $q) . "\n\n";
  47                 if ($x eq 't') {
  48                         return sub { tdump($_[0], $res, $mset, $q, $ctx) };
  49                 }
  50                 dump_mset(\$res, $mset);
  51                 $res .= '</pre>' . search_nav_bot($mset, $q) .
  52                         "\n\n" . foot($ctx);
  53         }
  54
  55         $res .= "</pre></body></html>";
  56         [$code, ['Content-Type'=>'text/html; charset=UTF-8'], [$res]];
  57 }
  58
  59 sub dump_mset {
  60         my ($res, $mset) = @_;
  61
  62         my $total = $mset->get_matches_estimated;
  63         my $pad = length("$total");
  64         my $pfx = ' ' x $pad;
  65         foreach my $m ($mset->items) {
  66                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
  67                 my $pct = $m->get_percent;
  68                 my $smsg = PublicInbox::SearchMsg->load_doc($m->get_document);
  69                 my $s = PublicInbox::Hval->new_oneline($smsg->subject);
  70                 my $f = $smsg->from_name;
  71                 $f = PublicInbox::Hval->new_oneline($f)->as_html;
  72                 my $ts = PublicInbox::View::fmt_ts($smsg->ts);
  73                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->as_href;
  74                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
  75                         $s->as_html . "</a></b>\n";
  76                 $$res .= "$pfx  - by $f @ $ts UTC [$pct%]\n\n";
  77         }
  78 }
  79
  80 sub err_txt {
  81         my ($err) = @_;
  82         my $u = 'http://xapian.org/docs/queryparser.html';
  83         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
  84         $err = PublicInbox::Hval->new_oneline($err)->as_html;
  85         "\n\nBad query: <b>$err</b>\n" .
  86                 qq{See <a\nhref="$u">$u</a> for Xapian query syntax};
  87 }
  88
  89 sub search_nav_top {
  90         my ($mset, $q) = @_;
  91
  92         my $rv = "Search results ordered by [";
  93         if ($q->{r}) {
  94                 my $d = $q->qs_html(r => 0);
  95                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
  96         } else {
  97                 my $d = $q->qs_html(r => 1);
  98                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
  99         }
 100
 101         $rv .= ']  view[';
 102
 103         my $x = $q->{x};
 104         if ($x eq '') {
 105                 my $t = $q->qs_html(x => 't');
 106                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">threaded</a>}
 107         } elsif ($q->{x} eq 't') {
 108                 my $s = $q->qs_html(x => '');
 109                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>threaded</b>};
 110         }
 111         my $A = $q->qs_html(x => 'A', r => undef);
 112         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 113 }
 114
 115 sub search_nav_bot {
 116         my ($mset, $q) = @_;
 117         my $total = $mset->get_matches_estimated;
 118         my $nr = scalar $mset->items;
 119         my $o = $q->{o};
 120         my $end = $o + $nr;
 121         my $beg = $o + 1;
 122         my $rv = "<hr /><pre>Results $beg-$end of $total";
 123         my $n = $o + $LIM;
 124
 125         if ($n < $total) {
 126                 my $qs = $q->qs_html(o => $n);
 127                 $rv .= qq{, <a\nhref="?$qs">next</a>}
 128         }
 129         if ($o > 0) {
 130                 $rv .= $n < $total ? '/' : ',      ';
 131                 my $p = $o - $LIM;
 132                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 133                 $rv .= qq{<a\nhref="?$qs">prev</a>};
 134         }
 135         $rv;
 136 }
 137
 138 sub tdump {
 139         my ($cb, $res, $mset, $q, $ctx) = @_;
 140         my $fh = $cb->([200, ['Content-Type'=>'text/html; charset=UTF-8']]);
 141         $fh->write($res .= '</pre>');
 142         my %pct;
 143         my @m = map {
 144                 my $i = $_;
 145                 my $m = PublicInbox::SearchMsg->load_doc($i->get_document);
 146                 $pct{$m->mid} = $i->get_percent;
 147                 $m = $m->mini_mime;
 148                 $m;
 149         } ($mset->items);
 150
 151         require PublicInbox::Thread;
 152         my $th = PublicInbox::Thread->new(@m);
 153         {
 154                 no warnings 'once';
 155                 $Mail::Thread::nosubject = 0;
 156         }
 157         $th->thread;
 158         if ($q->{r}) {
 159                 $th->order(sub {
 160                         sort { (eval { $pct{$b->topmost->messageid} } || 0)
 161                                         <=>
 162                                 (eval { $pct{$a->topmost->messageid} } || 0)
 163                         } @_;
 164                 });
 165         } else {
 166                 no warnings 'once';
 167                 $th->order(*PublicInbox::View::rsort_ts);
 168         }
 169
 170         my $git = $ctx->{git} ||= PublicInbox::Git->new($ctx->{git_dir});
 171         my $state = {
 172                 ctx => $ctx,
 173                 anchor_idx => 0,
 174                 pct => \%pct,
 175                 cur_level => 0
 176         };
 177         $ctx->{searchview} = 1;
 178         tdump_ent($fh, $git, $state, $_, 0) for $th->rootset;
 179         PublicInbox::View::thread_adj_level($fh, $state, 0);
 180         Email::Address->purge_cache;
 181
 182         $fh->write(search_nav_bot($mset, $q). "\n\n" .
 183                         foot($ctx). '</pre></body></html>');
 184
 185         $fh->close;
 186 }
 187
 188 sub tdump_ent {
 189         my ($fh, $git, $state, $node, $level) = @_;
 190         return unless $node;
 191         my $mime = $node->message;
 192
 193         if ($mime) {
 194                 # lazy load the full message from mini_mime:
 195                 my $mid = $mime->header('Message-ID');
 196                 $mime = eval {
 197                         my $path = mid2path(mid_clean($mid));
 198                         Email::MIME->new($git->cat_file('HEAD:'.$path));
 199                 };
 200         }
 201         if ($mime) {
 202                 my $end =
 203                   PublicInbox::View::thread_adj_level($fh, $state, $level);
 204                 PublicInbox::View::index_entry($fh, $mime, $level, $state);
 205                 $fh->write($end) if $end;
 206         } else {
 207                 my $mid = $node->messageid;
 208                 PublicInbox::View::ghost_flush($fh, $state, '', $mid, $level);
 209         }
 210         tdump_ent($fh, $git, $state, $node->child, $level + 1);
 211         tdump_ent($fh, $git, $state, $node->next, $level);
 212 }
 213
 214 sub foot {
 215         my ($ctx) = @_;
 216         my $foot = $ctx->{footer} || '';
 217         qq{Back to <a\nhref=".">index</a>.\n$foot};
 218 }
 219
 220 sub html_start {
 221         my ($q, $ctx) = @_;
 222         my $query = PublicInbox::Hval->new_oneline($q->{q});
 223
 224         my $qh = $query->as_html;
 225         my $A = $q->qs_html(x => 'A', r => undef);
 226         my $res = '<html><head>' . PublicInbox::Hval::STYLE .
 227                 "<title>$qh - search results</title>" .
 228                 qq{<link\nrel=alternate\ntitle="Atom feed"\n} .
 229                 qq!href="?$A"\ntype="application/atom+xml"/></head>! .
 230                 qq{<body><form\naction="">} .
 231                 qq{<input\nname=q\nvalue="$qh"\ntype=text />};
 232
 233         $res .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 234         if (my $x = $q->{x}) {
 235                 my $xh = PublicInbox::Hval->new_oneline($x)->as_html;
 236                 $res .= qq{<input\ntype=hidden\nname=x\nvalue="$xh" />};
 237         }
 238
 239         $res .= qq{<input\ntype=submit\nvalue=search /></form>};
 240 }
 241
 242 sub adump {
 243         my ($cb, $mset, $q, $ctx) = @_;
 244         my $fh = $cb->([ 200, ['Content-Type' => 'application/atom+xml']]);
 245         my $git = $ctx->{git} ||= PublicInbox::Git->new($ctx->{git_dir});
 246         my $feed_opts = PublicInbox::Feed::get_feedopts($ctx);
 247         my $x = PublicInbox::Hval->new_oneline($q->{q})->as_html;
 248         $x = qq{$x - search results};
 249         $feed_opts->{atomurl} = $feed_opts->{url} . '?'. $q->qs_html;
 250         $feed_opts->{url} .= '?'. $q->qs_html(x => undef);
 251         $x = PublicInbox::Feed::atom_header($feed_opts, $x);
 252         $fh->write($x. PublicInbox::Feed::feed_updated());
 253
 254         for ($mset->items) {
 255                 $x = PublicInbox::SearchMsg->load_doc($_->get_document)->mid;
 256                 $x = mid2path($x);
 257                 PublicInbox::Feed::add_to_feed($feed_opts, $fh, $x, $git);
 258         }
 259         PublicInbox::Feed::end_feed($fh);
 260 }
 261
 262 package PublicInbox::SearchQuery;
 263 use strict;
 264 use warnings;
 265 use PublicInbox::Hval;
 266
 267 sub new {
 268         my ($class, $cgi) = @_;
 269         my $r = $cgi->param('r');
 270         bless {
 271                 q => $cgi->param('q'),
 272                 x => $cgi->param('x') || '',
 273                 o => int($cgi->param('o') || 0) || 0,
 274                 r => (defined $r && $r ne '0'),
 275         }, $class;
 276 }
 277
 278 sub qs_html {
 279         my ($self, %over) = @_;
 280
 281         if (keys %over) {
 282                 my $tmp = bless { %$self }, ref($self);
 283                 foreach my $k (keys %over) {
 284                         $tmp->{$k} = $over{$k};
 285                 }
 286                 $self = $tmp;
 287         }
 288
 289         my $q = PublicInbox::Hval->new($self->{q})->as_href;
 290         $q =~ s/%20/+/g; # improve URL readability
 291         my $qs = "q=$q";
 292
 293         if (my $o = $self->{o}) { # ignore o == 0
 294                 $qs .= "&amp;o=$o";
 295         }
 296         if (my $r = $self->{r}) {
 297                 $qs .= "&amp;r";
 298         }
 299         if (my $x = $self->{x}) {
 300                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A');
 301         }
 302         $qs;
 303 }
 304
 305 1;