lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::SearchMsg;
   9 use PublicInbox::Hval;
  10 use PublicInbox::View;
  11 use PublicInbox::MID qw(mid2path mid_clean);
  12 use Email::MIME;
  13 require PublicInbox::Git;
  14 our $LIM = 50;
  15
  16 sub sres_top_html {
  17         my ($ctx) = @_;
  18         my $q = PublicInbox::SearchQuery->new($ctx->{cgi});
  19         my $code = 200;
  20
  21         # double the limit for expanded views:
  22         my $opts = {
  23                 limit => $LIM,
  24                 offset => $q->{o},
  25                 mset => 1,
  26                 relevance => $q->{r},
  27         };
  28         my ($mset, $total);
  29
  30         eval {
  31                 $mset = $ctx->{srch}->query($q->{q}, $opts);
  32                 $total = $mset->get_matches_estimated;
  33         };
  34         my $err = $@;
  35         my $res = html_start($q, $ctx) . '<pre>'
  36         if ($err) {
  37                 $code = 400;
  38                 $res .= err_txt($err) . "</pre><hr /><pre>" . foot($ctx);
  39         } elsif ($total == 0) {
  40                 $code = 404;
  41                 $res .= "\n\n[No results found]</pre><hr /><pre>".foot($ctx);
  42         } else {
  43                 my $x = $q->{x};
  44                 return sub { adump($_[0], $mset, $q, $ctx) } if ($x eq 'A');
  45
  46                 $res .= search_nav_top($mset, $q);
  47                 if ($x eq 't') {
  48                         return sub { tdump($_[0], $res, $mset, $q, $ctx) };
  49                 }
  50                 $res .= "\n\n";
  51                 dump_mset(\$res, $mset);
  52                 $res .= search_nav_bot($mset, $q) . "\n\n" . foot($ctx);
  53         }
  54
  55         $res .= "</pre></body></html>";
  56         [$code, ['Content-Type'=>'text/html; charset=UTF-8'], [$res]];
  57 }
  58
  59 sub dump_mset {
  60         my ($res, $mset) = @_;
  61
  62         my $total = $mset->get_matches_estimated;
  63         my $pad = length("$total");
  64         my $pfx = ' ' x $pad;
  65         foreach my $m ($mset->items) {
  66                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
  67                 my $pct = $m->get_percent;
  68                 my $smsg = PublicInbox::SearchMsg->load_doc($m->get_document);
  69                 my $s = PublicInbox::Hval->new_oneline($smsg->subject);
  70                 my $f = $smsg->from_name;
  71                 $f = PublicInbox::Hval->new_oneline($f)->as_html;
  72                 my $ts = PublicInbox::View::fmt_ts($smsg->ts);
  73                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->as_href;
  74                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
  75                         $s->as_html . "</a></b>\n";
  76                 $$res .= "$pfx  - by $f @ $ts UTC [$pct%]\n\n";
  77         }
  78 }
  79
  80 sub err_txt {
  81         my ($err) = @_;
  82         my $u = 'http://xapian.org/docs/queryparser.html';
  83         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
  84         $err = PublicInbox::Hval->new_oneline($err)->as_html;
  85         "\n\nBad query: <b>$err</b>\n" .
  86                 qq{See <a\nhref="$u">$u</a> for Xapian query syntax};
  87 }
  88
  89 sub search_nav_top {
  90         my ($mset, $q) = @_;
  91
  92         my $rv = "Search results ordered by [";
  93         if ($q->{r}) {
  94                 my $d = $q->qs_html(r => 0);
  95                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
  96         } else {
  97                 my $d = $q->qs_html(r => 1);
  98                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
  99         }
 100
 101         $rv .= ']  view[';
 102
 103         my $x = $q->{x};
 104         if ($x eq '') {
 105                 my $t = $q->qs_html(x => 't');
 106                 $rv .= qq{<b>summary</b>|};
 107                 $rv .= qq{<a\nhref="?$t">threaded</a>}
 108         } elsif ($q->{x} eq 't') {
 109                 my $s = $q->qs_html(x => '');
 110                 $rv .= qq{<a\nhref="?$s">summary</a>|};
 111                 $rv .= qq{<b>threaded</b>};
 112         }
 113         my $A = $q->qs_html(x => 'A', r => undef);
 114         $rv .= qq{|<a\nhref="?$A">Atom</a>};
 115         $rv .= ']';
 116 }
 117
 118 sub search_nav_bot {
 119         my ($mset, $q) = @_;
 120         my $total = $mset->get_matches_estimated;
 121         my $nr = scalar $mset->items;
 122         my $o = $q->{o};
 123         my $end = $o + $nr;
 124         my $beg = $o + 1;
 125         my $rv = "<hr /><pre>Results $beg-$end of $total";
 126         my $n = $o + $LIM;
 127
 128         if ($n < $total) {
 129                 my $qs = $q->qs_html(o => $n);
 130                 $rv .= qq{, <a\nhref="?$qs">next</a>}
 131         }
 132         if ($o > 0) {
 133                 $rv .= $n < $total ? '/' : ',      ';
 134                 my $p = $o - $LIM;
 135                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 136                 $rv .= qq{<a\nhref="?$qs">prev</a>};
 137         }
 138         $rv;
 139 }
 140
 141 sub tdump {
 142         my ($cb, $res, $mset, $q, $ctx) = @_;
 143         my $fh = $cb->([200, ['Content-Type'=>'text/html; charset=UTF-8']]);
 144         $fh->write($res);
 145         my %pct;
 146         my @m = map {
 147                 my $i = $_;
 148                 my $m = PublicInbox::SearchMsg->load_doc($i->get_document);
 149                 $pct{$m->mid} = $i->get_percent;
 150                 $m = $m->mini_mime;
 151                 $m;
 152         } ($mset->items);
 153
 154         require PublicInbox::Thread;
 155         my $th = PublicInbox::Thread->new(@m);
 156         {
 157                 no warnings 'once';
 158                 $Mail::Thread::nosubject = 0;
 159         }
 160         $th->thread;
 161         if ($q->{r}) {
 162                 $th->order(sub {
 163                         sort { (eval { $pct{$b->topmost->messageid} } || 0)
 164                                         <=>
 165                                 (eval { $pct{$a->topmost->messageid} } || 0)
 166                         } @_;
 167                 });
 168         } else {
 169                 no warnings 'once';
 170                 $th->order(*PublicInbox::View::rsort_ts);
 171         }
 172
 173         my $git = $ctx->{git} ||= PublicInbox::Git->new($ctx->{git_dir});
 174         my $state = { ctx => $ctx, anchor_idx => 0, pct => \%pct };
 175         $ctx->{searchview} = 1;
 176         tdump_ent($fh, $git, $state, $_, 0) for $th->rootset;
 177         Email::Address->purge_cache;
 178
 179         $fh->write(search_nav_bot($mset, $q). "\n\n" .
 180                         foot($ctx). '</pre></body></html>');
 181
 182         $fh->close;
 183 }
 184
 185 sub tdump_ent {
 186         my ($fh, $git, $state, $node, $level) = @_;
 187         return unless $node;
 188         my $mime = $node->message;
 189
 190         if ($mime) {
 191                 # lazy load the full message from mini_mime:
 192                 my $mid = $mime->header('Message-ID');
 193                 $mime = eval {
 194                         my $path = mid2path(mid_clean($mid));
 195                         Email::MIME->new($git->cat_file('HEAD:'.$path));
 196                 };
 197         }
 198         if ($mime) {
 199                 PublicInbox::View::index_entry($fh, $mime, $level, $state);
 200         } else {
 201                 my $mid = $node->messageid;
 202                 $fh->write(PublicInbox::View::ghost_table('', $mid, $level));
 203         }
 204         tdump_ent($fh, $git, $state, $node->child, $level + 1);
 205         tdump_ent($fh, $git, $state, $node->next, $level);
 206 }
 207
 208 sub foot {
 209         my ($ctx) = @_;
 210         my $foot = $ctx->{footer} || '';
 211         qq{Back to <a\nhref=".">index</a>.\n$foot};
 212 }
 213
 214 sub html_start {
 215         my ($q, $ctx) = @_;
 216         my $query = PublicInbox::Hval->new_oneline($q->{q});
 217
 218         my $qh = $query->as_html;
 219         my $A = $q->qs_html(x => 'A', r => undef);
 220         my $res = "<html><head><title>$qh - search results</title>" .
 221                 qq{<link\nrel=alternate\ntitle="Atom feed"\n} .
 222                 qq!href="?$A"\ntype="application/atom+xml"/></head>! .
 223                 qq{<body><form\naction="">} .
 224                 qq{<input\nname=q\nvalue="$qh"\ntype=text />};
 225
 226         $res .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 227         if (my $x = $q->{x}) {
 228                 my $xh = PublicInbox::Hval->new_oneline($x)->as_html;
 229                 $res .= qq{<input\ntype=hidden\nname=x\nvalue="$xh" />};
 230         }
 231
 232         $res .= qq{<input\ntype=submit\nvalue=search /></form>};
 233 }
 234
 235 sub adump {
 236         my ($cb, $mset, $q, $ctx) = @_;
 237         my $fh = $cb->([ 200, ['Content-Type' => 'application/atom+xml']]);
 238         my $git = $ctx->{git_dir} ||= PublicInbox::Git->new($ctx->{git_dir});
 239         my $feed_opts = PublicInbox::Feed::get_feedopts($ctx);
 240         my $x = PublicInbox::Hval->new_oneline($q->{q})->as_html;
 241         $x = qq{$x - search results};
 242         $feed_opts->{atomurl} = $feed_opts->{url} . '?'. $q->qs_html;
 243         $feed_opts->{url} .= '?'. $q->qs_html(x => undef);
 244         $x = PublicInbox::Feed::atom_header($feed_opts, $x);
 245         $fh->write($x. PublicInbox::Feed::feed_updated());
 246
 247         for ($mset->items) {
 248                 $x = PublicInbox::SearchMsg->load_doc($_->get_document)->mid;
 249                 $x = mid2path($x);
 250                 PublicInbox::Feed::add_to_feed($feed_opts, $fh, $x, $git);
 251         }
 252         PublicInbox::Feed::end_feed($fh);
 253 }
 254
 255 package PublicInbox::SearchQuery;
 256 use strict;
 257 use warnings;
 258 use PublicInbox::Hval;
 259
 260 sub new {
 261         my ($class, $cgi) = @_;
 262         my $r = $cgi->param('r');
 263         bless {
 264                 q => $cgi->param('q'),
 265                 x => $cgi->param('x') || '',
 266                 o => int($cgi->param('o') || 0) || 0,
 267                 r => (defined $r && $r ne '0'),
 268         }, $class;
 269 }
 270
 271 sub qs_html {
 272         my ($self, %over) = @_;
 273
 274         if (keys %over) {
 275                 my $tmp = bless { %$self }, ref($self);
 276                 foreach my $k (keys %over) {
 277                         $tmp->{$k} = $over{$k};
 278                 }
 279                 $self = $tmp;
 280         }
 281
 282         my $q = PublicInbox::Hval->new($self->{q})->as_href;
 283         $q =~ s/%20/+/g; # improve URL readability
 284         my $qs = "q=$q";
 285
 286         if (my $o = $self->{o}) { # ignore o == 0
 287                 $qs .= "&amp;o=$o";
 288         }
 289         if (my $r = $self->{r}) {
 290                 $qs .= "&amp;r";
 291         }
 292         if (my $x = $self->{x}) {
 293                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A');
 294         }
 295         $qs;
 296 }
 297
 298 1;