lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 package PublicInbox::SearchView;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::SearchMsg;
   7 use PublicInbox::Hval;
   8 use PublicInbox::View;
   9 use PublicInbox::MID qw(mid2path mid_clean);
  10 use Email::MIME;
  11 use POSIX qw/strftime/;
  12 our $LIM = 50;
  13
  14 sub sres_top_html {
  15         my ($ctx) = @_;
  16         my $q = PublicInbox::SearchQuery->new($ctx->{cgi});
  17         my $code = 200;
  18
  19         # double the limit for expanded views:
  20         my $opts = {
  21                 limit => $LIM,
  22                 offset => $q->{o},
  23                 mset => 1,
  24                 relevance => $q->{r},
  25         };
  26         my ($mset, $total);
  27
  28         eval {
  29                 $mset = $ctx->{srch}->query($q->{q}, $opts);
  30                 $total = $mset->get_matches_estimated;
  31         };
  32         my $err = $@;
  33         my $res = html_start($q) . PublicInbox::View::PRE_WRAP;
  34         if ($err) {
  35                 $code = 400;
  36                 $res .= err_txt($err) . "</pre><hr /><pre>" . foot($ctx);
  37         } elsif ($total == 0) {
  38                 $code = 404;
  39                 $res .= "\n\n[No results found]</pre><hr /><pre>".foot($ctx);
  40         } else {
  41                 my $x = $q->{x};
  42                 # TODO
  43                 #return sub { adump($_[0], $mset, $q, $ctx) } if ($x eq 'A');
  44
  45                 $res .= search_nav_top($mset, $q);
  46                 if ($x eq 't') {
  47                         return sub { tdump($_[0], $res, $mset, $q, $ctx) };
  48                 }
  49                 $res .= "\n\n";
  50                 dump_mset(\$res, $mset);
  51                 $res .= search_nav_bot($mset, $q) . "\n\n" . foot($ctx);
  52         }
  53
  54         $res .= "</pre></body></html>";
  55         [$code, ['Content-Type'=>'text/html; charset=UTF-8'], [$res]];
  56 }
  57
  58 sub dump_mset {
  59         my ($res, $mset) = @_;
  60
  61         my $total = $mset->get_matches_estimated;
  62         my $pad = length("$total");
  63         my $pfx = ' ' x $pad;
  64         foreach my $m ($mset->items) {
  65                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
  66                 my $pct = $m->get_percent;
  67                 my $smsg = PublicInbox::SearchMsg->load_doc($m->get_document);
  68                 my $s = PublicInbox::Hval->new_oneline($smsg->subject);
  69                 my $f = $smsg->from_name;
  70                 $f = PublicInbox::Hval->new_oneline($f)->as_html;
  71                 my $d = strftime('%Y-%m-%d %H:%M', gmtime($smsg->ts));
  72                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->as_href;
  73                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
  74                         $s->as_html . "</a></b>\n";
  75                 $$res .= "$pfx  - by $f @ $d UTC [$pct%]\n\n";
  76         }
  77 }
  78
  79 sub err_txt {
  80         my ($err) = @_;
  81         my $u = 'http://xapian.org/docs/queryparser.html';
  82         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
  83         $err = PublicInbox::Hval->new_oneline($err)->as_html;
  84         "\n\nBad query: <b>$err</b>\n" .
  85                 qq{See <a\nhref="$u">$u</a> for Xapian query syntax};
  86 }
  87
  88 sub search_nav_top {
  89         my ($mset, $q) = @_;
  90
  91         my $rv = "Search results ordered by [";
  92         if ($q->{r}) {
  93                 my $d = $q->qs_html(r => 0);
  94                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
  95         } else {
  96                 my $d = $q->qs_html(r => 1);
  97                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
  98         }
  99
 100         $rv .= ']  view[';
 101
 102         my $x = $q->{x};
 103         if ($x eq '') {
 104                 my $t = $q->qs_html(x => 't');
 105                 $rv .= qq{<b>summary</b>|};
 106                 $rv .= qq{<a\nhref="?$t">threaded</a>}
 107         } elsif ($q->{x} eq 't') {
 108                 my $s = $q->qs_html(x => '');
 109                 $rv .= qq{<a\nhref="?$s">summary</a>|};
 110                 $rv .= qq{<b>threaded</b>};
 111         }
 112         # my $A = $q->qs_html(x => 'a');
 113         # $rv .= qq{|<a\nhref="?$A">Atom</a>}; # TODO
 114         $rv .= ']';
 115 }
 116
 117 sub search_nav_bot {
 118         my ($mset, $q) = @_;
 119         my $total = $mset->get_matches_estimated;
 120         my $nr = scalar $mset->items;
 121         my $o = $q->{o};
 122         my $end = $o + $nr;
 123         my $beg = $o + 1;
 124         my $rv = "<hr /><pre>Results $beg-$end of $total";
 125         my $n = $o + $LIM;
 126
 127         if ($n < $total) {
 128                 my $qs = $q->qs_html(o => $n);
 129                 $rv .= qq{, <a\nhref="?$qs">next</a>}
 130         }
 131         if ($o > 0) {
 132                 $rv .= $n < $total ? '/' : ',      ';
 133                 my $p = $o - $LIM;
 134                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 135                 $rv .= qq{<a\nhref="?$qs">prev</a>};
 136         }
 137         $rv;
 138 }
 139
 140 sub tdump {
 141         my ($cb, $res, $mset, $q, $ctx) = @_;
 142         my $fh = $cb->([200, ['Content-Type'=>'text/html; charset=UTF-8']]);
 143         $fh->write($res);
 144         my %pct;
 145         my @m = map {
 146                 my $i = $_;
 147                 my $m = PublicInbox::SearchMsg->load_doc($i->get_document);
 148                 $pct{$m->mid} = $i->get_percent;
 149                 $m = $m->mini_mime;
 150                 $m;
 151         } ($mset->items);
 152
 153         require PublicInbox::Thread;
 154         my $th = PublicInbox::Thread->new(@m);
 155         {
 156                 no warnings 'once';
 157                 $Mail::Thread::nosubject = 0;
 158         }
 159         $th->thread;
 160         if ($q->{r}) {
 161                 $th->order(sub {
 162                         sort { (eval { $pct{$b->topmost->messageid} } || 0)
 163                                         <=>
 164                                 (eval { $pct{$a->topmost->messageid} } || 0)
 165                         } @_;
 166                 });
 167         } else {
 168                 no warnings 'once';
 169                 $th->order(*PublicInbox::View::rsort_ts);
 170         }
 171
 172         require PublicInbox::GitCatFile;
 173         my $git = PublicInbox::GitCatFile->new($ctx->{git_dir});
 174         my $state = { ctx => $ctx, anchor_idx => 0, pct => \%pct };
 175         $ctx->{searchview} = 1;
 176         tdump_ent($fh, $git, $state, $_, 0) for $th->rootset;
 177         $git = undef;
 178         Email::Address->purge_cache;
 179
 180         $fh->write(search_nav_bot($mset, $q). "\n\n" .
 181                         foot($ctx). '</pre></body></html>');
 182
 183         $fh->close;
 184 }
 185
 186 sub tdump_ent {
 187         my ($fh, $git, $state, $node, $level) = @_;
 188         return unless $node;
 189         my $mime = $node->message;
 190
 191         if ($mime) {
 192                 # lazy load the full message from mini_mime:
 193                 my $mid = $mime->header('Message-ID');
 194                 $mime = eval {
 195                         my $path = mid2path(mid_clean($mid));
 196                         Email::MIME->new($git->cat_file('HEAD:'.$path));
 197                 };
 198         }
 199         if ($mime) {
 200                 PublicInbox::View::index_entry($fh, $mime, $level, $state);
 201         } else {
 202                 my $mid = $node->messageid;
 203                 $fh->write(PublicInbox::View::ghost_table('', $mid, $level));
 204         }
 205         tdump_ent($fh, $git, $state, $node->child, $level + 1);
 206         tdump_ent($fh, $git, $state, $node->next, $level);
 207 }
 208
 209 sub foot {
 210         my ($ctx) = @_;
 211         my $foot = $ctx->{footer} || '';
 212         qq{Back to <a\nhref=".">index</a>.\n$foot};
 213 }
 214
 215 sub html_start {
 216         my ($q) = @_;
 217         my $query = PublicInbox::Hval->new_oneline($q->{q});
 218
 219         my $qh = $query->as_html;
 220         my $res = "<html><head><title>$qh - search results</title></head>" .
 221                   qq{<body><form\naction="">} .
 222                   qq{<input\nname=q\nvalue="$qh"\ntype=text />};
 223
 224         $res .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 225         if (my $x = $q->{x}) {
 226                 my $xh = PublicInbox::Hval->new_oneline($x)->as_html;
 227                 $res .= qq{<input\ntype=hidden\nname=x\nvalue="$xh" />};
 228         }
 229
 230         $res .= qq{<input\ntype=submit\nvalue=search /></form>};
 231 }
 232
 233 package PublicInbox::SearchQuery;
 234 use strict;
 235 use warnings;
 236 use fields qw(q o t x r);
 237 use PublicInbox::Hval;
 238
 239 sub new {
 240         my ($class, $cgi) = @_;
 241         my $self = fields::new($class);
 242         $self->{q} = $cgi->param('q');
 243         $self->{x} = $cgi->param('x') || '';
 244         $self->{o} = int($cgi->param('o') || 0) || 0;
 245         my $r = $cgi->param('r');
 246         $self->{r} = (defined $r && $r ne '0');
 247
 248         $self;
 249 }
 250
 251 sub qs_html {
 252         my ($self, %over) = @_;
 253
 254         if (keys %over) {
 255                 my $tmp = fields::new(ref($self));
 256                 %$tmp = %$self;
 257                 foreach my $k (keys %over) {
 258                         $tmp->{$k} = $over{$k};
 259                 }
 260                 $self = $tmp;
 261         }
 262
 263         my $q = PublicInbox::Hval->new($self->{q})->as_href;
 264         $q =~ s/%20/+/g; # improve URL readability
 265         my $qs = "q=$q";
 266
 267         if (my $o = $self->{o}) { # ignore o == 0
 268                 $qs .= "&amp;o=$o";
 269         }
 270         if (my $r = $self->{r}) {
 271                 $qs .= "&amp;r";
 272         }
 273         if (my $x = $self->{x}) {
 274                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A');
 275         }
 276         $qs;
 277 }
 278
 279 1;