lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::SearchMsg;
   9 use PublicInbox::Hval qw/ascii_html/;
  10 use PublicInbox::View;
  11 use PublicInbox::MID qw(mid2path mid_mime mid_clean mid_escape);
  12 use Email::MIME;
  13 require PublicInbox::Git;
  14 require PublicInbox::SearchThread;
  15 our $LIM = 50;
  16
  17 sub noop {}
  18
  19 sub sres_top_html {
  20         my ($ctx) = @_;
  21         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  22         my $code = 200;
  23
  24         # double the limit for expanded views:
  25         my $opts = {
  26                 limit => $LIM,
  27                 offset => $q->{o},
  28                 mset => 1,
  29                 relevance => $q->{r},
  30         };
  31         my ($mset, $total);
  32         eval {
  33                 $mset = $ctx->{srch}->query($q->{'q'}, $opts);
  34                 $total = $mset->get_matches_estimated;
  35         };
  36         my $err = $@;
  37         ctx_prepare($q, $ctx);
  38         my $cb;
  39         if ($err) {
  40                 $code = 400;
  41                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  42                 $cb = *noop;
  43         } elsif ($total == 0) {
  44                 $code = 404;
  45                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  46                 $cb = *noop;
  47         } else {
  48                 my $x = $q->{x};
  49                 return sub { adump($_[0], $mset, $q, $ctx) } if ($x eq 'A');
  50
  51                 $ctx->{-html_tip} = search_nav_top($mset, $q) . "\n\n";
  52                 if ($x eq 't') {
  53                         $cb = mset_thread($ctx, $mset, $q);
  54                 } else {
  55                         $cb = mset_summary($ctx, $mset, $q);
  56                 }
  57         }
  58         PublicInbox::WwwStream->response($ctx, $code, $cb);
  59 }
  60
  61 # display non-threaded search results similar to what users expect from
  62 # regular WWW search engines:
  63 sub mset_summary {
  64         my ($ctx, $mset, $q) = @_;
  65
  66         my $total = $mset->get_matches_estimated;
  67         my $pad = length("$total");
  68         my $pfx = ' ' x $pad;
  69         my $res = \($ctx->{-html_tip});
  70         foreach my $m ($mset->items) {
  71                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
  72                 my $pct = $m->get_percent;
  73                 my $smsg = PublicInbox::SearchMsg->load_doc($m->get_document);
  74                 my $s = ascii_html($smsg->subject);
  75                 my $f = ascii_html($smsg->from_name);
  76                 my $ts = PublicInbox::View::fmt_ts($smsg->ts);
  77                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
  78                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
  79                         $s . "</a></b>\n";
  80                 $$res .= "$pfx  - by $f @ $ts UTC [$pct%]\n\n";
  81         }
  82         $$res .= search_nav_bot($mset, $q);
  83         *noop;
  84 }
  85
  86 sub err_txt {
  87         my ($ctx, $err) = @_;
  88         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
  89         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
  90         $err = ascii_html($err);
  91         "\nBad query: <b>$err</b>\n" .
  92                 qq{See <a\nhref="$u">$u</a> for help on using search};
  93 }
  94
  95 sub search_nav_top {
  96         my ($mset, $q) = @_;
  97
  98         my $rv = "<pre>Search results ordered by [";
  99         if ($q->{r}) {
 100                 my $d = $q->qs_html(r => 0);
 101                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 102         } else {
 103                 my $d = $q->qs_html(r => 1);
 104                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 105         }
 106
 107         $rv .= ']  view[';
 108
 109         my $x = $q->{x};
 110         if ($x eq '') {
 111                 my $t = $q->qs_html(x => 't');
 112                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">threaded</a>}
 113         } elsif ($q->{x} eq 't') {
 114                 my $s = $q->qs_html(x => '');
 115                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>threaded</b>};
 116         }
 117         my $A = $q->qs_html(x => 'A', r => undef);
 118         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 119 }
 120
 121 sub search_nav_bot {
 122         my ($mset, $q) = @_;
 123         my $total = $mset->get_matches_estimated;
 124         my $nr = scalar $mset->items;
 125         my $o = $q->{o};
 126         my $end = $o + $nr;
 127         my $beg = $o + 1;
 128         my $rv = "</pre><hr><pre>Results $beg-$end of $total";
 129         my $n = $o + $LIM;
 130
 131         if ($n < $total) {
 132                 my $qs = $q->qs_html(o => $n);
 133                 $rv .= qq{, <a\nhref="?$qs"\nrel=next>next</a>}
 134         }
 135         if ($o > 0) {
 136                 $rv .= $n < $total ? '/' : ',      ';
 137                 my $p = $o - $LIM;
 138                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 139                 $rv .= qq{<a\nhref="?$qs"\nrel=prev>prev</a>};
 140         }
 141         $rv .= '</pre>';
 142 }
 143
 144 sub mset_thread {
 145         my ($ctx, $mset, $q) = @_;
 146         my %pct;
 147         my @m = map {
 148                 my $i = $_;
 149                 my $m = PublicInbox::SearchMsg->load_doc($i->get_document);
 150                 $pct{$m->mid} = $i->get_percent;
 151                 $m;
 152         } ($mset->items);
 153
 154         my $th = PublicInbox::SearchThread->new(\@m);
 155         $th->thread;
 156         if ($q->{r}) { # order by relevance
 157                 $th->order(sub {
 158                         [ sort { (eval { $pct{$b->topmost->{id}} } || 0)
 159                                         <=>
 160                                 (eval { $pct{$a->topmost->{id}} } || 0)
 161                         } @{$_[0]} ];
 162                 });
 163         } else { # order by time (default for threaded view)
 164                 $th->order(*PublicInbox::View::sort_ts);
 165         }
 166         my $skel = search_nav_bot($mset, $q). "<pre>";
 167         my $inbox = $ctx->{-inbox};
 168         $ctx->{-upfx} = '';
 169         $ctx->{anchor_idx} = 1;
 170         $ctx->{cur_level} = 0;
 171         $ctx->{dst} = \$skel;
 172         $ctx->{mapping} = {};
 173         $ctx->{pct} = \%pct;
 174         $ctx->{prev_attr} = '';
 175         $ctx->{prev_level} = 0;
 176         $ctx->{seen} = {};
 177         $ctx->{s_nr} = scalar(@m).'+ results';
 178
 179         PublicInbox::View::walk_thread($th, $ctx,
 180                 *PublicInbox::View::pre_thread);
 181
 182         my $msgs = \@m;
 183         my $mime;
 184         sub {
 185                 return unless $msgs;
 186                 while ($mime = shift @$msgs) {
 187                         $mime = $inbox->msg_by_smsg($mime) and last;
 188                 }
 189                 if ($mime) {
 190                         $mime = Email::MIME->new($mime);
 191                         return PublicInbox::View::index_entry($mime, $ctx,
 192                                 scalar @$msgs);
 193                 }
 194                 $msgs = undef;
 195                 $skel .= "\n</pre>";
 196         };
 197 }
 198
 199 sub ctx_prepare {
 200         my ($q, $ctx) = @_;
 201         my $qh = ascii_html($q->{'q'});
 202         $ctx->{-q_value_html} = $qh;
 203         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 204         $ctx->{-title_html} = "$qh - search results";
 205         my $extra = '';
 206         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 207         if (my $x = $q->{x}) {
 208                 $x = ascii_html($x);
 209                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 210         }
 211         $ctx->{-extra_form_html} = $extra;
 212 }
 213
 214 sub adump {
 215         my ($cb, $mset, $q, $ctx) = @_;
 216         my $fh = $cb->([ 200, ['Content-Type' => 'application/atom+xml']]);
 217         my $ibx = $ctx->{-inbox};
 218         my $feed_opts = PublicInbox::Feed::get_feedopts($ctx);
 219         my $x = ascii_html($q->{'q'});
 220         $x = qq{$x - search results};
 221         $feed_opts->{atomurl} = $feed_opts->{url} . '?'. $q->qs_html;
 222         $feed_opts->{url} .= '?'. $q->qs_html(x => undef);
 223         $x = PublicInbox::Feed::atom_header($feed_opts, $x);
 224         $fh->write($x. PublicInbox::Feed::feed_updated());
 225
 226         for ($mset->items) {
 227                 $x = PublicInbox::SearchMsg->load_doc($_->get_document)->mid;
 228                 $x = mid2path($x);
 229                 my $s = PublicInbox::Feed::feed_entry($feed_opts, $x, $ibx);
 230                 $fh->write($s) if defined $s;
 231         }
 232         PublicInbox::Feed::end_feed($fh);
 233 }
 234
 235 package PublicInbox::SearchQuery;
 236 use strict;
 237 use warnings;
 238 use PublicInbox::Hval;
 239 use PublicInbox::MID qw(mid_escape);
 240
 241 sub new {
 242         my ($class, $qp) = @_;
 243
 244         my $r = $qp->{r};
 245         bless {
 246                 q => $qp->{'q'},
 247                 x => $qp->{x} || '',
 248                 o => (($qp->{o} || '0') =~ /(\d+)/),
 249                 r => (defined $r && $r ne '0'),
 250         }, $class;
 251 }
 252
 253 sub qs_html {
 254         my ($self, %over) = @_;
 255
 256         if (keys %over) {
 257                 my $tmp = bless { %$self }, ref($self);
 258                 foreach my $k (keys %over) {
 259                         $tmp->{$k} = $over{$k};
 260                 }
 261                 $self = $tmp;
 262         }
 263
 264         my $q = mid_escape($self->{'q'});
 265         $q =~ s/%20/+/g; # improve URL readability
 266         my $qs = "q=$q";
 267
 268         if (my $o = $self->{o}) { # ignore o == 0
 269                 $qs .= "&amp;o=$o";
 270         }
 271         if (my $r = $self->{r}) {
 272                 $qs .= "&amp;r";
 273         }
 274         if (my $x = $self->{x}) {
 275                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A');
 276         }
 277         $qs;
 278 }
 279
 280 1;