lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use URI::Escape qw(uri_unescape uri_escape);
   9 use PublicInbox::SearchMsg;
  10 use PublicInbox::Hval qw/ascii_html obfuscate_addrs/;
  11 use PublicInbox::View;
  12 use PublicInbox::WwwAtomStream;
  13 use PublicInbox::MID qw(MID_ESC);
  14 use PublicInbox::MIME;
  15 require PublicInbox::Git;
  16 require PublicInbox::SearchThread;
  17 our $LIM = 200;
  18
  19 sub noop {}
  20
  21 sub mbox_results {
  22         my ($ctx) = @_;
  23         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  24         my $x = $q->{x};
  25         require PublicInbox::Mbox;
  26         return PublicInbox::Mbox::mbox_all($ctx, $q->{'q'}) if $x eq 'm';
  27         sres_top_html($ctx);
  28 }
  29
  30 sub sres_top_html {
  31         my ($ctx) = @_;
  32         my $srch = $ctx->{-inbox}->search or
  33                 return PublicInbox::WWW::need($ctx, 'Search');
  34         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  35         my $x = $q->{x};
  36         my $query = $q->{'q'};
  37
  38         my $code = 200;
  39         # double the limit for expanded views:
  40         my $opts = {
  41                 limit => $q->{l},
  42                 offset => $q->{o},
  43                 mset => 1,
  44                 relevance => $q->{r},
  45         };
  46         my ($mset, $total, $err, $cb);
  47 retry:
  48         eval {
  49                 $mset = $srch->query($query, $opts);
  50                 $total = $mset->get_matches_estimated;
  51         };
  52         $err = $@;
  53         ctx_prepare($q, $ctx);
  54         if ($err) {
  55                 $code = 400;
  56                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  57                 $cb = *noop;
  58         } elsif ($total == 0) {
  59                 if (defined($ctx->{-uxs_retried})) {
  60                         # undo retry damage:
  61                         $q->{'q'} = $ctx->{-uxs_retried};
  62                 } elsif (index($q->{'q'}, '%') >= 0) {
  63                         $ctx->{-uxs_retried} = $q->{'q'};
  64                         $q->{'q'} = uri_unescape($q->{'q'});
  65                         goto retry;
  66                 }
  67                 $code = 404;
  68                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  69                 $cb = *noop;
  70         } else {
  71                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  72
  73                 $ctx->{-html_tip} = search_nav_top($mset, $q, $ctx);
  74                 if ($x eq 't') {
  75                         $cb = mset_thread($ctx, $mset, $q);
  76                 } else {
  77                         $cb = mset_summary($ctx, $mset, $q);
  78                 }
  79         }
  80         PublicInbox::WwwStream->response($ctx, $code, $cb);
  81 }
  82
  83 # allow undef for individual doc loads...
  84 sub load_doc_retry {
  85         my ($srch, $mitem) = @_;
  86
  87         eval {
  88                 $srch->retry_reopen(sub {
  89                         PublicInbox::SearchMsg->load_doc($mitem->get_document)
  90                 });
  91         }
  92 }
  93
  94 # display non-nested search results similar to what users expect from
  95 # regular WWW search engines:
  96 sub mset_summary {
  97         my ($ctx, $mset, $q) = @_;
  98
  99         my $total = $mset->get_matches_estimated;
 100         my $pad = length("$total");
 101         my $pfx = ' ' x $pad;
 102         my $res = \($ctx->{-html_tip});
 103         my $ibx = $ctx->{-inbox};
 104         my $srch = $ibx->search;
 105         my $obfs_ibx = $ibx->{obfuscate} ? $ibx : undef;
 106         foreach my $m ($mset->items) {
 107                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
 108                 my $pct = $m->get_percent;
 109                 my $smsg = load_doc_retry($srch, $m);
 110                 unless ($smsg) {
 111                         eval {
 112                                 $m = "$m ".$m->get_docid . " expired\n";
 113                                 $ctx->{env}->{'psgi.errors'}->print($m);
 114                         };
 115                         next;
 116                 }
 117                 my $s = ascii_html($smsg->subject);
 118                 my $f = ascii_html($smsg->from_name);
 119                 if ($obfs_ibx) {
 120                         obfuscate_addrs($obfs_ibx, $s);
 121                         obfuscate_addrs($obfs_ibx, $f);
 122                 }
 123                 my $date = PublicInbox::View::fmt_ts($smsg->ds);
 124                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
 125                 $s = '(no subject)' if $s eq '';
 126                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
 127                         $s . "</a></b>\n";
 128                 $$res .= "$pfx  - by $f @ $date UTC [$pct%]\n\n";
 129         }
 130         $$res .= search_nav_bot($mset, $q);
 131         *noop;
 132 }
 133
 134 sub err_txt {
 135         my ($ctx, $err) = @_;
 136         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
 137         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 138         $err = ascii_html($err);
 139         "\nBad query: <b>$err</b>\n" .
 140                 qq{See <a\nhref="$u">$u</a> for help on using search};
 141 }
 142
 143 sub search_nav_top {
 144         my ($mset, $q, $ctx) = @_;
 145         my $m = $q->qs_html(x => 'm', r => undef);
 146         my $rv = qq{<form\naction="?$m"\nmethod="post"><pre>};
 147         my $initial_q = $ctx->{-uxs_retried};
 148         if (defined $initial_q) {
 149                 my $rewritten = $q->{'q'};
 150                 utf8::decode($initial_q);
 151                 utf8::decode($rewritten);
 152                 $initial_q = ascii_html($initial_q);
 153                 $rewritten = ascii_html($rewritten);
 154                 $rv .= " Warning: Initial query:\n <b>$initial_q</b>\n";
 155                 $rv .= " returned no results, used:\n";
 156                 $rv .= " <b>$rewritten</b>\n instead\n\n";
 157         }
 158
 159         $rv .= 'Search results ordered by [';
 160         if ($q->{r}) {
 161                 my $d = $q->qs_html(r => 0);
 162                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 163         } else {
 164                 my $d = $q->qs_html(r => 1);
 165                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 166         }
 167
 168         $rv .= ']  view[';
 169
 170         my $x = $q->{x};
 171         if ($x eq '') {
 172                 my $t = $q->qs_html(x => 't');
 173                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">nested</a>}
 174         } elsif ($q->{x} eq 't') {
 175                 my $s = $q->qs_html(x => '');
 176                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>nested</b>};
 177         }
 178         my $A = $q->qs_html(x => 'A', r => undef);
 179         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 180         $rv .= qq{\n\t\t\t\t\t\tdownload: };
 181         $rv .= qq{<input\ntype=submit\nvalue="mbox.gz"/></pre></form><pre>};
 182 }
 183
 184 sub search_nav_bot {
 185         my ($mset, $q) = @_;
 186         my $total = $mset->get_matches_estimated;
 187         my $o = $q->{o};
 188         my $l = $q->{l};
 189         my $end = $o + $mset->size;
 190         my $beg = $o + 1;
 191         my $rv = '</pre><hr><pre id=t>';
 192         if ($beg <= $end) {
 193                 $rv .= "Results $beg-$end of $total";
 194                 $rv .= ' (estimated)' if $end != $total;
 195         } else {
 196                 $rv .= "No more results, only $total";
 197         }
 198         my $n = $o + $l;
 199
 200         if ($n < $total) {
 201                 my $qs = $q->qs_html(o => $n, l => $l);
 202                 $rv .= qq{  <a\nhref="?$qs"\nrel=next>next</a>}
 203         }
 204         if ($o > 0) {
 205                 $rv .= $n < $total ? '/' : '       ';
 206                 my $p = $o - $l;
 207                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 208                 $rv .= qq{<a\nhref="?$qs"\nrel=prev>prev</a>};
 209         }
 210         $rv .= '</pre>';
 211 }
 212
 213 sub sort_relevance {
 214         my ($pct) = @_;
 215         sub {
 216                 [ sort { (eval { $pct->{$b->topmost->{id}} } || 0)
 217                                 <=>
 218                         (eval { $pct->{$a->topmost->{id}} } || 0)
 219         } @{$_[0]} ] };
 220 }
 221
 222 sub mset_thread {
 223         my ($ctx, $mset, $q) = @_;
 224         my %pct;
 225         my $ibx = $ctx->{-inbox};
 226         my $msgs = $ibx->search->retry_reopen(sub { [ map {
 227                 my $i = $_;
 228                 my $smsg = PublicInbox::SearchMsg->load_doc($i->get_document);
 229                 $pct{$smsg->mid} = $i->get_percent;
 230                 $smsg;
 231         } ($mset->items) ]});
 232         my $r = $q->{r};
 233         my $rootset = PublicInbox::SearchThread::thread($msgs,
 234                 $r ? sort_relevance(\%pct) : *PublicInbox::View::sort_ds,
 235                 $ctx);
 236         my $skel = search_nav_bot($mset, $q). "<pre>";
 237         $ctx->{-upfx} = '';
 238         $ctx->{anchor_idx} = 1;
 239         $ctx->{cur_level} = 0;
 240         $ctx->{dst} = \$skel;
 241         $ctx->{mapping} = {};
 242         $ctx->{pct} = \%pct;
 243         $ctx->{prev_attr} = '';
 244         $ctx->{prev_level} = 0;
 245         $ctx->{s_nr} = scalar(@$msgs).'+ results';
 246
 247         # reduce hash lookups in skel_dump
 248         $ctx->{-obfuscate} = $ctx->{-inbox}->{obfuscate};
 249         PublicInbox::View::walk_thread($rootset, $ctx,
 250                 *PublicInbox::View::pre_thread);
 251
 252         @$msgs = reverse @$msgs if $r;
 253         sub {
 254                 return unless $msgs;
 255                 my $smsg;
 256                 while (my $m = pop @$msgs) {
 257                         $smsg = $ibx->smsg_mime($m) and last;
 258                 }
 259                 if ($smsg) {
 260                         return PublicInbox::View::index_entry($smsg, $ctx,
 261                                 scalar @$msgs);
 262                 }
 263                 $msgs = undef;
 264                 $skel .= "\n</pre>";
 265         };
 266 }
 267
 268 sub ctx_prepare {
 269         my ($q, $ctx) = @_;
 270         my $qh = $q->{'q'};
 271         utf8::decode($qh);
 272         $qh = ascii_html($qh);
 273         $ctx->{-q_value_html} = $qh;
 274         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 275         $ctx->{-title_html} = "$qh - search results";
 276         my $extra = '';
 277         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 278         if (my $x = $q->{x}) {
 279                 $x = ascii_html($x);
 280                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 281         }
 282         $ctx->{-extra_form_html} = $extra;
 283 }
 284
 285 sub adump {
 286         my ($cb, $mset, $q, $ctx) = @_;
 287         my $ibx = $ctx->{-inbox};
 288         my @items = $mset->items;
 289         $ctx->{search_query} = $q;
 290         my $srch = $ibx->search;
 291         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
 292                 while (my $x = shift @items) {
 293                         $x = load_doc_retry($srch, $x);
 294                         $x = $ibx->smsg_mime($x) and return $x;
 295                 }
 296                 return undef;
 297         });
 298 }
 299
 300 package PublicInbox::SearchQuery;
 301 use strict;
 302 use warnings;
 303 use URI::Escape qw(uri_escape);
 304 use PublicInbox::Hval;
 305 use PublicInbox::MID qw(MID_ESC);
 306
 307 sub new {
 308         my ($class, $qp) = @_;
 309
 310         my $r = $qp->{r};
 311         my ($l) = (($qp->{l} || '') =~ /([0-9]+)/);
 312         $l = $LIM if !$l || $l > $LIM;
 313         bless {
 314                 q => $qp->{'q'},
 315                 x => $qp->{x} || '',
 316                 o => (($qp->{o} || '0') =~ /([0-9]+)/),
 317                 l => $l,
 318                 r => (defined $r && $r ne '0'),
 319         }, $class;
 320 }
 321
 322 sub qs_html {
 323         my ($self, %over) = @_;
 324
 325         if (keys %over) {
 326                 my $tmp = bless { %$self }, ref($self);
 327                 foreach my $k (keys %over) {
 328                         $tmp->{$k} = $over{$k};
 329                 }
 330                 $self = $tmp;
 331         }
 332
 333         my $q = uri_escape($self->{'q'}, MID_ESC);
 334         $q =~ s/%20/+/g; # improve URL readability
 335         my $qs = "q=$q";
 336
 337         if (my $o = $self->{o}) { # ignore o == 0
 338                 $qs .= "&amp;o=$o";
 339         }
 340         if (my $l = $self->{l}) {
 341                 $qs .= "&amp;l=$l" unless $l == $LIM;
 342         }
 343         if (my $r = $self->{r}) {
 344                 $qs .= "&amp;r";
 345         }
 346         if (my $x = $self->{x}) {
 347                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A' || $x eq 'm');
 348         }
 349         $qs;
 350 }
 351
 352 1;