lib/PublicInbox/SearchView.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 #
   4 # Displays search results for the web interface
   5 package PublicInbox::SearchView;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::SearchMsg;
   9 use PublicInbox::Hval qw/ascii_html/;
  10 use PublicInbox::View;
  11 use PublicInbox::WwwAtomStream;
  12 use PublicInbox::MID qw(mid2path mid_mime mid_clean mid_escape);
  13 use Email::MIME;
  14 require PublicInbox::Git;
  15 require PublicInbox::SearchThread;
  16 our $LIM = 50;
  17
  18 sub noop {}
  19
  20 sub sres_top_html {
  21         my ($ctx) = @_;
  22         my $q = PublicInbox::SearchQuery->new($ctx->{qp});
  23         my $code = 200;
  24
  25         # double the limit for expanded views:
  26         my $opts = {
  27                 limit => $LIM,
  28                 offset => $q->{o},
  29                 mset => 1,
  30                 relevance => $q->{r},
  31         };
  32         my ($mset, $total);
  33         eval {
  34                 $mset = $ctx->{srch}->query($q->{'q'}, $opts);
  35                 $total = $mset->get_matches_estimated;
  36         };
  37         my $err = $@;
  38         ctx_prepare($q, $ctx);
  39         my $cb;
  40         if ($err) {
  41                 $code = 400;
  42                 $ctx->{-html_tip} = '<pre>'.err_txt($ctx, $err).'</pre><hr>';
  43                 $cb = *noop;
  44         } elsif ($total == 0) {
  45                 $code = 404;
  46                 $ctx->{-html_tip} = "<pre>\n[No results found]</pre><hr>";
  47                 $cb = *noop;
  48         } else {
  49                 my $x = $q->{x};
  50                 return adump($_[0], $mset, $q, $ctx) if $x eq 'A';
  51
  52                 $ctx->{-html_tip} = search_nav_top($mset, $q) . "\n\n";
  53                 if ($x eq 't') {
  54                         $cb = mset_thread($ctx, $mset, $q);
  55                 } else {
  56                         $cb = mset_summary($ctx, $mset, $q);
  57                 }
  58         }
  59         PublicInbox::WwwStream->response($ctx, $code, $cb);
  60 }
  61
  62 # display non-threaded search results similar to what users expect from
  63 # regular WWW search engines:
  64 sub mset_summary {
  65         my ($ctx, $mset, $q) = @_;
  66
  67         my $total = $mset->get_matches_estimated;
  68         my $pad = length("$total");
  69         my $pfx = ' ' x $pad;
  70         my $res = \($ctx->{-html_tip});
  71         foreach my $m ($mset->items) {
  72                 my $rank = sprintf("%${pad}d", $m->get_rank + 1);
  73                 my $pct = $m->get_percent;
  74                 my $smsg = PublicInbox::SearchMsg->load_doc($m->get_document);
  75                 my $s = ascii_html($smsg->subject);
  76                 my $f = ascii_html($smsg->from_name);
  77                 my $ts = PublicInbox::View::fmt_ts($smsg->ts);
  78                 my $mid = PublicInbox::Hval->new_msgid($smsg->mid)->{href};
  79                 $$res .= qq{$rank. <b><a\nhref="$mid/">}.
  80                         $s . "</a></b>\n";
  81                 $$res .= "$pfx  - by $f @ $ts UTC [$pct%]\n\n";
  82         }
  83         $$res .= search_nav_bot($mset, $q);
  84         *noop;
  85 }
  86
  87 sub err_txt {
  88         my ($ctx, $err) = @_;
  89         my $u = $ctx->{-inbox}->base_url($ctx->{env}) . '_/text/help/';
  90         $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
  91         $err = ascii_html($err);
  92         "\nBad query: <b>$err</b>\n" .
  93                 qq{See <a\nhref="$u">$u</a> for help on using search};
  94 }
  95
  96 sub search_nav_top {
  97         my ($mset, $q) = @_;
  98
  99         my $rv = "<pre>Search results ordered by [";
 100         if ($q->{r}) {
 101                 my $d = $q->qs_html(r => 0);
 102                 $rv .= qq{<a\nhref="?$d">date</a>|<b>relevance</b>};
 103         } else {
 104                 my $d = $q->qs_html(r => 1);
 105                 $rv .= qq{<b>date</b>|<a\nhref="?$d">relevance</a>};
 106         }
 107
 108         $rv .= ']  view[';
 109
 110         my $x = $q->{x};
 111         if ($x eq '') {
 112                 my $t = $q->qs_html(x => 't');
 113                 $rv .= qq{<b>summary</b>|<a\nhref="?$t">threaded</a>}
 114         } elsif ($q->{x} eq 't') {
 115                 my $s = $q->qs_html(x => '');
 116                 $rv .= qq{<a\nhref="?$s">summary</a>|<b>threaded</b>};
 117         }
 118         my $A = $q->qs_html(x => 'A', r => undef);
 119         $rv .= qq{|<a\nhref="?$A">Atom feed</a>]};
 120 }
 121
 122 sub search_nav_bot {
 123         my ($mset, $q) = @_;
 124         my $total = $mset->get_matches_estimated;
 125         my $nr = scalar $mset->items;
 126         my $o = $q->{o};
 127         my $end = $o + $nr;
 128         my $beg = $o + 1;
 129         my $rv = "</pre><hr><pre>Results $beg-$end of $total";
 130         my $n = $o + $LIM;
 131
 132         if ($n < $total) {
 133                 my $qs = $q->qs_html(o => $n);
 134                 $rv .= qq{, <a\nhref="?$qs"\nrel=next>next</a>}
 135         }
 136         if ($o > 0) {
 137                 $rv .= $n < $total ? '/' : ',      ';
 138                 my $p = $o - $LIM;
 139                 my $qs = $q->qs_html(o => ($p > 0 ? $p : 0));
 140                 $rv .= qq{<a\nhref="?$qs"\nrel=prev>prev</a>};
 141         }
 142         $rv .= '</pre>';
 143 }
 144
 145 sub mset_thread {
 146         my ($ctx, $mset, $q) = @_;
 147         my %pct;
 148         my @m = map {
 149                 my $i = $_;
 150                 my $m = PublicInbox::SearchMsg->load_doc($i->get_document);
 151                 $pct{$m->mid} = $i->get_percent;
 152                 $m;
 153         } ($mset->items);
 154
 155         my $th = PublicInbox::SearchThread->new(\@m);
 156         $th->thread;
 157         if ($q->{r}) { # order by relevance
 158                 $th->order(sub {
 159                         [ sort { (eval { $pct{$b->topmost->{id}} } || 0)
 160                                         <=>
 161                                 (eval { $pct{$a->topmost->{id}} } || 0)
 162                         } @{$_[0]} ];
 163                 });
 164         } else { # order by time (default for threaded view)
 165                 $th->order(*PublicInbox::View::sort_ts);
 166         }
 167         my $skel = search_nav_bot($mset, $q). "<pre>";
 168         my $inbox = $ctx->{-inbox};
 169         $ctx->{-upfx} = '';
 170         $ctx->{anchor_idx} = 1;
 171         $ctx->{cur_level} = 0;
 172         $ctx->{dst} = \$skel;
 173         $ctx->{mapping} = {};
 174         $ctx->{pct} = \%pct;
 175         $ctx->{prev_attr} = '';
 176         $ctx->{prev_level} = 0;
 177         $ctx->{seen} = {};
 178         $ctx->{s_nr} = scalar(@m).'+ results';
 179
 180         PublicInbox::View::walk_thread($th, $ctx,
 181                 *PublicInbox::View::pre_thread);
 182
 183         my $msgs = \@m;
 184         my $mime;
 185         sub {
 186                 return unless $msgs;
 187                 while ($mime = shift @$msgs) {
 188                         $mime = $inbox->msg_by_smsg($mime) and last;
 189                 }
 190                 if ($mime) {
 191                         $mime = Email::MIME->new($mime);
 192                         return PublicInbox::View::index_entry($mime, $ctx,
 193                                 scalar @$msgs);
 194                 }
 195                 $msgs = undef;
 196                 $skel .= "\n</pre>";
 197         };
 198 }
 199
 200 sub ctx_prepare {
 201         my ($q, $ctx) = @_;
 202         my $qh = ascii_html($q->{'q'});
 203         $ctx->{-q_value_html} = $qh;
 204         $ctx->{-atom} = '?'.$q->qs_html(x => 'A', r => undef);
 205         $ctx->{-title_html} = "$qh - search results";
 206         my $extra = '';
 207         $extra .= qq{<input\ntype=hidden\nname=r />} if $q->{r};
 208         if (my $x = $q->{x}) {
 209                 $x = ascii_html($x);
 210                 $extra .= qq{<input\ntype=hidden\nname=x\nvalue="$x" />};
 211         }
 212         $ctx->{-extra_form_html} = $extra;
 213 }
 214
 215 sub adump {
 216         my ($cb, $mset, $q, $ctx) = @_;
 217         my $ibx = $ctx->{-inbox};
 218         my @items = $mset->items;
 219         $ctx->{search_query} = $q;
 220         PublicInbox::WwwAtomStream->response($ctx, 200, sub {
 221                 while (my $x = shift @items) {
 222                         $x = PublicInbox::SearchMsg->load_doc($x->get_document);
 223                         $x = $ibx->msg_by_smsg($x) and
 224                                         return Email::MIME->new($x);
 225                 }
 226                 return undef;
 227         });
 228 }
 229
 230 package PublicInbox::SearchQuery;
 231 use strict;
 232 use warnings;
 233 use PublicInbox::Hval;
 234 use PublicInbox::MID qw(mid_escape);
 235
 236 sub new {
 237         my ($class, $qp) = @_;
 238
 239         my $r = $qp->{r};
 240         bless {
 241                 q => $qp->{'q'},
 242                 x => $qp->{x} || '',
 243                 o => (($qp->{o} || '0') =~ /(\d+)/),
 244                 r => (defined $r && $r ne '0'),
 245         }, $class;
 246 }
 247
 248 sub qs_html {
 249         my ($self, %over) = @_;
 250
 251         if (keys %over) {
 252                 my $tmp = bless { %$self }, ref($self);
 253                 foreach my $k (keys %over) {
 254                         $tmp->{$k} = $over{$k};
 255                 }
 256                 $self = $tmp;
 257         }
 258
 259         my $q = mid_escape($self->{'q'});
 260         $q =~ s/%20/+/g; # improve URL readability
 261         my $qs = "q=$q";
 262
 263         if (my $o = $self->{o}) { # ignore o == 0
 264                 $qs .= "&amp;o=$o";
 265         }
 266         if (my $r = $self->{r}) {
 267                 $qs .= "&amp;r";
 268         }
 269         if (my $x = $self->{x}) {
 270                 $qs .= "&amp;x=$x" if ($x eq 't' || $x eq 'A');
 271         }
 272         $qs;
 273 }
 274
 275 1;