lib/PublicInbox/SharedKV.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # fork()-friendly key-value store.  Will be used for making
   5 # augmenting Maildirs and mboxes less expensive, maybe.
   6 # We use flock(2) to avoid SQLite lock problems (busy timeouts, backoff)
   7 package PublicInbox::SharedKV;
   8 use strict;
   9 use v5.10.1;
  10 use parent qw(PublicInbox::Lock);
  11 use File::Temp qw(tempdir);
  12 use DBI ();
  13 use PublicInbox::Spawn;
  14 use File::Path qw(rmtree make_path);
  15
  16 sub dbh {
  17         my ($self, $lock) = @_;
  18         $self->{dbh} // do {
  19                 my $f = $self->{filename};
  20                 $lock //= $self->lock_for_scope_fast;
  21                 my $dbh = DBI->connect("dbi:SQLite:dbname=$f", '', '', {
  22                         AutoCommit => 1,
  23                         RaiseError => 1,
  24                         PrintError => 0,
  25                         sqlite_use_immediate_transaction => 1,
  26                         # no sqlite_unicode here, this is for binary data
  27                 });
  28                 my $opt = $self->{opt} // {};
  29                 $dbh->do('PRAGMA synchronous = OFF') if !$opt->{fsync};
  30                 $dbh->do('PRAGMA journal_mode = '.
  31                                 ($opt->{journal_mode} // 'WAL'));
  32                 $dbh->do(<<'');
  33 CREATE TABLE IF NOT EXISTS kv (
  34         k VARBINARY PRIMARY KEY NOT NULL,
  35         v VARBINARY NOT NULL,
  36         UNIQUE (k)
  37 )
  38
  39                 $self->{dbh} = $dbh;
  40         }
  41 }
  42
  43 sub new {
  44         my ($cls, $dir, $base, $opt) = @_;
  45         my $self = bless { opt => $opt }, $cls;
  46         make_path($dir) if defined($dir) && !-d $dir;
  47         $dir //= $self->{"tmp$$.$self"} = tempdir("skv.$$-XXXX", TMPDIR => 1);
  48         $base //= '';
  49         my $f = $self->{filename} = "$dir/$base.sqlite3";
  50         $self->{lock_path} = $opt->{lock_path} // "$dir/$base.flock";
  51         unless (-s $f) {
  52                 require PublicInbox::Syscall;
  53                 PublicInbox::Syscall::nodatacow_dir($dir); # for journal/shm/wal
  54                 open my $fh, '+>>', $f or die "failed to open $f: $!";
  55         }
  56         $self;
  57 }
  58
  59 sub index_values {
  60         my ($self) = @_;
  61         my $lock = $self->lock_for_scope_fast;
  62         $self->dbh($lock)->do('CREATE INDEX IF NOT EXISTS idx_v ON kv (v)');
  63 }
  64
  65 sub set_maybe {
  66         my ($self, $key, $val, $lock) = @_;
  67         $lock //= $self->lock_for_scope_fast;
  68         my $e = $self->{dbh}->prepare_cached(<<'')->execute($key, $val);
  69 INSERT OR IGNORE INTO kv (k,v) VALUES (?, ?)
  70
  71         $e == 0 ? undef : $e;
  72 }
  73
  74 # caller calls sth->fetchrow_array
  75 sub each_kv_iter {
  76         my ($self) = @_;
  77         my $sth = $self->{dbh}->prepare_cached(<<'', undef, 1);
  78 SELECT k,v FROM kv
  79
  80         $sth->execute;
  81         $sth
  82 }
  83
  84 sub keys {
  85         my ($self, @pfx) = @_;
  86         my $sql = 'SELECT k FROM kv';
  87         if (defined $pfx[0]) {
  88                 $sql .= ' WHERE k LIKE ? ESCAPE ?';
  89                 my $anywhere = !!$pfx[1];
  90                 $pfx[1] = '\\';
  91                 $pfx[0] =~ s/([%_\\])/\\$1/g; # glob chars
  92                 $pfx[0] .= '%';
  93                 substr($pfx[0], 0, 0, '%') if $anywhere;
  94         } else {
  95                 @pfx = (); # [0] may've been undef
  96         }
  97         map { $_->[0] } @{$self->dbh->selectall_arrayref($sql, undef, @pfx)};
  98 }
  99
 100 sub delete_by_val {
 101         my ($self, $val, $lock) = @_;
 102         $lock //= $self->lock_for_scope_fast;
 103         $self->{dbh}->prepare_cached(<<'')->execute($val) + 0;
 104 DELETE FROM kv WHERE v = ?
 105
 106 }
 107
 108 sub replace_values {
 109         my ($self, $oldval, $newval, $lock) = @_;
 110         $lock //= $self->lock_for_scope_fast;
 111         $self->{dbh}->prepare_cached(<<'')->execute($newval, $oldval) + 0;
 112 UPDATE kv SET v = ? WHERE v = ?
 113
 114 }
 115
 116 sub set {
 117         my ($self, $key, $val) = @_;
 118         if (defined $val) {
 119                 my $e = $self->{dbh}->prepare_cached(<<'')->execute($key, $val);
 120 INSERT OR REPLACE INTO kv (k,v) VALUES (?,?)
 121
 122                 $e == 0 ? undef : $e;
 123         } else {
 124                 $self->{dbh}->prepare_cached(<<'')->execute($key);
 125 DELETE FROM kv WHERE k = ?
 126
 127         }
 128 }
 129
 130 sub get {
 131         my ($self, $key) = @_;
 132         my $sth = $self->{dbh}->prepare_cached(<<'', undef, 1);
 133 SELECT v FROM kv WHERE k = ?
 134
 135         $sth->execute($key);
 136         $sth->fetchrow_array;
 137 }
 138
 139 sub xchg {
 140         my ($self, $key, $newval, $lock) = @_;
 141         $lock //= $self->lock_for_scope_fast;
 142         my $oldval = get($self, $key);
 143         if (defined $newval) {
 144                 set($self, $key, $newval);
 145         } else {
 146                 $self->{dbh}->prepare_cached(<<'')->execute($key);
 147 DELETE FROM kv WHERE k = ?
 148
 149         }
 150         $oldval;
 151 }
 152
 153 sub count {
 154         my ($self) = @_;
 155         my $sth = $self->{dbh}->prepare_cached(<<'');
 156 SELECT COUNT(k) FROM kv
 157
 158         $sth->execute;
 159         $sth->fetchrow_array;
 160 }
 161
 162 # faster than ->count due to how SQLite works
 163 sub has_entries {
 164         my ($self) = @_;
 165         my @n = $self->{dbh}->selectrow_array('SELECT k FROM kv LIMIT 1');
 166         scalar(@n) ? 1 : undef;
 167 }
 168
 169 sub dbh_release {
 170         my ($self, $lock) = @_;
 171         my $dbh = delete $self->{dbh} or return;
 172         $lock //= $self->lock_for_scope_fast; # may be needed for WAL
 173         %{$dbh->{CachedKids}} = (); # cleanup prepare_cached
 174         $dbh->disconnect;
 175 }
 176
 177 sub DESTROY {
 178         my ($self) = @_;
 179         dbh_release($self);
 180         my $dir = delete $self->{"tmp$$.$self"} or return;
 181         my $tries = 0;
 182         do {
 183                 $! = 0;
 184                 eval { rmtree($dir) };
 185         } while ($@ && $!{ENOENT} && $tries++ < 5);
 186         warn "error removing $dir: $@" if $@;
 187         warn "Took $tries tries to remove $dir\n" if $tries;
 188 }
 189
 190 1;