lib/PublicInbox/Sigfd.pm

   1 # Copyright (C) 2019-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Sigfd;
   4 use strict;
   5 use parent qw(PublicInbox::DS);
   6 use fields qw(sig); # hashref similar to %SIG, but signal numbers as keys
   7 use PublicInbox::Syscall qw(signalfd EPOLLIN EPOLLET SFD_NONBLOCK);
   8 use POSIX ();
   9 use IO::Handle ();
  10
  11 # returns a coderef to unblock signals if neither signalfd or kqueue
  12 # are available.
  13 sub new {
  14         my ($class, $sig, $flags) = @_;
  15         my $self = fields::new($class);
  16         my %signo = map {;
  17                 my $cb = $sig->{$_};
  18                 my $num = ($_ eq 'WINCH' && $^O =~ /linux|bsd/i) ? 28 : do {
  19                         my $m = "SIG$_";
  20                         POSIX->$m;
  21                 };
  22                 $num => $cb;
  23         } keys %$sig;
  24         my $io;
  25         my $fd = signalfd(-1, [keys %signo], $flags);
  26         if (defined $fd && $fd >= 0) {
  27                 $io = IO::Handle->new_from_fd($fd, 'r+');
  28         } elsif (eval { require PublicInbox::DSKQXS }) {
  29                 $io = PublicInbox::DSKQXS->signalfd([keys %signo], $flags);
  30         } else {
  31                 return; # wake up every second to check for signals
  32         }
  33         if ($flags & SFD_NONBLOCK) { # it can go into the event loop
  34                 $self->SUPER::new($io, EPOLLIN | EPOLLET);
  35         } else { # master main loop
  36                 $self->{sock} = $io;
  37         }
  38         $self->{sig} = \%signo;
  39         $self;
  40 }
  41
  42 # PublicInbox::Daemon in master main loop (blocking)
  43 sub wait_once ($) {
  44         my ($self) = @_;
  45         # 128 == sizeof(struct signalfd_siginfo)
  46         my $r = sysread($self->{sock}, my $buf, 128 * 64);
  47         if (defined($r)) {
  48                 my $nr = $r / 128 - 1; # $nr may be -1
  49                 for my $off (0..$nr) {
  50                         # the first uint32_t of signalfd_siginfo: ssi_signo
  51                         my $signo = unpack('L', substr($buf, 128 * $off, 4));
  52                         my $cb = $self->{sig}->{$signo};
  53                         $cb->($signo) if $cb ne 'IGNORE';
  54                 }
  55         }
  56         $r;
  57 }
  58
  59 # called by PublicInbox::DS in epoll_wait loop
  60 sub event_step {
  61         while (wait_once($_[0])) {} # non-blocking
  62 }
  63
  64 1;