lib/PublicInbox/Sigfd.pm

   1 # Copyright (C) 2019-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Wraps a signalfd (or similar) for PublicInbox::DS
   5 # fields: (sig: hashref similar to %SIG, but signal numbers as keys)
   6 package PublicInbox::Sigfd;
   7 use strict;
   8 use parent qw(PublicInbox::DS);
   9 use PublicInbox::Syscall qw(signalfd EPOLLIN EPOLLET SFD_NONBLOCK);
  10 use POSIX qw(:signal_h);
  11 use IO::Handle ();
  12
  13 # returns a coderef to unblock signals if neither signalfd or kqueue
  14 # are available.
  15 sub new {
  16         my ($class, $sig, $flags) = @_;
  17         my %signo = map {;
  18                 my $cb = $sig->{$_};
  19                 # SIGWINCH is 28 on FreeBSD, NetBSD, OpenBSD
  20                 my $num = ($_ eq 'WINCH' && $^O =~ /linux|bsd/i) ? 28 : do {
  21                         my $m = "SIG$_";
  22                         POSIX->$m;
  23                 };
  24                 $num => $cb;
  25         } keys %$sig;
  26         my $self = bless { sig => \%signo }, $class;
  27         my $io;
  28         my $fd = signalfd(-1, [keys %signo], $flags);
  29         if (defined $fd && $fd >= 0) {
  30                 $io = IO::Handle->new_from_fd($fd, 'r+');
  31         } elsif (eval { require PublicInbox::DSKQXS }) {
  32                 $io = PublicInbox::DSKQXS->signalfd([keys %signo], $flags);
  33         } else {
  34                 return; # wake up every second to check for signals
  35         }
  36         if ($flags & SFD_NONBLOCK) { # it can go into the event loop
  37                 $self->SUPER::new($io, EPOLLIN | EPOLLET);
  38         } else { # master main loop
  39                 $self->{sock} = $io;
  40                 $self;
  41         }
  42 }
  43
  44 # PublicInbox::Daemon in master main loop (blocking)
  45 sub wait_once ($) {
  46         my ($self) = @_;
  47         # 128 == sizeof(struct signalfd_siginfo)
  48         my $r = sysread($self->{sock}, my $buf, 128 * 64);
  49         if (defined($r)) {
  50                 my $nr = $r / 128 - 1; # $nr may be -1
  51                 for my $off (0..$nr) {
  52                         # the first uint32_t of signalfd_siginfo: ssi_signo
  53                         my $signo = unpack('L', substr($buf, 128 * $off, 4));
  54                         my $cb = $self->{sig}->{$signo};
  55                         $cb->($signo) if $cb ne 'IGNORE';
  56                 }
  57         }
  58         $r;
  59 }
  60
  61 # called by PublicInbox::DS in epoll_wait loop
  62 sub event_step {
  63         while (wait_once($_[0])) {} # non-blocking
  64 }
  65
  66 sub sig_setmask { sigprocmask(SIG_SETMASK, @_) or die "sigprocmask: $!" }
  67
  68 sub block_signals () {
  69         my $oldset = POSIX::SigSet->new;
  70         my $newset = POSIX::SigSet->new;
  71         $newset->fillset or die "fillset: $!";
  72         sig_setmask($newset, $oldset);
  73         $oldset;
  74 }
  75
  76 1;