lib/PublicInbox/Smsg.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # A small/skeleton/slim representation of a message.
   5
   6 # This used to be "SearchMsg", but we split out overview
   7 # indexing into over.sqlite3 so it's not just "search".  There
   8 # may be many of these objects loaded in memory at once for
   9 # large threads in our WWW UI and the NNTP range responses.
  10 package PublicInbox::Smsg;
  11 use strict;
  12 use warnings;
  13 use base qw(Exporter);
  14 our @EXPORT_OK = qw(subject_normalized);
  15 use PublicInbox::MID qw/mid_mime/;
  16 use PublicInbox::Address;
  17 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  18 use Time::Local qw(timegm);
  19
  20 sub new {
  21         my ($class, $mime) = @_;
  22         bless { mime => $mime }, $class;
  23 }
  24
  25 sub wrap {
  26         my ($class, $mid) = @_;
  27         bless { mid => $mid }, $class;
  28 }
  29
  30 sub get_val ($$) {
  31         my ($doc, $col) = @_;
  32         # sortable_unserialise is defined by PublicInbox::Search::load_xapian()
  33         sortable_unserialise($doc->get_value($col));
  34 }
  35
  36 sub to_doc_data {
  37         my ($self) = @_;
  38         join("\n",
  39                 $self->subject,
  40                 $self->from,
  41                 $self->references,
  42                 $self->to,
  43                 $self->cc,
  44                 $self->{blob},
  45                 $self->{mid},
  46                 $self->{bytes} // '',
  47                 $self->{lines} // ''
  48         );
  49 }
  50
  51 sub load_from_data ($$) {
  52         my ($self) = $_[0]; # data = $_[1]
  53         (
  54                 $self->{subject},
  55                 $self->{from},
  56                 $self->{references},
  57
  58                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  59                 # some NNTP clients will use that for message displays.
  60                 # NNTP only, and only stored in Over(view), not Xapian
  61                 $self->{to},
  62                 $self->{cc},
  63
  64                 $self->{blob},
  65                 $self->{mid},
  66
  67                 # NNTP only
  68                 $self->{bytes},
  69                 $self->{lines}
  70         ) = split(/\n/, $_[1]);
  71 }
  72
  73 sub load_expand {
  74         my ($self, $doc) = @_;
  75         my $data = $doc->get_data or return;
  76         $self->{ts} = get_val($doc, PublicInbox::Search::TS());
  77         my $dt = get_val($doc, PublicInbox::Search::DT());
  78         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
  79         $self->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
  80         utf8::decode($data);
  81         load_from_data($self, $data);
  82         $self;
  83 }
  84
  85 sub psgi_cull ($) {
  86         my ($self) = @_;
  87         from_name($self); # fill in {from_name} so we can delete {from}
  88
  89         # drop NNTP-only fields which aren't relevant to PSGI results:
  90         # saves ~80K on a 200 item search result:
  91         delete @$self{qw(from ts to cc bytes lines)};
  92         $self;
  93 }
  94
  95 # Only called by PSGI interface, not NNTP
  96 sub from_mitem {
  97         my ($mitem, $srch) = @_;
  98         return $srch->retry_reopen(\&from_mitem, $mitem) if $srch;
  99         my $self = bless {}, __PACKAGE__;
 100         psgi_cull(load_expand($self, $mitem->get_document));
 101 }
 102
 103 # :bytes and :lines metadata in RFC 3977
 104 sub bytes ($) { $_[0]->{bytes} }
 105 sub lines ($) { $_[0]->{lines} }
 106
 107 sub __hdr ($$) {
 108         my ($self, $field) = @_;
 109         $self->{lc($field)} //= do {
 110                 my $mime = $self->{mime} or return;
 111                 my $val = join(', ', $mime->header($field));
 112                 $val =~ tr/\r//d;
 113                 $val =~ tr/\t\n/  /;
 114                 $val;
 115         };
 116 }
 117
 118 sub subject ($) { __hdr($_[0], 'Subject') }
 119 sub to ($) { __hdr($_[0], 'To') }
 120 sub cc ($) { __hdr($_[0], 'Cc') }
 121
 122 # no strftime, that is locale-dependent and not for RFC822
 123 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 124 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 125
 126 sub date ($) {
 127         my ($self) = @_;
 128         my $ds = $self->{ds};
 129         return unless defined $ds;
 130         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 131         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 132                                 $mday, $year+1900, $hour, $min, $sec);
 133
 134 }
 135
 136 sub from ($) {
 137         my ($self) = @_;
 138         my $from = __hdr($self, 'From');
 139         if (defined $from && !defined $self->{from_name}) {
 140                 my @n = PublicInbox::Address::names($from);
 141                 $self->{from_name} = join(', ', @n);
 142         }
 143         $from;
 144 }
 145
 146 sub from_name {
 147         my ($self) = @_;
 148         my $from_name = $self->{from_name};
 149         return $from_name if defined $from_name;
 150         $self->from;
 151         $self->{from_name};
 152 }
 153
 154 sub ts {
 155         my ($self) = @_;
 156         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 157 }
 158
 159 sub ds {
 160         my ($self) = @_;
 161         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 162 }
 163
 164 sub references {
 165         my ($self) = @_;
 166         my $x = $self->{references};
 167         defined $x ? $x : '';
 168 }
 169
 170 sub mid ($;$) {
 171         my ($self, $mid) = @_;
 172
 173         if (defined $mid) {
 174                 $self->{mid} = $mid;
 175         } elsif (defined(my $rv = $self->{mid})) {
 176                 $rv;
 177         } else {
 178                 die "NO {mime} for mid\n" unless $self->{mime};
 179                 mid_mime($self->{mime}) # v1 w/o Xapian
 180         }
 181 }
 182
 183 our $REPLY_RE = qr/^re:\s+/i;
 184
 185 sub subject_normalized ($) {
 186         my ($subj) = @_;
 187         $subj =~ s/\A\s+//s; # no leading space
 188         $subj =~ s/\s+\z//s; # no trailing space
 189         $subj =~ s/\s+/ /gs; # no redundant spaces
 190         $subj =~ s/\.+\z//; # no trailing '.'
 191         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 192         $subj;
 193 }
 194
 195 1;