lib/PublicInbox/Smsg.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # A small/skeleton/slim representation of a message.
   5
   6 # This used to be "SearchMsg", but we split out overview
   7 # indexing into over.sqlite3 so it's not just "search".  There
   8 # may be many of these objects loaded in memory at once for
   9 # large threads in our WWW UI and the NNTP range responses.
  10 package PublicInbox::Smsg;
  11 use strict;
  12 use warnings;
  13 use base qw(Exporter);
  14 our @EXPORT_OK = qw(subject_normalized);
  15 use PublicInbox::MID qw/mid_clean mid_mime/;
  16 use PublicInbox::Address;
  17 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  18 use Time::Local qw(timegm);
  19
  20 sub new {
  21         my ($class, $mime) = @_;
  22         bless { mime => $mime }, $class;
  23 }
  24
  25 sub wrap {
  26         my ($class, $mid) = @_;
  27         bless { mid => $mid }, $class;
  28 }
  29
  30 sub get_val ($$) {
  31         my ($doc, $col) = @_;
  32         # sortable_unserialise is defined by PublicInbox::Search::load_xapian()
  33         sortable_unserialise($doc->get_value($col));
  34 }
  35
  36 sub to_doc_data {
  37         my ($self, $oid, $mid0) = @_;
  38         $oid = '' unless defined $oid;
  39         join("\n",
  40                 $self->subject,
  41                 $self->from,
  42                 $self->references,
  43                 $self->to,
  44                 $self->cc,
  45                 $oid,
  46                 $mid0,
  47                 $self->{bytes} // '',
  48                 $self->{lines} // ''
  49         );
  50 }
  51
  52 sub load_from_data ($$) {
  53         my ($self) = $_[0]; # data = $_[1]
  54         (
  55                 $self->{subject},
  56                 $self->{from},
  57                 $self->{references},
  58
  59                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  60                 # some NNTP clients will use that for message displays.
  61                 # NNTP only, and only stored in Over(view), not Xapian
  62                 $self->{to},
  63                 $self->{cc},
  64
  65                 $self->{blob},
  66                 $self->{mid},
  67
  68                 # NNTP only
  69                 $self->{bytes},
  70                 $self->{lines}
  71         ) = split(/\n/, $_[1]);
  72 }
  73
  74 sub load_expand {
  75         my ($self, $doc) = @_;
  76         my $data = $doc->get_data or return;
  77         $self->{ts} = get_val($doc, PublicInbox::Search::TS());
  78         my $dt = get_val($doc, PublicInbox::Search::DT());
  79         my ($yyyy, $mon, $dd, $hh, $mm, $ss) = unpack('A4A2A2A2A2A2', $dt);
  80         $self->{ds} = timegm($ss, $mm, $hh, $dd, $mon - 1, $yyyy);
  81         utf8::decode($data);
  82         load_from_data($self, $data);
  83         $self;
  84 }
  85
  86 sub psgi_cull ($) {
  87         my ($self) = @_;
  88         from_name($self); # fill in {from_name} so we can delete {from}
  89
  90         # drop NNTP-only fields which aren't relevant to PSGI results:
  91         # saves ~80K on a 200 item search result:
  92         delete @$self{qw(from ts to cc bytes lines)};
  93         $self;
  94 }
  95
  96 # Only called by PSGI interface, not NNTP
  97 sub from_mitem {
  98         my ($mitem, $srch) = @_;
  99         return $srch->retry_reopen(\&from_mitem, $mitem) if $srch;
 100         my $self = bless {}, __PACKAGE__;
 101         psgi_cull(load_expand($self, $mitem->get_document));
 102 }
 103
 104 # :bytes and :lines metadata in RFC 3977
 105 sub bytes ($) { $_[0]->{bytes} }
 106 sub lines ($) { $_[0]->{lines} }
 107
 108 sub __hdr ($$) {
 109         my ($self, $field) = @_;
 110         my $val = $self->{$field};
 111         return $val if defined $val;
 112
 113         my $mime = $self->{mime} or return;
 114         my @raw = $mime->header($field);
 115         $val = join(', ', @raw);
 116         $val =~ tr/\t\n/  /;
 117         $val =~ tr/\r//d;
 118         $self->{$field} = $val;
 119 }
 120
 121 sub subject ($) { __hdr($_[0], 'subject') }
 122 sub to ($) { __hdr($_[0], 'to') }
 123 sub cc ($) { __hdr($_[0], 'cc') }
 124
 125 # no strftime, that is locale-dependent and not for RFC822
 126 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 127 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 128
 129 sub date ($) {
 130         my ($self) = @_;
 131         my $ds = $self->{ds};
 132         return unless defined $ds;
 133         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 134         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 135                                 $mday, $year+1900, $hour, $min, $sec);
 136
 137 }
 138
 139 sub from ($) {
 140         my ($self) = @_;
 141         my $from = __hdr($self, 'from');
 142         if (defined $from && !defined $self->{from_name}) {
 143                 my @n = PublicInbox::Address::names($from);
 144                 $self->{from_name} = join(', ', @n);
 145         }
 146         $from;
 147 }
 148
 149 sub from_name {
 150         my ($self) = @_;
 151         my $from_name = $self->{from_name};
 152         return $from_name if defined $from_name;
 153         $self->from;
 154         $self->{from_name};
 155 }
 156
 157 sub ts {
 158         my ($self) = @_;
 159         $self->{ts} ||= eval { msg_timestamp($self->{mime}->header_obj) } || 0;
 160 }
 161
 162 sub ds {
 163         my ($self) = @_;
 164         $self->{ds} ||= eval { msg_datestamp($self->{mime}->header_obj); } || 0;
 165 }
 166
 167 sub references {
 168         my ($self) = @_;
 169         my $x = $self->{references};
 170         defined $x ? $x : '';
 171 }
 172
 173 sub mid ($;$) {
 174         my ($self, $mid) = @_;
 175
 176         if (defined $mid) {
 177                 $self->{mid} = $mid;
 178         } elsif (defined(my $rv = $self->{mid})) {
 179                 $rv;
 180         } else {
 181                 die "NO {mime} for mid\n" unless $self->{mime};
 182                 $self->_extract_mid; # v1 w/o Xapian
 183         }
 184 }
 185
 186 sub _extract_mid { mid_clean(mid_mime($_[0]->{mime})) }
 187
 188 our $REPLY_RE = qr/^re:\s+/i;
 189
 190 sub subject_normalized ($) {
 191         my ($subj) = @_;
 192         $subj =~ s/\A\s+//s; # no leading space
 193         $subj =~ s/\s+\z//s; # no trailing space
 194         $subj =~ s/\s+/ /gs; # no redundant spaces
 195         $subj =~ s/\.+\z//; # no trailing '.'
 196         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 197         $subj;
 198 }
 199
 200 1;