lib/PublicInbox/Smsg.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # A small/skeleton/slim representation of a message.
   5
   6 # This used to be "SearchMsg", but we split out overview
   7 # indexing into over.sqlite3 so it's not just "search".  There
   8 # may be many of these objects loaded in memory at once for
   9 # large threads in our WWW UI and the NNTP range responses.
  10 package PublicInbox::Smsg;
  11 use strict;
  12 use warnings;
  13 use base qw(Exporter);
  14 our @EXPORT_OK = qw(subject_normalized);
  15 use PublicInbox::MID qw(mids references);
  16 use PublicInbox::Address;
  17 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  18
  19 sub to_doc_data {
  20         my ($self) = @_;
  21         join("\n",
  22                 $self->{subject},
  23                 $self->{from},
  24                 $self->{references} // '',
  25                 $self->{to},
  26                 $self->{cc},
  27                 $self->{blob},
  28                 $self->{mid},
  29                 $self->{bytes} // '',
  30                 $self->{lines} // ''
  31         );
  32 }
  33
  34 sub load_from_data ($$) {
  35         my ($self) = $_[0]; # data = $_[1]
  36         utf8::decode($_[1]);
  37         (
  38                 $self->{subject},
  39                 $self->{from},
  40                 $self->{references},
  41
  42                 # To: and Cc: are stored to optimize HDR/XHDR in NNTP since
  43                 # some NNTP clients will use that for message displays.
  44                 # NNTP only, and only stored in Over(view), not Xapian
  45                 $self->{to},
  46                 $self->{cc},
  47
  48                 $self->{blob},
  49                 $self->{mid},
  50
  51                 # NNTP only
  52                 $self->{bytes},
  53                 $self->{lines}
  54         ) = split(/\n/, $_[1]);
  55 }
  56
  57 sub psgi_cull ($) {
  58         my ($self) = @_;
  59
  60         # ghosts don't have ->{from}
  61         my $from = delete($self->{from}) // '';
  62         my @n = PublicInbox::Address::names($from);
  63         $self->{from_name} = join(', ', @n);
  64
  65         # drop NNTP-only fields which aren't relevant to PSGI results:
  66         # saves ~80K on a 200 item search result:
  67         # TODO: we may need to keep some of these for JMAP...
  68         delete @$self{qw(tid to cc bytes lines)};
  69         $self;
  70 }
  71
  72 sub parse_references ($$$) {
  73         my ($smsg, $hdr, $mids) = @_;
  74         my $refs = references($hdr);
  75         push(@$refs, @$mids) if scalar(@$mids) > 1;
  76         return $refs if scalar(@$refs) == 0;
  77
  78         # prevent circular references here:
  79         my %seen = ( ($smsg->{mid} // '') => 1 );
  80         my @keep;
  81         foreach my $ref (@$refs) {
  82                 if (length($ref) > PublicInbox::MID::MAX_MID_SIZE) {
  83                         warn "References: <$ref> too long, ignoring\n";
  84                         next;
  85                 }
  86                 $seen{$ref} //= push(@keep, $ref);
  87         }
  88         $smsg->{references} = '<'.join('> <', @keep).'>' if @keep;
  89         \@keep;
  90 }
  91
  92 # used for v2, Import and v1 non-SQLite WWW code paths
  93 sub populate {
  94         my ($self, $hdr, $sync) = @_;
  95         for my $f (qw(From To Cc Subject)) {
  96                 my @all = $hdr->header($f);
  97                 my $val = join(', ', @all);
  98                 $val =~ tr/\r//d;
  99                 # MIME decoding can create NULs, replace them with spaces
 100                 # to protect git and NNTP clients
 101                 $val =~ tr/\0\t\n/   /;
 102
 103                 # rare: in case headers have wide chars (not RFC2047-encoded)
 104                 utf8::decode($val);
 105
 106                 # lower-case fields for read-only stuff
 107                 $self->{lc($f)} = $val;
 108
 109                 # Capitalized From/Subject for git-fast-import
 110                 next if $f eq 'To' || $f eq 'Cc';
 111                 if (scalar(@all) > 1) {
 112                         $val = $all[0];
 113                         $val =~ tr/\r//d;
 114                         $val =~ tr/\0\t\n/   /;
 115                 }
 116                 $self->{$f} = $val if $val ne '';
 117         }
 118         $sync //= {};
 119         $self->{-ds} = [ my @ds = msg_datestamp($hdr, $sync->{autime}) ];
 120         $self->{-ts} = [ my @ts = msg_timestamp($hdr, $sync->{cotime}) ];
 121         $self->{ds} //= $ds[0]; # no zone
 122         $self->{ts} //= $ts[0];
 123         $self->{mid} //= mids($hdr)->[0];
 124 }
 125
 126 # no strftime, that is locale-dependent and not for RFC822
 127 my @DoW = qw(Sun Mon Tue Wed Thu Fri Sat);
 128 my @MoY = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
 129
 130 sub date ($) { # for NNTP
 131         my ($self) = @_;
 132         my $ds = $self->{ds};
 133         return unless defined $ds;
 134         my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($ds);
 135         "$DoW[$wday], " . sprintf("%02d $MoY[$mon] %04d %02d:%02d:%02d +0000",
 136                                 $mday, $year+1900, $hour, $min, $sec);
 137 }
 138
 139 sub internaldate { # for IMAP
 140         my ($self) = @_;
 141         my ($sec, $min, $hour, $mday, $mon, $year) = gmtime($self->{ts} // 0);
 142         sprintf("%02d-$MoY[$mon]-%04d %02d:%02d:%02d +0000",
 143                                 $mday, $year+1900, $hour, $min, $sec);
 144 }
 145
 146 our $REPLY_RE = qr/^re:\s+/i;
 147
 148 sub subject_normalized ($) {
 149         my ($subj) = @_;
 150         $subj =~ s/\A\s+//s; # no leading space
 151         $subj =~ s/\s+\z//s; # no trailing space
 152         $subj =~ s/\s+/ /gs; # no redundant spaces
 153         $subj =~ s/\.+\z//; # no trailing '.'
 154         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 155         $subj;
 156 }
 157
 158 # returns the number of bytes to add if given a non-CRLF arg
 159 sub crlf_adjust ($) {
 160         if (index($_[0], "\r\n") < 0) {
 161                 # common case is LF-only, every \n needs an \r;
 162                 # so favor a cheap tr// over an expensive m//g
 163                 $_[0] =~ tr/\n/\n/;
 164         } else { # count number of '\n' w/o '\r', expensive:
 165                 scalar(my @n = ($_[0] =~ m/(?<!\r)\n/g));
 166         }
 167 }
 168
 169 sub set_bytes { $_[0]->{bytes} = $_[2] + crlf_adjust($_[1]) }
 170
 171 1;