lib/PublicInbox/SolverGit.pm

   1 # Copyright (C) 2019-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "Solve" blobs which don't exist in git code repositories by
   5 # searching inboxes for post-image blobs.
   6
   7 # this emits a lot of debugging/tracing information which may be
   8 # publicly viewed over HTTP(S).  Be careful not to expose
   9 # local filesystem layouts in the process.
  10 package PublicInbox::SolverGit;
  11 use strict;
  12 use v5.10.1;
  13 use File::Temp 0.19 (); # 0.19 for ->newdir
  14 use Fcntl qw(SEEK_SET);
  15 use PublicInbox::Git qw(git_unquote git_quote);
  16 use PublicInbox::MsgIter qw(msg_part_text);
  17 use PublicInbox::Qspawn;
  18 use PublicInbox::Tmpfile;
  19 use URI::Escape qw(uri_escape_utf8);
  20
  21 # POSIX requires _POSIX_ARG_MAX >= 4096, and xargs is required to
  22 # subtract 2048 bytes.  We also don't factor in environment variable
  23 # headroom into this.
  24 use POSIX qw(sysconf _SC_ARG_MAX);
  25 my $ARG_SIZE_MAX = (sysconf(_SC_ARG_MAX) || 4096) - 2048;
  26 my $OID_MIN = 7;
  27
  28 # By default, "git format-patch" generates filenames with a four-digit
  29 # prefix, so that means 9999 patch series are OK, right? :>
  30 # Maybe we can make this configurable, main concern is disk space overhead
  31 # for uncompressed patch fragments.  Aside from space, public-inbox-httpd
  32 # is otherwise unaffected by having many patches, here, as it can share
  33 # work fairly.  Other PSGI servers may have trouble, though.
  34 my $MAX_PATCH = 9999;
  35
  36 my $LF = qr!\r?\n!;
  37 my $ANY = qr![^\r\n]+!;
  38 my $MODE = '100644|120000|100755';
  39 my $FN = qr!(?:("?[^/\n]+/[^\r\n]+)|/dev/null)!;
  40 my %BAD_COMPONENT = ('' => 1, '.' => 1, '..' => 1);
  41
  42 # di = diff info / a hashref with information about a diff ($di):
  43 # {
  44 #       oid_a => abbreviated pre-image oid,
  45 #       oid_b => abbreviated post-image oid,
  46 #       tmp => anonymous file handle with the diff,
  47 #       hdr_lines => string of various header lines for mode information
  48 #       mode_a => original mode of oid_a (string, not integer),
  49 #       ibx => PublicInbox::Inbox object containing the diff
  50 #       smsg => PublicInbox::Smsg object containing diff
  51 #       path_a => pre-image path
  52 #       path_b => post-image path
  53 #       n => numeric path of the patch (relative to worktree)
  54 # }
  55
  56 sub dbg ($$) {
  57         print { $_[0]->{out} } $_[1], "\n" or ERR($_[0], "print(dbg): $!");
  58 }
  59
  60 sub done ($$) {
  61         my ($self, $res) = @_;
  62         my $ucb = delete($self->{user_cb}) or return;
  63         $ucb->($res, $self->{uarg});
  64 }
  65
  66 sub ERR ($$) {
  67         my ($self, $err) = @_;
  68         print { $self->{out} } $err, "\n";
  69         eval { done($self, $err) };
  70         die $err;
  71 }
  72
  73 # look for existing objects already in git repos
  74 sub solve_existing ($$) {
  75         my ($self, $want) = @_;
  76         my $oid_b = $want->{oid_b};
  77         my $have_hints = scalar keys %$want > 1;
  78         my @ambiguous; # Array of [ git, $oids]
  79         foreach my $git (@{$self->{gits}}) {
  80                 my ($oid_full, $type, $size) = $git->check($oid_b);
  81                 if (defined($type) && (!$have_hints || $type eq 'blob')) {
  82                         return [ $git, $oid_full, $type, int($size) ];
  83                 }
  84
  85                 next if length($oid_b) == 40;
  86
  87                 # parse stderr of "git cat-file --batch-check"
  88                 my $err = $git->last_check_err;
  89                 my (@oids) = ($err =~ /\b([a-f0-9]{40})\s+blob\b/g);
  90                 next unless scalar(@oids);
  91
  92                 # TODO: do something with the ambiguous array?
  93                 # push @ambiguous, [ $git, @oids ];
  94
  95                 dbg($self, "`$oid_b' ambiguous in " .
  96                                 join("\n\t", $git->pub_urls($self->{psgi_env}))
  97                                 . "\n" .
  98                                 join('', map { "$_ blob\n" } @oids));
  99         }
 100         scalar(@ambiguous) ? \@ambiguous : undef;
 101 }
 102
 103 sub extract_diff ($$) {
 104         my ($p, $arg) = @_;
 105         my ($self, $diffs, $pre, $post, $ibx, $smsg) = @$arg;
 106         my ($part) = @$p; # ignore $depth and @idx;
 107         my $ct = $part->content_type || 'text/plain';
 108         my ($s, undef) = msg_part_text($part, $ct);
 109         defined $s or return;
 110
 111         # Email::MIME::Encodings forces QP to be CRLF upon decoding,
 112         # change it back to LF:
 113         my $cte = $part->header('Content-Transfer-Encoding') || '';
 114         if ($cte =~ /\bquoted-printable\b/i && $part->crlf eq "\n") {
 115                 $s =~ s/\r\n/\n/sg;
 116         }
 117
 118
 119         $s =~ m!( # $1 start header lines we save for debugging:
 120
 121                 # everything before ^index is optional, but we don't
 122                 # want to match ^(old|copy|rename|deleted|...) unless
 123                 # we match /^diff --git/ first:
 124                 (?: # begin optional stuff:
 125
 126                 # try to get the pre-and-post filenames as $2 and $3
 127                 (?:^diff\x20--git\x20$FN\x20$FN$LF)
 128
 129                 (?:^(?: # pass all this to git-apply:
 130                         # old mode $4
 131                         (?:old\x20mode\x20($MODE))
 132                         |
 133                         # new mode (possibly new file) ($5)
 134                         (?:new\x20(?:file\x20)?mode\x20($MODE))
 135                         |
 136                         (?:(?:copy|rename|deleted|
 137                                 dissimilarity|similarity)$ANY)
 138                 )$LF)*
 139
 140                 )? # end of optional stuff, everything below is required
 141
 142                 # match the pre and post-image OIDs as $6 $7
 143                 ^index\x20(${pre}[a-f0-9]*)\.\.(${post}[a-f0-9]*)
 144                         # mode if unchanged $8
 145                         (?:\x20(100644|120000|100755))?$LF
 146         ) # end of header lines ($1)
 147         ( # $9 is the patch body
 148                 # "--- a/foo.c" sets pre-filename ($10) in case
 149                 # $2 is missing
 150                 (?:^---\x20$FN$LF)
 151
 152                 # "+++ b/foo.c" sets post-filename ($11) in case
 153                 # $3 is missing
 154                 (?:^\+{3}\x20$FN$LF)
 155
 156                 # the meat of the diff, including "^\\No newline ..."
 157                 # We also allow for totally blank lines w/o leading spaces,
 158                 # because git-apply(1) handles that case, too
 159                 (?:^(?:[\@\+\x20\-\\][^\n]*|)$LF)+
 160         )!smx or return;
 161
 162         my $di = {
 163                 hdr_lines => $1,
 164                 oid_a => $6,
 165                 oid_b => $7,
 166                 mode_a => $5 // $8 // $4, # new (file) // unchanged // old
 167         };
 168         my $path_a = $2 // $10;
 169         my $path_b = $3 // $11;
 170         my $patch = $9;
 171
 172         # don't care for leading 'a/' and 'b/'
 173         my (undef, @a) = split(m{/}, git_unquote($path_a)) if defined($path_a);
 174         my (undef, @b) = split(m{/}, git_unquote($path_b));
 175
 176         # get rid of path-traversal attempts and junk patches:
 177         # it's junk at best, an attack attempt at worse:
 178         foreach (@a, @b) { return if $BAD_COMPONENT{$_} }
 179
 180         $di->{path_a} = join('/', @a) if @a;
 181         $di->{path_b} = join('/', @b);
 182
 183         my $path = ++$self->{tot};
 184         $di->{n} = $path;
 185         open(my $tmp, '>:utf8', $self->{tmp}->dirname . "/$path") or
 186                 die "open(tmp): $!";
 187         print $tmp $di->{hdr_lines}, $patch or die "print(tmp): $!";
 188         close $tmp or die "close(tmp): $!";
 189
 190         # for debugging/diagnostics:
 191         $di->{ibx} = $ibx;
 192         $di->{smsg} = $smsg;
 193
 194         push @$diffs, $di;
 195 }
 196
 197 sub path_searchable ($) { defined($_[0]) && $_[0] =~ m!\A[\w/\. \-]+\z! }
 198
 199 # ".." appears in path names, which confuses Xapian into treating
 200 # it as a range query.  So we split on ".." since Xapian breaks
 201 # on punctuation anyways:
 202 sub filename_query ($) {
 203         join('', map { qq( dfn:"$_") } split(/\.\./, $_[0]));
 204 }
 205
 206 sub find_extract_diffs ($$$) {
 207         my ($self, $ibx, $want) = @_;
 208         my $srch = $ibx->search or return;
 209
 210         my $post = $want->{oid_b} or die 'BUG: no {oid_b}';
 211         $post =~ /\A[a-f0-9]+\z/ or die "BUG: oid_b not hex: $post";
 212
 213         my $q = "dfpost:$post";
 214         my $pre = $want->{oid_a};
 215         if (defined $pre && $pre =~ /\A[a-f0-9]+\z/) {
 216                 $q .= " dfpre:$pre";
 217         } else {
 218                 $pre = '[a-f0-9]{7}'; # for $re below
 219         }
 220
 221         my $path_b = $want->{path_b};
 222         if (path_searchable($path_b)) {
 223                 $q .= filename_query($path_b);
 224
 225                 my $path_a = $want->{path_a};
 226                 if (path_searchable($path_a) && $path_a ne $path_b) {
 227                         $q .= filename_query($path_a);
 228                 }
 229         }
 230
 231         my $mset = $srch->mset($q, { relevance => 1 });
 232         my $diffs = [];
 233         for my $smsg (@{$srch->mset_to_smsg($ibx, $mset)}) {
 234                 my $eml = $ibx->smsg_eml($smsg) or next;
 235                 $eml->each_part(\&extract_diff,
 236                                 [$self, $diffs, $pre, $post, $ibx, $smsg], 1);
 237         }
 238         @$diffs ? $diffs : undef;
 239 }
 240
 241 sub update_index_result ($$) {
 242         my ($bref, $self) = @_;
 243         my ($qsp, $msg) = delete @$self{qw(-qsp -msg)};
 244         if (my $err = $qsp->{err}) {
 245                 ERR($self, "git update-index error: $err");
 246         }
 247         dbg($self, $msg);
 248         next_step($self); # onto do_git_apply
 249 }
 250
 251 sub prepare_index ($) {
 252         my ($self) = @_;
 253         my $patches = $self->{patches};
 254         $self->{nr} = 0;
 255
 256         my $di = $patches->[0] or die 'no patches';
 257         my $oid_a = $di->{oid_a} or die '{oid_a} unset';
 258         my $existing = $self->{found}->{$oid_a};
 259
 260         # no index creation for added files
 261         $oid_a =~ /\A0+\z/ and return next_step($self);
 262
 263         die "BUG: $oid_a not not found" unless $existing;
 264
 265         my $oid_full = $existing->[1];
 266         my $path_a = $di->{path_a} or die "BUG: path_a missing for $oid_full";
 267         my $mode_a = $di->{mode_a} // '100644';
 268
 269         my $in = tmpfile("update-index.$oid_full") or die "tmpfile: $!";
 270         print $in "$mode_a $oid_full\t$path_a\0" or die "print: $!";
 271         $in->flush or die "flush: $!";
 272         sysseek($in, 0, SEEK_SET) or die "seek: $!";
 273
 274         dbg($self, 'preparing index');
 275         my $rdr = { 0 => $in };
 276         my $cmd = [ qw(git update-index -z --index-info) ];
 277         my $qsp = PublicInbox::Qspawn->new($cmd, $self->{git_env}, $rdr);
 278         $path_a = git_quote($path_a);
 279         $self->{-qsp} = $qsp;
 280         $self->{-msg} = "index prepared:\n$mode_a $oid_full\t$path_a";
 281         $qsp->psgi_qx($self->{psgi_env}, undef, \&update_index_result, $self);
 282 }
 283
 284 # pure Perl "git init"
 285 sub do_git_init ($) {
 286         my ($self) = @_;
 287         my $dir = $self->{tmp}->dirname;
 288         my $git_dir = "$dir/git";
 289
 290         foreach ('', qw(objects refs objects/info refs/heads)) {
 291                 mkdir("$git_dir/$_") or die "mkdir $_: $!";
 292         }
 293         open my $fh, '>', "$git_dir/config" or die "open git/config: $!";
 294         print $fh <<'EOF' or die "print git/config $!";
 295 [core]
 296         repositoryFormatVersion = 0
 297         filemode = true
 298         bare = false
 299         fsyncObjectfiles = false
 300         logAllRefUpdates = false
 301 EOF
 302         close $fh or die "close git/config: $!";
 303
 304         open $fh, '>', "$git_dir/HEAD" or die "open git/HEAD: $!";
 305         print $fh "ref: refs/heads/master\n" or die "print git/HEAD: $!";
 306         close $fh or die "close git/HEAD: $!";
 307
 308         my $f = 'objects/info/alternates';
 309         open $fh, '>', "$git_dir/$f" or die "open: $f: $!";
 310         foreach my $git (@{$self->{gits}}) {
 311                 print $fh $git->git_path('objects'),"\n" or die "print $f: $!";
 312         }
 313         close $fh or die "close: $f: $!";
 314         my $tmp_git = $self->{tmp_git} = PublicInbox::Git->new($git_dir);
 315         $tmp_git->{-tmp} = $self->{tmp};
 316         $self->{git_env} = {
 317                 GIT_DIR => $git_dir,
 318                 GIT_INDEX_FILE => "$git_dir/index",
 319         };
 320         prepare_index($self);
 321 }
 322
 323 sub do_finish ($) {
 324         my ($self) = @_;
 325         my ($found, $oid_want) = @$self{qw(found oid_want)};
 326         if (my $exists = $found->{$oid_want}) {
 327                 return done($self, $exists);
 328         }
 329
 330         # let git disambiguate if oid_want was too short,
 331         # but long enough to be unambiguous:
 332         my $tmp_git = $self->{tmp_git};
 333         if (my @res = $tmp_git->check($oid_want)) {
 334                 return done($self, $found->{$res[0]});
 335         }
 336         if (my $err = $tmp_git->last_check_err) {
 337                 dbg($self, $err);
 338         }
 339         done($self, undef);
 340 }
 341
 342 sub event_step ($) {
 343         my ($self) = @_;
 344         eval {
 345                 # step 1: resolve blobs to patches in the todo queue
 346                 if (my $want = pop @{$self->{todo}}) {
 347                         # this populates {patches} and {todo}
 348                         resolve_patch($self, $want);
 349
 350                 # step 2: then we instantiate a working tree once
 351                 # the todo queue is finally empty:
 352                 } elsif (!defined($self->{tmp_git})) {
 353                         do_git_init($self);
 354
 355                 # step 3: apply each patch in the stack
 356                 } elsif (scalar @{$self->{patches}}) {
 357                         do_git_apply($self);
 358
 359                 # step 4: execute the user-supplied callback with
 360                 # our result: (which may be undef)
 361                 # Other steps may call user_cb to terminate prematurely
 362                 # on error
 363                 } elsif (exists $self->{user_cb}) {
 364                         do_finish($self);
 365                 } else {
 366                         die 'about to call user_cb twice'; # Oops :x
 367                 }
 368         }; # eval
 369         my $err = $@;
 370         if ($err) {
 371                 $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 372                 dbg($self, "E: $err");
 373                 eval { done($self, $err) };
 374         }
 375 }
 376
 377 sub next_step ($) {
 378         my ($self) = @_;
 379         # if outside of public-inbox-httpd, caller is expected to be
 380         # looping event_step, anyways
 381         my $async = $self->{psgi_env}->{'pi-httpd.async'} or return;
 382         # PublicInbox::HTTPD::Async->new
 383         $async->(undef, undef, $self);
 384 }
 385
 386 sub mark_found ($$$) {
 387         my ($self, $oid, $found_info) = @_;
 388         my $found = $self->{found};
 389         $found->{$oid} = $found_info;
 390         my $oid_cur = $found_info->[1];
 391         while ($oid_cur ne $oid && length($oid_cur) > $OID_MIN) {
 392                 $found->{$oid_cur} = $found_info;
 393                 chop($oid_cur);
 394         }
 395 }
 396
 397 sub parse_ls_files ($$) {
 398         my ($self, $bref) = @_;
 399         my ($qsp, $di) = delete @$self{qw(-qsp -cur_di)};
 400         if (my $err = $qsp->{err}) {
 401                 die "git ls-files error: $err";
 402         }
 403
 404         my ($line, @extra) = split(/\0/, $$bref);
 405         scalar(@extra) and die "BUG: extra files in index: <",
 406                                 join('> <', @extra), ">";
 407
 408         my ($info, $file) = split(/\t/, $line, 2);
 409         my ($mode_b, $oid_b_full, $stage) = split(/ /, $info);
 410         if ($file ne $di->{path_b}) {
 411                 die
 412 "BUG: index mismatch: file=$file != path_b=$di->{path_b}";
 413         }
 414
 415         my $tmp_git = $self->{tmp_git} or die 'no git working tree';
 416         my (undef, undef, $size) = $tmp_git->check($oid_b_full);
 417         defined($size) or die "check $oid_b_full failed";
 418
 419         dbg($self, "index at:\n$mode_b $oid_b_full\t$file");
 420         my $created = [ $tmp_git, $oid_b_full, 'blob', $size, $di ];
 421         mark_found($self, $di->{oid_b}, $created);
 422         next_step($self); # onto the next patch
 423 }
 424
 425 sub ls_files_result {
 426         my ($bref, $self) = @_;
 427         eval { parse_ls_files($self, $bref) };
 428         ERR($self, $@) if $@;
 429 }
 430
 431 sub oids_same_ish ($$) {
 432         (index($_[0], $_[1]) == 0) || (index($_[1], $_[0]) == 0);
 433 }
 434
 435 sub skip_identical ($$$) {
 436         my ($self, $patches, $cur_oid_b) = @_;
 437         while (my $nxt = $patches->[0]) {
 438                 if (oids_same_ish($cur_oid_b, $nxt->{oid_b})) {
 439                         dbg($self, 'skipping '.di_url($self, $nxt).
 440                                 " for $cur_oid_b");
 441                         shift @$patches;
 442                 } else {
 443                         return;
 444                 }
 445         }
 446 }
 447
 448 sub apply_result ($$) {
 449         my ($bref, $self) = @_;
 450         my ($qsp, $di) = delete @$self{qw(-qsp -cur_di)};
 451         dbg($self, $$bref);
 452         my $patches = $self->{patches};
 453         if (my $err = $qsp->{err}) {
 454                 my $msg = "git apply error: $err";
 455                 my $nxt = $patches->[0];
 456                 if ($nxt && oids_same_ish($nxt->{oid_b}, $di->{oid_b})) {
 457                         dbg($self, $msg);
 458                         dbg($self, 'trying '.di_url($self, $nxt));
 459                         return do_git_apply($self);
 460                 } else {
 461                         ERR($self, $msg);
 462                 }
 463         } else {
 464                 skip_identical($self, $patches, $di->{oid_b});
 465         }
 466
 467         my @cmd = qw(git ls-files -s -z);
 468         $qsp = PublicInbox::Qspawn->new(\@cmd, $self->{git_env});
 469         $self->{-cur_di} = $di;
 470         $self->{-qsp} = $qsp;
 471         $qsp->psgi_qx($self->{psgi_env}, undef, \&ls_files_result, $self);
 472 }
 473
 474 sub do_git_apply ($) {
 475         my ($self) = @_;
 476         my $dn = $self->{tmp}->dirname;
 477         my $patches = $self->{patches};
 478
 479         # we need --ignore-whitespace because some patches are CRLF
 480         my @cmd = (qw(git apply --cached --ignore-whitespace
 481                         --unidiff-zero --whitespace=warn --verbose));
 482         my $len = length(join(' ', @cmd));
 483         my $total = $self->{tot};
 484         my $di; # keep track of the last one for "git ls-files"
 485         my $prv_oid_b;
 486
 487         do {
 488                 my $i = ++$self->{nr};
 489                 $di = shift @$patches;
 490                 dbg($self, "\napplying [$i/$total] " . di_url($self, $di) .
 491                         "\n" . $di->{hdr_lines});
 492                 my $path = $di->{n};
 493                 $len += length($path) + 1;
 494                 push @cmd, $path;
 495                 $prv_oid_b = $di->{oid_b};
 496         } while (@$patches && $len < $ARG_SIZE_MAX &&
 497                  !oids_same_ish($patches->[0]->{oid_b}, $prv_oid_b));
 498
 499         my $opt = { 2 => 1, -C => $dn, quiet => 1 };
 500         my $qsp = PublicInbox::Qspawn->new(\@cmd, $self->{git_env}, $opt);
 501         $self->{-cur_di} = $di;
 502         $self->{-qsp} = $qsp;
 503         $qsp->psgi_qx($self->{psgi_env}, undef, \&apply_result, $self);
 504 }
 505
 506 sub di_url ($$) {
 507         my ($self, $di) = @_;
 508         # note: we don't pass the PSGI env unconditionally, here,
 509         # different inboxes can have different HTTP_HOST on the same instance.
 510         my $ibx = $di->{ibx};
 511         my $env = $self->{psgi_env} if $ibx eq $self->{inboxes}->[0];
 512         my $url = $ibx->base_url($env);
 513         my $mid = $di->{smsg}->{mid};
 514         defined($url) ? "$url$mid/" : "<$mid>";
 515 }
 516
 517 sub resolve_patch ($$) {
 518         my ($self, $want) = @_;
 519
 520         if (scalar(@{$self->{patches}}) > $MAX_PATCH) {
 521                 die "Aborting, too many steps to $self->{oid_want}";
 522         }
 523
 524         # see if we can find the blob in an existing git repo:
 525         my $cur_want = $want->{oid_b};
 526         if ($self->{seen_oid}->{$cur_want}++) {
 527                 die "Loop detected solving $cur_want\n";
 528         }
 529         if (my $existing = solve_existing($self, $want)) {
 530                 my ($found_git, undef, $type, undef) = @$existing;
 531                 dbg($self, "found $cur_want in " .
 532                         join(" ||\n\t",
 533                                 $found_git->pub_urls($self->{psgi_env})));
 534
 535                 if ($cur_want eq $self->{oid_want} || $type ne 'blob') {
 536                         eval { done($self, $existing) };
 537                         die "E: $@" if $@;
 538                         return;
 539                 }
 540                 mark_found($self, $cur_want, $existing);
 541                 return next_step($self); # onto patch application
 542         }
 543
 544         # scan through inboxes to look for emails which results in
 545         # the oid we want:
 546         foreach my $ibx (@{$self->{inboxes}}) {
 547                 my $diffs = find_extract_diffs($self, $ibx, $want) or next;
 548
 549                 unshift @{$self->{patches}}, @$diffs;
 550                 dbg($self, "found $cur_want in ".
 551                         join(" ||\n\t", map { di_url($self, $_) } @$diffs));
 552
 553                 # good, we can find a path to the oid we $want, now
 554                 # lets see if we need to apply more patches:
 555                 my $di = $diffs->[0];
 556                 my $src = $di->{oid_a};
 557
 558                 unless ($src =~ /\A0+\z/) {
 559                         # we have to solve it using another oid, fine:
 560                         my $job = { oid_b => $src, path_b => $di->{path_a} };
 561                         push @{$self->{todo}}, $job;
 562                 }
 563                 return next_step($self); # onto the next todo item
 564         }
 565         if (length($cur_want) > $OID_MIN) {
 566                 chop($cur_want);
 567                 dbg($self, "retrying $want->{oid_b} as $cur_want");
 568                 $want->{oid_b} = $cur_want;
 569                 push @{$self->{todo}}, $want;
 570                 return next_step($self); # retry with shorter abbrev
 571         }
 572
 573         dbg($self, "could not find $cur_want");
 574         eval { done($self, undef) };
 575         die "E: $@" if $@;
 576 }
 577
 578 # this API is designed to avoid creating self-referential structures;
 579 # so user_cb never references the SolverGit object
 580 sub new {
 581         my ($class, $ibx, $user_cb, $uarg) = @_;
 582
 583         bless {
 584                 gits => $ibx->{-repo_objs},
 585                 user_cb => $user_cb,
 586                 uarg => $uarg,
 587                 # -cur_di, -qsp, -msg => temporary fields for Qspawn callbacks
 588
 589                 # TODO: config option for searching related inboxes
 590                 inboxes => [ $ibx ],
 591         }, $class;
 592 }
 593
 594 # recreate $oid_want using $hints
 595 # hints keys: path_a, path_b, oid_a (note: `oid_b' is NOT a hint)
 596 # Calls {user_cb} with: [ ::Git object, oid_full, type, size, di (diff_info) ]
 597 # with found object, or undef if nothing was found
 598 # Calls {user_cb} with a string error on fatal errors
 599 sub solve ($$$$$) {
 600         my ($self, $env, $out, $oid_want, $hints) = @_;
 601
 602         # should we even get here? Probably not, but somebody
 603         # could be manually typing URLs:
 604         return done($self, undef) if $oid_want =~ /\A0+\z/;
 605
 606         $self->{oid_want} = $oid_want;
 607         $self->{out} = $out;
 608         $self->{seen_oid} = {};
 609         $self->{tot} = 0;
 610         $self->{psgi_env} = $env;
 611         $self->{todo} = [ { %$hints, oid_b => $oid_want } ];
 612         $self->{patches} = []; # [ $di, $di, ... ]
 613         $self->{found} = {}; # { abbr => [ ::Git, oid, type, size, $di ] }
 614         $self->{tmp} = File::Temp->newdir("solver.$oid_want-XXXXXXXX", TMPDIR => 1);
 615
 616         dbg($self, "solving $oid_want ...");
 617         if (my $async = $env->{'pi-httpd.async'}) {
 618                 # PublicInbox::HTTPD::Async->new
 619                 $async->(undef, undef, $self);
 620         } else {
 621                 event_step($self) while $self->{user_cb};
 622         }
 623 }
 624
 625 1;