lib/PublicInbox/SolverGit.pm

   1 # Copyright (C) 2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # "Solve" blobs which don't exist in git code repositories by
   5 # searching inboxes for post-image blobs.
   6
   7 # this emits a lot of debugging/tracing information which may be
   8 # publically viewed over HTTP(S).  Be careful not to expose
   9 # local filesystem layouts in the process.
  10 package PublicInbox::SolverGit;
  11 use strict;
  12 use warnings;
  13 use 5.010_001;
  14 use File::Temp 0.19 ();
  15 use Fcntl qw(SEEK_SET);
  16 use PublicInbox::Git qw(git_unquote git_quote);
  17 use PublicInbox::MsgIter qw(msg_iter msg_part_text);
  18 use PublicInbox::Qspawn;
  19 use PublicInbox::Tmpfile;
  20 use URI::Escape qw(uri_escape_utf8);
  21
  22 # POSIX requires _POSIX_ARG_MAX >= 4096, and xargs is required to
  23 # subtract 2048 bytes.  We also don't factor in environment variable
  24 # headroom into this.
  25 use POSIX qw(sysconf _SC_ARG_MAX);
  26 my $ARG_SIZE_MAX = (sysconf(_SC_ARG_MAX) || 4096) - 2048;
  27 my $OID_MIN = 7;
  28
  29 # By default, "git format-patch" generates filenames with a four-digit
  30 # prefix, so that means 9999 patch series are OK, right? :>
  31 # Maybe we can make this configurable, main concern is disk space overhead
  32 # for uncompressed patch fragments.  Aside from space, public-inbox-httpd
  33 # is otherwise unaffected by having many patches, here, as it can share
  34 # work fairly.  Other PSGI servers may have trouble, though.
  35 my $MAX_PATCH = 9999;
  36
  37 # di = diff info / a hashref with information about a diff ($di):
  38 # {
  39 #       oid_a => abbreviated pre-image oid,
  40 #       oid_b => abbreviated post-image oid,
  41 #       tmp => anonymous file handle with the diff,
  42 #       hdr_lines => string of various header lines for mode information
  43 #       mode_a => original mode of oid_a (string, not integer),
  44 #       ibx => PublicInbox::Inbox object containing the diff
  45 #       smsg => PublicInbox::SearchMsg object containing diff
  46 #       path_a => pre-image path
  47 #       path_b => post-image path
  48 #       n => numeric path of the patch (relative to worktree)
  49 # }
  50
  51 sub dbg ($$) {
  52         print { $_[0]->{out} } $_[1], "\n" or ERR($_[0], "print(dbg): $!");
  53 }
  54
  55 sub done ($$) {
  56         my ($self, $res) = @_;
  57         my $ucb = delete($self->{user_cb}) or return;
  58         $ucb->($res, $self->{uarg});
  59 }
  60
  61 sub ERR ($$) {
  62         my ($self, $err) = @_;
  63         print { $self->{out} } $err, "\n";
  64         eval { done($self, $err) };
  65         die $err;
  66 }
  67
  68 # look for existing objects already in git repos
  69 sub solve_existing ($$) {
  70         my ($self, $want) = @_;
  71         my $oid_b = $want->{oid_b};
  72         my $have_hints = scalar keys %$want > 1;
  73         my @ambiguous; # Array of [ git, $oids]
  74         foreach my $git (@{$self->{gits}}) {
  75                 my ($oid_full, $type, $size) = $git->check($oid_b);
  76                 if (defined($type) && (!$have_hints || $type eq 'blob')) {
  77                         return [ $git, $oid_full, $type, int($size) ];
  78                 }
  79
  80                 next if length($oid_b) == 40;
  81
  82                 # parse stderr of "git cat-file --batch-check"
  83                 my $err = $git->last_check_err;
  84                 my (@oids) = ($err =~ /\b([a-f0-9]{40})\s+blob\b/g);
  85                 next unless scalar(@oids);
  86
  87                 # TODO: do something with the ambiguous array?
  88                 # push @ambiguous, [ $git, @oids ];
  89
  90                 dbg($self, "`$oid_b' ambiguous in " .
  91                                 join("\n\t", $git->pub_urls($self->{psgi_env}))
  92                                 . "\n" .
  93                                 join('', map { "$_ blob\n" } @oids));
  94         }
  95         scalar(@ambiguous) ? \@ambiguous : undef;
  96 }
  97
  98 sub extract_diff ($$) {
  99         my ($p, $arg) = @_;
 100         my ($self, $diffs, $pre, $post, $ibx, $smsg) = @$arg;
 101         my ($part) = @$p; # ignore $depth and @idx;
 102         my $ct = $part->content_type || 'text/plain';
 103         my ($s, undef) = msg_part_text($part, $ct);
 104         defined $s or return;
 105         my $di = {};
 106
 107         # Email::MIME::Encodings forces QP to be CRLF upon decoding,
 108         # change it back to LF:
 109         my $cte = $part->header('Content-Transfer-Encoding') || '';
 110         if ($cte =~ /\bquoted-printable\b/i && $part->crlf eq "\n") {
 111                 $s =~ s/\r\n/\n/sg;
 112         }
 113
 114         state $LF = qr!\r?\n!;
 115         state $ANY = qr![^\r\n]+!;
 116         state $MODE = '100644|120000|100755';
 117         state $FN = qr!(?:("?[^/\n]+/[^\r\n]+)|/dev/null)!;
 118
 119         $s =~ m!( # $1 start header lines we save for debugging:
 120
 121                 # everything before ^index is optional, but we don't
 122                 # want to match ^(old|copy|rename|deleted|...) unless
 123                 # we match /^diff --git/ first:
 124                 (?: # begin optional stuff:
 125
 126                 # try to get the pre-and-post filenames as $2 and $3
 127                 (?:^diff\x20--git\x20$FN\x20$FN$LF)
 128
 129                 (?:^(?: # pass all this to git-apply:
 130                         # old mode $4
 131                         (?:old\x20mode\x20($MODE))
 132                         |
 133                         # new mode (possibly new file) ($5)
 134                         (?:new\x20(?:file\x20)?mode\x20($MODE))
 135                         |
 136                         (?:(?:copy|rename|deleted|
 137                                 dissimilarity|similarity)$ANY)
 138                 )$LF)*
 139
 140                 )? # end of optional stuff, everything below is required
 141
 142                 # match the pre and post-image OIDs as $6 $7
 143                 ^index\x20(${pre}[a-f0-9]*)\.\.(${post}[a-f0-9]*)
 144                         # mode if unchanged $8
 145                         (?:\x20(100644|120000|100755))?$LF
 146         ) # end of header lines ($1)
 147         ( # $9 is the patch body
 148                 # "--- a/foo.c" sets pre-filename ($10) in case
 149                 # $2 is missing
 150                 (?:^---\x20$FN$LF)
 151
 152                 # "+++ b/foo.c" sets post-filename ($11) in case
 153                 # $3 is missing
 154                 (?:^\+{3}\x20$FN$LF)
 155
 156                 # the meat of the diff, including "^\\No newline ..."
 157                 # We also allow for totally blank lines w/o leading spaces,
 158                 # because git-apply(1) handles that case, too
 159                 (?:^(?:[\@\+\x20\-\\][^\r\n]*|)$LF)+
 160         )!smx or return;
 161
 162         my $hdr_lines = $1;
 163         my $path_a = $2 // $10;
 164         my $path_b = $3 // $11;
 165         $di->{oid_a} = $6;
 166         $di->{oid_b} = $7;
 167         $di->{mode_a} = $5 // $8 // $4; # new (file) // unchanged // old
 168         my $patch = $9;
 169
 170         # don't care for leading 'a/' and 'b/'
 171         my (undef, @a) = split(m{/}, git_unquote($path_a));
 172         my (undef, @b) = split(m{/}, git_unquote($path_b));
 173
 174         # get rid of path-traversal attempts and junk patches:
 175         # it's junk at best, an attack attempt at worse:
 176         state $bad_component = { map { $_ => 1 } ('', '.', '..') };
 177         foreach (@a, @b) { return if $bad_component->{$_} }
 178
 179         $di->{path_a} = join('/', @a);
 180         $di->{path_b} = join('/', @b);
 181
 182         utf8::encode($hdr_lines);
 183         utf8::encode($patch);
 184         my $path = ++$self->{tot};
 185         $di->{n} = $path;
 186         open(my $tmp, '>', $self->{tmp}->dirname . "/$path") or
 187                 die "open(tmp): $!";
 188         print $tmp $hdr_lines, $patch or die "print(tmp): $!";
 189         close $tmp or die "close(tmp): $!";
 190
 191         # for debugging/diagnostics:
 192         $di->{ibx} = $ibx;
 193         $di->{smsg} = $smsg;
 194         $di->{hdr_lines} = $hdr_lines;
 195
 196         push @$diffs, $di;
 197 }
 198
 199 sub path_searchable ($) { defined($_[0]) && $_[0] =~ m!\A[\w/\. \-]+\z! }
 200
 201 # ".." appears in path names, which confuses Xapian into treating
 202 # it as a range query.  So we split on ".." since Xapian breaks
 203 # on punctuation anyways:
 204 sub filename_query ($) {
 205         join('', map { qq( dfn:"$_") } split(/\.\./, $_[0]));
 206 }
 207
 208 sub find_extract_diffs ($$$) {
 209         my ($self, $ibx, $want) = @_;
 210         my $srch = $ibx->search or return;
 211
 212         my $post = $want->{oid_b} or die 'BUG: no {oid_b}';
 213         $post =~ /\A[a-f0-9]+\z/ or die "BUG: oid_b not hex: $post";
 214
 215         my $q = "dfpost:$post";
 216         my $pre = $want->{oid_a};
 217         if (defined $pre && $pre =~ /\A[a-f0-9]+\z/) {
 218                 $q .= " dfpre:$pre";
 219         } else {
 220                 $pre = '[a-f0-9]{7}'; # for $re below
 221         }
 222
 223         my $path_b = $want->{path_b};
 224         if (path_searchable($path_b)) {
 225                 $q .= filename_query($path_b);
 226
 227                 my $path_a = $want->{path_a};
 228                 if (path_searchable($path_a) && $path_a ne $path_b) {
 229                         $q .= filename_query($path_a);
 230                 }
 231         }
 232
 233         my $msgs = $srch->query($q, { relevance => 1 });
 234
 235         my $diffs = [];
 236         foreach my $smsg (@$msgs) {
 237                 $ibx->smsg_mime($smsg) or next;
 238                 my $mime = delete $smsg->{mime};
 239                 msg_iter($mime, \&extract_diff,
 240                                 [$self, $diffs, $pre, $post, $ibx, $smsg]);
 241         }
 242         @$diffs ? $diffs : undef;
 243 }
 244
 245 sub update_index_result ($$) {
 246         my ($bref, $self) = @_;
 247         my ($qsp, $msg) = delete @$self{qw(-qsp -msg)};
 248         if (my $err = $qsp->{err}) {
 249                 ERR($self, "git update-index error: $err");
 250         }
 251         dbg($self, $msg);
 252         next_step($self); # onto do_git_apply
 253 }
 254
 255 sub prepare_index ($) {
 256         my ($self) = @_;
 257         my $patches = $self->{patches};
 258         $self->{nr} = 0;
 259
 260         my $di = $patches->[0] or die 'no patches';
 261         my $oid_a = $di->{oid_a} or die '{oid_a} unset';
 262         my $existing = $self->{found}->{$oid_a};
 263
 264         # no index creation for added files
 265         $oid_a =~ /\A0+\z/ and return next_step($self);
 266
 267         die "BUG: $oid_a not not found" unless $existing;
 268
 269         my $oid_full = $existing->[1];
 270         my $path_a = $di->{path_a} or die "BUG: path_a missing for $oid_full";
 271         my $mode_a = $di->{mode_a} // '100644';
 272
 273         my $in = tmpfile("update-index.$oid_full") or die "tmpfile: $!";
 274         print $in "$mode_a $oid_full\t$path_a\0" or die "print: $!";
 275         $in->flush or die "flush: $!";
 276         sysseek($in, 0, 0) or die "seek: $!";
 277
 278         dbg($self, 'preparing index');
 279         my $rdr = { 0 => $in };
 280         my $cmd = [ qw(git update-index -z --index-info) ];
 281         my $qsp = PublicInbox::Qspawn->new($cmd, $self->{git_env}, $rdr);
 282         $path_a = git_quote($path_a);
 283         $self->{-qsp} = $qsp;
 284         $self->{-msg} = "index prepared:\n$mode_a $oid_full\t$path_a";
 285         $qsp->psgi_qx($self->{psgi_env}, undef, \&update_index_result, $self);
 286 }
 287
 288 # pure Perl "git init"
 289 sub do_git_init ($) {
 290         my ($self) = @_;
 291         my $dir = $self->{tmp}->dirname;
 292         my $git_dir = "$dir/git";
 293
 294         foreach ('', qw(objects refs objects/info refs/heads)) {
 295                 mkdir("$git_dir/$_") or die "mkdir $_: $!";
 296         }
 297         open my $fh, '>', "$git_dir/config" or die "open git/config: $!";
 298         print $fh <<'EOF' or die "print git/config $!";
 299 [core]
 300         repositoryFormatVersion = 0
 301         filemode = true
 302         bare = false
 303         fsyncObjectfiles = false
 304         logAllRefUpdates = false
 305 EOF
 306         close $fh or die "close git/config: $!";
 307
 308         open $fh, '>', "$git_dir/HEAD" or die "open git/HEAD: $!";
 309         print $fh "ref: refs/heads/master\n" or die "print git/HEAD: $!";
 310         close $fh or die "close git/HEAD: $!";
 311
 312         my $f = 'objects/info/alternates';
 313         open $fh, '>', "$git_dir/$f" or die "open: $f: $!";
 314         foreach my $git (@{$self->{gits}}) {
 315                 print $fh $git->git_path('objects'),"\n" or die "print $f: $!";
 316         }
 317         close $fh or die "close: $f: $!";
 318         my $tmp_git = $self->{tmp_git} = PublicInbox::Git->new($git_dir);
 319         $tmp_git->{-tmp} = $self->{tmp};
 320         $self->{git_env} = {
 321                 GIT_DIR => $git_dir,
 322                 GIT_INDEX_FILE => "$git_dir/index",
 323         };
 324         prepare_index($self);
 325 }
 326
 327 sub do_finish ($) {
 328         my ($self) = @_;
 329         my ($found, $oid_want) = @$self{qw(found oid_want)};
 330         if (my $exists = $found->{$oid_want}) {
 331                 return done($self, $exists);
 332         }
 333
 334         # let git disambiguate if oid_want was too short,
 335         # but long enough to be unambiguous:
 336         my $tmp_git = $self->{tmp_git};
 337         if (my @res = $tmp_git->check($oid_want)) {
 338                 return done($self, $found->{$res[0]});
 339         }
 340         if (my $err = $tmp_git->last_check_err) {
 341                 dbg($self, $err);
 342         }
 343         done($self, undef);
 344 }
 345
 346 sub event_step ($) {
 347         my ($self) = @_;
 348         eval {
 349                 # step 1: resolve blobs to patches in the todo queue
 350                 if (my $want = pop @{$self->{todo}}) {
 351                         # this populates {patches} and {todo}
 352                         resolve_patch($self, $want);
 353
 354                 # step 2: then we instantiate a working tree once
 355                 # the todo queue is finally empty:
 356                 } elsif (!defined($self->{tmp_git})) {
 357                         do_git_init($self);
 358
 359                 # step 3: apply each patch in the stack
 360                 } elsif (scalar @{$self->{patches}}) {
 361                         do_git_apply($self);
 362
 363                 # step 4: execute the user-supplied callback with
 364                 # our result: (which may be undef)
 365                 # Other steps may call user_cb to terminate prematurely
 366                 # on error
 367                 } elsif (exists $self->{user_cb}) {
 368                         do_finish($self);
 369                 } else {
 370                         die 'about to call user_cb twice'; # Oops :x
 371                 }
 372         }; # eval
 373         my $err = $@;
 374         if ($err) {
 375                 $err =~ s/^\s*Exception:\s*//; # bad word to show users :P
 376                 dbg($self, "E: $err");
 377                 eval { done($self, $err) };
 378         }
 379 }
 380
 381 sub next_step ($) {
 382         my ($self) = @_;
 383         # if outside of public-inbox-httpd, caller is expected to be
 384         # looping event_step, anyways
 385         my $async = $self->{psgi_env}->{'pi-httpd.async'} or return;
 386         # PublicInbox::HTTPD::Async->new
 387         $async->(undef, undef, $self);
 388 }
 389
 390 sub mark_found ($$$) {
 391         my ($self, $oid, $found_info) = @_;
 392         my $found = $self->{found};
 393         $found->{$oid} = $found_info;
 394         my $oid_cur = $found_info->[1];
 395         while ($oid_cur ne $oid && length($oid_cur) > $OID_MIN) {
 396                 $found->{$oid_cur} = $found_info;
 397                 chop($oid_cur);
 398         }
 399 }
 400
 401 sub parse_ls_files ($$) {
 402         my ($self, $bref) = @_;
 403         my ($qsp, $di) = delete @$self{qw(-qsp -cur_di)};
 404         if (my $err = $qsp->{err}) {
 405                 die "git ls-files error: $err";
 406         }
 407
 408         my ($line, @extra) = split(/\0/, $$bref);
 409         scalar(@extra) and die "BUG: extra files in index: <",
 410                                 join('> <', @extra), ">";
 411
 412         my ($info, $file) = split(/\t/, $line, 2);
 413         my ($mode_b, $oid_b_full, $stage) = split(/ /, $info);
 414         if ($file ne $di->{path_b}) {
 415                 die
 416 "BUG: index mismatch: file=$file != path_b=$di->{path_b}";
 417         }
 418
 419         my $tmp_git = $self->{tmp_git} or die 'no git working tree';
 420         my (undef, undef, $size) = $tmp_git->check($oid_b_full);
 421         defined($size) or die "check $oid_b_full failed";
 422
 423         dbg($self, "index at:\n$mode_b $oid_b_full\t$file");
 424         my $created = [ $tmp_git, $oid_b_full, 'blob', $size, $di ];
 425         mark_found($self, $di->{oid_b}, $created);
 426         next_step($self); # onto the next patch
 427 }
 428
 429 sub ls_files_result {
 430         my ($bref, $self) = @_;
 431         eval { parse_ls_files($self, $bref) };
 432         ERR($self, $@) if $@;
 433 }
 434
 435 sub oids_same_ish ($$) {
 436         (index($_[0], $_[1]) == 0) || (index($_[1], $_[0]) == 0);
 437 }
 438
 439 sub skip_identical ($$$) {
 440         my ($self, $patches, $cur_oid_b) = @_;
 441         while (my $nxt = $patches->[0]) {
 442                 if (oids_same_ish($cur_oid_b, $nxt->{oid_b})) {
 443                         dbg($self, 'skipping '.di_url($self, $nxt).
 444                                 " for $cur_oid_b");
 445                         shift @$patches;
 446                 } else {
 447                         return;
 448                 }
 449         }
 450 }
 451
 452 sub apply_result ($$) {
 453         my ($bref, $self) = @_;
 454         my ($qsp, $di) = delete @$self{qw(-qsp -cur_di)};
 455         dbg($self, $$bref);
 456         my $patches = $self->{patches};
 457         if (my $err = $qsp->{err}) {
 458                 my $msg = "git apply error: $err";
 459                 my $nxt = $patches->[0];
 460                 if ($nxt && oids_same_ish($nxt->{oid_b}, $di->{oid_b})) {
 461                         dbg($self, $msg);
 462                         dbg($self, 'trying '.di_url($self, $nxt));
 463                         return do_git_apply($self);
 464                 } else {
 465                         ERR($self, $msg);
 466                 }
 467         } else {
 468                 skip_identical($self, $patches, $di->{oid_b});
 469         }
 470
 471         my @cmd = qw(git ls-files -s -z);
 472         $qsp = PublicInbox::Qspawn->new(\@cmd, $self->{git_env});
 473         $self->{-cur_di} = $di;
 474         $self->{-qsp} = $qsp;
 475         $qsp->psgi_qx($self->{psgi_env}, undef, \&ls_files_result, $self);
 476 }
 477
 478 sub do_git_apply ($) {
 479         my ($self) = @_;
 480         my $dn = $self->{tmp}->dirname;
 481         my $patches = $self->{patches};
 482
 483         # we need --ignore-whitespace because some patches are CRLF
 484         my @cmd = (qw(git apply --cached --ignore-whitespace
 485                         --unidiff-zero --whitespace=warn --verbose));
 486         my $len = length(join(' ', @cmd));
 487         my $total = $self->{tot};
 488         my $di; # keep track of the last one for "git ls-files"
 489         my $prv_oid_b;
 490
 491         do {
 492                 my $i = ++$self->{nr};
 493                 $di = shift @$patches;
 494                 dbg($self, "\napplying [$i/$total] " . di_url($self, $di) .
 495                         "\n" . $di->{hdr_lines});
 496                 my $path = $di->{n};
 497                 $len += length($path) + 1;
 498                 push @cmd, $path;
 499                 $prv_oid_b = $di->{oid_b};
 500         } while (@$patches && $len < $ARG_SIZE_MAX &&
 501                  !oids_same_ish($patches->[0]->{oid_b}, $prv_oid_b));
 502
 503         my $opt = { 2 => 1, -C => $dn, quiet => 1 };
 504         my $qsp = PublicInbox::Qspawn->new(\@cmd, $self->{git_env}, $opt);
 505         $self->{-cur_di} = $di;
 506         $self->{-qsp} = $qsp;
 507         $qsp->psgi_qx($self->{psgi_env}, undef, \&apply_result, $self);
 508 }
 509
 510 sub di_url ($$) {
 511         my ($self, $di) = @_;
 512         # note: we don't pass the PSGI env unconditionally, here,
 513         # different inboxes can have different HTTP_HOST on the same instance.
 514         my $ibx = $di->{ibx};
 515         my $env = $self->{psgi_env} if $ibx eq $self->{inboxes}->[0];
 516         my $url = $ibx->base_url($env);
 517         my $mid = $di->{smsg}->{mid};
 518         defined($url) ? "$url$mid/" : "<$mid>";
 519 }
 520
 521 sub resolve_patch ($$) {
 522         my ($self, $want) = @_;
 523
 524         if (scalar(@{$self->{patches}}) > $MAX_PATCH) {
 525                 die "Aborting, too many steps to $self->{oid_want}";
 526         }
 527
 528         # see if we can find the blob in an existing git repo:
 529         my $cur_want = $want->{oid_b};
 530         if ($self->{seen_oid}->{$cur_want}++) {
 531                 die "Loop detected solving $cur_want\n";
 532         }
 533         if (my $existing = solve_existing($self, $want)) {
 534                 my ($found_git, undef, $type, undef) = @$existing;
 535                 dbg($self, "found $cur_want in " .
 536                         join("\n", $found_git->pub_urls($self->{psgi_env})));
 537
 538                 if ($cur_want eq $self->{oid_want} || $type ne 'blob') {
 539                         eval { done($self, $existing) };
 540                         die "E: $@" if $@;
 541                         return;
 542                 }
 543                 mark_found($self, $cur_want, $existing);
 544                 return next_step($self); # onto patch application
 545         }
 546
 547         # scan through inboxes to look for emails which results in
 548         # the oid we want:
 549         foreach my $ibx (@{$self->{inboxes}}) {
 550                 my $diffs = find_extract_diffs($self, $ibx, $want) or next;
 551
 552                 unshift @{$self->{patches}}, @$diffs;
 553                 dbg($self, "found $cur_want in ".
 554                         join("\n\t", map { di_url($self, $_) } @$diffs));
 555
 556                 # good, we can find a path to the oid we $want, now
 557                 # lets see if we need to apply more patches:
 558                 my $di = $diffs->[0];
 559                 my $src = $di->{oid_a};
 560
 561                 unless ($src =~ /\A0+\z/) {
 562                         # we have to solve it using another oid, fine:
 563                         my $job = { oid_b => $src, path_b => $di->{path_a} };
 564                         push @{$self->{todo}}, $job;
 565                 }
 566                 return next_step($self); # onto the next todo item
 567         }
 568         if (length($cur_want) > $OID_MIN) {
 569                 chop($cur_want);
 570                 dbg($self, "retrying $want->{oid_b} as $cur_want");
 571                 $want->{oid_b} = $cur_want;
 572                 push @{$self->{todo}}, $want;
 573                 return next_step($self); # retry with shorter abbrev
 574         }
 575
 576         dbg($self, "could not find $cur_want");
 577         eval { done($self, undef) };
 578         die "E: $@" if $@;
 579 }
 580
 581 # this API is designed to avoid creating self-referential structures;
 582 # so user_cb never references the SolverGit object
 583 sub new {
 584         my ($class, $ibx, $user_cb, $uarg) = @_;
 585
 586         bless {
 587                 gits => $ibx->{-repo_objs},
 588                 user_cb => $user_cb,
 589                 uarg => $uarg,
 590                 # -cur_di, -qsp, -msg => temporary fields for Qspawn callbacks
 591
 592                 # TODO: config option for searching related inboxes
 593                 inboxes => [ $ibx ],
 594         }, $class;
 595 }
 596
 597 # recreate $oid_want using $hints
 598 # hints keys: path_a, path_b, oid_a
 599 # Calls {user_cb} with: [ ::Git object, oid_full, type, size, di (diff_info) ]
 600 # with found object, or undef if nothing was found
 601 # Calls {user_cb} with a string error on fatal errors
 602 sub solve ($$$$$) {
 603         my ($self, $env, $out, $oid_want, $hints) = @_;
 604
 605         # should we even get here? Probably not, but somebody
 606         # could be manually typing URLs:
 607         return done($self, undef) if $oid_want =~ /\A0+\z/;
 608
 609         $self->{oid_want} = $oid_want;
 610         $self->{out} = $out;
 611         $self->{seen_oid} = {};
 612         $self->{tot} = 0;
 613         $self->{psgi_env} = $env;
 614         $self->{todo} = [ { %$hints, oid_b => $oid_want } ];
 615         $self->{patches} = []; # [ $di, $di, ... ]
 616         $self->{found} = {}; # { abbr => [ ::Git, oid, type, size, $di ] }
 617         $self->{tmp} = File::Temp->newdir("solver.$oid_want-XXXXXXXX", TMPDIR => 1);
 618
 619         dbg($self, "solving $oid_want ...");
 620         if (my $async = $env->{'pi-httpd.async'}) {
 621                 # PublicInbox::HTTPD::Async->new
 622                 $async->(undef, undef, $self);
 623         } else {
 624                 event_step($self) while $self->{user_cb};
 625         }
 626 }
 627
 628 1;