lib/PublicInbox/Spamcheck/Spamc.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Spamcheck::Spamc;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Spawn qw(popen_rd spawn);
   7 use IO::Handle;
   8 use Fcntl qw(:DEFAULT SEEK_SET);
   9
  10 sub new {
  11         my ($class) = @_;
  12         bless {
  13                 checkcmd => [qw(spamc -E --headers)],
  14                 hamcmd => [qw(spamc -L ham)],
  15                 spamcmd => [qw(spamc -L spam)],
  16         }, $class;
  17 }
  18
  19 sub spamcheck {
  20         my ($self, $msg, $out) = @_;
  21
  22         my $tmp;
  23         my $fd = _msg_to_fd($self, $msg, \$tmp);
  24         my $rdr = { 0 => $fd };
  25         my ($fh, $pid) = popen_rd($self->{checkcmd}, undef, $rdr);
  26         defined $pid or die "failed to popen_rd spamc: $!\n";
  27         my $r;
  28         unless (ref $out) {
  29                 my $buf = '';
  30                 $out = \$buf;
  31         }
  32         do {
  33                 $r = sysread($fh, $$out, 65536, length($$out));
  34         } while (defined($r) && $r != 0);
  35         defined $r or die "read failed: $!";
  36         close $fh or die "close failed: $!";
  37         waitpid($pid, 0);
  38         ($? || $$out eq '') ? 0 : 1;
  39 }
  40
  41 sub hamlearn {
  42         my ($self, $msg, $rdr) = @_;
  43         _learn($self, $msg, $rdr, 'hamcmd');
  44 }
  45
  46 sub spamlearn {
  47         my ($self, $msg, $rdr) = @_;
  48         _learn($self, $msg, $rdr, 'spamcmd');
  49 }
  50
  51 sub _learn {
  52         my ($self, $msg, $rdr, $field) = @_;
  53         $rdr ||= {};
  54         $rdr->{1} ||= $self->_devnull;
  55         $rdr->{2} ||= $self->_devnull;
  56         my $tmp;
  57         $rdr->{0} = _msg_to_fd($self, $msg, \$tmp);
  58         my $pid = spawn($self->{$field}, undef, $rdr);
  59         waitpid($pid, 0);
  60         !$?;
  61 }
  62
  63 sub _devnull {
  64         my ($self) = @_;
  65         my $fd = $self->{-devnullfd};
  66         return $fd if defined $fd;
  67         open my $fh, '+>', '/dev/null' or
  68                                 die "failed to open /dev/null: $!";
  69         $self->{-devnull} = $fh;
  70         $self->{-devnullfd} = fileno($fh);
  71 }
  72
  73 sub _msg_to_fd {
  74         my ($self, $msg, $tmpref) = @_;
  75         my $fd;
  76         if (my $ref = ref($msg)) {
  77                 my $fileno = eval { fileno($msg) };
  78                 return $fileno if defined $fileno;
  79
  80                 open(my $tmpfh, '+>', undef) or die "failed to open: $!";
  81                 $tmpfh->autoflush(1);
  82                 $msg = \($msg->as_string) if $ref ne 'SCALAR';
  83                 print $tmpfh $$msg or die "failed to print: $!";
  84                 sysseek($tmpfh, 0, SEEK_SET) or
  85                         die "sysseek(fh) failed: $!";
  86                 $$tmpref = $tmpfh;
  87
  88                 return fileno($tmpfh);
  89         }
  90         $msg;
  91 }
  92
  93 1;