lib/PublicInbox/Spamcheck/Spamc.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Default spam filter class for wrapping spamc(1)
   5 package PublicInbox::Spamcheck::Spamc;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::Spawn qw(popen_rd spawn);
   9 use IO::Handle;
  10 use Fcntl qw(SEEK_SET);
  11
  12 sub new {
  13         my ($class) = @_;
  14         bless {
  15                 checkcmd => [qw(spamc -E --headers)],
  16                 hamcmd => [qw(spamc -L ham)],
  17                 spamcmd => [qw(spamc -L spam)],
  18         }, $class;
  19 }
  20
  21 sub spamcheck {
  22         my ($self, $msg, $out) = @_;
  23
  24         my $rdr = { 0 => _msg_to_fh($self, $msg) };
  25         my ($fh, $pid) = popen_rd($self->{checkcmd}, undef, $rdr);
  26         unless (ref $out) {
  27                 my $buf = '';
  28                 $out = \$buf;
  29         }
  30         $$out = do { local $/; <$fh> };
  31         close $fh or die "close failed: $!";
  32         waitpid($pid, 0);
  33         ($? || $$out eq '') ? 0 : 1;
  34 }
  35
  36 sub hamlearn {
  37         my ($self, $msg, $rdr) = @_;
  38         _learn($self, $msg, $rdr, 'hamcmd');
  39 }
  40
  41 sub spamlearn {
  42         my ($self, $msg, $rdr) = @_;
  43         _learn($self, $msg, $rdr, 'spamcmd');
  44 }
  45
  46 sub _learn {
  47         my ($self, $msg, $rdr, $field) = @_;
  48         $rdr ||= {};
  49         $rdr->{0} = _msg_to_fh($self, $msg);
  50         $rdr->{1} ||= $self->_devnull;
  51         $rdr->{2} ||= $self->_devnull;
  52         my $pid = spawn($self->{$field}, undef, $rdr);
  53         waitpid($pid, 0);
  54         !$?;
  55 }
  56
  57 sub _devnull {
  58         my ($self) = @_;
  59         $self->{-devnull} //= do {
  60                 open my $fh, '+>', '/dev/null' or
  61                                 die "failed to open /dev/null: $!";
  62                 $fh
  63         }
  64 }
  65
  66 sub _msg_to_fh {
  67         my ($self, $msg) = @_;
  68         if (my $ref = ref($msg)) {
  69                 my $fd = eval { fileno($msg) };
  70                 return $msg if defined($fd) && $fd >= 0;
  71
  72                 open(my $tmpfh, '+>', undef) or die "failed to open: $!";
  73                 $tmpfh->autoflush(1);
  74                 $msg = \($msg->as_string) if $ref ne 'SCALAR';
  75                 print $tmpfh $$msg or die "failed to print: $!";
  76                 sysseek($tmpfh, 0, SEEK_SET) or
  77                         die "sysseek(fh) failed: $!";
  78
  79                 return $tmpfh;
  80         }
  81         $msg;
  82 }
  83
  84 1;