lib/PublicInbox/Spamcheck/Spamc.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Default spam filter class for wrapping spamc(1)
   5 package PublicInbox::Spamcheck::Spamc;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::Spawn qw(popen_rd spawn);
   9 use IO::Handle;
  10 use Fcntl qw(SEEK_SET);
  11
  12 sub new {
  13         my ($class) = @_;
  14         bless {
  15                 checkcmd => [qw(spamc -E --headers)],
  16                 hamcmd => [qw(spamc -L ham)],
  17                 spamcmd => [qw(spamc -L spam)],
  18         }, $class;
  19 }
  20
  21 sub spamcheck {
  22         my ($self, $msg, $out) = @_;
  23
  24         my $rdr = { 0 => _msg_to_fh($self, $msg) };
  25         my ($fh, $pid) = popen_rd($self->{checkcmd}, undef, $rdr);
  26         my $r;
  27         unless (ref $out) {
  28                 my $buf = '';
  29                 $out = \$buf;
  30         }
  31 again:
  32         do {
  33                 $r = sysread($fh, $$out, 65536, length($$out));
  34         } while (defined($r) && $r != 0);
  35         unless (defined $r) {
  36                 goto again if $!{EINTR};
  37                 die "read failed: $!";
  38         }
  39         close $fh or die "close failed: $!";
  40         waitpid($pid, 0);
  41         ($? || $$out eq '') ? 0 : 1;
  42 }
  43
  44 sub hamlearn {
  45         my ($self, $msg, $rdr) = @_;
  46         _learn($self, $msg, $rdr, 'hamcmd');
  47 }
  48
  49 sub spamlearn {
  50         my ($self, $msg, $rdr) = @_;
  51         _learn($self, $msg, $rdr, 'spamcmd');
  52 }
  53
  54 sub _learn {
  55         my ($self, $msg, $rdr, $field) = @_;
  56         $rdr ||= {};
  57         $rdr->{0} = _msg_to_fh($self, $msg);
  58         $rdr->{1} ||= $self->_devnull;
  59         $rdr->{2} ||= $self->_devnull;
  60         my $pid = spawn($self->{$field}, undef, $rdr);
  61         waitpid($pid, 0);
  62         !$?;
  63 }
  64
  65 sub _devnull {
  66         my ($self) = @_;
  67         $self->{-devnull} //= do {
  68                 open my $fh, '+>', '/dev/null' or
  69                                 die "failed to open /dev/null: $!";
  70                 $fh
  71         }
  72 }
  73
  74 sub _msg_to_fh {
  75         my ($self, $msg) = @_;
  76         if (my $ref = ref($msg)) {
  77                 my $fd = eval { fileno($msg) };
  78                 return $msg if defined($fd) && $fd >= 0;
  79
  80                 open(my $tmpfh, '+>', undef) or die "failed to open: $!";
  81                 $tmpfh->autoflush(1);
  82                 $msg = \($msg->as_string) if $ref ne 'SCALAR';
  83                 print $tmpfh $$msg or die "failed to print: $!";
  84                 sysseek($tmpfh, 0, SEEK_SET) or
  85                         die "sysseek(fh) failed: $!";
  86
  87                 return $tmpfh;
  88         }
  89         $msg;
  90 }
  91
  92 1;