lib/PublicInbox/Spamcheck/Spamc.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::Spamcheck::Spamc;
   4 use strict;
   5 use warnings;
   6 use PublicInbox::Spawn qw(popen_rd spawn);
   7 use IO::Handle;
   8 use Fcntl qw(:DEFAULT SEEK_SET);
   9
  10 sub new {
  11         my ($class) = @_;
  12         bless {
  13                 checkcmd => [qw(spamc -E --headers)],
  14                 hamcmd => [qw(spamc -L ham)],
  15                 spamcmd => [qw(spamc -L spam)],
  16         }, $class;
  17 }
  18
  19 sub spamcheck {
  20         my ($self, $msg, $out) = @_;
  21
  22         my $tmp;
  23         my $fd = _msg_to_fd($self, $msg, \$tmp);
  24         my $rdr = { 0 => $fd };
  25         my ($fh, $pid) = popen_rd($self->{checkcmd}, undef, $rdr);
  26         defined $pid or die "failed to popen_rd spamc: $!\n";
  27         my $r;
  28         unless (ref $out) {
  29                 my $buf = '';
  30                 $out = \$buf;
  31         }
  32 again:
  33         do {
  34                 $r = sysread($fh, $$out, 65536, length($$out));
  35         } while (defined($r) && $r != 0);
  36         unless (defined $r) {
  37                 goto again if $!{EINTR};
  38                 die "read failed: $!";
  39         }
  40         close $fh or die "close failed: $!";
  41         waitpid($pid, 0);
  42         ($? || $$out eq '') ? 0 : 1;
  43 }
  44
  45 sub hamlearn {
  46         my ($self, $msg, $rdr) = @_;
  47         _learn($self, $msg, $rdr, 'hamcmd');
  48 }
  49
  50 sub spamlearn {
  51         my ($self, $msg, $rdr) = @_;
  52         _learn($self, $msg, $rdr, 'spamcmd');
  53 }
  54
  55 sub _learn {
  56         my ($self, $msg, $rdr, $field) = @_;
  57         $rdr ||= {};
  58         $rdr->{1} ||= $self->_devnull;
  59         $rdr->{2} ||= $self->_devnull;
  60         my $tmp;
  61         $rdr->{0} = _msg_to_fd($self, $msg, \$tmp);
  62         my $pid = spawn($self->{$field}, undef, $rdr);
  63         waitpid($pid, 0);
  64         !$?;
  65 }
  66
  67 sub _devnull {
  68         my ($self) = @_;
  69         my $fd = $self->{-devnullfd};
  70         return $fd if defined $fd;
  71         open my $fh, '+>', '/dev/null' or
  72                                 die "failed to open /dev/null: $!";
  73         $self->{-devnull} = $fh;
  74         $self->{-devnullfd} = fileno($fh);
  75 }
  76
  77 sub _msg_to_fd {
  78         my ($self, $msg, $tmpref) = @_;
  79         my $fd;
  80         if (my $ref = ref($msg)) {
  81                 my $fileno = eval { fileno($msg) };
  82                 return $fileno if defined $fileno;
  83
  84                 open(my $tmpfh, '+>', undef) or die "failed to open: $!";
  85                 $tmpfh->autoflush(1);
  86                 $msg = \($msg->as_string) if $ref ne 'SCALAR';
  87                 print $tmpfh $$msg or die "failed to print: $!";
  88                 sysseek($tmpfh, 0, SEEK_SET) or
  89                         die "sysseek(fh) failed: $!";
  90                 $$tmpref = $tmpfh;
  91
  92                 return fileno($tmpfh);
  93         }
  94         $msg;
  95 }
  96
  97 1;