lib/PublicInbox/Spamcheck/Spamc.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Default spam filter class for wrapping spamc(1)
   5 package PublicInbox::Spamcheck::Spamc;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::Spawn qw(popen_rd spawn);
   9 use IO::Handle;
  10 use Fcntl qw(SEEK_SET);
  11
  12 sub new {
  13         my ($class) = @_;
  14         bless {
  15                 checkcmd => [qw(spamc -E --headers)],
  16                 hamcmd => [qw(spamc -L ham)],
  17                 spamcmd => [qw(spamc -L spam)],
  18         }, $class;
  19 }
  20
  21 sub spamcheck {
  22         my ($self, $msg, $out) = @_;
  23
  24         my $rdr = { 0 => _msg_to_fh($self, $msg) };
  25         my ($fh, $pid) = popen_rd($self->{checkcmd}, undef, $rdr);
  26         defined $pid or die "failed to popen_rd spamc: $!\n";
  27         my $r;
  28         unless (ref $out) {
  29                 my $buf = '';
  30                 $out = \$buf;
  31         }
  32 again:
  33         do {
  34                 $r = sysread($fh, $$out, 65536, length($$out));
  35         } while (defined($r) && $r != 0);
  36         unless (defined $r) {
  37                 goto again if $!{EINTR};
  38                 die "read failed: $!";
  39         }
  40         close $fh or die "close failed: $!";
  41         waitpid($pid, 0);
  42         ($? || $$out eq '') ? 0 : 1;
  43 }
  44
  45 sub hamlearn {
  46         my ($self, $msg, $rdr) = @_;
  47         _learn($self, $msg, $rdr, 'hamcmd');
  48 }
  49
  50 sub spamlearn {
  51         my ($self, $msg, $rdr) = @_;
  52         _learn($self, $msg, $rdr, 'spamcmd');
  53 }
  54
  55 sub _learn {
  56         my ($self, $msg, $rdr, $field) = @_;
  57         $rdr ||= {};
  58         $rdr->{0} = _msg_to_fh($self, $msg);
  59         $rdr->{1} ||= $self->_devnull;
  60         $rdr->{2} ||= $self->_devnull;
  61         my $pid = spawn($self->{$field}, undef, $rdr);
  62         waitpid($pid, 0);
  63         !$?;
  64 }
  65
  66 sub _devnull {
  67         my ($self) = @_;
  68         $self->{-devnull} //= do {
  69                 open my $fh, '+>', '/dev/null' or
  70                                 die "failed to open /dev/null: $!";
  71                 $fh
  72         }
  73 }
  74
  75 sub _msg_to_fh {
  76         my ($self, $msg) = @_;
  77         if (my $ref = ref($msg)) {
  78                 my $fd = eval { fileno($msg) };
  79                 return $msg if defined($fd) && $fd >= 0;
  80
  81                 open(my $tmpfh, '+>', undef) or die "failed to open: $!";
  82                 $tmpfh->autoflush(1);
  83                 $msg = \($msg->as_string) if $ref ne 'SCALAR';
  84                 print $tmpfh $$msg or die "failed to print: $!";
  85                 sysseek($tmpfh, 0, SEEK_SET) or
  86                         die "sysseek(fh) failed: $!";
  87
  88                 return $tmpfh;
  89         }
  90         $msg;
  91 }
  92
  93 1;