lib/PublicInbox/Spamcheck/Spamc.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Default spam filter class for wrapping spamc(1)
   5 package PublicInbox::Spamcheck::Spamc;
   6 use strict;
   7 use warnings;
   8 use PublicInbox::Spawn qw(popen_rd spawn);
   9 use IO::Handle;
  10 use Fcntl qw(:DEFAULT SEEK_SET);
  11
  12 sub new {
  13         my ($class) = @_;
  14         bless {
  15                 checkcmd => [qw(spamc -E --headers)],
  16                 hamcmd => [qw(spamc -L ham)],
  17                 spamcmd => [qw(spamc -L spam)],
  18         }, $class;
  19 }
  20
  21 sub spamcheck {
  22         my ($self, $msg, $out) = @_;
  23
  24         my $tmp;
  25         my $fd = _msg_to_fd($self, $msg, \$tmp);
  26         my $rdr = { 0 => $fd };
  27         my ($fh, $pid) = popen_rd($self->{checkcmd}, undef, $rdr);
  28         defined $pid or die "failed to popen_rd spamc: $!\n";
  29         my $r;
  30         unless (ref $out) {
  31                 my $buf = '';
  32                 $out = \$buf;
  33         }
  34 again:
  35         do {
  36                 $r = sysread($fh, $$out, 65536, length($$out));
  37         } while (defined($r) && $r != 0);
  38         unless (defined $r) {
  39                 goto again if $!{EINTR};
  40                 die "read failed: $!";
  41         }
  42         close $fh or die "close failed: $!";
  43         waitpid($pid, 0);
  44         ($? || $$out eq '') ? 0 : 1;
  45 }
  46
  47 sub hamlearn {
  48         my ($self, $msg, $rdr) = @_;
  49         _learn($self, $msg, $rdr, 'hamcmd');
  50 }
  51
  52 sub spamlearn {
  53         my ($self, $msg, $rdr) = @_;
  54         _learn($self, $msg, $rdr, 'spamcmd');
  55 }
  56
  57 sub _learn {
  58         my ($self, $msg, $rdr, $field) = @_;
  59         $rdr ||= {};
  60         $rdr->{1} ||= $self->_devnull;
  61         $rdr->{2} ||= $self->_devnull;
  62         my $tmp;
  63         $rdr->{0} = _msg_to_fd($self, $msg, \$tmp);
  64         my $pid = spawn($self->{$field}, undef, $rdr);
  65         waitpid($pid, 0);
  66         !$?;
  67 }
  68
  69 sub _devnull {
  70         my ($self) = @_;
  71         my $fd = $self->{-devnullfd};
  72         return $fd if defined $fd;
  73         open my $fh, '+>', '/dev/null' or
  74                                 die "failed to open /dev/null: $!";
  75         $self->{-devnull} = $fh;
  76         $self->{-devnullfd} = fileno($fh);
  77 }
  78
  79 sub _msg_to_fd {
  80         my ($self, $msg, $tmpref) = @_;
  81         my $fd;
  82         if (my $ref = ref($msg)) {
  83                 my $fileno = eval { fileno($msg) };
  84                 return $fileno if defined $fileno;
  85
  86                 open(my $tmpfh, '+>', undef) or die "failed to open: $!";
  87                 $tmpfh->autoflush(1);
  88                 $msg = \($msg->as_string) if $ref ne 'SCALAR';
  89                 print $tmpfh $$msg or die "failed to print: $!";
  90                 sysseek($tmpfh, 0, SEEK_SET) or
  91                         die "sysseek(fh) failed: $!";
  92                 $$tmpref = $tmpfh;
  93
  94                 return fileno($tmpfh);
  95         }
  96         $msg;
  97 }
  98
  99 1;