lib/PublicInbox/Spawn.pm

   1 # Copyright (C) 2016-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # This allows vfork to be used for spawning subprocesses if
   5 # ~/.cache/public-inbox/inline-c is writable or if PERL_INLINE_DIRECTORY
   6 # is explicitly defined in the environment (and writable).
   7 # Under Linux, vfork can make a big difference in spawning performance
   8 # as process size increases (fork still needs to mark pages for CoW use).
   9 # Currently, we only use this for code intended for long running
  10 # daemons (inside the PSGI code (-httpd) and -nntpd).  The short-lived
  11 # scripts (-mda, -index, -learn, -init) either use IPC::run or standard
  12 # Perl routines.
  13 #
  14 # There'll probably be more OS-level C stuff here, down the line.
  15 # We don't want too many DSOs: https://udrepper.livejournal.com/8790.html
  16
  17 package PublicInbox::Spawn;
  18 use strict;
  19 use parent qw(Exporter);
  20 use Symbol qw(gensym);
  21 use PublicInbox::ProcessPipe;
  22 our @EXPORT_OK = qw/which spawn popen_rd/;
  23 our @RLIMITS = qw(RLIMIT_CPU RLIMIT_CORE RLIMIT_DATA);
  24
  25 my $vfork_spawn = <<'VFORK_SPAWN';
  26 #include <sys/types.h>
  27 #include <sys/time.h>
  28 #include <sys/resource.h>
  29 #include <unistd.h>
  30 #include <stdlib.h>
  31 #include <errno.h>
  32
  33 /* some platforms need alloca.h, but some don't */
  34 #if defined(__GNUC__) && !defined(alloca)
  35 #  define alloca(sz) __builtin_alloca(sz)
  36 #endif
  37
  38 #include <signal.h>
  39 #include <assert.h>
  40
  41 /*
  42  * From the av_len apidoc:
  43  *   Note that, unlike what the name implies, it returns
  44  *   the highest index in the array, so to get the size of
  45  *   the array you need to use "av_len(av) + 1".
  46  *   This is unlike "sv_len", which returns what you would expect.
  47  */
  48 #define AV2C_COPY(dst, src) do { \
  49         I32 i; \
  50         I32 top_index = av_len(src); \
  51         I32 real_len = top_index + 1; \
  52         I32 capa = real_len + 1; \
  53         dst = alloca(capa * sizeof(char *)); \
  54         for (i = 0; i < real_len; i++) { \
  55                 SV **sv = av_fetch(src, i, 0); \
  56                 dst[i] = SvPV_nolen(*sv); \
  57         } \
  58         dst[real_len] = 0; \
  59 } while (0)
  60
  61 /* needs to be safe inside a vfork'ed process */
  62 static void exit_err(int *cerrnum)
  63 {
  64         *cerrnum = errno;
  65         _exit(1);
  66 }
  67
  68 /*
  69  * unstable internal API.  It'll be updated depending on
  70  * whatever we'll need in the future.
  71  * Be sure to update PublicInbox::SpawnPP if this changes
  72  */
  73 int pi_fork_exec(SV *redirref, SV *file, SV *cmdref, SV *envref, SV *rlimref,
  74                  const char *cd)
  75 {
  76         AV *redir = (AV *)SvRV(redirref);
  77         AV *cmd = (AV *)SvRV(cmdref);
  78         AV *env = (AV *)SvRV(envref);
  79         AV *rlim = (AV *)SvRV(rlimref);
  80         const char *filename = SvPV_nolen(file);
  81         pid_t pid;
  82         char **argv, **envp;
  83         sigset_t set, old, cset;
  84         int ret, perrnum, cerrnum = 0;
  85
  86         AV2C_COPY(argv, cmd);
  87         AV2C_COPY(envp, env);
  88
  89         ret = sigfillset(&set);
  90         assert(ret == 0 && "BUG calling sigfillset");
  91         ret = sigprocmask(SIG_SETMASK, &set, &old);
  92         assert(ret == 0 && "BUG calling sigprocmask to block");
  93         ret = sigemptyset(&cset);
  94         assert(ret == 0 && "BUG calling sigemptyset");
  95         ret = sigaddset(&cset, SIGCHLD);
  96         assert(ret == 0 && "BUG calling sigaddset for SIGCHLD");
  97         pid = vfork();
  98         if (pid == 0) {
  99                 int sig;
 100                 I32 i, child_fd, max = av_len(redir);
 101
 102                 for (child_fd = 0; child_fd <= max; child_fd++) {
 103                         SV **parent = av_fetch(redir, child_fd, 0);
 104                         int parent_fd = SvIV(*parent);
 105                         if (parent_fd == child_fd)
 106                                 continue;
 107                         if (dup2(parent_fd, child_fd) < 0)
 108                                 exit_err(&cerrnum);
 109                 }
 110                 for (sig = 1; sig < NSIG; sig++)
 111                         signal(sig, SIG_DFL); /* ignore errors on signals */
 112                 if (*cd && chdir(cd) < 0)
 113                         exit_err(&cerrnum);
 114
 115                 max = av_len(rlim);
 116                 for (i = 0; i < max; i += 3) {
 117                         struct rlimit rl;
 118                         SV **res = av_fetch(rlim, i, 0);
 119                         SV **soft = av_fetch(rlim, i + 1, 0);
 120                         SV **hard = av_fetch(rlim, i + 2, 0);
 121
 122                         rl.rlim_cur = SvIV(*soft);
 123                         rl.rlim_max = SvIV(*hard);
 124                         if (setrlimit(SvIV(*res), &rl) < 0)
 125                                 exit_err(&cerrnum);
 126                 }
 127
 128                 /*
 129                  * don't bother unblocking other signals for now, just SIGCHLD.
 130                  * we don't want signals to the group taking out a subprocess
 131                  */
 132                 (void)sigprocmask(SIG_UNBLOCK, &cset, NULL);
 133                 execve(filename, argv, envp);
 134                 exit_err(&cerrnum);
 135         }
 136         perrnum = errno;
 137         ret = sigprocmask(SIG_SETMASK, &old, NULL);
 138         assert(ret == 0 && "BUG calling sigprocmask to restore");
 139         if (cerrnum) {
 140                 if (pid > 0)
 141                         waitpid(pid, NULL, 0);
 142                 pid = -1;
 143                 errno = cerrnum;
 144         } else if (perrnum) {
 145                 errno = perrnum;
 146         }
 147         return (int)pid;
 148 }
 149 VFORK_SPAWN
 150
 151 # btrfs on Linux is copy-on-write (COW) by default.  As of Linux 5.7,
 152 # this still leads to fragmentation for SQLite and Xapian files where
 153 # random I/O happens, so we disable COW just for SQLite files and Xapian
 154 # directories.  Disabling COW disables checksumming, so we only do this
 155 # for regeneratable files, and not canonical git storage (git doesn't
 156 # checksum refs, only data under $GIT_DIR/objects).
 157 my $set_nodatacow = $^O eq 'linux' ? <<'SET_NODATACOW' : '';
 158 #include <sys/ioctl.h>
 159 #include <sys/vfs.h>
 160 #include <linux/magic.h>
 161 #include <linux/fs.h>
 162 #include <errno.h>
 163 #include <stdio.h>
 164 #include <string.h>
 165
 166 void set_nodatacow(int fd)
 167 {
 168         struct statfs buf;
 169         int val = 0;
 170
 171         if (fstatfs(fd, &buf) < 0) {
 172                 fprintf(stderr, "fstatfs: %s\\n", strerror(errno));
 173                 return;
 174         }
 175
 176         /* only btrfs is known to have this problem, so skip for non-btrfs */
 177         if (buf.f_type != BTRFS_SUPER_MAGIC)
 178                 return;
 179
 180         if (ioctl(fd, FS_IOC_GETFLAGS, &val) < 0) {
 181                 fprintf(stderr, "FS_IOC_GET_FLAGS: %s\\n", strerror(errno));
 182                 return;
 183         }
 184         val |= FS_NOCOW_FL;
 185         if (ioctl(fd, FS_IOC_SETFLAGS, &val) < 0)
 186                 fprintf(stderr, "FS_IOC_SET_FLAGS: %s\\n", strerror(errno));
 187 }
 188 SET_NODATACOW
 189
 190 my $inline_dir = $ENV{PERL_INLINE_DIRECTORY} //= (
 191                 $ENV{XDG_CACHE_HOME} //
 192                 ( ($ENV{HOME} // '/nonexistent').'/.cache' )
 193         ).'/public-inbox/inline-c';
 194
 195 $set_nodatacow = $vfork_spawn = undef unless -d $inline_dir && -w _;
 196 if (defined $vfork_spawn) {
 197         # Inline 0.64 or later has locking in multi-process env,
 198         # but we support 0.5 on Debian wheezy
 199         use Fcntl qw(:flock);
 200         eval {
 201                 my $f = "$inline_dir/.public-inbox.lock";
 202                 open my $fh, '>', $f or die "failed to open $f: $!\n";
 203                 flock($fh, LOCK_EX) or die "LOCK_EX failed on $f: $!\n";
 204                 eval 'use Inline C => $vfork_spawn . $set_nodatacow';
 205                 my $err = $@;
 206                 my $ndc_err;
 207                 if ($err && $set_nodatacow) { # missing Linux kernel headers
 208                         $ndc_err = $err;
 209                         undef $set_nodatacow;
 210                         eval 'use Inline C => $vfork_spawn';
 211                 }
 212                 flock($fh, LOCK_UN) or die "LOCK_UN failed on $f: $!\n";
 213                 die $err if $err;
 214                 warn $ndc_err if $ndc_err;
 215         };
 216         if ($@) {
 217                 warn "Inline::C failed for vfork: $@\n";
 218                 $set_nodatacow = $vfork_spawn = undef;
 219         }
 220 }
 221
 222 unless (defined $vfork_spawn) {
 223         require PublicInbox::SpawnPP;
 224         *pi_fork_exec = \&PublicInbox::SpawnPP::pi_fork_exec
 225 }
 226 unless ($set_nodatacow) {
 227         require PublicInbox::NDC_PP;
 228         no warnings 'once';
 229         *set_nodatacow = \&PublicInbox::NDC_PP::set_nodatacow;
 230 }
 231 undef $set_nodatacow;
 232 undef $vfork_spawn;
 233
 234 sub which ($) {
 235         my ($file) = @_;
 236         return $file if index($file, '/') >= 0;
 237         foreach my $p (split(':', $ENV{PATH})) {
 238                 $p .= "/$file";
 239                 return $p if -x $p;
 240         }
 241         undef;
 242 }
 243
 244 sub spawn ($;$$) {
 245         my ($cmd, $env, $opts) = @_;
 246         my $f = which($cmd->[0]);
 247         defined $f or die "$cmd->[0]: command not found\n";
 248         my @env;
 249         $opts ||= {};
 250
 251         my %env = $env ? (%ENV, %$env) : %ENV;
 252         while (my ($k, $v) = each %env) {
 253                 push @env, "$k=$v";
 254         }
 255         my $redir = [];
 256         for my $child_fd (0..2) {
 257                 my $parent_fd = $opts->{$child_fd};
 258                 if (defined($parent_fd) && $parent_fd !~ /\A[0-9]+\z/) {
 259                         defined(my $fd = fileno($parent_fd)) or
 260                                         die "$parent_fd not an IO GLOB? $!";
 261                         $parent_fd = $fd;
 262                 }
 263                 $redir->[$child_fd] = $parent_fd // $child_fd;
 264         }
 265         my $rlim = [];
 266
 267         foreach my $l (@RLIMITS) {
 268                 defined(my $v = $opts->{$l}) or next;
 269                 my $r = eval "require BSD::Resource; BSD::Resource::$l();";
 270                 unless (defined $r) {
 271                         warn "$l undefined by BSD::Resource: $@\n";
 272                         next;
 273                 }
 274                 push @$rlim, $r, @$v;
 275         }
 276         my $cd = $opts->{'-C'} // ''; # undef => NULL mapping doesn't work?
 277         my $pid = pi_fork_exec($redir, $f, $cmd, \@env, $rlim, $cd);
 278         die "fork_exec @$cmd failed: $!\n" unless $pid > 0;
 279         $pid;
 280 }
 281
 282 sub popen_rd {
 283         my ($cmd, $env, $opts) = @_;
 284         pipe(my ($r, $w)) or die "pipe: $!\n";
 285         $opts ||= {};
 286         $opts->{1} = fileno($w);
 287         my $pid = spawn($cmd, $env, $opts);
 288         return ($r, $pid) if wantarray;
 289         my $ret = gensym;
 290         tie *$ret, 'PublicInbox::ProcessPipe', $pid, $r;
 291         $ret;
 292 }
 293
 294 1;