lib/PublicInbox/Spawn.pm

   1 # Copyright (C) 2016-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # This allows vfork to be used for spawning subprocesses if
   5 # ~/.cache/public-inbox/inline-c is writable or if PERL_INLINE_DIRECTORY
   6 # is explicitly defined in the environment (and writable).
   7 # Under Linux, vfork can make a big difference in spawning performance
   8 # as process size increases (fork still needs to mark pages for CoW use).
   9 # Currently, we only use this for code intended for long running
  10 # daemons (inside the PSGI code (-httpd) and -nntpd).  The short-lived
  11 # scripts (-mda, -index, -learn, -init) either use IPC::run or standard
  12 # Perl routines.
  13 #
  14 # There'll probably be more OS-level C stuff here, down the line.
  15 # We don't want too many DSOs: https://udrepper.livejournal.com/8790.html
  16
  17 package PublicInbox::Spawn;
  18 use strict;
  19 use parent qw(Exporter);
  20 use Symbol qw(gensym);
  21 use PublicInbox::ProcessPipe;
  22 our @EXPORT_OK = qw(which spawn popen_rd run_die nodatacow_dir);
  23 our @RLIMITS = qw(RLIMIT_CPU RLIMIT_CORE RLIMIT_DATA);
  24
  25 my $vfork_spawn = <<'VFORK_SPAWN';
  26 #include <sys/types.h>
  27 #include <sys/time.h>
  28 #include <sys/resource.h>
  29 #include <unistd.h>
  30 #include <stdlib.h>
  31 #include <errno.h>
  32
  33 /* some platforms need alloca.h, but some don't */
  34 #if defined(__GNUC__) && !defined(alloca)
  35 #  define alloca(sz) __builtin_alloca(sz)
  36 #endif
  37
  38 #include <signal.h>
  39 #include <assert.h>
  40
  41 /*
  42  * From the av_len apidoc:
  43  *   Note that, unlike what the name implies, it returns
  44  *   the highest index in the array, so to get the size of
  45  *   the array you need to use "av_len(av) + 1".
  46  *   This is unlike "sv_len", which returns what you would expect.
  47  */
  48 #define AV2C_COPY(dst, src) do { \
  49         I32 i; \
  50         I32 top_index = av_len(src); \
  51         I32 real_len = top_index + 1; \
  52         I32 capa = real_len + 1; \
  53         dst = alloca(capa * sizeof(char *)); \
  54         for (i = 0; i < real_len; i++) { \
  55                 SV **sv = av_fetch(src, i, 0); \
  56                 dst[i] = SvPV_nolen(*sv); \
  57         } \
  58         dst[real_len] = 0; \
  59 } while (0)
  60
  61 /* needs to be safe inside a vfork'ed process */
  62 static void exit_err(int *cerrnum)
  63 {
  64         *cerrnum = errno;
  65         _exit(1);
  66 }
  67
  68 /*
  69  * unstable internal API.  It'll be updated depending on
  70  * whatever we'll need in the future.
  71  * Be sure to update PublicInbox::SpawnPP if this changes
  72  */
  73 int pi_fork_exec(SV *redirref, SV *file, SV *cmdref, SV *envref, SV *rlimref,
  74                  const char *cd)
  75 {
  76         AV *redir = (AV *)SvRV(redirref);
  77         AV *cmd = (AV *)SvRV(cmdref);
  78         AV *env = (AV *)SvRV(envref);
  79         AV *rlim = (AV *)SvRV(rlimref);
  80         const char *filename = SvPV_nolen(file);
  81         pid_t pid;
  82         char **argv, **envp;
  83         sigset_t set, old, cset;
  84         int ret, perrnum, cerrnum = 0;
  85
  86         AV2C_COPY(argv, cmd);
  87         AV2C_COPY(envp, env);
  88
  89         ret = sigfillset(&set);
  90         assert(ret == 0 && "BUG calling sigfillset");
  91         ret = sigprocmask(SIG_SETMASK, &set, &old);
  92         assert(ret == 0 && "BUG calling sigprocmask to block");
  93         ret = sigemptyset(&cset);
  94         assert(ret == 0 && "BUG calling sigemptyset");
  95         ret = sigaddset(&cset, SIGCHLD);
  96         assert(ret == 0 && "BUG calling sigaddset for SIGCHLD");
  97         pid = vfork();
  98         if (pid == 0) {
  99                 int sig;
 100                 I32 i, child_fd, max = av_len(redir);
 101
 102                 for (child_fd = 0; child_fd <= max; child_fd++) {
 103                         SV **parent = av_fetch(redir, child_fd, 0);
 104                         int parent_fd = SvIV(*parent);
 105                         if (parent_fd == child_fd)
 106                                 continue;
 107                         if (dup2(parent_fd, child_fd) < 0)
 108                                 exit_err(&cerrnum);
 109                 }
 110                 for (sig = 1; sig < NSIG; sig++)
 111                         signal(sig, SIG_DFL); /* ignore errors on signals */
 112                 if (*cd && chdir(cd) < 0)
 113                         exit_err(&cerrnum);
 114
 115                 max = av_len(rlim);
 116                 for (i = 0; i < max; i += 3) {
 117                         struct rlimit rl;
 118                         SV **res = av_fetch(rlim, i, 0);
 119                         SV **soft = av_fetch(rlim, i + 1, 0);
 120                         SV **hard = av_fetch(rlim, i + 2, 0);
 121
 122                         rl.rlim_cur = SvIV(*soft);
 123                         rl.rlim_max = SvIV(*hard);
 124                         if (setrlimit(SvIV(*res), &rl) < 0)
 125                                 exit_err(&cerrnum);
 126                 }
 127
 128                 /*
 129                  * don't bother unblocking other signals for now, just SIGCHLD.
 130                  * we don't want signals to the group taking out a subprocess
 131                  */
 132                 (void)sigprocmask(SIG_UNBLOCK, &cset, NULL);
 133                 execve(filename, argv, envp);
 134                 exit_err(&cerrnum);
 135         }
 136         perrnum = errno;
 137         ret = sigprocmask(SIG_SETMASK, &old, NULL);
 138         assert(ret == 0 && "BUG calling sigprocmask to restore");
 139         if (cerrnum) {
 140                 if (pid > 0)
 141                         waitpid(pid, NULL, 0);
 142                 pid = -1;
 143                 errno = cerrnum;
 144         } else if (perrnum) {
 145                 errno = perrnum;
 146         }
 147         return (int)pid;
 148 }
 149 VFORK_SPAWN
 150
 151 # btrfs on Linux is copy-on-write (COW) by default.  As of Linux 5.7,
 152 # this still leads to fragmentation for SQLite and Xapian files where
 153 # random I/O happens, so we disable COW just for SQLite files and Xapian
 154 # directories.  Disabling COW disables checksumming, so we only do this
 155 # for regeneratable files, and not canonical git storage (git doesn't
 156 # checksum refs, only data under $GIT_DIR/objects).
 157 my $set_nodatacow = $^O eq 'linux' ? <<'SET_NODATACOW' : '';
 158 #include <sys/ioctl.h>
 159 #include <sys/vfs.h>
 160 #include <linux/magic.h>
 161 #include <linux/fs.h>
 162 #include <dirent.h>
 163 #include <errno.h>
 164 #include <stdio.h>
 165 #include <string.h>
 166
 167 void nodatacow_fd(int fd)
 168 {
 169         struct statfs buf;
 170         int val = 0;
 171
 172         if (fstatfs(fd, &buf) < 0) {
 173                 fprintf(stderr, "fstatfs: %s\\n", strerror(errno));
 174                 return;
 175         }
 176
 177         /* only btrfs is known to have this problem, so skip for non-btrfs */
 178         if (buf.f_type != BTRFS_SUPER_MAGIC)
 179                 return;
 180
 181         if (ioctl(fd, FS_IOC_GETFLAGS, &val) < 0) {
 182                 fprintf(stderr, "FS_IOC_GET_FLAGS: %s\\n", strerror(errno));
 183                 return;
 184         }
 185         val |= FS_NOCOW_FL;
 186         if (ioctl(fd, FS_IOC_SETFLAGS, &val) < 0)
 187                 fprintf(stderr, "FS_IOC_SET_FLAGS: %s\\n", strerror(errno));
 188 }
 189
 190 void nodatacow_dir(const char *dir)
 191 {
 192         DIR *dh = opendir(dir);
 193         int fd;
 194
 195         if (!dh) croak("opendir(%s): %s", dir, strerror(errno));
 196         fd = dirfd(dh);
 197         if (fd >= 0)
 198                 nodatacow_fd(fd);
 199         /* ENOTSUP probably won't happen under Linux... */
 200         closedir(dh);
 201 }
 202 SET_NODATACOW
 203
 204 # last choice for script/lei, 1st choice for lei internals
 205 # compatible with PublicInbox::CmdIPC4
 206 my $fdpass = <<'FDPASS';
 207 #include <sys/types.h>
 208 #include <sys/uio.h>
 209 #include <sys/socket.h>
 210
 211 #if defined(CMSG_SPACE) && defined(CMSG_LEN)
 212 #define SEND_FD_CAPA 4
 213 #define SEND_FD_SPACE (SEND_FD_CAPA * sizeof(int))
 214 union my_cmsg {
 215         struct cmsghdr hdr;
 216         char pad[sizeof(struct cmsghdr) + 16 + SEND_FD_SPACE];
 217 };
 218
 219 int send_cmd4(PerlIO *s, SV *svfds, SV *data, int flags)
 220 {
 221         struct msghdr msg = { 0 };
 222         union my_cmsg cmsg = { 0 };
 223         STRLEN dlen = 0;
 224         struct iovec iov;
 225         AV *fds = (AV *)SvRV(svfds);
 226         I32 i, nfds = av_len(fds) + 1;
 227         int *fdp;
 228
 229         if (SvOK(data)) {
 230                 iov.iov_base = SvPV(data, dlen);
 231                 iov.iov_len = dlen;
 232         }
 233         if (!dlen) { /* must be non-zero */
 234                 iov.iov_base = &msg.msg_namelen; /* whatever */
 235                 iov.iov_len = 1;
 236         }
 237         msg.msg_iov = &iov;
 238         msg.msg_iovlen = 1;
 239         if (nfds) {
 240                 if (nfds > SEND_FD_CAPA) {
 241                         fprintf(stderr, "FIXME: bump SEND_FD_CAPA=%d\n", nfds);
 242                         nfds = SEND_FD_CAPA;
 243                 }
 244                 msg.msg_control = &cmsg.hdr;
 245                 msg.msg_controllen = CMSG_SPACE(nfds * sizeof(int));
 246                 cmsg.hdr.cmsg_level = SOL_SOCKET;
 247                 cmsg.hdr.cmsg_type = SCM_RIGHTS;
 248                 cmsg.hdr.cmsg_len = CMSG_LEN(nfds * sizeof(int));
 249                 fdp = (int *)CMSG_DATA(&cmsg.hdr);
 250                 for (i = 0; i < nfds; i++) {
 251                         SV **fd = av_fetch(fds, i, 0);
 252                         *fdp++ = SvIV(*fd);
 253                 }
 254         }
 255         return sendmsg(PerlIO_fileno(s), &msg, flags) >= 0;
 256 }
 257
 258 void recv_cmd4(PerlIO *s, SV *buf, STRLEN n)
 259 {
 260         union my_cmsg cmsg = { 0 };
 261         struct msghdr msg = { 0 };
 262         struct iovec iov;
 263         size_t i;
 264         Inline_Stack_Vars;
 265         Inline_Stack_Reset;
 266
 267         if (!SvOK(buf))
 268                 sv_setpvn(buf, "", 0);
 269         iov.iov_base = SvGROW(buf, n + 1);
 270         iov.iov_len = n;
 271         msg.msg_iov = &iov;
 272         msg.msg_iovlen = 1;
 273         msg.msg_control = &cmsg.hdr;
 274         msg.msg_controllen = CMSG_SPACE(SEND_FD_SPACE);
 275
 276         i = recvmsg(PerlIO_fileno(s), &msg, 0);
 277         if (i < 0)
 278                 croak("recvmsg: %s", strerror(errno));
 279         SvCUR_set(buf, i);
 280         if (i > 0 && cmsg.hdr.cmsg_level == SOL_SOCKET &&
 281                         cmsg.hdr.cmsg_type == SCM_RIGHTS) {
 282                 size_t len = cmsg.hdr.cmsg_len;
 283                 int *fdp = (int *)CMSG_DATA(&cmsg.hdr);
 284                 for (i = 0; CMSG_LEN((i + 1) * sizeof(int)) <= len; i++)
 285                         Inline_Stack_Push(sv_2mortal(newSViv(*fdp++)));
 286         }
 287         Inline_Stack_Done;
 288 }
 289 #endif /* defined(CMSG_SPACE) && defined(CMSG_LEN) */
 290 FDPASS
 291
 292 my $inline_dir = $ENV{PERL_INLINE_DIRECTORY} //= (
 293                 $ENV{XDG_CACHE_HOME} //
 294                 ( ($ENV{HOME} // '/nonexistent').'/.cache' )
 295         ).'/public-inbox/inline-c';
 296
 297 $set_nodatacow = $vfork_spawn = $fdpass = undef unless -d $inline_dir && -w _;
 298 if (defined $vfork_spawn) {
 299         # Inline 0.64 or later has locking in multi-process env,
 300         # but we support 0.5 on Debian wheezy
 301         use Fcntl qw(:flock);
 302         eval {
 303                 my $f = "$inline_dir/.public-inbox.lock";
 304                 open my $fh, '>', $f or die "failed to open $f: $!\n";
 305                 flock($fh, LOCK_EX) or die "LOCK_EX failed on $f: $!\n";
 306                 eval 'use Inline C => $vfork_spawn.$fdpass.$set_nodatacow';
 307                         # . ', BUILD_NOISY => 1';
 308                 my $err = $@;
 309                 my $ndc_err;
 310                 if ($err && $set_nodatacow) { # missing Linux kernel headers
 311                         $ndc_err = $err;
 312                         undef $set_nodatacow;
 313                         eval 'use Inline C => $vfork_spawn . $fdpass';
 314                 }
 315                 flock($fh, LOCK_UN) or die "LOCK_UN failed on $f: $!\n";
 316                 die $err if $err;
 317                 warn $ndc_err if $ndc_err;
 318         };
 319         if ($@) {
 320                 warn "Inline::C failed for vfork: $@\n";
 321                 $set_nodatacow = $vfork_spawn = $fdpass = undef;
 322         }
 323 }
 324
 325 unless (defined $vfork_spawn) {
 326         require PublicInbox::SpawnPP;
 327         *pi_fork_exec = \&PublicInbox::SpawnPP::pi_fork_exec
 328 }
 329 unless ($set_nodatacow) {
 330         require PublicInbox::NDC_PP;
 331         no warnings 'once';
 332         *nodatacow_fd = \&PublicInbox::NDC_PP::nodatacow_fd;
 333         *nodatacow_dir = \&PublicInbox::NDC_PP::nodatacow_dir;
 334 }
 335
 336 undef $set_nodatacow;
 337 undef $vfork_spawn;
 338 undef $fdpass;
 339
 340 sub which ($) {
 341         my ($file) = @_;
 342         return $file if index($file, '/') >= 0;
 343         foreach my $p (split(':', $ENV{PATH})) {
 344                 $p .= "/$file";
 345                 return $p if -x $p;
 346         }
 347         undef;
 348 }
 349
 350 sub spawn ($;$$) {
 351         my ($cmd, $env, $opts) = @_;
 352         my $f = which($cmd->[0]);
 353         defined $f or die "$cmd->[0]: command not found\n";
 354         my @env;
 355         $opts ||= {};
 356
 357         my %env = $env ? (%ENV, %$env) : %ENV;
 358         while (my ($k, $v) = each %env) {
 359                 push @env, "$k=$v";
 360         }
 361         my $redir = [];
 362         for my $child_fd (0..2) {
 363                 my $parent_fd = $opts->{$child_fd};
 364                 if (defined($parent_fd) && $parent_fd !~ /\A[0-9]+\z/) {
 365                         defined(my $fd = fileno($parent_fd)) or
 366                                         die "$parent_fd not an IO GLOB? $!";
 367                         $parent_fd = $fd;
 368                 }
 369                 $redir->[$child_fd] = $parent_fd // $child_fd;
 370         }
 371         my $rlim = [];
 372
 373         foreach my $l (@RLIMITS) {
 374                 defined(my $v = $opts->{$l}) or next;
 375                 my $r = eval "require BSD::Resource; BSD::Resource::$l();";
 376                 unless (defined $r) {
 377                         warn "$l undefined by BSD::Resource: $@\n";
 378                         next;
 379                 }
 380                 push @$rlim, $r, @$v;
 381         }
 382         my $cd = $opts->{'-C'} // ''; # undef => NULL mapping doesn't work?
 383         my $pid = pi_fork_exec($redir, $f, $cmd, \@env, $rlim, $cd);
 384         die "fork_exec @$cmd failed: $!\n" unless $pid > 0;
 385         $pid;
 386 }
 387
 388 sub popen_rd {
 389         my ($cmd, $env, $opt) = @_;
 390         pipe(my ($r, $w)) or die "pipe: $!\n";
 391         $opt ||= {};
 392         $opt->{1} = fileno($w);
 393         my $pid = spawn($cmd, $env, $opt);
 394         return ($r, $pid) if wantarray;
 395         my $ret = gensym;
 396         tie *$ret, 'PublicInbox::ProcessPipe', $pid, $r, @$opt{qw(cb arg)};
 397         $ret;
 398 }
 399
 400 sub run_die ($;$$) {
 401         my ($cmd, $env, $rdr) = @_;
 402         my $pid = spawn($cmd, $env, $rdr);
 403         waitpid($pid, 0) == $pid or die "@$cmd did not finish";
 404         $? == 0 or die "@$cmd failed: \$?=$?\n";
 405 }
 406
 407 1;