lib/PublicInbox/Spawn.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 #
   4 # This allows vfork to be used for spawning subprocesses if
   5 # PERL_INLINE_DIRECTORY is explicitly defined in the environment.
   6 # Under Linux, vfork can make a big difference in spawning performance
   7 # as process size increases (fork still needs to mark pages for CoW use).
   8 # Currently, we only use this for code intended for long running
   9 # daemons (inside the PSGI code (-httpd) and -nntpd).  The short-lived
  10 # scripts (-mda, -index, -learn, -init) either use IPC::run or standard
  11 # Perl routines.
  12
  13 package PublicInbox::Spawn;
  14 use strict;
  15 use warnings;
  16 use base qw(Exporter);
  17 use Symbol qw(gensym);
  18 use IO::Handle;
  19 use PublicInbox::ProcessPipe;
  20 our @EXPORT_OK = qw/which spawn popen_rd/;
  21 sub RLIMITS () { qw(RLIMIT_CPU RLIMIT_CORE RLIMIT_DATA) }
  22
  23 my $vfork_spawn = <<'VFORK_SPAWN';
  24 #include <sys/types.h>
  25 #include <sys/uio.h>
  26 #include <sys/time.h>
  27 #include <sys/resource.h>
  28 #include <unistd.h>
  29 #include <stdlib.h>
  30
  31 /* some platforms need alloca.h, but some don't */
  32 #if defined(__GNUC__) && !defined(alloca)
  33 #  define alloca(sz) __builtin_alloca(sz)
  34 #endif
  35
  36 #include <signal.h>
  37 #include <assert.h>
  38
  39 /*
  40  * From the av_len apidoc:
  41  *   Note that, unlike what the name implies, it returns
  42  *   the highest index in the array, so to get the size of
  43  *   the array you need to use "av_len(av) + 1".
  44  *   This is unlike "sv_len", which returns what you would expect.
  45  */
  46 #define AV2C_COPY(dst, src) do { \
  47         I32 i; \
  48         I32 top_index = av_len(src); \
  49         I32 real_len = top_index + 1; \
  50         I32 capa = real_len + 1; \
  51         dst = alloca(capa * sizeof(char *)); \
  52         for (i = 0; i < real_len; i++) { \
  53                 SV **sv = av_fetch(src, i, 0); \
  54                 dst[i] = SvPV_nolen(*sv); \
  55         } \
  56         dst[real_len] = 0; \
  57 } while (0)
  58
  59 static void *deconst(const char *s)
  60 {
  61         union { const char *in; void *out; } u;
  62         u.in = s;
  63         return u.out;
  64 }
  65
  66 /* needs to be safe inside a vfork'ed process */
  67 static void xerr(const char *msg)
  68 {
  69         struct iovec iov[3];
  70         const char *err = strerror(errno); /* should be safe in practice */
  71
  72         iov[0].iov_base = deconst(msg);
  73         iov[0].iov_len = strlen(msg);
  74         iov[1].iov_base = deconst(err);
  75         iov[1].iov_len = strlen(err);
  76         iov[2].iov_base = deconst("\n");
  77         iov[2].iov_len = 1;
  78         writev(2, iov, 3);
  79         _exit(1);
  80 }
  81
  82 /*
  83  * unstable internal API.  It'll be updated depending on
  84  * whatever we'll need in the future.
  85  * Be sure to update PublicInbox::SpawnPP if this changes
  86  */
  87 int pi_fork_exec(SV *redirref, SV *file, SV *cmdref, SV *envref, SV *rlimref,
  88                  const char *cd)
  89 {
  90         AV *redir = (AV *)SvRV(redirref);
  91         AV *cmd = (AV *)SvRV(cmdref);
  92         AV *env = (AV *)SvRV(envref);
  93         AV *rlim = (AV *)SvRV(rlimref);
  94         const char *filename = SvPV_nolen(file);
  95         pid_t pid;
  96         char **argv, **envp;
  97         sigset_t set, old;
  98         int ret, errnum;
  99
 100         AV2C_COPY(argv, cmd);
 101         AV2C_COPY(envp, env);
 102
 103         ret = sigfillset(&set);
 104         assert(ret == 0 && "BUG calling sigfillset");
 105         ret = sigprocmask(SIG_SETMASK, &set, &old);
 106         assert(ret == 0 && "BUG calling sigprocmask to block");
 107         pid = vfork();
 108         if (pid == 0) {
 109                 int sig;
 110                 I32 i, child_fd, max = av_len(redir);
 111
 112                 for (child_fd = 0; child_fd <= max; child_fd++) {
 113                         SV **parent = av_fetch(redir, child_fd, 0);
 114                         int parent_fd = SvIV(*parent);
 115                         if (parent_fd == child_fd)
 116                                 continue;
 117                         if (dup2(parent_fd, child_fd) < 0)
 118                                 xerr("dup2");
 119                 }
 120                 for (sig = 1; sig < NSIG; sig++)
 121                         signal(sig, SIG_DFL); /* ignore errors on signals */
 122                 if (*cd && chdir(cd) < 0)
 123                         xerr("chdir");
 124
 125                 max = av_len(rlim);
 126                 for (i = 0; i < max; i += 3) {
 127                         struct rlimit rl;
 128                         SV **res = av_fetch(rlim, i, 0);
 129                         SV **soft = av_fetch(rlim, i + 1, 0);
 130                         SV **hard = av_fetch(rlim, i + 2, 0);
 131
 132                         rl.rlim_cur = SvIV(*soft);
 133                         rl.rlim_max = SvIV(*hard);
 134                         if (setrlimit(SvIV(*res), &rl) < 0)
 135                                 xerr("sertlimit");
 136                 }
 137
 138                 /*
 139                  * don't bother unblocking, we don't want signals
 140                  * to the group taking out a subprocess
 141                  */
 142                 execve(filename, argv, envp);
 143                 xerr("execve failed");
 144         }
 145         errnum = errno;
 146         ret = sigprocmask(SIG_SETMASK, &old, NULL);
 147         assert(ret == 0 && "BUG calling sigprocmask to restore");
 148         errno = errnum;
 149
 150         return (int)pid;
 151 }
 152 VFORK_SPAWN
 153
 154 my $inline_dir = $ENV{PERL_INLINE_DIRECTORY};
 155 $vfork_spawn = undef unless defined $inline_dir && -d $inline_dir && -w _;
 156 if (defined $vfork_spawn) {
 157         # Inline 0.64 or later has locking in multi-process env,
 158         # but we support 0.5 on Debian wheezy
 159         use Fcntl qw(:flock);
 160         eval {
 161                 my $f = "$inline_dir/.public-inbox.lock";
 162                 open my $fh, '>', $f or die "failed to open $f: $!\n";
 163                 flock($fh, LOCK_EX) or die "LOCK_EX failed on $f: $!\n";
 164                 eval 'use Inline C => $vfork_spawn'; #, BUILD_NOISY => 1';
 165                 my $err = $@;
 166                 flock($fh, LOCK_UN) or die "LOCK_UN failed on $f: $!\n";
 167                 die $err if $err;
 168         };
 169         if ($@) {
 170                 warn "Inline::C failed for vfork: $@\n";
 171                 $vfork_spawn = undef;
 172         }
 173 }
 174
 175 unless (defined $vfork_spawn) {
 176         require PublicInbox::SpawnPP;
 177         *pi_fork_exec = \&PublicInbox::SpawnPP::pi_fork_exec
 178 }
 179
 180 sub which ($) {
 181         my ($file) = @_;
 182         return $file if index($file, '/') >= 0;
 183         foreach my $p (split(':', $ENV{PATH})) {
 184                 $p .= "/$file";
 185                 return $p if -x $p;
 186         }
 187         undef;
 188 }
 189
 190 sub spawn ($;$$) {
 191         my ($cmd, $env, $opts) = @_;
 192         my $f = which($cmd->[0]);
 193         defined $f or die "$cmd->[0]: command not found\n";
 194         my @env;
 195         $opts ||= {};
 196
 197         my %env = $env ? (%ENV, %$env) : %ENV;
 198         while (my ($k, $v) = each %env) {
 199                 push @env, "$k=$v";
 200         }
 201         my $redir = [];
 202         for my $child_fd (0..2) {
 203                 my $parent_fd = $opts->{$child_fd};
 204                 if (defined($parent_fd) && $parent_fd !~ /\A[0-9]+\z/) {
 205                         defined(my $fd = fileno($parent_fd)) or
 206                                         die "$parent_fd not an IO GLOB? $!";
 207                         $parent_fd = $fd;
 208                 }
 209                 $redir->[$child_fd] = $parent_fd // $child_fd;
 210         }
 211         my $rlim = [];
 212
 213         foreach my $l (RLIMITS()) {
 214                 defined(my $v = $opts->{$l}) or next;
 215                 my $r = eval "require BSD::Resource; BSD::Resource::$l();";
 216                 unless (defined $r) {
 217                         warn "$l undefined by BSD::Resource: $@\n";
 218                         next;
 219                 }
 220                 push @$rlim, $r, @$v;
 221         }
 222         my $cd = $opts->{'-C'} // ''; # undef => NULL mapping doesn't work?
 223         my $pid = pi_fork_exec($redir, $f, $cmd, \@env, $rlim, $cd);
 224         $pid < 0 ? undef : $pid;
 225 }
 226
 227 sub popen_rd {
 228         my ($cmd, $env, $opts) = @_;
 229         pipe(my ($r, $w)) or die "pipe: $!\n";
 230         $opts ||= {};
 231         $opts->{1} = fileno($w);
 232         my $pid = spawn($cmd, $env, $opts);
 233         return unless defined $pid;
 234         return ($r, $pid) if wantarray;
 235         my $ret = gensym;
 236         tie *$ret, 'PublicInbox::ProcessPipe', $pid, $r;
 237         $ret;
 238 }
 239
 240 1;