lib/PublicInbox/SpawnPP.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Pure-Perl implementation of "spawn".  This can't take advantage
   5 # of vfork, so no speedups under Linux for spawning from large processes.
   6 # Do not require this directly, only use from PublicInbox::Spawn
   7 package PublicInbox::SpawnPP;
   8 use v5.12;
   9 use POSIX qw(dup2 _exit setpgid :signal_h);
  10 # this is loaded by PublicInbox::Spawn, so we can't use/require it, here
  11
  12 # Pure Perl implementation for folks that do not use Inline::C
  13 sub pi_fork_exec ($$$$$$$) {
  14         my ($redir, $f, $cmd, $env, $rlim, $cd, $pgid) = @_;
  15         my $old = POSIX::SigSet->new();
  16         my $set = POSIX::SigSet->new();
  17         $set->fillset or die "sigfillset: $!";
  18         sigprocmask(SIG_SETMASK, $set, $old) or die "SIG_SETMASK(set): $!";
  19         my $syserr;
  20         pipe(my ($r, $w)) or die "pipe: $!";
  21         my $pid = fork // die "fork (+exec) @$cmd: $!\n";
  22         if ($pid == 0) {
  23                 close $r;
  24                 $SIG{__DIE__} = sub {
  25                         warn(@_);
  26                         syswrite($w, my $num = $! + 0);
  27                         _exit(1);
  28                 };
  29                 for my $child_fd (0..$#$redir) {
  30                         my $parent_fd = $redir->[$child_fd];
  31                         next if $parent_fd == $child_fd;
  32                         dup2($parent_fd, $child_fd) or
  33                                 die "dup2($parent_fd, $child_fd): $!";
  34                 }
  35                 if ($pgid >= 0 && !defined(setpgid(0, $pgid))) {
  36                         die "setpgid(0, $pgid): $!";
  37                 }
  38                 $SIG{$_} = 'DEFAULT' for grep(!/\A__/, keys %SIG);
  39                 if ($cd ne '') {
  40                         chdir $cd or die "chdir $cd: $!";
  41                 }
  42                 while (@$rlim) {
  43                         my ($r, $soft, $hard) = splice(@$rlim, 0, 3);
  44                         BSD::Resource::setrlimit($r, $soft, $hard) or
  45                                 die "setrlimit($r=[$soft,$hard]: $!)";
  46                 }
  47                 $old->delset(POSIX::SIGCHLD) or die "sigdelset CHLD: $!";
  48                 sigprocmask(SIG_SETMASK, $old) or die "SIG_SETMASK ~CHLD: $!";
  49                 $cmd->[0] = $f;
  50                 if ($ENV{MOD_PERL}) {
  51                         $f = PublicInbox::Spawn::which('env');
  52                         @$cmd = ('env', '-i', @$env, @$cmd);
  53                 } else {
  54                         %ENV = map { split(/=/, $_, 2) } @$env;
  55                 }
  56                 exec { $f } @$cmd;
  57                 die "exec @$cmd failed: $!";
  58         }
  59         close $w;
  60         sigprocmask(SIG_SETMASK, $old) or die "SIG_SETMASK(old): $!";
  61         if (my $cerrnum = do { local $/, <$r> }) {
  62                 $! = $cerrnum;
  63                 die "forked child $@: $!";
  64         }
  65         $pid;
  66 }
  67
  68 1;