lib/PublicInbox/SpawnPP.pm

   1 # Copyright (C) 2016 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 package PublicInbox::SpawnPP;
   4 use strict;
   5 use warnings;
   6 use POSIX qw(dup2 :signal_h);
   7
   8 # Pure Perl implementation for folks that do not use Inline::C
   9 sub public_inbox_fork_exec ($$$$$$) {
  10         my ($in, $out, $err, $f, $cmd, $env) = @_;
  11         my $old = POSIX::SigSet->new();
  12         my $set = POSIX::SigSet->new();
  13         $set->fillset or die "fillset failed: $!";
  14         sigprocmask(SIG_SETMASK, $set, $old) or die "can't block signals: $!";
  15         my $pid = fork;
  16         if ($pid == 0) {
  17                 if ($in != 0) {
  18                         dup2($in, 0) or die "dup2 failed for stdin: $!";
  19                 }
  20                 if ($out != 1) {
  21                         dup2($out, 1) or die "dup2 failed for stdout: $!";
  22                 }
  23                 if ($err != 2) {
  24                         dup2($err, 2) or die "dup2 failed for stderr: $!";
  25                 }
  26
  27                 if ($ENV{MOD_PERL}) {
  28                         exec qw(env -i), @$env, @$cmd;
  29                         die "exec env -i ... $cmd->[0] failed: $!\n";
  30                 } else {
  31                         local %ENV = map { split(/=/, $_, 2) } @$env;
  32                         exec @$cmd;
  33                         die "exec $cmd->[0] failed: $!\n";
  34                 }
  35         }
  36         sigprocmask(SIG_SETMASK, $old) or die "can't unblock signals: $!";
  37         $pid;
  38 }
  39
  40 1;