lib/PublicInbox/Syscall.pm

   1 # This is a fork of the (for now) unmaintained Sys::Syscall 0.25,
   2 # specifically the Debian libsys-syscall-perl 0.25-6 version to
   3 # fix upstream regressions in 0.25.
   4 #
   5 # See devel/syscall-list in the public-inbox source tree for maintenance
   6 # <https://80x24.org/public-inbox.git>, and machines from the GCC Farm:
   7 # <https://cfarm.tetaneutral.net/>
   8 #
   9 # This license differs from the rest of public-inbox
  10 #
  11 # This module is Copyright (c) 2005 Six Apart, Ltd.
  12 # Copyright (C) all contributors <meta@public-inbox.org>
  13 #
  14 # All rights reserved.
  15 #
  16 # You may distribute under the terms of either the GNU General Public
  17 # License or the Artistic License, as specified in the Perl README file.
  18 package PublicInbox::Syscall;
  19 use v5.12;
  20 use parent qw(Exporter);
  21 use POSIX qw(ENOENT ENOSYS EINVAL O_NONBLOCK);
  22 use Socket qw(SOL_SOCKET SCM_RIGHTS);
  23 use Config;
  24
  25 # $VERSION = '0.25'; # Sys::Syscall version
  26 our @EXPORT_OK = qw(epoll_ctl epoll_create epoll_wait
  27                   EPOLLIN EPOLLOUT EPOLLET
  28                   EPOLL_CTL_ADD EPOLL_CTL_DEL EPOLL_CTL_MOD
  29                   EPOLLONESHOT EPOLLEXCLUSIVE
  30                   signalfd rename_noreplace);
  31 our %EXPORT_TAGS = (epoll => [qw(epoll_ctl epoll_create epoll_wait
  32                              EPOLLIN EPOLLOUT
  33                              EPOLL_CTL_ADD EPOLL_CTL_DEL EPOLL_CTL_MOD
  34                              EPOLLONESHOT EPOLLEXCLUSIVE)],
  35                 );
  36
  37 use constant {
  38         EPOLLIN => 1,
  39         EPOLLOUT => 4,
  40         # EPOLLERR => 8,
  41         # EPOLLHUP => 16,
  42         # EPOLLRDBAND => 128,
  43         EPOLLEXCLUSIVE => (1 << 28),
  44         EPOLLONESHOT => (1 << 30),
  45         EPOLLET => (1 << 31),
  46         EPOLL_CTL_ADD => 1,
  47         EPOLL_CTL_DEL => 2,
  48         EPOLL_CTL_MOD => 3,
  49         SIZEOF_int => $Config{intsize},
  50         SIZEOF_size_t => $Config{sizesize},
  51         NUL => "\0",
  52 };
  53
  54 use constant {
  55         TMPL_size_t => SIZEOF_size_t == 8 ? 'Q' : 'L',
  56         BYTES_4_hole => SIZEOF_size_t == 8 ? 'L' : '',
  57         # cmsg_len, cmsg_level, cmsg_type
  58         SIZEOF_cmsghdr => SIZEOF_int * 2 + SIZEOF_size_t,
  59 };
  60
  61 my @BYTES_4_hole = BYTES_4_hole ? (0) : ();
  62 our $loaded_syscall = 0;
  63
  64 sub _load_syscall {
  65     # props to Gaal for this!
  66     return if $loaded_syscall++;
  67     my $clean = sub {
  68         delete @INC{qw<syscall.ph asm/unistd.ph bits/syscall.ph
  69                         _h2ph_pre.ph sys/syscall.ph>};
  70     };
  71     $clean->(); # don't trust modules before us
  72     my $rv = eval { require 'syscall.ph'; 1 } || eval { require 'sys/syscall.ph'; 1 };
  73     $clean->(); # don't require modules after us trust us
  74     $rv;
  75 }
  76
  77
  78 our (
  79      $SYS_epoll_create,
  80      $SYS_epoll_ctl,
  81      $SYS_epoll_wait,
  82      $SYS_signalfd4,
  83      $SYS_renameat2,
  84      );
  85
  86 my ($SYS_sendmsg, $SYS_recvmsg);
  87 my $SYS_fstatfs; # don't need fstatfs64, just statfs.f_type
  88 my ($FS_IOC_GETFLAGS, $FS_IOC_SETFLAGS);
  89 my $SFD_CLOEXEC = 02000000; # Perl does not expose O_CLOEXEC
  90 our $no_deprecated = 0;
  91
  92 if ($^O eq "linux") {
  93     my (undef, undef, $release, undef, $machine) = POSIX::uname();
  94     my ($maj, $min) = ($release =~ /\A([0-9]+)\.([0-9]+)/);
  95     $SYS_renameat2 = 0 if "$maj.$min" < 3.15;
  96     # whether the machine requires 64-bit numbers to be on 8-byte
  97     # boundaries.
  98     my $u64_mod_8 = 0;
  99
 100     # if we're running on an x86_64 kernel, but a 32-bit process,
 101     # we need to use the x32 or i386 syscall numbers.
 102     if ($machine eq "x86_64" && $Config{ptrsize} == 4) {
 103         $machine = $Config{cppsymbols} =~ /\b__ILP32__=1\b/ ? 'x32' : 'i386';
 104     }
 105
 106     # Similarly for mips64 vs mips
 107     if ($machine eq "mips64" && $Config{ptrsize} == 4) {
 108         $machine = "mips";
 109     }
 110
 111     if ($machine =~ m/^i[3456]86$/) {
 112         $SYS_epoll_create = 254;
 113         $SYS_epoll_ctl    = 255;
 114         $SYS_epoll_wait   = 256;
 115         $SYS_signalfd4 = 327;
 116         $SYS_renameat2 //= 353;
 117         $SYS_fstatfs = 100;
 118         $SYS_sendmsg = 370;
 119         $SYS_recvmsg = 372;
 120         $FS_IOC_GETFLAGS = 0x80046601;
 121         $FS_IOC_SETFLAGS = 0x40046602;
 122     } elsif ($machine eq "x86_64") {
 123         $SYS_epoll_create = 213;
 124         $SYS_epoll_ctl    = 233;
 125         $SYS_epoll_wait   = 232;
 126         $SYS_signalfd4 = 289;
 127         $SYS_renameat2 //= 316;
 128         $SYS_fstatfs = 138;
 129         $SYS_sendmsg = 46;
 130         $SYS_recvmsg = 47;
 131         $FS_IOC_GETFLAGS = 0x80086601;
 132         $FS_IOC_SETFLAGS = 0x40086602;
 133     } elsif ($machine eq 'x32') {
 134         $SYS_epoll_create = 1073742037;
 135         $SYS_epoll_ctl = 1073742057;
 136         $SYS_epoll_wait = 1073742056;
 137         $SYS_signalfd4 = 1073742113;
 138         $SYS_renameat2 //= 0x40000000 + 316;
 139         $SYS_fstatfs = 138;
 140         $SYS_sendmsg = 0x40000206;
 141         $SYS_recvmsg = 0x40000207;
 142         $FS_IOC_GETFLAGS = 0x80046601;
 143         $FS_IOC_SETFLAGS = 0x40046602;
 144     } elsif ($machine eq 'sparc64') {
 145         $SYS_epoll_create = 193;
 146         $SYS_epoll_ctl = 194;
 147         $SYS_epoll_wait = 195;
 148         $u64_mod_8 = 1;
 149         $SYS_signalfd4 = 317;
 150         $SYS_renameat2 //= 345;
 151         $SFD_CLOEXEC = 020000000;
 152         $SYS_fstatfs = 158;
 153         $SYS_sendmsg = 114;
 154         $SYS_recvmsg = 113;
 155         $FS_IOC_GETFLAGS = 0x40086601;
 156         $FS_IOC_SETFLAGS = 0x80086602;
 157     } elsif ($machine =~ m/^parisc/) {
 158         $SYS_epoll_create = 224;
 159         $SYS_epoll_ctl    = 225;
 160         $SYS_epoll_wait   = 226;
 161         $u64_mod_8        = 1;
 162         $SYS_signalfd4 = 309;
 163     } elsif ($machine =~ m/^ppc64/) {
 164         $SYS_epoll_create = 236;
 165         $SYS_epoll_ctl    = 237;
 166         $SYS_epoll_wait   = 238;
 167         $u64_mod_8        = 1;
 168         $SYS_signalfd4 = 313;
 169         $SYS_renameat2 //= 357;
 170         $SYS_fstatfs = 100;
 171         $SYS_sendmsg = 341;
 172         $SYS_recvmsg = 342;
 173         $FS_IOC_GETFLAGS = 0x40086601;
 174         $FS_IOC_SETFLAGS = 0x80086602;
 175     } elsif ($machine eq "ppc") {
 176         $SYS_epoll_create = 236;
 177         $SYS_epoll_ctl    = 237;
 178         $SYS_epoll_wait   = 238;
 179         $u64_mod_8        = 1;
 180         $SYS_signalfd4 = 313;
 181         $SYS_renameat2 //= 357;
 182         $SYS_fstatfs = 100;
 183         $FS_IOC_GETFLAGS = 0x40086601;
 184         $FS_IOC_SETFLAGS = 0x80086602;
 185     } elsif ($machine =~ m/^s390/) { # untested, no machine on cfarm
 186         $SYS_epoll_create = 249;
 187         $SYS_epoll_ctl    = 250;
 188         $SYS_epoll_wait   = 251;
 189         $u64_mod_8        = 1;
 190         $SYS_signalfd4 = 322;
 191         $SYS_renameat2 //= 347;
 192         $SYS_fstatfs = 100;
 193         $SYS_sendmsg = 370;
 194         $SYS_recvmsg = 372;
 195     } elsif ($machine eq 'ia64') { # untested, no machine on cfarm
 196         $SYS_epoll_create = 1243;
 197         $SYS_epoll_ctl    = 1244;
 198         $SYS_epoll_wait   = 1245;
 199         $u64_mod_8        = 1;
 200         $SYS_signalfd4 = 289;
 201     } elsif ($machine eq "alpha") { # untested, no machine on cfarm
 202         # natural alignment, ints are 32-bits
 203         $SYS_epoll_create = 407;
 204         $SYS_epoll_ctl    = 408;
 205         $SYS_epoll_wait   = 409;
 206         $u64_mod_8        = 1;
 207         $SYS_signalfd4 = 484;
 208         $SFD_CLOEXEC = 010000000;
 209     } elsif ($machine eq 'aarch64' || $machine eq 'loongarch64') {
 210         $SYS_epoll_create = 20;  # (sys_epoll_create1)
 211         $SYS_epoll_ctl    = 21;
 212         $SYS_epoll_wait   = 22;  # (sys_epoll_pwait)
 213         $u64_mod_8        = 1;
 214         $no_deprecated    = 1;
 215         $SYS_signalfd4 = 74;
 216         $SYS_renameat2 //= 276;
 217         $SYS_fstatfs = 44;
 218         $SYS_sendmsg = 211;
 219         $SYS_recvmsg = 212;
 220         $FS_IOC_GETFLAGS = 0x80086601;
 221         $FS_IOC_SETFLAGS = 0x40086602;
 222     } elsif ($machine =~ m/arm(v\d+)?.*l/) { # ARM OABI (untested on cfarm)
 223         $SYS_epoll_create = 250;
 224         $SYS_epoll_ctl    = 251;
 225         $SYS_epoll_wait   = 252;
 226         $u64_mod_8        = 1;
 227         $SYS_signalfd4 = 355;
 228         $SYS_renameat2 //= 382;
 229         $SYS_fstatfs = 100;
 230         $SYS_sendmsg = 296;
 231         $SYS_recvmsg = 297;
 232     } elsif ($machine =~ m/^mips64/) { # cfarm only has 32-bit userspace
 233         $SYS_epoll_create = 5207;
 234         $SYS_epoll_ctl    = 5208;
 235         $SYS_epoll_wait   = 5209;
 236         $u64_mod_8        = 1;
 237         $SYS_signalfd4 = 5283;
 238         $SYS_renameat2 //= 5311;
 239         $SYS_fstatfs = 5135;
 240         $SYS_sendmsg = 5045;
 241         $SYS_recvmsg = 5046;
 242         $FS_IOC_GETFLAGS = 0x40046601;
 243         $FS_IOC_SETFLAGS = 0x80046602;
 244     } elsif ($machine =~ m/^mips/) { # 32-bit, tested on mips64 cfarm machine
 245         $SYS_epoll_create = 4248;
 246         $SYS_epoll_ctl    = 4249;
 247         $SYS_epoll_wait   = 4250;
 248         $u64_mod_8        = 1;
 249         $SYS_signalfd4 = 4324;
 250         $SYS_renameat2 //= 4351;
 251         $SYS_fstatfs = 4100;
 252         $SYS_sendmsg = 4179;
 253         $SYS_recvmsg = 4177;
 254         $FS_IOC_GETFLAGS = 0x40046601;
 255         $FS_IOC_SETFLAGS = 0x80046602;
 256     } else {
 257         # as a last resort, try using the *.ph files which may not
 258         # exist or may be wrong
 259         _load_syscall();
 260         $SYS_epoll_create = eval { &SYS_epoll_create; } || 0;
 261         $SYS_epoll_ctl    = eval { &SYS_epoll_ctl;    } || 0;
 262         $SYS_epoll_wait   = eval { &SYS_epoll_wait;   } || 0;
 263
 264         # Note: do NOT add new syscalls to depend on *.ph, here.
 265         # Better to miss syscalls (so we can fallback to IO::Poll)
 266         # than to use wrong ones, since the names are not stable
 267         # (at least not on FreeBSD), if the actual numbers are.
 268     }
 269
 270     if ($u64_mod_8) {
 271         *epoll_wait = \&epoll_wait_mod8;
 272         *epoll_ctl = \&epoll_ctl_mod8;
 273     } else {
 274         *epoll_wait = \&epoll_wait_mod4;
 275         *epoll_ctl = \&epoll_ctl_mod4;
 276     }
 277 }
 278 # use Inline::C for *BSD-only or general POSIX stuff.
 279 # Linux guarantees stable syscall numbering, BSDs only offer a stable libc
 280 # use scripts/syscall-list on Linux to detect new syscall numbers
 281
 282 ############################################################################
 283 # epoll functions
 284 ############################################################################
 285
 286 sub epoll_defined { $SYS_epoll_create ? 1 : 0; }
 287
 288 sub epoll_create {
 289         syscall($SYS_epoll_create, $no_deprecated ? 0 : 100);
 290 }
 291
 292 # epoll_ctl wrapper
 293 # ARGS: (epfd, op, fd, events_mask)
 294 sub epoll_ctl_mod4 {
 295     syscall($SYS_epoll_ctl, $_[0]+0, $_[1]+0, $_[2]+0, pack("LLL", $_[3], $_[2], 0));
 296 }
 297 sub epoll_ctl_mod8 {
 298     syscall($SYS_epoll_ctl, $_[0]+0, $_[1]+0, $_[2]+0, pack("LLLL", $_[3], 0, $_[2], 0));
 299 }
 300
 301 # epoll_wait wrapper
 302 # ARGS: (epfd, maxevents, timeout (milliseconds), arrayref)
 303 #  arrayref: values modified to be [$fd, $event]
 304 our $epoll_wait_events = '';
 305 our $epoll_wait_size = 0;
 306 sub epoll_wait_mod4 {
 307         my ($epfd, $maxevents, $timeout_msec, $events) = @_;
 308         # resize our static buffer if maxevents bigger than we've ever done
 309         if ($maxevents > $epoll_wait_size) {
 310                 $epoll_wait_size = $maxevents;
 311                 vec($epoll_wait_events, $maxevents * 12 * 8 - 1, 1) = 0;
 312         }
 313         @$events = ();
 314         my $ct = syscall($SYS_epoll_wait, $epfd, $epoll_wait_events,
 315                         $maxevents, $timeout_msec);
 316         for (0..$ct - 1) {
 317                 # 12-byte struct epoll_event
 318                 # 4 bytes uint32_t events mask (skipped, useless to us)
 319                 # 8 bytes: epoll_data_t union (first 4 bytes are the fd)
 320                 # So we skip the first 4 bytes and take the middle 4:
 321                 $events->[$_] = unpack('L', substr($epoll_wait_events,
 322                                                         12 * $_ + 4, 4));
 323         }
 324 }
 325
 326 sub epoll_wait_mod8 {
 327         my ($epfd, $maxevents, $timeout_msec, $events) = @_;
 328
 329         # resize our static buffer if maxevents bigger than we've ever done
 330         if ($maxevents > $epoll_wait_size) {
 331                 $epoll_wait_size = $maxevents;
 332                 vec($epoll_wait_events, $maxevents * 16 * 8 - 1, 1) = 0;
 333         }
 334         @$events = ();
 335         my $ct = syscall($SYS_epoll_wait, $epfd, $epoll_wait_events,
 336                         $maxevents, $timeout_msec,
 337                         $no_deprecated ? undef : ());
 338         for (0..$ct - 1) {
 339                 # 16-byte struct epoll_event
 340                 # 4 bytes uint32_t events mask (skipped, useless to us)
 341                 # 4 bytes padding (skipped, useless)
 342                 # 8 bytes epoll_data_t union (first 4 bytes are the fd)
 343                 # So skip the first 8 bytes, take 4, and ignore the last 4:
 344                 $events->[$_] = unpack('L', substr($epoll_wait_events,
 345                                                         16 * $_ + 8, 4));
 346         }
 347 }
 348
 349 sub signalfd ($$) {
 350         my ($signos, $nonblock) = @_;
 351         if ($SYS_signalfd4) {
 352                 my $set = POSIX::SigSet->new(@$signos);
 353                 syscall($SYS_signalfd4, -1, "$$set",
 354                         # $Config{sig_count} is NSIG, so this is NSIG/8:
 355                         int($Config{sig_count}/8),
 356                         # SFD_NONBLOCK == O_NONBLOCK for every architecture
 357                         ($nonblock ? O_NONBLOCK : 0) |$SFD_CLOEXEC);
 358         } else {
 359                 $! = ENOSYS;
 360                 undef;
 361         }
 362 }
 363
 364 sub _rename_noreplace_racy ($$) {
 365         my ($old, $new) = @_;
 366         if (link($old, $new)) {
 367                 warn "unlink $old: $!\n" if !unlink($old) && $! != ENOENT;
 368                 1
 369         } else {
 370                 undef;
 371         }
 372 }
 373
 374 # TODO: support FD args?
 375 sub rename_noreplace ($$) {
 376         my ($old, $new) = @_;
 377         if ($SYS_renameat2) { # RENAME_NOREPLACE = 1, AT_FDCWD = -100
 378                 my $ret = syscall($SYS_renameat2, -100, $old, -100, $new, 1);
 379                 if ($ret == 0) {
 380                         1; # like rename() perlop
 381                 } elsif ($! == ENOSYS || $! == EINVAL) {
 382                         undef $SYS_renameat2;
 383                         _rename_noreplace_racy($old, $new);
 384                 } else {
 385                         undef
 386                 }
 387         } else {
 388                 _rename_noreplace_racy($old, $new);
 389         }
 390 }
 391
 392 sub nodatacow_fh ($) {
 393         my ($fh) = @_;
 394         my $buf = "\0" x 120;
 395         syscall($SYS_fstatfs // return, fileno($fh), $buf) == 0 or
 396                 return warn("fstatfs: $!\n");
 397         my $f_type = unpack('l!', $buf); # statfs.f_type is a signed word
 398         return if $f_type != 0x9123683E; # BTRFS_SUPER_MAGIC
 399
 400         $FS_IOC_GETFLAGS //
 401                 return warn('FS_IOC_GETFLAGS undefined for platform');
 402         ioctl($fh, $FS_IOC_GETFLAGS, $buf) //
 403                 return warn("FS_IOC_GETFLAGS: $!\n");
 404         my $attr = unpack('l!', $buf);
 405         return if ($attr & 0x00800000); # FS_NOCOW_FL;
 406         ioctl($fh, $FS_IOC_SETFLAGS, pack('l', $attr | 0x00800000)) //
 407                 warn("FS_IOC_SETFLAGS: $!\n");
 408 }
 409
 410 sub nodatacow_dir {
 411         if (open my $fh, '<', $_[0]) { nodatacow_fh($fh) }
 412 }
 413
 414 sub CMSG_ALIGN ($) { ($_[0] + SIZEOF_size_t - 1) & ~(SIZEOF_size_t - 1) }
 415 use constant CMSG_ALIGN_SIZEOF_cmsghdr => CMSG_ALIGN(SIZEOF_cmsghdr);
 416 sub CMSG_SPACE ($) { CMSG_ALIGN($_[0]) + CMSG_ALIGN_SIZEOF_cmsghdr }
 417 sub CMSG_LEN ($) { CMSG_ALIGN_SIZEOF_cmsghdr + $_[0] }
 418 use constant msg_controllen => CMSG_SPACE(10 * SIZEOF_int) + 16; # 10 FDs
 419
 420 if (defined($SYS_sendmsg) && defined($SYS_recvmsg)) {
 421 no warnings 'once';
 422 *send_cmd4 = sub ($$$$) {
 423         my ($sock, $fds, undef, $flags) = @_;
 424         my $iov = pack('P'.TMPL_size_t,
 425                         $_[2] // NUL, length($_[2] // NUL) || 1);
 426         my $cmsghdr = pack(TMPL_size_t . # cmsg_len
 427                         'LL' .  # cmsg_level, cmsg_type,
 428                         ('i' x scalar(@$fds)),
 429                         CMSG_LEN(scalar(@$fds) * SIZEOF_int), # cmsg_len
 430                         SOL_SOCKET, SCM_RIGHTS, # cmsg_{level,type}
 431                         @$fds); # CMSG_DATA
 432         my $mh = pack('PL' . # msg_name, msg_namelen (socklen_t (U32))
 433                         BYTES_4_hole . # 4-byte padding on 64-bit
 434                         'P'.TMPL_size_t . # msg_iov, msg_iovlen,
 435                         'P'.TMPL_size_t . # msg_control, msg_controllen,
 436                         'i', # msg_flags
 437                         NUL, 0, # msg_name, msg_namelen (unused)
 438                         @BYTES_4_hole,
 439                         $iov, 1, # msg_iov, msg_iovlen
 440                         $cmsghdr, # msg_control
 441                         CMSG_SPACE(scalar(@$fds) * SIZEOF_int), # msg_controllen
 442                         0); # msg_flags
 443         my $sent;
 444         my $try = 0;
 445         do {
 446                 $sent = syscall($SYS_sendmsg, fileno($sock), $mh, $flags);
 447         } while ($sent < 0 &&
 448                         ($!{ENOBUFS} || $!{ENOMEM} || $!{ETOOMANYREFS}) &&
 449                         (++$try < 50) &&
 450                         warn "sleeping on sendmsg: $! (#$try)\n" &&
 451                         select(undef, undef, undef, 0.1) == 0);
 452         $sent >= 0 ? $sent : undef;
 453 };
 454
 455 *recv_cmd4 = sub ($$$) {
 456         my ($sock, undef, $len) = @_;
 457         vec($_[1], ($len + 1) * 8, 1) = 0;
 458         my $cmsghdr = "\0" x msg_controllen; # 10 * sizeof(int)
 459         my $iov = pack('P'.TMPL_size_t, $_[1], $len);
 460         my $mh = pack('PL' . # msg_name, msg_namelen (socklen_t (U32))
 461                         BYTES_4_hole . # 4-byte padding on 64-bit
 462                         'P'.TMPL_size_t . # msg_iov, msg_iovlen,
 463                         'P'.TMPL_size_t . # msg_control, msg_controllen,
 464                         'i', # msg_flags
 465                         NUL, 0, # msg_name, msg_namelen (unused)
 466                         @BYTES_4_hole,
 467                         $iov, 1, # msg_iov, msg_iovlen
 468                         $cmsghdr, # msg_control
 469                         msg_controllen,
 470                         0); # msg_flags
 471         my $r = syscall($SYS_recvmsg, fileno($sock), $mh, 0);
 472         return (undef) if $r < 0; # $! set
 473         substr($_[1], $r, length($_[1]), '');
 474         my @ret;
 475         if ($r > 0) {
 476                 my ($len, $lvl, $type, @fds) = unpack(TMPL_size_t . # cmsg_len
 477                                         'LLi*', # cmsg_level, cmsg_type, @fds
 478                                         $cmsghdr);
 479                 if ($lvl == SOL_SOCKET && $type == SCM_RIGHTS) {
 480                         $len -= CMSG_ALIGN_SIZEOF_cmsghdr;
 481                         @ret = @fds[0..(($len / SIZEOF_int) - 1)];
 482                 }
 483         }
 484         @ret;
 485 };
 486 }
 487
 488 1;
 489
 490 =head1 WARRANTY
 491
 492 This is free software. IT COMES WITHOUT WARRANTY OF ANY KIND.
 493
 494 =head1 AUTHORS
 495
 496 Brad Fitzpatrick <brad@danga.com>