lib/PublicInbox/Syscall.pm

   1 # This is a fork of the (for now) unmaintained Sys::Syscall 0.25,
   2 # specifically the Debian libsys-syscall-perl 0.25-6 version to
   3 # fix upstream regressions in 0.25.
   4 #
   5 # See devel/syscall-list in the public-inbox source tree for maintenance
   6 # <https://80x24.org/public-inbox.git>, and machines from the GCC Farm:
   7 # <https://cfarm.tetaneutral.net/>
   8 #
   9 # This license differs from the rest of public-inbox
  10 #
  11 # This module is Copyright (c) 2005 Six Apart, Ltd.
  12 # Copyright (C) all contributors <meta@public-inbox.org>
  13 #
  14 # All rights reserved.
  15 #
  16 # You may distribute under the terms of either the GNU General Public
  17 # License or the Artistic License, as specified in the Perl README file.
  18 package PublicInbox::Syscall;
  19 use v5.12;
  20 use parent qw(Exporter);
  21 use POSIX qw(ENOENT ENOSYS EINVAL O_NONBLOCK);
  22 use Socket qw(SOL_SOCKET SCM_RIGHTS);
  23 use Config;
  24 our %SIGNUM = (WINCH => 28); # most Linux, {Free,Net,Open}BSD, *Darwin
  25
  26 # $VERSION = '0.25'; # Sys::Syscall version
  27 our @EXPORT_OK = qw(epoll_ctl epoll_create epoll_wait
  28                   EPOLLIN EPOLLOUT EPOLLET
  29                   EPOLL_CTL_ADD EPOLL_CTL_DEL EPOLL_CTL_MOD
  30                   EPOLLONESHOT EPOLLEXCLUSIVE
  31                   signalfd rename_noreplace %SIGNUM);
  32 our %EXPORT_TAGS = (epoll => [qw(epoll_ctl epoll_create epoll_wait
  33                              EPOLLIN EPOLLOUT
  34                              EPOLL_CTL_ADD EPOLL_CTL_DEL EPOLL_CTL_MOD
  35                              EPOLLONESHOT EPOLLEXCLUSIVE)],
  36                 );
  37
  38 use constant {
  39         EPOLLIN => 1,
  40         EPOLLOUT => 4,
  41         # EPOLLERR => 8,
  42         # EPOLLHUP => 16,
  43         # EPOLLRDBAND => 128,
  44         EPOLLEXCLUSIVE => (1 << 28),
  45         EPOLLONESHOT => (1 << 30),
  46         EPOLLET => (1 << 31),
  47         EPOLL_CTL_ADD => 1,
  48         EPOLL_CTL_DEL => 2,
  49         EPOLL_CTL_MOD => 3,
  50         SIZEOF_int => $Config{intsize},
  51         SIZEOF_size_t => $Config{sizesize},
  52         NUL => "\0",
  53 };
  54
  55 use constant {
  56         TMPL_size_t => SIZEOF_size_t == 8 ? 'Q' : 'L',
  57         BYTES_4_hole => SIZEOF_size_t == 8 ? 'L' : '',
  58         # cmsg_len, cmsg_level, cmsg_type
  59         SIZEOF_cmsghdr => SIZEOF_int * 2 + SIZEOF_size_t,
  60 };
  61
  62 my @BYTES_4_hole = BYTES_4_hole ? (0) : ();
  63
  64 our (
  65      $SYS_epoll_create,
  66      $SYS_epoll_ctl,
  67      $SYS_epoll_wait,
  68      $SYS_signalfd4,
  69      $SYS_renameat2,
  70      );
  71
  72 my ($SYS_sendmsg, $SYS_recvmsg);
  73 my $SYS_fstatfs; # don't need fstatfs64, just statfs.f_type
  74 my ($FS_IOC_GETFLAGS, $FS_IOC_SETFLAGS);
  75 my $SFD_CLOEXEC = 02000000; # Perl does not expose O_CLOEXEC
  76 our $no_deprecated = 0;
  77
  78 if ($^O eq "linux") {
  79     my (undef, undef, $release, undef, $machine) = POSIX::uname();
  80     my ($maj, $min) = ($release =~ /\A([0-9]+)\.([0-9]+)/);
  81     $SYS_renameat2 = 0 if "$maj.$min" < 3.15;
  82     # whether the machine requires 64-bit numbers to be on 8-byte
  83     # boundaries.
  84     my $u64_mod_8 = 0;
  85
  86     if ($Config{ptrsize} == 4) {
  87         # if we're running on an x86_64 kernel, but a 32-bit process,
  88         # we need to use the x32 or i386 syscall numbers.
  89         if ($machine eq 'x86_64') {
  90             $machine = $Config{cppsymbols} =~ /\b__ILP32__=1\b/ ? 'x32' : 'i386'
  91         } elsif ($machine eq 'mips64') { # similarly for mips64 vs mips
  92             $machine = 'mips';
  93         }
  94     }
  95
  96     if ($machine =~ m/^i[3456]86$/) {
  97         $SYS_epoll_create = 254;
  98         $SYS_epoll_ctl    = 255;
  99         $SYS_epoll_wait   = 256;
 100         $SYS_signalfd4 = 327;
 101         $SYS_renameat2 //= 353;
 102         $SYS_fstatfs = 100;
 103         $SYS_sendmsg = 370;
 104         $SYS_recvmsg = 372;
 105         $FS_IOC_GETFLAGS = 0x80046601;
 106         $FS_IOC_SETFLAGS = 0x40046602;
 107     } elsif ($machine eq "x86_64") {
 108         $SYS_epoll_create = 213;
 109         $SYS_epoll_ctl    = 233;
 110         $SYS_epoll_wait   = 232;
 111         $SYS_signalfd4 = 289;
 112         $SYS_renameat2 //= 316;
 113         $SYS_fstatfs = 138;
 114         $SYS_sendmsg = 46;
 115         $SYS_recvmsg = 47;
 116         $FS_IOC_GETFLAGS = 0x80086601;
 117         $FS_IOC_SETFLAGS = 0x40086602;
 118     } elsif ($machine eq 'x32') {
 119         $SYS_epoll_create = 1073742037;
 120         $SYS_epoll_ctl = 1073742057;
 121         $SYS_epoll_wait = 1073742056;
 122         $SYS_signalfd4 = 1073742113;
 123         $SYS_renameat2 //= 0x40000000 + 316;
 124         $SYS_fstatfs = 138;
 125         $SYS_sendmsg = 0x40000206;
 126         $SYS_recvmsg = 0x40000207;
 127         $FS_IOC_GETFLAGS = 0x80046601;
 128         $FS_IOC_SETFLAGS = 0x40046602;
 129     } elsif ($machine eq 'sparc64') {
 130         $SYS_epoll_create = 193;
 131         $SYS_epoll_ctl = 194;
 132         $SYS_epoll_wait = 195;
 133         $u64_mod_8 = 1;
 134         $SYS_signalfd4 = 317;
 135         $SYS_renameat2 //= 345;
 136         $SFD_CLOEXEC = 020000000;
 137         $SYS_fstatfs = 158;
 138         $SYS_sendmsg = 114;
 139         $SYS_recvmsg = 113;
 140         $FS_IOC_GETFLAGS = 0x40086601;
 141         $FS_IOC_SETFLAGS = 0x80086602;
 142     } elsif ($machine =~ m/^parisc/) {
 143         $SYS_epoll_create = 224;
 144         $SYS_epoll_ctl    = 225;
 145         $SYS_epoll_wait   = 226;
 146         $u64_mod_8        = 1;
 147         $SYS_signalfd4 = 309;
 148         $SIGNUM{WINCH} = 23;
 149     } elsif ($machine =~ m/^ppc64/) {
 150         $SYS_epoll_create = 236;
 151         $SYS_epoll_ctl    = 237;
 152         $SYS_epoll_wait   = 238;
 153         $u64_mod_8        = 1;
 154         $SYS_signalfd4 = 313;
 155         $SYS_renameat2 //= 357;
 156         $SYS_fstatfs = 100;
 157         $SYS_sendmsg = 341;
 158         $SYS_recvmsg = 342;
 159         $FS_IOC_GETFLAGS = 0x40086601;
 160         $FS_IOC_SETFLAGS = 0x80086602;
 161     } elsif ($machine eq "ppc") {
 162         $SYS_epoll_create = 236;
 163         $SYS_epoll_ctl    = 237;
 164         $SYS_epoll_wait   = 238;
 165         $u64_mod_8        = 1;
 166         $SYS_signalfd4 = 313;
 167         $SYS_renameat2 //= 357;
 168         $SYS_fstatfs = 100;
 169         $FS_IOC_GETFLAGS = 0x40086601;
 170         $FS_IOC_SETFLAGS = 0x80086602;
 171     } elsif ($machine =~ m/^s390/) { # untested, no machine on cfarm
 172         $SYS_epoll_create = 249;
 173         $SYS_epoll_ctl    = 250;
 174         $SYS_epoll_wait   = 251;
 175         $u64_mod_8        = 1;
 176         $SYS_signalfd4 = 322;
 177         $SYS_renameat2 //= 347;
 178         $SYS_fstatfs = 100;
 179         $SYS_sendmsg = 370;
 180         $SYS_recvmsg = 372;
 181     } elsif ($machine eq 'ia64') { # untested, no machine on cfarm
 182         $SYS_epoll_create = 1243;
 183         $SYS_epoll_ctl    = 1244;
 184         $SYS_epoll_wait   = 1245;
 185         $u64_mod_8        = 1;
 186         $SYS_signalfd4 = 289;
 187     } elsif ($machine eq "alpha") { # untested, no machine on cfarm
 188         # natural alignment, ints are 32-bits
 189         $SYS_epoll_create = 407;
 190         $SYS_epoll_ctl    = 408;
 191         $SYS_epoll_wait   = 409;
 192         $u64_mod_8        = 1;
 193         $SYS_signalfd4 = 484;
 194         $SFD_CLOEXEC = 010000000;
 195     } elsif ($machine =~ /\A(?:loong)?aarch64\z/ || $machine eq 'riscv64') {
 196         $SYS_epoll_create = 20;  # (sys_epoll_create1)
 197         $SYS_epoll_ctl    = 21;
 198         $SYS_epoll_wait   = 22;  # (sys_epoll_pwait)
 199         $u64_mod_8        = 1;
 200         $no_deprecated    = 1;
 201         $SYS_signalfd4 = 74;
 202         $SYS_renameat2 //= 276;
 203         $SYS_fstatfs = 44;
 204         $SYS_sendmsg = 211;
 205         $SYS_recvmsg = 212;
 206         $FS_IOC_GETFLAGS = 0x80086601;
 207         $FS_IOC_SETFLAGS = 0x40086602;
 208     } elsif ($machine =~ m/arm(v\d+)?.*l/) { # ARM OABI (untested on cfarm)
 209         $SYS_epoll_create = 250;
 210         $SYS_epoll_ctl    = 251;
 211         $SYS_epoll_wait   = 252;
 212         $u64_mod_8        = 1;
 213         $SYS_signalfd4 = 355;
 214         $SYS_renameat2 //= 382;
 215         $SYS_fstatfs = 100;
 216         $SYS_sendmsg = 296;
 217         $SYS_recvmsg = 297;
 218     } elsif ($machine =~ m/^mips64/) { # cfarm only has 32-bit userspace
 219         $SYS_epoll_create = 5207;
 220         $SYS_epoll_ctl    = 5208;
 221         $SYS_epoll_wait   = 5209;
 222         $u64_mod_8        = 1;
 223         $SYS_signalfd4 = 5283;
 224         $SYS_renameat2 //= 5311;
 225         $SYS_fstatfs = 5135;
 226         $SYS_sendmsg = 5045;
 227         $SYS_recvmsg = 5046;
 228         $FS_IOC_GETFLAGS = 0x40046601;
 229         $FS_IOC_SETFLAGS = 0x80046602;
 230     } elsif ($machine =~ m/^mips/) { # 32-bit, tested on mips64 cfarm machine
 231         $SYS_epoll_create = 4248;
 232         $SYS_epoll_ctl    = 4249;
 233         $SYS_epoll_wait   = 4250;
 234         $u64_mod_8        = 1;
 235         $SYS_signalfd4 = 4324;
 236         $SYS_renameat2 //= 4351;
 237         $SYS_fstatfs = 4100;
 238         $SYS_sendmsg = 4179;
 239         $SYS_recvmsg = 4177;
 240         $FS_IOC_GETFLAGS = 0x40046601;
 241         $FS_IOC_SETFLAGS = 0x80046602;
 242         $SIGNUM{WINCH} = 20;
 243     } else {
 244         warn <<EOM;
 245 machine=$machine ptrsize=$Config{ptrsize} has no syscall definitions
 246 git clone https://80x24.org/public-inbox.git and
 247 Send the output of ./devel/syscall-list to meta\@public-inbox.org
 248 EOM
 249     }
 250     if ($u64_mod_8) {
 251         *epoll_wait = \&epoll_wait_mod8;
 252         *epoll_ctl = \&epoll_ctl_mod8;
 253     } else {
 254         *epoll_wait = \&epoll_wait_mod4;
 255         *epoll_ctl = \&epoll_ctl_mod4;
 256     }
 257 }
 258 # use Inline::C for *BSD-only or general POSIX stuff.
 259 # Linux guarantees stable syscall numbering, BSDs only offer a stable libc
 260 # use devel/syscall-list on Linux to detect new syscall numbers
 261
 262 ############################################################################
 263 # epoll functions
 264 ############################################################################
 265
 266 sub epoll_create {
 267         syscall($SYS_epoll_create, $no_deprecated ? 0 : 100);
 268 }
 269
 270 # epoll_ctl wrapper
 271 # ARGS: (epfd, op, fd, events_mask)
 272 sub epoll_ctl_mod4 {
 273     syscall($SYS_epoll_ctl, $_[0]+0, $_[1]+0, $_[2]+0, pack("LLL", $_[3], $_[2], 0));
 274 }
 275 sub epoll_ctl_mod8 {
 276     syscall($SYS_epoll_ctl, $_[0]+0, $_[1]+0, $_[2]+0, pack("LLLL", $_[3], 0, $_[2], 0));
 277 }
 278
 279 # epoll_wait wrapper
 280 # ARGS: (epfd, maxevents, timeout (milliseconds), arrayref)
 281 #  arrayref: values modified to be [$fd, $event]
 282 our $epoll_wait_events = '';
 283 our $epoll_wait_size = 0;
 284 sub epoll_wait_mod4 {
 285         my ($epfd, $maxevents, $timeout_msec, $events) = @_;
 286         # resize our static buffer if maxevents bigger than we've ever done
 287         if ($maxevents > $epoll_wait_size) {
 288                 $epoll_wait_size = $maxevents;
 289                 vec($epoll_wait_events, $maxevents * 12 * 8 - 1, 1) = 0;
 290         }
 291         @$events = ();
 292         my $ct = syscall($SYS_epoll_wait, $epfd, $epoll_wait_events,
 293                         $maxevents, $timeout_msec);
 294         for (0..$ct - 1) {
 295                 # 12-byte struct epoll_event
 296                 # 4 bytes uint32_t events mask (skipped, useless to us)
 297                 # 8 bytes: epoll_data_t union (first 4 bytes are the fd)
 298                 # So we skip the first 4 bytes and take the middle 4:
 299                 $events->[$_] = unpack('L', substr($epoll_wait_events,
 300                                                         12 * $_ + 4, 4));
 301         }
 302 }
 303
 304 sub epoll_wait_mod8 {
 305         my ($epfd, $maxevents, $timeout_msec, $events) = @_;
 306
 307         # resize our static buffer if maxevents bigger than we've ever done
 308         if ($maxevents > $epoll_wait_size) {
 309                 $epoll_wait_size = $maxevents;
 310                 vec($epoll_wait_events, $maxevents * 16 * 8 - 1, 1) = 0;
 311         }
 312         @$events = ();
 313         my $ct = syscall($SYS_epoll_wait, $epfd, $epoll_wait_events,
 314                         $maxevents, $timeout_msec,
 315                         $no_deprecated ? undef : ());
 316         for (0..$ct - 1) {
 317                 # 16-byte struct epoll_event
 318                 # 4 bytes uint32_t events mask (skipped, useless to us)
 319                 # 4 bytes padding (skipped, useless)
 320                 # 8 bytes epoll_data_t union (first 4 bytes are the fd)
 321                 # So skip the first 8 bytes, take 4, and ignore the last 4:
 322                 $events->[$_] = unpack('L', substr($epoll_wait_events,
 323                                                         16 * $_ + 8, 4));
 324         }
 325 }
 326
 327 sub signalfd ($$) {
 328         my ($signos, $nonblock) = @_;
 329         if ($SYS_signalfd4) {
 330                 my $set = POSIX::SigSet->new(@$signos);
 331                 syscall($SYS_signalfd4, -1, "$$set",
 332                         # $Config{sig_count} is NSIG, so this is NSIG/8:
 333                         int($Config{sig_count}/8),
 334                         # SFD_NONBLOCK == O_NONBLOCK for every architecture
 335                         ($nonblock ? O_NONBLOCK : 0) |$SFD_CLOEXEC);
 336         } else {
 337                 $! = ENOSYS;
 338                 undef;
 339         }
 340 }
 341
 342 sub _rename_noreplace_racy ($$) {
 343         my ($old, $new) = @_;
 344         if (link($old, $new)) {
 345                 warn "unlink $old: $!\n" if !unlink($old) && $! != ENOENT;
 346                 1
 347         } else {
 348                 undef;
 349         }
 350 }
 351
 352 # TODO: support FD args?
 353 sub rename_noreplace ($$) {
 354         my ($old, $new) = @_;
 355         if ($SYS_renameat2) { # RENAME_NOREPLACE = 1, AT_FDCWD = -100
 356                 my $ret = syscall($SYS_renameat2, -100, $old, -100, $new, 1);
 357                 if ($ret == 0) {
 358                         1; # like rename() perlop
 359                 } elsif ($! == ENOSYS || $! == EINVAL) {
 360                         undef $SYS_renameat2;
 361                         _rename_noreplace_racy($old, $new);
 362                 } else {
 363                         undef
 364                 }
 365         } else {
 366                 _rename_noreplace_racy($old, $new);
 367         }
 368 }
 369
 370 sub nodatacow_fh ($) {
 371         my ($fh) = @_;
 372         my $buf = "\0" x 120;
 373         syscall($SYS_fstatfs // return, fileno($fh), $buf) == 0 or
 374                 return warn("fstatfs: $!\n");
 375         my $f_type = unpack('l!', $buf); # statfs.f_type is a signed word
 376         return if $f_type != 0x9123683E; # BTRFS_SUPER_MAGIC
 377
 378         $FS_IOC_GETFLAGS //
 379                 return warn('FS_IOC_GETFLAGS undefined for platform');
 380         ioctl($fh, $FS_IOC_GETFLAGS, $buf) //
 381                 return warn("FS_IOC_GETFLAGS: $!\n");
 382         my $attr = unpack('l!', $buf);
 383         return if ($attr & 0x00800000); # FS_NOCOW_FL;
 384         ioctl($fh, $FS_IOC_SETFLAGS, pack('l', $attr | 0x00800000)) //
 385                 warn("FS_IOC_SETFLAGS: $!\n");
 386 }
 387
 388 sub nodatacow_dir {
 389         if (open my $fh, '<', $_[0]) { nodatacow_fh($fh) }
 390 }
 391
 392 sub CMSG_ALIGN ($) { ($_[0] + SIZEOF_size_t - 1) & ~(SIZEOF_size_t - 1) }
 393 use constant CMSG_ALIGN_SIZEOF_cmsghdr => CMSG_ALIGN(SIZEOF_cmsghdr);
 394 sub CMSG_SPACE ($) { CMSG_ALIGN($_[0]) + CMSG_ALIGN_SIZEOF_cmsghdr }
 395 sub CMSG_LEN ($) { CMSG_ALIGN_SIZEOF_cmsghdr + $_[0] }
 396 use constant msg_controllen => CMSG_SPACE(10 * SIZEOF_int) + 16; # 10 FDs
 397
 398 if (defined($SYS_sendmsg) && defined($SYS_recvmsg)) {
 399 no warnings 'once';
 400 *send_cmd4 = sub ($$$$) {
 401         my ($sock, $fds, undef, $flags) = @_;
 402         my $iov = pack('P'.TMPL_size_t,
 403                         $_[2] // NUL, length($_[2] // NUL) || 1);
 404         my $cmsghdr = pack(TMPL_size_t . # cmsg_len
 405                         'LL' .  # cmsg_level, cmsg_type,
 406                         ('i' x scalar(@$fds)),
 407                         CMSG_LEN(scalar(@$fds) * SIZEOF_int), # cmsg_len
 408                         SOL_SOCKET, SCM_RIGHTS, # cmsg_{level,type}
 409                         @$fds); # CMSG_DATA
 410         my $mh = pack('PL' . # msg_name, msg_namelen (socklen_t (U32))
 411                         BYTES_4_hole . # 4-byte padding on 64-bit
 412                         'P'.TMPL_size_t . # msg_iov, msg_iovlen,
 413                         'P'.TMPL_size_t . # msg_control, msg_controllen,
 414                         'i', # msg_flags
 415                         NUL, 0, # msg_name, msg_namelen (unused)
 416                         @BYTES_4_hole,
 417                         $iov, 1, # msg_iov, msg_iovlen
 418                         $cmsghdr, # msg_control
 419                         CMSG_SPACE(scalar(@$fds) * SIZEOF_int), # msg_controllen
 420                         0); # msg_flags
 421         my $sent;
 422         my $try = 0;
 423         do {
 424                 $sent = syscall($SYS_sendmsg, fileno($sock), $mh, $flags);
 425         } while ($sent < 0 &&
 426                         ($!{ENOBUFS} || $!{ENOMEM} || $!{ETOOMANYREFS}) &&
 427                         (++$try < 50) &&
 428                         warn "sleeping on sendmsg: $! (#$try)\n" &&
 429                         select(undef, undef, undef, 0.1) == 0);
 430         $sent >= 0 ? $sent : undef;
 431 };
 432
 433 *recv_cmd4 = sub ($$$) {
 434         my ($sock, undef, $len) = @_;
 435         vec($_[1] //= '', ($len + 1) * 8, 1) = 0;
 436         my $cmsghdr = "\0" x msg_controllen; # 10 * sizeof(int)
 437         my $iov = pack('P'.TMPL_size_t, $_[1], $len);
 438         my $mh = pack('PL' . # msg_name, msg_namelen (socklen_t (U32))
 439                         BYTES_4_hole . # 4-byte padding on 64-bit
 440                         'P'.TMPL_size_t . # msg_iov, msg_iovlen,
 441                         'P'.TMPL_size_t . # msg_control, msg_controllen,
 442                         'i', # msg_flags
 443                         NUL, 0, # msg_name, msg_namelen (unused)
 444                         @BYTES_4_hole,
 445                         $iov, 1, # msg_iov, msg_iovlen
 446                         $cmsghdr, # msg_control
 447                         msg_controllen,
 448                         0); # msg_flags
 449         my $r = syscall($SYS_recvmsg, fileno($sock), $mh, 0);
 450         return (undef) if $r < 0; # $! set
 451         substr($_[1], $r, length($_[1]), '');
 452         my @ret;
 453         if ($r > 0) {
 454                 my ($len, $lvl, $type, @fds) = unpack(TMPL_size_t . # cmsg_len
 455                                         'LLi*', # cmsg_level, cmsg_type, @fds
 456                                         $cmsghdr);
 457                 if ($lvl == SOL_SOCKET && $type == SCM_RIGHTS) {
 458                         $len -= CMSG_ALIGN_SIZEOF_cmsghdr;
 459                         @ret = @fds[0..(($len / SIZEOF_int) - 1)];
 460                 }
 461         }
 462         @ret;
 463 };
 464 }
 465
 466 1;
 467
 468 =head1 WARRANTY
 469
 470 This is free software. IT COMES WITHOUT WARRANTY OF ANY KIND.
 471
 472 =head1 AUTHORS
 473
 474 Brad Fitzpatrick <brad@danga.com>