lib/PublicInbox/TestCommon.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # internal APIs used only for tests
   5 package PublicInbox::TestCommon;
   6 use strict;
   7 use parent qw(Exporter);
   8 use v5.10.1;
   9 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD :seek);
  10 use POSIX qw(dup2);
  11 use IO::Socket::INET;
  12 use File::Spec;
  13 our @EXPORT;
  14 my $lei_loud = $ENV{TEST_LEI_ERR_LOUD};
  15 our ($lei_opt, $lei_out, $lei_err, $lei_cwdfh);
  16 BEGIN {
  17         @EXPORT = qw(tmpdir tcp_server tcp_connect require_git require_mods
  18                 run_script start_script key2sub xsys xsys_e xqx eml_load tick
  19                 have_xapian_compact json_utf8 setup_public_inboxes create_inbox
  20                 tcp_host_port test_lei lei lei_ok $lei_out $lei_err $lei_opt
  21                 test_httpd xbail require_cmd is_xdeeply);
  22         require Test::More;
  23         my @methods = grep(!/\W/, @Test::More::EXPORT);
  24         eval(join('', map { "*$_=\\&Test::More::$_;" } @methods));
  25         die $@ if $@;
  26         push @EXPORT, @methods;
  27 }
  28
  29 sub xbail (@) { BAIL_OUT join(' ', map { ref() ? (explain($_)) : ($_) } @_) }
  30
  31 sub eml_load ($) {
  32         my ($path, $cb) = @_;
  33         open(my $fh, '<', $path) or die "open $path: $!";
  34         require PublicInbox::Eml;
  35         PublicInbox::Eml->new(\(do { local $/; <$fh> }));
  36 }
  37
  38 sub tmpdir (;$) {
  39         my ($base) = @_;
  40         require File::Temp;
  41         unless (defined $base) {
  42                 ($base) = ($0 =~ m!\b([^/]+)\.[^\.]+\z!);
  43         }
  44         my $tmpdir = File::Temp->newdir("pi-$base-$$-XXXX", TMPDIR => 1);
  45         ($tmpdir->dirname, $tmpdir);
  46 }
  47
  48 sub tcp_server () {
  49         my %opt = (
  50                 ReuseAddr => 1,
  51                 Proto => 'tcp',
  52                 Type => Socket::SOCK_STREAM(),
  53                 Listen => 1024,
  54                 Blocking => 0,
  55         );
  56         eval {
  57                 die 'IPv4-only' if $ENV{TEST_IPV4_ONLY};
  58                 require IO::Socket::INET6;
  59                 IO::Socket::INET6->new(%opt, LocalAddr => '[::1]')
  60         } || eval {
  61                 die 'IPv6-only' if $ENV{TEST_IPV6_ONLY};
  62                 IO::Socket::INET->new(%opt, LocalAddr => '127.0.0.1')
  63         } || BAIL_OUT "failed to create TCP server: $! ($@)";
  64 }
  65
  66 sub tcp_host_port ($) {
  67         my ($s) = @_;
  68         my ($h, $p) = ($s->sockhost, $s->sockport);
  69         my $ipv4 = $s->sockdomain == Socket::AF_INET();
  70         if (wantarray) {
  71                 $ipv4 ? ($h, $p) : ("[$h]", $p);
  72         } else {
  73                 $ipv4 ? "$h:$p" : "[$h]:$p";
  74         }
  75 }
  76
  77 sub tcp_connect {
  78         my ($dest, %opt) = @_;
  79         my $addr = tcp_host_port($dest);
  80         my $s = ref($dest)->new(
  81                 Proto => 'tcp',
  82                 Type => Socket::SOCK_STREAM(),
  83                 PeerAddr => $addr,
  84                 %opt,
  85         ) or BAIL_OUT "failed to connect to $addr: $!";
  86         $s->autoflush(1);
  87         $s;
  88 }
  89
  90 sub require_cmd ($;$) {
  91         my ($cmd, $maybe) = @_;
  92         require PublicInbox::Spawn;
  93         my $bin = PublicInbox::Spawn::which($cmd);
  94         return $bin if $bin;
  95         $maybe ? 0 : plan(skip_all => "$cmd missing from PATH for $0");
  96 }
  97
  98 sub have_xapian_compact () {
  99         require_cmd($ENV{XAPIAN_COMPACT} || 'xapian-compact', 1);
 100 }
 101
 102 sub require_git ($;$) {
 103         my ($req, $maybe) = @_;
 104         my ($req_maj, $req_min, $req_sub) = split(/\./, $req);
 105         my ($cur_maj, $cur_min, $cur_sub) = (xqx([qw(git --version)])
 106                         =~ /version (\d+)\.(\d+)(?:\.(\d+))?/);
 107
 108         my $req_int = ($req_maj << 24) | ($req_min << 16) | ($req_sub // 0);
 109         my $cur_int = ($cur_maj << 24) | ($cur_min << 16) | ($cur_sub // 0);
 110         if ($cur_int < $req_int) {
 111                 return 0 if $maybe;
 112                 plan skip_all =>
 113                         "git $req+ required, have $cur_maj.$cur_min.$cur_sub";
 114         }
 115         1;
 116 }
 117
 118 sub require_mods {
 119         my @mods = @_;
 120         my $maybe = pop @mods if $mods[-1] =~ /\A[0-9]+\z/;
 121         my @need;
 122         while (my $mod = shift(@mods)) {
 123                 if ($mod eq 'lei') {
 124                         require_git(2.6, $maybe ? $maybe : ());
 125                         push @mods, qw(DBD::SQLite Search::Xapian);
 126                         $mod = 'json'; # fall-through
 127                 }
 128                 if ($mod eq 'json') {
 129                         $mod = 'Cpanel::JSON::XS||JSON::MaybeXS||JSON||JSON::PP'
 130                 } elsif ($mod eq '-httpd') {
 131                         push @mods, qw(Plack::Builder Plack::Util);
 132                         next;
 133                 } elsif ($mod eq '-imapd') {
 134                         push @mods, qw(Parse::RecDescent DBD::SQLite
 135                                         Email::Address::XS||Mail::Address);
 136                         next;
 137                 } elsif ($mod eq '-nntpd') {
 138                         push @mods, qw(DBD::SQLite);
 139                         next;
 140                 }
 141                 if ($mod eq 'Search::Xapian') {
 142                         if (eval { require PublicInbox::Search } &&
 143                                 PublicInbox::Search::load_xapian()) {
 144                                 next;
 145                         }
 146                 } elsif (index($mod, '||') >= 0) { # "Foo||Bar"
 147                         my $ok;
 148                         for my $m (split(/\Q||\E/, $mod)) {
 149                                 eval "require $m";
 150                                 next if $@;
 151                                 $ok = $m;
 152                                 last;
 153                         }
 154                         next if $ok;
 155                 } else {
 156                         eval "require $mod";
 157                 }
 158                 if ($@) {
 159                         diag "require $mod: $@" if $mod =~ /Gcf2/;
 160                         push @need, $mod;
 161                 } elsif ($mod eq 'IO::Socket::SSL' &&
 162                         # old versions of IO::Socket::SSL aren't supported
 163                         # by libnet, at least:
 164                         # https://rt.cpan.org/Ticket/Display.html?id=100529
 165                                 !eval{ IO::Socket::SSL->VERSION(2.007); 1 }) {
 166                         push @need, $@;
 167                 }
 168         }
 169         return unless @need;
 170         my $m = join(', ', @need)." missing for $0";
 171         skip($m, $maybe) if $maybe;
 172         plan(skip_all => $m)
 173 }
 174
 175 sub key2script ($) {
 176         my ($key) = @_;
 177         return $key if ($key eq 'git' || index($key, '/') >= 0);
 178         # n.b. we may have scripts which don't start with "public-inbox" in
 179         # the future:
 180         $key =~ s/\A([-\.])/public-inbox$1/;
 181         'blib/script/'.$key;
 182 }
 183
 184 my @io_mode = ([ *STDIN{IO}, '+<&' ], [ *STDOUT{IO}, '+>&' ],
 185                 [ *STDERR{IO}, '+>&' ]);
 186
 187 sub _prepare_redirects ($) {
 188         my ($fhref) = @_;
 189         my $orig_io = [];
 190         for (my $fd = 0; $fd <= $#io_mode; $fd++) {
 191                 my $fh = $fhref->[$fd] or next;
 192                 my ($oldfh, $mode) = @{$io_mode[$fd]};
 193                 open my $orig, $mode, $oldfh or die "$oldfh $mode stash: $!";
 194                 $orig_io->[$fd] = $orig;
 195                 open $oldfh, $mode, $fh or die "$oldfh $mode redirect: $!";
 196         }
 197         $orig_io;
 198 }
 199
 200 sub _undo_redirects ($) {
 201         my ($orig_io) = @_;
 202         for (my $fd = 0; $fd <= $#io_mode; $fd++) {
 203                 my $fh = $orig_io->[$fd] or next;
 204                 my ($oldfh, $mode) = @{$io_mode[$fd]};
 205                 open $oldfh, $mode, $fh or die "$$oldfh $mode redirect: $!";
 206         }
 207 }
 208
 209 # $opt->{run_mode} (or $ENV{TEST_RUN_MODE}) allows choosing between
 210 # three ways to spawn our own short-lived Perl scripts for testing:
 211 #
 212 # 0 - (fork|vfork) + execve, the most realistic but slowest
 213 # 1 - (not currently implemented)
 214 # 2 - preloading and running in current process (slightly faster than 1)
 215 #
 216 # 2 is not compatible with scripts which use "exit" (which we'll try to
 217 # avoid in the future).
 218 # The default is 2.
 219 our $run_script_exit_code;
 220 sub RUN_SCRIPT_EXIT () { "RUN_SCRIPT_EXIT\n" };
 221 sub run_script_exit {
 222         $run_script_exit_code = $_[0] // 0;
 223         die RUN_SCRIPT_EXIT;
 224 }
 225
 226 our %cached_scripts;
 227 sub key2sub ($) {
 228         my ($key) = @_;
 229         $cached_scripts{$key} //= do {
 230                 my $f = key2script($key);
 231                 open my $fh, '<', $f or die "open $f: $!";
 232                 my $str = do { local $/; <$fh> };
 233                 my $pkg = (split(m!/!, $f))[-1];
 234                 $pkg =~ s/([a-z])([a-z0-9]+)(\.t)?\z/\U$1\E$2/;
 235                 $pkg .= "_T" if $3;
 236                 $pkg =~ tr/-.//d;
 237                 $pkg = "PublicInbox::TestScript::$pkg";
 238                 eval <<EOF;
 239 package $pkg;
 240 use strict;
 241 use subs qw(exit);
 242
 243 *exit = \\&PublicInbox::TestCommon::run_script_exit;
 244 sub main {
 245 # the below "line" directive is a magic comment, see perlsyn(1) manpage
 246 # line 1 "$f"
 247 $str
 248         0;
 249 }
 250 1;
 251 EOF
 252                 $pkg->can('main');
 253         }
 254 }
 255
 256 sub _run_sub ($$$) {
 257         my ($sub, $key, $argv) = @_;
 258         local @ARGV = @$argv;
 259         $run_script_exit_code = undef;
 260         my $exit_code = eval { $sub->(@$argv) };
 261         if ($@ eq RUN_SCRIPT_EXIT) {
 262                 $@ = '';
 263                 $exit_code = $run_script_exit_code;
 264                 $? = ($exit_code << 8);
 265         } elsif (defined($exit_code)) {
 266                 $? = ($exit_code << 8);
 267         } elsif ($@) { # mimic die() behavior when uncaught
 268                 warn "E: eval-ed $key: $@\n";
 269                 $? = ($! << 8) if $!;
 270                 $? = (255 << 8) if $? == 0;
 271         } else {
 272                 die "BUG: eval-ed $key: no exit code or \$@\n";
 273         }
 274 }
 275
 276 sub run_script ($;$$) {
 277         my ($cmd, $env, $opt) = @_;
 278         my ($key, @argv) = @$cmd;
 279         my $run_mode = $ENV{TEST_RUN_MODE} // $opt->{run_mode} // 1;
 280         my $sub = $run_mode == 0 ? undef : key2sub($key);
 281         my $fhref = [];
 282         my $spawn_opt = {};
 283         for my $fd (0..2) {
 284                 my $redir = $opt->{$fd};
 285                 my $ref = ref($redir);
 286                 if ($ref eq 'SCALAR') {
 287                         open my $fh, '+>', undef or die "open: $!";
 288                         $fhref->[$fd] = $fh;
 289                         $spawn_opt->{$fd} = $fh;
 290                         next if $fd > 0;
 291                         $fh->autoflush(1);
 292                         print $fh $$redir or die "print: $!";
 293                         seek($fh, 0, SEEK_SET) or die "seek: $!";
 294                 } elsif ($ref eq 'GLOB') {
 295                         $spawn_opt->{$fd} = $fhref->[$fd] = $redir;
 296                 } elsif ($ref) {
 297                         die "unable to deal with $ref $redir";
 298                 }
 299         }
 300         if ($key =~ /-(index|convert|extindex|convert|xcpdb)\z/) {
 301                 unshift @argv, '--no-fsync';
 302         }
 303         if ($run_mode == 0) {
 304                 # spawn an independent new process, like real-world use cases:
 305                 require PublicInbox::Spawn;
 306                 my $cmd = [ key2script($key), @argv ];
 307                 if (my $d = $opt->{'-C'}) {
 308                         $cmd->[0] = File::Spec->rel2abs($cmd->[0]);
 309                         $spawn_opt->{'-C'} = $d;
 310                 }
 311                 my $pid = PublicInbox::Spawn::spawn($cmd, $env, $spawn_opt);
 312                 if (defined $pid) {
 313                         my $r = waitpid($pid, 0) // die "waitpid: $!";
 314                         $r == $pid or die "waitpid: expected $pid, got $r";
 315                 }
 316         } else { # localize and run everything in the same process:
 317                 # note: "local *STDIN = *STDIN;" and so forth did not work in
 318                 # old versions of perl
 319                 local %ENV = $env ? (%ENV, %$env) : %ENV;
 320                 local @SIG{keys %SIG} = map { undef } values %SIG;
 321                 local $SIG{FPE} = 'IGNORE'; # Perl default
 322                 local $0 = join(' ', @$cmd);
 323                 my $orig_io = _prepare_redirects($fhref);
 324                 my $cwdfh = $lei_cwdfh;
 325                 if (my $d = $opt->{'-C'}) {
 326                         unless ($cwdfh) {
 327                                 opendir $cwdfh, '.' or die "opendir .: $!";
 328                         }
 329                         chdir $d or die "chdir $d: $!";
 330                 }
 331                 _run_sub($sub, $key, \@argv);
 332                 eval { PublicInbox::Inbox::cleanup_task() };
 333                 die "fchdir(restore): $!" if $cwdfh && !chdir($cwdfh);
 334                 _undo_redirects($orig_io);
 335                 select STDOUT;
 336         }
 337
 338         # slurp the redirects back into user-supplied strings
 339         for my $fd (1..2) {
 340                 my $fh = $fhref->[$fd] or next;
 341                 next unless -f $fh;
 342                 seek($fh, 0, SEEK_SET) or die "seek: $!";
 343                 my $redir = $opt->{$fd};
 344                 local $/;
 345                 $$redir = <$fh>;
 346         }
 347         $? == 0;
 348 }
 349
 350 sub tick (;$) {
 351         my $tick = shift // 0.1;
 352         select undef, undef, undef, $tick;
 353         1;
 354 }
 355
 356 sub wait_for_tail ($;$) {
 357         my ($tail_pid, $want) = @_;
 358         my $wait = 2;
 359         if ($^O eq 'linux') { # GNU tail may use inotify
 360                 state $tail_has_inotify;
 361                 return tick if $want < 0 && $tail_has_inotify;
 362                 my $end = time + $wait;
 363                 my @ino;
 364                 do {
 365                         @ino = grep {
 366                                 readlink($_) =~ /\binotify\b/
 367                         } glob("/proc/$tail_pid/fd/*");
 368                 } while (!@ino && time <= $end and tick);
 369                 return if !@ino;
 370                 $tail_has_inotify = 1;
 371                 $ino[0] =~ s!/fd/!/fdinfo/!;
 372                 my @info;
 373                 do {
 374                         if (open my $fh, '<', $ino[0]) {
 375                                 local $/ = "\n";
 376                                 @info = grep(/^inotify wd:/, <$fh>);
 377                         }
 378                 } while (scalar(@info) < $want && time <= $end and tick);
 379         } else {
 380                 sleep($wait);
 381         }
 382 }
 383
 384 # like system() built-in, but uses spawn() for env/rdr + vfork
 385 sub xsys {
 386         my ($cmd, $env, $rdr) = @_;
 387         if (ref($cmd)) {
 388                 $rdr ||= {};
 389         } else {
 390                 $cmd = [ @_ ];
 391                 $env = undef;
 392                 $rdr = {};
 393         }
 394         run_script($cmd, $env, { %$rdr, run_mode => 0 });
 395         $? >> 8
 396 }
 397
 398 sub xsys_e { # like "/bin/sh -e"
 399         xsys(@_) == 0 or
 400                 BAIL_OUT (ref $_[0] ? "@{$_[0]}" : "@_"). " failed \$?=$?"
 401 }
 402
 403 # like `backtick` or qx{} op, but uses spawn() for env/rdr + vfork
 404 sub xqx {
 405         my ($cmd, $env, $rdr) = @_;
 406         $rdr //= {};
 407         run_script($cmd, $env, { %$rdr, run_mode => 0, 1 => \(my $out) });
 408         wantarray ? split(/^/m, $out) : $out;
 409 }
 410
 411 sub start_script {
 412         my ($cmd, $env, $opt) = @_;
 413         my ($key, @argv) = @$cmd;
 414         my $run_mode = $ENV{TEST_RUN_MODE} // $opt->{run_mode} // 2;
 415         my $sub = $run_mode == 0 ? undef : key2sub($key);
 416         my $tail_pid;
 417         if (my $tail_cmd = $ENV{TAIL}) {
 418                 my @paths;
 419                 for (@argv) {
 420                         next unless /\A--std(?:err|out)=(.+)\z/;
 421                         push @paths, $1;
 422                 }
 423                 if ($opt) {
 424                         for (1, 2) {
 425                                 my $f = $opt->{$_} or next;
 426                                 if (!ref($f)) {
 427                                         push @paths, $f;
 428                                 } elsif (ref($f) eq 'GLOB' && $^O eq 'linux') {
 429                                         my $fd = fileno($f);
 430                                         my $f = readlink "/proc/$$/fd/$fd";
 431                                         push @paths, $f if -e $f;
 432                                 }
 433                         }
 434                 }
 435                 if (@paths) {
 436                         $tail_pid = fork // die "fork: $!";
 437                         if ($tail_pid == 0) {
 438                                 # make sure files exist, first
 439                                 open my $fh, '>>', $_ for @paths;
 440                                 open(STDOUT, '>&STDERR') or die "1>&2: $!";
 441                                 exec(split(' ', $tail_cmd), @paths);
 442                                 die "$tail_cmd failed: $!";
 443                         }
 444                         wait_for_tail($tail_pid, scalar @paths);
 445                 }
 446         }
 447         my $pid = fork // die "fork: $!\n";
 448         if ($pid == 0) {
 449                 eval { PublicInbox::DS->Reset };
 450                 # pretend to be systemd (cf. sd_listen_fds(3))
 451                 # 3 == SD_LISTEN_FDS_START
 452                 my $fd;
 453                 for ($fd = 0; 1; $fd++) {
 454                         my $s = $opt->{$fd};
 455                         last if $fd >= 3 && !defined($s);
 456                         next unless $s;
 457                         my $fl = fcntl($s, F_GETFD, 0);
 458                         if (($fl & FD_CLOEXEC) != FD_CLOEXEC) {
 459                                 warn "got FD:".fileno($s)." w/o CLOEXEC\n";
 460                         }
 461                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 462                         dup2(fileno($s), $fd) or die "dup2 failed: $!\n";
 463                 }
 464                 %ENV = (%ENV, %$env) if $env;
 465                 my $fds = $fd - 3;
 466                 if ($fds > 0) {
 467                         $ENV{LISTEN_PID} = $$;
 468                         $ENV{LISTEN_FDS} = $fds;
 469                 }
 470                 $0 = join(' ', @$cmd);
 471                 if ($sub) {
 472                         eval { PublicInbox::DS->Reset };
 473                         _run_sub($sub, $key, \@argv);
 474                         POSIX::_exit($? >> 8);
 475                 } else {
 476                         exec(key2script($key), @argv);
 477                         die "FAIL: ",join(' ', $key, @argv), ": $!\n";
 478                 }
 479         }
 480         PublicInboxTestProcess->new($pid, $tail_pid);
 481 }
 482
 483 # favor lei() or lei_ok() over $lei for new code
 484 sub lei (@) {
 485         my ($cmd, $env, $xopt) = @_;
 486         $lei_out = $lei_err = '';
 487         if (!ref($cmd)) {
 488                 ($env, $xopt) = grep { (!defined) || ref } @_;
 489                 $cmd = [ grep { defined && !ref } @_ ];
 490         }
 491         my $res = run_script(['lei', @$cmd], $env, $xopt // $lei_opt);
 492         if ($lei_err ne '') {
 493                 if ($lei_err =~ /Use of uninitialized/ ||
 494                         $lei_err =~ m!\bArgument .*? isn't numeric in !) {
 495                         fail "lei_err=$lei_err";
 496                 } else {
 497                         diag "lei_err=$lei_err" if $lei_loud;
 498                 }
 499         }
 500         $res;
 501 };
 502
 503 sub lei_ok (@) {
 504         state $PWD = $ENV{PWD} // Cwd::getcwd();
 505         my $msg = ref($_[-1]) eq 'SCALAR' ? pop(@_) : undef;
 506         my $tmpdir = quotemeta(File::Spec->tmpdir);
 507         # filter out anything that looks like a path name for consistent logs
 508         my @msg = ref($_[0]) eq 'ARRAY' ? @{$_[0]} : @_;
 509         if (!$lei_loud) {
 510                 for (@msg) {
 511                         s!\A([a-z0-9]+://)[^/]+/!$1\$HOST_PORT/!;
 512                         s!$tmpdir\b/(?:[^/]+/)?!\$TMPDIR/!g;
 513                         s!\Q$PWD\E\b!\$PWD!g;
 514                 }
 515         }
 516         ok(lei(@_), "lei @msg". ($msg ? " ($$msg)" : '')) or
 517                 diag "\$?=$? err=$lei_err";
 518 }
 519
 520 sub json_utf8 () {
 521         state $x = ref(PublicInbox::Config->json)->new->utf8->canonical;
 522 }
 523
 524 sub is_xdeeply ($$$) {
 525         my ($x, $y, $desc) = @_;
 526         my $ok = is_deeply($x, $y, $desc);
 527         diag explain([$x, '!=', $y]) if !$ok;
 528         $ok;
 529 }
 530
 531 sub test_lei {
 532 SKIP: {
 533         my ($cb) = pop @_;
 534         my $test_opt = shift // {};
 535         local $lei_cwdfh;
 536         opendir $lei_cwdfh, '.' or xbail "opendir .: $!";
 537         require_git(2.6, 1) or skip('git 2.6+ required for lei test', 2);
 538         my $mods = $test_opt->{mods} // [ 'lei' ];
 539         require_mods(@$mods, 2);
 540         require PublicInbox::Config;
 541         require File::Path;
 542         local %ENV = %ENV;
 543         delete $ENV{XDG_DATA_HOME};
 544         delete $ENV{XDG_CONFIG_HOME};
 545         $ENV{GIT_COMMITTER_EMAIL} = 'lei@example.com';
 546         $ENV{GIT_COMMITTER_NAME} = 'lei user';
 547         my (undef, $fn, $lineno) = caller(0);
 548         my $t = "$fn:$lineno";
 549         require PublicInbox::Spawn;
 550         state $lei_daemon = PublicInbox::Spawn->can('send_cmd4') ||
 551                                 eval { require Socket::MsgHdr; 1 };
 552         unless ($lei_daemon) {
 553                 skip('Inline::C unconfigured/missing '.
 554 '(mkdir -p ~/.cache/public-inbox/inline-c) OR Socket::MsgHdr missing',
 555                         1);
 556         }
 557         $lei_opt = { 1 => \$lei_out, 2 => \$lei_err };
 558         my ($daemon_pid, $for_destroy, $daemon_xrd);
 559         my $tmpdir = $test_opt->{tmpdir};
 560         File::Path::mkpath($tmpdir) if (defined $tmpdir && !-d $tmpdir);
 561         ($tmpdir, $for_destroy) = tmpdir unless $tmpdir;
 562         state $persist_xrd = $ENV{TEST_LEI_DAEMON_PERSIST_DIR};
 563         SKIP: {
 564                 $ENV{TEST_LEI_ONESHOT} and
 565                         xbail 'TEST_LEI_ONESHOT no longer supported';
 566                 my $home = "$tmpdir/lei-daemon";
 567                 mkdir($home, 0700) or BAIL_OUT "mkdir: $!";
 568                 local $ENV{HOME} = $home;
 569                 my $persist;
 570                 if ($persist_xrd && !$test_opt->{daemon_only}) {
 571                         $persist = $daemon_xrd = $persist_xrd;
 572                 } else {
 573                         $daemon_xrd = "$home/xdg_run";
 574                         mkdir($daemon_xrd, 0700) or BAIL_OUT "mkdir: $!";
 575                 }
 576                 local $ENV{XDG_RUNTIME_DIR} = $daemon_xrd;
 577                 $cb->();
 578                 if ($persist) { # remove before ~/.local gets removed
 579                         File::Path::rmtree([glob("$home/*")]);
 580                         File::Path::rmtree("$home/.config");
 581                 } else {
 582                         lei_ok(qw(daemon-pid), \"daemon-pid after $t");
 583                         chomp($daemon_pid = $lei_out);
 584                         if (!$daemon_pid) {
 585                                 fail("daemon not running after $t");
 586                                 skip 'daemon died unexpectedly', 2;
 587                         }
 588                         ok(kill(0, $daemon_pid), "daemon running after $t");
 589                         lei_ok(qw(daemon-kill), \"daemon-kill after $t");
 590                 }
 591         }; # SKIP for lei_daemon
 592         if ($daemon_pid) {
 593                 for (0..10) {
 594                         kill(0, $daemon_pid) or last;
 595                         tick;
 596                 }
 597                 ok(!kill(0, $daemon_pid), "$t daemon stopped");
 598                 my $f = "$daemon_xrd/lei/errors.log";
 599                 open my $fh, '<', $f or BAIL_OUT "$f: $!";
 600                 my @l = <$fh>;
 601                 is_xdeeply(\@l, [],
 602                         "$t daemon XDG_RUNTIME_DIR/lei/errors.log empty");
 603         }
 604 }; # SKIP if missing git 2.6+ || Xapian || SQLite || json
 605 } # /test_lei
 606
 607 # returns the pathname to a ~/.public-inbox/config in scalar context,
 608 # ($test_home, $pi_config_pathname) in list context
 609 sub setup_public_inboxes () {
 610         my $test_home = "t/home2";
 611         my $pi_config = "$test_home/.public-inbox/config";
 612         my $stamp = "$test_home/setup-stamp";
 613         my @ret = ($test_home, $pi_config);
 614         return @ret if -f $stamp;
 615
 616         require PublicInbox::Lock;
 617         my $lk = bless { lock_path => "$test_home/setup.lock" },
 618                         'PublicInbox::Lock';
 619         my $end = $lk->lock_for_scope;
 620         return @ret if -f $stamp;
 621
 622         local $ENV{PI_CONFIG} = $pi_config;
 623         for my $V (1, 2) {
 624                 run_script([qw(-init --skip-docdata), "-V$V",
 625                                 '--newsgroup', "t.v$V", "t$V",
 626                                 "$test_home/t$V", "http://example.com/t$V",
 627                                 "t$V\@example.com" ]) or xbail "init v$V";
 628                 unlink "$test_home/t$V/description" or xbail "unlink $!";
 629         }
 630         require PublicInbox::Config;
 631         require PublicInbox::InboxWritable;
 632         my $cfg = PublicInbox::Config->new;
 633         my $seen = 0;
 634         $cfg->each_inbox(sub {
 635                 my ($ibx) = @_;
 636                 $ibx->{-no_fsync} = 1;
 637                 my $im = PublicInbox::InboxWritable->new($ibx)->importer(0);
 638                 my $V = $ibx->version;
 639                 my @eml = (glob('t/*.eml'), 't/data/0001.patch');
 640                 for (@eml) {
 641                         next if $_ eq 't/psgi_v2-old.eml'; # dup mid
 642                         $im->add(eml_load($_)) or BAIL_OUT "v$V add $_";
 643                         $seen++;
 644                 }
 645                 $im->done;
 646         });
 647         $seen or BAIL_OUT 'no imports';
 648         open my $fh, '>', $stamp or BAIL_OUT "open $stamp: $!";
 649         @ret;
 650 }
 651
 652 sub create_inbox ($$;@) {
 653         my $ident = shift;
 654         my $cb = pop;
 655         my %opt = @_;
 656         require PublicInbox::Lock;
 657         require PublicInbox::InboxWritable;
 658         my ($base) = ($0 =~ m!\b([^/]+)\.[^\.]+\z!);
 659         my $dir = "t/data-gen/$base.$ident";
 660         my $new = !-d $dir;
 661         if ($new) {
 662                 mkdir $dir; # may race
 663                 -d $dir or BAIL_OUT "$dir could not be created: $!";
 664         }
 665         my $lk = bless { lock_path => "$dir/creat.lock" }, 'PublicInbox::Lock';
 666         $opt{inboxdir} = File::Spec->rel2abs($dir);
 667         $opt{name} //= $ident;
 668         my $scope = $lk->lock_for_scope;
 669         my $pre_cb = delete $opt{pre_cb};
 670         $pre_cb->($dir) if $pre_cb && $new;
 671         $opt{-no_fsync} = 1;
 672         my $no_gc = delete $opt{-no_gc};
 673         my $tmpdir = delete $opt{tmpdir};
 674         my $addr = $opt{address} // [];
 675         $opt{-primary_address} //= $addr->[0] // "$ident\@example.com";
 676         my $parallel = delete($opt{importer_parallel}) // 0;
 677         my $creat_opt = { nproc => delete($opt{nproc}) // 1 };
 678         my $ibx = PublicInbox::InboxWritable->new({ %opt }, $creat_opt);
 679         if (!-f "$dir/creat.stamp") {
 680                 my $im = $ibx->importer($parallel);
 681                 $cb->($im, $ibx);
 682                 $im->done if $im;
 683                 unless ($no_gc) {
 684                         my @to_gc = $ibx->version == 1 ? ($ibx->{inboxdir}) :
 685                                         glob("$ibx->{inboxdir}/git/*.git");
 686                         for my $dir (@to_gc) {
 687                                 xsys_e([ qw(git gc -q) ], { GIT_DIR => $dir });
 688                         }
 689                 }
 690                 open my $s, '>', "$dir/creat.stamp" or
 691                         BAIL_OUT "error creating $dir/creat.stamp: $!";
 692         }
 693         if ($tmpdir) {
 694                 undef $ibx;
 695                 xsys([qw(/bin/cp -Rp), $dir, $tmpdir]) == 0 or
 696                         BAIL_OUT "cp $dir $tmpdir";
 697                 $opt{inboxdir} = $tmpdir;
 698                 $ibx = PublicInbox::InboxWritable->new(\%opt);
 699         }
 700         $ibx;
 701 }
 702
 703 sub test_httpd ($$;$) {
 704         my ($env, $client, $skip) = @_;
 705         for (qw(PI_CONFIG TMPDIR)) {
 706                 $env->{$_} or BAIL_OUT "$_ unset";
 707         }
 708         SKIP: {
 709                 require_mods(qw(Plack::Test::ExternalServer), $skip // 1);
 710                 my $sock = tcp_server() or die;
 711                 my ($out, $err) = map { "$env->{TMPDIR}/std$_.log" } qw(out err);
 712                 my $cmd = [ qw(-httpd -W0), "--stdout=$out", "--stderr=$err" ];
 713                 my $td = start_script($cmd, $env, { 3 => $sock });
 714                 my ($h, $p) = tcp_host_port($sock);
 715                 local $ENV{PLACK_TEST_EXTERNALSERVER_URI} = "http://$h:$p";
 716                 Plack::Test::ExternalServer::test_psgi(client => $client);
 717                 $td->join('TERM');
 718                 open my $fh, '<', $err or BAIL_OUT $!;
 719                 my $e = do { local $/; <$fh> };
 720                 if ($e =~ s/^Plack::Middleware::ReverseProxy missing,\n//gms) {
 721                         $e =~ s/^URL generation for redirects .*\n//gms;
 722                 }
 723                 is($e, '', 'no errors');
 724         }
 725 };
 726
 727
 728 package PublicInboxTestProcess;
 729 use strict;
 730
 731 # prevent new threads from inheriting these objects
 732 sub CLONE_SKIP { 1 }
 733
 734 sub new {
 735         my ($klass, $pid, $tail_pid) = @_;
 736         bless { pid => $pid, tail_pid => $tail_pid, owner => $$ }, $klass;
 737 }
 738
 739 sub kill {
 740         my ($self, $sig) = @_;
 741         CORE::kill($sig // 'TERM', $self->{pid});
 742 }
 743
 744 sub join {
 745         my ($self, $sig) = @_;
 746         my $pid = delete $self->{pid} or return;
 747         CORE::kill($sig, $pid) if defined $sig;
 748         my $ret = waitpid($pid, 0) // die "waitpid($pid): $!";
 749         $ret == $pid or die "waitpid($pid) != $ret";
 750 }
 751
 752 sub DESTROY {
 753         my ($self) = @_;
 754         return if $self->{owner} != $$;
 755         if (my $tail_pid = delete $self->{tail_pid}) {
 756                 PublicInbox::TestCommon::wait_for_tail($tail_pid, -1);
 757                 CORE::kill('TERM', $tail_pid);
 758         }
 759         $self->join('TERM');
 760 }
 761
 762 package PublicInbox::TestCommon::InboxWakeup;
 763 use strict;
 764 sub on_inbox_unlock { ${$_[0]}->($_[1]) }
 765
 766 1;