lib/PublicInbox/TestCommon.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # internal APIs used only for tests
   5 package PublicInbox::TestCommon;
   6 use strict;
   7 use parent qw(Exporter);
   8 use v5.10.1;
   9 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD :seek);
  10 use POSIX qw(dup2);
  11 use IO::Socket::INET;
  12 use File::Spec;
  13 our @EXPORT;
  14 my $lei_loud = $ENV{TEST_LEI_ERR_LOUD};
  15 our ($lei_opt, $lei_out, $lei_err, $lei_cwdfh);
  16 BEGIN {
  17         @EXPORT = qw(tmpdir tcp_server tcp_connect require_git require_mods
  18                 run_script start_script key2sub xsys xsys_e xqx eml_load tick
  19                 have_xapian_compact json_utf8 setup_public_inboxes create_inbox
  20                 tcp_host_port test_lei lei lei_ok $lei_out $lei_err $lei_opt
  21                 test_httpd xbail require_cmd is_xdeeply);
  22         require Test::More;
  23         my @methods = grep(!/\W/, @Test::More::EXPORT);
  24         eval(join('', map { "*$_=\\&Test::More::$_;" } @methods));
  25         die $@ if $@;
  26         push @EXPORT, @methods;
  27 }
  28
  29 sub xbail (@) { BAIL_OUT join(' ', map { ref() ? (explain($_)) : ($_) } @_) }
  30
  31 sub eml_load ($) {
  32         my ($path, $cb) = @_;
  33         open(my $fh, '<', $path) or die "open $path: $!";
  34         require PublicInbox::Eml;
  35         PublicInbox::Eml->new(\(do { local $/; <$fh> }));
  36 }
  37
  38 sub tmpdir (;$) {
  39         my ($base) = @_;
  40         require File::Temp;
  41         unless (defined $base) {
  42                 ($base) = ($0 =~ m!\b([^/]+)\.[^\.]+\z!);
  43         }
  44         my $tmpdir = File::Temp->newdir("pi-$base-$$-XXXX", TMPDIR => 1);
  45         ($tmpdir->dirname, $tmpdir);
  46 }
  47
  48 sub tcp_server () {
  49         my %opt = (
  50                 ReuseAddr => 1,
  51                 Proto => 'tcp',
  52                 Type => Socket::SOCK_STREAM(),
  53                 Listen => 1024,
  54                 Blocking => 0,
  55         );
  56         eval {
  57                 die 'IPv4-only' if $ENV{TEST_IPV4_ONLY};
  58                 require IO::Socket::INET6;
  59                 IO::Socket::INET6->new(%opt, LocalAddr => '[::1]')
  60         } || eval {
  61                 die 'IPv6-only' if $ENV{TEST_IPV6_ONLY};
  62                 IO::Socket::INET->new(%opt, LocalAddr => '127.0.0.1')
  63         } || BAIL_OUT "failed to create TCP server: $! ($@)";
  64 }
  65
  66 sub tcp_host_port ($) {
  67         my ($s) = @_;
  68         my ($h, $p) = ($s->sockhost, $s->sockport);
  69         my $ipv4 = $s->sockdomain == Socket::AF_INET();
  70         if (wantarray) {
  71                 $ipv4 ? ($h, $p) : ("[$h]", $p);
  72         } else {
  73                 $ipv4 ? "$h:$p" : "[$h]:$p";
  74         }
  75 }
  76
  77 sub tcp_connect {
  78         my ($dest, %opt) = @_;
  79         my $addr = tcp_host_port($dest);
  80         my $s = ref($dest)->new(
  81                 Proto => 'tcp',
  82                 Type => Socket::SOCK_STREAM(),
  83                 PeerAddr => $addr,
  84                 %opt,
  85         ) or BAIL_OUT "failed to connect to $addr: $!";
  86         $s->autoflush(1);
  87         $s;
  88 }
  89
  90 sub require_cmd ($;$) {
  91         my ($cmd, $maybe) = @_;
  92         require PublicInbox::Spawn;
  93         my $bin = PublicInbox::Spawn::which($cmd);
  94         return $bin if $bin;
  95         $maybe ? 0 : plan(skip_all => "$cmd missing from PATH for $0");
  96 }
  97
  98 sub have_xapian_compact () {
  99         require_cmd($ENV{XAPIAN_COMPACT} || 'xapian-compact', 1);
 100 }
 101
 102 sub require_git ($;$) {
 103         my ($req, $maybe) = @_;
 104         my ($req_maj, $req_min, $req_sub) = split(/\./, $req);
 105         my ($cur_maj, $cur_min, $cur_sub) = (xqx([qw(git --version)])
 106                         =~ /version (\d+)\.(\d+)(?:\.(\d+))?/);
 107
 108         my $req_int = ($req_maj << 24) | ($req_min << 16) | ($req_sub // 0);
 109         my $cur_int = ($cur_maj << 24) | ($cur_min << 16) | ($cur_sub // 0);
 110         if ($cur_int < $req_int) {
 111                 return 0 if $maybe;
 112                 plan skip_all =>
 113                         "git $req+ required, have $cur_maj.$cur_min.$cur_sub";
 114         }
 115         1;
 116 }
 117
 118 sub require_mods {
 119         my @mods = @_;
 120         my $maybe = pop @mods if $mods[-1] =~ /\A[0-9]+\z/;
 121         my @need;
 122         while (my $mod = shift(@mods)) {
 123                 if ($mod eq 'lei') {
 124                         require_git(2.6, $maybe ? $maybe : ());
 125                         push @mods, qw(DBD::SQLite Search::Xapian);
 126                         $mod = 'json'; # fall-through
 127                 }
 128                 if ($mod eq 'json') {
 129                         $mod = 'Cpanel::JSON::XS||JSON::MaybeXS||JSON||JSON::PP'
 130                 } elsif ($mod eq '-httpd') {
 131                         push @mods, qw(Plack::Builder Plack::Util);
 132                         next;
 133                 } elsif ($mod eq '-imapd') {
 134                         push @mods, qw(Parse::RecDescent DBD::SQLite
 135                                         Email::Address::XS||Mail::Address);
 136                         next;
 137                 } elsif ($mod eq '-nntpd') {
 138                         push @mods, qw(DBD::SQLite);
 139                         next;
 140                 }
 141                 if ($mod eq 'Search::Xapian') {
 142                         if (eval { require PublicInbox::Search } &&
 143                                 PublicInbox::Search::load_xapian()) {
 144                                 next;
 145                         }
 146                 } elsif (index($mod, '||') >= 0) { # "Foo||Bar"
 147                         my $ok;
 148                         for my $m (split(/\Q||\E/, $mod)) {
 149                                 eval "require $m";
 150                                 next if $@;
 151                                 $ok = $m;
 152                                 last;
 153                         }
 154                         next if $ok;
 155                 } else {
 156                         eval "require $mod";
 157                 }
 158                 if ($@) {
 159                         diag "require $mod: $@" if $mod =~ /Gcf2/;
 160                         push @need, $mod;
 161                 } elsif ($mod eq 'IO::Socket::SSL' &&
 162                         # old versions of IO::Socket::SSL aren't supported
 163                         # by libnet, at least:
 164                         # https://rt.cpan.org/Ticket/Display.html?id=100529
 165                                 !eval{ IO::Socket::SSL->VERSION(2.007); 1 }) {
 166                         push @need, $@;
 167                 }
 168         }
 169         return unless @need;
 170         my $m = join(', ', @need)." missing for $0";
 171         skip($m, $maybe) if $maybe;
 172         plan(skip_all => $m)
 173 }
 174
 175 sub key2script ($) {
 176         my ($key) = @_;
 177         return $key if ($key eq 'git' || index($key, '/') >= 0);
 178         # n.b. we may have scripts which don't start with "public-inbox" in
 179         # the future:
 180         $key =~ s/\A([-\.])/public-inbox$1/;
 181         'blib/script/'.$key;
 182 }
 183
 184 my @io_mode = ([ *STDIN{IO}, '+<&' ], [ *STDOUT{IO}, '+>&' ],
 185                 [ *STDERR{IO}, '+>&' ]);
 186
 187 sub _prepare_redirects ($) {
 188         my ($fhref) = @_;
 189         my $orig_io = [];
 190         for (my $fd = 0; $fd <= $#io_mode; $fd++) {
 191                 my $fh = $fhref->[$fd] or next;
 192                 my ($oldfh, $mode) = @{$io_mode[$fd]};
 193                 open my $orig, $mode, $oldfh or die "$oldfh $mode stash: $!";
 194                 $orig_io->[$fd] = $orig;
 195                 open $oldfh, $mode, $fh or die "$oldfh $mode redirect: $!";
 196         }
 197         $orig_io;
 198 }
 199
 200 sub _undo_redirects ($) {
 201         my ($orig_io) = @_;
 202         for (my $fd = 0; $fd <= $#io_mode; $fd++) {
 203                 my $fh = $orig_io->[$fd] or next;
 204                 my ($oldfh, $mode) = @{$io_mode[$fd]};
 205                 open $oldfh, $mode, $fh or die "$$oldfh $mode redirect: $!";
 206         }
 207 }
 208
 209 # $opt->{run_mode} (or $ENV{TEST_RUN_MODE}) allows choosing between
 210 # three ways to spawn our own short-lived Perl scripts for testing:
 211 #
 212 # 0 - (fork|vfork) + execve, the most realistic but slowest
 213 # 1 - (not currently implemented)
 214 # 2 - preloading and running in current process (slightly faster than 1)
 215 #
 216 # 2 is not compatible with scripts which use "exit" (which we'll try to
 217 # avoid in the future).
 218 # The default is 2.
 219 our $run_script_exit_code;
 220 sub RUN_SCRIPT_EXIT () { "RUN_SCRIPT_EXIT\n" };
 221 sub run_script_exit {
 222         $run_script_exit_code = $_[0] // 0;
 223         die RUN_SCRIPT_EXIT;
 224 }
 225
 226 our %cached_scripts;
 227 sub key2sub ($) {
 228         my ($key) = @_;
 229         $cached_scripts{$key} //= do {
 230                 my $f = key2script($key);
 231                 open my $fh, '<', $f or die "open $f: $!";
 232                 my $str = do { local $/; <$fh> };
 233                 my $pkg = (split(m!/!, $f))[-1];
 234                 $pkg =~ s/([a-z])([a-z0-9]+)(\.t)?\z/\U$1\E$2/;
 235                 $pkg .= "_T" if $3;
 236                 $pkg =~ tr/-.//d;
 237                 $pkg = "PublicInbox::TestScript::$pkg";
 238                 eval <<EOF;
 239 package $pkg;
 240 use strict;
 241 use subs qw(exit);
 242
 243 *exit = \\&PublicInbox::TestCommon::run_script_exit;
 244 sub main {
 245 # the below "line" directive is a magic comment, see perlsyn(1) manpage
 246 # line 1 "$f"
 247 $str
 248         0;
 249 }
 250 1;
 251 EOF
 252                 $pkg->can('main');
 253         }
 254 }
 255
 256 sub _run_sub ($$$) {
 257         my ($sub, $key, $argv) = @_;
 258         local @ARGV = @$argv;
 259         $run_script_exit_code = undef;
 260         my $exit_code = eval { $sub->(@$argv) };
 261         if ($@ eq RUN_SCRIPT_EXIT) {
 262                 $@ = '';
 263                 $exit_code = $run_script_exit_code;
 264                 $? = ($exit_code << 8);
 265         } elsif (defined($exit_code)) {
 266                 $? = ($exit_code << 8);
 267         } elsif ($@) { # mimic die() behavior when uncaught
 268                 warn "E: eval-ed $key: $@\n";
 269                 $? = ($! << 8) if $!;
 270                 $? = (255 << 8) if $? == 0;
 271         } else {
 272                 die "BUG: eval-ed $key: no exit code or \$@\n";
 273         }
 274 }
 275
 276 sub run_script ($;$$) {
 277         my ($cmd, $env, $opt) = @_;
 278         my ($key, @argv) = @$cmd;
 279         my $run_mode = $ENV{TEST_RUN_MODE} // $opt->{run_mode} // 1;
 280         my $sub = $run_mode == 0 ? undef : key2sub($key);
 281         my $fhref = [];
 282         my $spawn_opt = {};
 283         for my $fd (0..2) {
 284                 my $redir = $opt->{$fd};
 285                 my $ref = ref($redir);
 286                 if ($ref eq 'SCALAR') {
 287                         open my $fh, '+>', undef or die "open: $!";
 288                         $fhref->[$fd] = $fh;
 289                         $spawn_opt->{$fd} = $fh;
 290                         next if $fd > 0;
 291                         $fh->autoflush(1);
 292                         print $fh $$redir or die "print: $!";
 293                         seek($fh, 0, SEEK_SET) or die "seek: $!";
 294                 } elsif ($ref eq 'GLOB') {
 295                         $spawn_opt->{$fd} = $fhref->[$fd] = $redir;
 296                 } elsif ($ref) {
 297                         die "unable to deal with $ref $redir";
 298                 }
 299         }
 300         if ($key =~ /-(index|convert|extindex|convert|xcpdb)\z/) {
 301                 unshift @argv, '--no-fsync';
 302         }
 303         if ($run_mode == 0) {
 304                 # spawn an independent new process, like real-world use cases:
 305                 require PublicInbox::Spawn;
 306                 my $cmd = [ key2script($key), @argv ];
 307                 if (my $d = $opt->{'-C'}) {
 308                         $cmd->[0] = File::Spec->rel2abs($cmd->[0]);
 309                         $spawn_opt->{'-C'} = $d;
 310                 }
 311                 my $pid = PublicInbox::Spawn::spawn($cmd, $env, $spawn_opt);
 312                 if (defined $pid) {
 313                         my $r = waitpid($pid, 0) // die "waitpid: $!";
 314                         $r == $pid or die "waitpid: expected $pid, got $r";
 315                 }
 316         } else { # localize and run everything in the same process:
 317                 # note: "local *STDIN = *STDIN;" and so forth did not work in
 318                 # old versions of perl
 319                 local %ENV = $env ? (%ENV, %$env) : %ENV;
 320                 local %SIG = %SIG;
 321                 local $0 = join(' ', @$cmd);
 322                 my $orig_io = _prepare_redirects($fhref);
 323                 my $cwdfh = $lei_cwdfh;
 324                 if (my $d = $opt->{'-C'}) {
 325                         unless ($cwdfh) {
 326                                 opendir $cwdfh, '.' or die "opendir .: $!";
 327                         }
 328                         chdir $d or die "chdir $d: $!";
 329                 }
 330                 _run_sub($sub, $key, \@argv);
 331                 eval { PublicInbox::Inbox::cleanup_task() };
 332                 die "fchdir(restore): $!" if $cwdfh && !chdir($cwdfh);
 333                 _undo_redirects($orig_io);
 334                 select STDOUT;
 335         }
 336
 337         # slurp the redirects back into user-supplied strings
 338         for my $fd (1..2) {
 339                 my $fh = $fhref->[$fd] or next;
 340                 next unless -f $fh;
 341                 seek($fh, 0, SEEK_SET) or die "seek: $!";
 342                 my $redir = $opt->{$fd};
 343                 local $/;
 344                 $$redir = <$fh>;
 345         }
 346         $? == 0;
 347 }
 348
 349 sub tick (;$) {
 350         my $tick = shift // 0.1;
 351         select undef, undef, undef, $tick;
 352         1;
 353 }
 354
 355 sub wait_for_tail ($;$) {
 356         my ($tail_pid, $want) = @_;
 357         my $wait = 2;
 358         if ($^O eq 'linux') { # GNU tail may use inotify
 359                 state $tail_has_inotify;
 360                 return tick if $want < 0 && $tail_has_inotify;
 361                 my $end = time + $wait;
 362                 my @ino;
 363                 do {
 364                         @ino = grep {
 365                                 readlink($_) =~ /\binotify\b/
 366                         } glob("/proc/$tail_pid/fd/*");
 367                 } while (!@ino && time <= $end and tick);
 368                 return if !@ino;
 369                 $tail_has_inotify = 1;
 370                 $ino[0] =~ s!/fd/!/fdinfo/!;
 371                 my @info;
 372                 do {
 373                         if (open my $fh, '<', $ino[0]) {
 374                                 local $/ = "\n";
 375                                 @info = grep(/^inotify wd:/, <$fh>);
 376                         }
 377                 } while (scalar(@info) < $want && time <= $end and tick);
 378         } else {
 379                 sleep($wait);
 380         }
 381 }
 382
 383 # like system() built-in, but uses spawn() for env/rdr + vfork
 384 sub xsys {
 385         my ($cmd, $env, $rdr) = @_;
 386         if (ref($cmd)) {
 387                 $rdr ||= {};
 388         } else {
 389                 $cmd = [ @_ ];
 390                 $env = undef;
 391                 $rdr = {};
 392         }
 393         run_script($cmd, $env, { %$rdr, run_mode => 0 });
 394         $? >> 8
 395 }
 396
 397 sub xsys_e { # like "/bin/sh -e"
 398         xsys(@_) == 0 or
 399                 BAIL_OUT (ref $_[0] ? "@{$_[0]}" : "@_"). " failed \$?=$?"
 400 }
 401
 402 # like `backtick` or qx{} op, but uses spawn() for env/rdr + vfork
 403 sub xqx {
 404         my ($cmd, $env, $rdr) = @_;
 405         $rdr //= {};
 406         run_script($cmd, $env, { %$rdr, run_mode => 0, 1 => \(my $out) });
 407         wantarray ? split(/^/m, $out) : $out;
 408 }
 409
 410 sub start_script {
 411         my ($cmd, $env, $opt) = @_;
 412         my ($key, @argv) = @$cmd;
 413         my $run_mode = $ENV{TEST_RUN_MODE} // $opt->{run_mode} // 2;
 414         my $sub = $run_mode == 0 ? undef : key2sub($key);
 415         my $tail_pid;
 416         if (my $tail_cmd = $ENV{TAIL}) {
 417                 my @paths;
 418                 for (@argv) {
 419                         next unless /\A--std(?:err|out)=(.+)\z/;
 420                         push @paths, $1;
 421                 }
 422                 if ($opt) {
 423                         for (1, 2) {
 424                                 my $f = $opt->{$_} or next;
 425                                 if (!ref($f)) {
 426                                         push @paths, $f;
 427                                 } elsif (ref($f) eq 'GLOB' && $^O eq 'linux') {
 428                                         my $fd = fileno($f);
 429                                         my $f = readlink "/proc/$$/fd/$fd";
 430                                         push @paths, $f if -e $f;
 431                                 }
 432                         }
 433                 }
 434                 if (@paths) {
 435                         $tail_pid = fork // die "fork: $!";
 436                         if ($tail_pid == 0) {
 437                                 # make sure files exist, first
 438                                 open my $fh, '>>', $_ for @paths;
 439                                 open(STDOUT, '>&STDERR') or die "1>&2: $!";
 440                                 exec(split(' ', $tail_cmd), @paths);
 441                                 die "$tail_cmd failed: $!";
 442                         }
 443                         wait_for_tail($tail_pid, scalar @paths);
 444                 }
 445         }
 446         my $pid = fork // die "fork: $!\n";
 447         if ($pid == 0) {
 448                 eval { PublicInbox::DS->Reset };
 449                 # pretend to be systemd (cf. sd_listen_fds(3))
 450                 # 3 == SD_LISTEN_FDS_START
 451                 my $fd;
 452                 for ($fd = 0; 1; $fd++) {
 453                         my $s = $opt->{$fd};
 454                         last if $fd >= 3 && !defined($s);
 455                         next unless $s;
 456                         my $fl = fcntl($s, F_GETFD, 0);
 457                         if (($fl & FD_CLOEXEC) != FD_CLOEXEC) {
 458                                 warn "got FD:".fileno($s)." w/o CLOEXEC\n";
 459                         }
 460                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 461                         dup2(fileno($s), $fd) or die "dup2 failed: $!\n";
 462                 }
 463                 %ENV = (%ENV, %$env) if $env;
 464                 my $fds = $fd - 3;
 465                 if ($fds > 0) {
 466                         $ENV{LISTEN_PID} = $$;
 467                         $ENV{LISTEN_FDS} = $fds;
 468                 }
 469                 $0 = join(' ', @$cmd);
 470                 if ($sub) {
 471                         eval { PublicInbox::DS->Reset };
 472                         _run_sub($sub, $key, \@argv);
 473                         POSIX::_exit($? >> 8);
 474                 } else {
 475                         exec(key2script($key), @argv);
 476                         die "FAIL: ",join(' ', $key, @argv), ": $!\n";
 477                 }
 478         }
 479         PublicInboxTestProcess->new($pid, $tail_pid);
 480 }
 481
 482 # favor lei() or lei_ok() over $lei for new code
 483 sub lei (@) {
 484         my ($cmd, $env, $xopt) = @_;
 485         $lei_out = $lei_err = '';
 486         if (!ref($cmd)) {
 487                 ($env, $xopt) = grep { (!defined) || ref } @_;
 488                 $cmd = [ grep { defined && !ref } @_ ];
 489         }
 490         my $res = run_script(['lei', @$cmd], $env, $xopt // $lei_opt);
 491         if ($lei_err ne '') {
 492                 if ($lei_err =~ /Use of uninitialized/ ||
 493                         $lei_err =~ m!\bArgument .*? isn't numeric in !) {
 494                         fail "lei_err=$lei_err";
 495                 } else {
 496                         diag "lei_err=$lei_err" if $lei_loud;
 497                 }
 498         }
 499         $res;
 500 };
 501
 502 sub lei_ok (@) {
 503         state $PWD = $ENV{PWD} // Cwd::getcwd();
 504         my $msg = ref($_[-1]) eq 'SCALAR' ? pop(@_) : undef;
 505         my $tmpdir = quotemeta(File::Spec->tmpdir);
 506         # filter out anything that looks like a path name for consistent logs
 507         my @msg = ref($_[0]) eq 'ARRAY' ? @{$_[0]} : @_;
 508         if (!$lei_loud) {
 509                 for (@msg) {
 510                         s!\A([a-z0-9]+://)[^/]+/!$1\$HOST_PORT/!;
 511                         s!$tmpdir\b/(?:[^/]+/)?!\$TMPDIR/!g;
 512                         s!\Q$PWD\E\b!\$PWD!g;
 513                 }
 514         }
 515         ok(lei(@_), "lei @msg". ($msg ? " ($$msg)" : '')) or
 516                 diag "\$?=$? err=$lei_err";
 517 }
 518
 519 sub json_utf8 () {
 520         state $x = ref(PublicInbox::Config->json)->new->utf8->canonical;
 521 }
 522
 523 sub is_xdeeply ($$$) {
 524         my ($x, $y, $desc) = @_;
 525         my $ok = is_deeply($x, $y, $desc);
 526         diag explain([$x, '!=', $y]) if !$ok;
 527         $ok;
 528 }
 529
 530 sub test_lei {
 531 SKIP: {
 532         my ($cb) = pop @_;
 533         my $test_opt = shift // {};
 534         local $lei_cwdfh;
 535         opendir $lei_cwdfh, '.' or xbail "opendir .: $!";
 536         require_git(2.6, 1) or skip('git 2.6+ required for lei test', 2);
 537         my $mods = $test_opt->{mods} // [ 'lei' ];
 538         require_mods(@$mods, 2);
 539         require PublicInbox::Config;
 540         require File::Path;
 541         local %ENV = %ENV;
 542         delete $ENV{XDG_DATA_HOME};
 543         delete $ENV{XDG_CONFIG_HOME};
 544         $ENV{GIT_COMMITTER_EMAIL} = 'lei@example.com';
 545         $ENV{GIT_COMMITTER_NAME} = 'lei user';
 546         my (undef, $fn, $lineno) = caller(0);
 547         my $t = "$fn:$lineno";
 548         require PublicInbox::Spawn;
 549         state $lei_daemon = PublicInbox::Spawn->can('send_cmd4') ||
 550                                 eval { require Socket::MsgHdr; 1 };
 551         unless ($lei_daemon) {
 552                 skip('Inline::C unconfigured/missing '.
 553 '(mkdir -p ~/.cache/public-inbox/inline-c) OR Socket::MsgHdr missing',
 554                         1);
 555         }
 556         $lei_opt = { 1 => \$lei_out, 2 => \$lei_err };
 557         my ($daemon_pid, $for_destroy, $daemon_xrd);
 558         my $tmpdir = $test_opt->{tmpdir};
 559         File::Path::mkpath($tmpdir) if (defined $tmpdir && !-d $tmpdir);
 560         ($tmpdir, $for_destroy) = tmpdir unless $tmpdir;
 561         state $persist_xrd = $ENV{TEST_LEI_DAEMON_PERSIST_DIR};
 562         SKIP: {
 563                 $ENV{TEST_LEI_ONESHOT} and
 564                         xbail 'TEST_LEI_ONESHOT no longer supported';
 565                 my $home = "$tmpdir/lei-daemon";
 566                 mkdir($home, 0700) or BAIL_OUT "mkdir: $!";
 567                 local $ENV{HOME} = $home;
 568                 my $persist;
 569                 if ($persist_xrd && !$test_opt->{daemon_only}) {
 570                         $persist = $daemon_xrd = $persist_xrd;
 571                 } else {
 572                         $daemon_xrd = "$home/xdg_run";
 573                         mkdir($daemon_xrd, 0700) or BAIL_OUT "mkdir: $!";
 574                 }
 575                 local $ENV{XDG_RUNTIME_DIR} = $daemon_xrd;
 576                 $cb->();
 577                 if ($persist) { # remove before ~/.local gets removed
 578                         File::Path::rmtree([glob("$home/*")]);
 579                         File::Path::rmtree("$home/.config");
 580                 } else {
 581                         lei_ok(qw(daemon-pid), \"daemon-pid after $t");
 582                         chomp($daemon_pid = $lei_out);
 583                         if (!$daemon_pid) {
 584                                 fail("daemon not running after $t");
 585                                 skip 'daemon died unexpectedly', 2;
 586                         }
 587                         ok(kill(0, $daemon_pid), "daemon running after $t");
 588                         lei_ok(qw(daemon-kill), \"daemon-kill after $t");
 589                 }
 590         }; # SKIP for lei_daemon
 591         if ($daemon_pid) {
 592                 for (0..10) {
 593                         kill(0, $daemon_pid) or last;
 594                         tick;
 595                 }
 596                 ok(!kill(0, $daemon_pid), "$t daemon stopped");
 597                 my $f = "$daemon_xrd/lei/errors.log";
 598                 open my $fh, '<', $f or BAIL_OUT "$f: $!";
 599                 my @l = <$fh>;
 600                 is_xdeeply(\@l, [],
 601                         "$t daemon XDG_RUNTIME_DIR/lei/errors.log empty");
 602         }
 603 }; # SKIP if missing git 2.6+ || Xapian || SQLite || json
 604 } # /test_lei
 605
 606 # returns the pathname to a ~/.public-inbox/config in scalar context,
 607 # ($test_home, $pi_config_pathname) in list context
 608 sub setup_public_inboxes () {
 609         my $test_home = "t/home2";
 610         my $pi_config = "$test_home/.public-inbox/config";
 611         my $stamp = "$test_home/setup-stamp";
 612         my @ret = ($test_home, $pi_config);
 613         return @ret if -f $stamp;
 614
 615         require PublicInbox::Lock;
 616         my $lk = bless { lock_path => "$test_home/setup.lock" },
 617                         'PublicInbox::Lock';
 618         my $end = $lk->lock_for_scope;
 619         return @ret if -f $stamp;
 620
 621         local $ENV{PI_CONFIG} = $pi_config;
 622         for my $V (1, 2) {
 623                 run_script([qw(-init --skip-docdata), "-V$V",
 624                                 '--newsgroup', "t.v$V", "t$V",
 625                                 "$test_home/t$V", "http://example.com/t$V",
 626                                 "t$V\@example.com" ]) or xbail "init v$V";
 627                 unlink "$test_home/t$V/description" or xbail "unlink $!";
 628         }
 629         require PublicInbox::Config;
 630         require PublicInbox::InboxWritable;
 631         my $cfg = PublicInbox::Config->new;
 632         my $seen = 0;
 633         $cfg->each_inbox(sub {
 634                 my ($ibx) = @_;
 635                 $ibx->{-no_fsync} = 1;
 636                 my $im = PublicInbox::InboxWritable->new($ibx)->importer(0);
 637                 my $V = $ibx->version;
 638                 my @eml = (glob('t/*.eml'), 't/data/0001.patch');
 639                 for (@eml) {
 640                         next if $_ eq 't/psgi_v2-old.eml'; # dup mid
 641                         $im->add(eml_load($_)) or BAIL_OUT "v$V add $_";
 642                         $seen++;
 643                 }
 644                 $im->done;
 645         });
 646         $seen or BAIL_OUT 'no imports';
 647         open my $fh, '>', $stamp or BAIL_OUT "open $stamp: $!";
 648         @ret;
 649 }
 650
 651 sub create_inbox ($$;@) {
 652         my $ident = shift;
 653         my $cb = pop;
 654         my %opt = @_;
 655         require PublicInbox::Lock;
 656         require PublicInbox::InboxWritable;
 657         my ($base) = ($0 =~ m!\b([^/]+)\.[^\.]+\z!);
 658         my $dir = "t/data-gen/$base.$ident";
 659         my $new = !-d $dir;
 660         if ($new) {
 661                 mkdir $dir; # may race
 662                 -d $dir or BAIL_OUT "$dir could not be created: $!";
 663         }
 664         my $lk = bless { lock_path => "$dir/creat.lock" }, 'PublicInbox::Lock';
 665         $opt{inboxdir} = File::Spec->rel2abs($dir);
 666         $opt{name} //= $ident;
 667         my $scope = $lk->lock_for_scope;
 668         my $pre_cb = delete $opt{pre_cb};
 669         $pre_cb->($dir) if $pre_cb && $new;
 670         $opt{-no_fsync} = 1;
 671         my $no_gc = delete $opt{-no_gc};
 672         my $tmpdir = delete $opt{tmpdir};
 673         my $addr = $opt{address} // [];
 674         $opt{-primary_address} //= $addr->[0] // "$ident\@example.com";
 675         my $parallel = delete($opt{importer_parallel}) // 0;
 676         my $creat_opt = { nproc => delete($opt{nproc}) // 1 };
 677         my $ibx = PublicInbox::InboxWritable->new({ %opt }, $creat_opt);
 678         if (!-f "$dir/creat.stamp") {
 679                 my $im = $ibx->importer($parallel);
 680                 $cb->($im, $ibx);
 681                 $im->done if $im;
 682                 unless ($no_gc) {
 683                         my @to_gc = $ibx->version == 1 ? ($ibx->{inboxdir}) :
 684                                         glob("$ibx->{inboxdir}/git/*.git");
 685                         for my $dir (@to_gc) {
 686                                 xsys_e([ qw(git gc -q) ], { GIT_DIR => $dir });
 687                         }
 688                 }
 689                 open my $s, '>', "$dir/creat.stamp" or
 690                         BAIL_OUT "error creating $dir/creat.stamp: $!";
 691         }
 692         if ($tmpdir) {
 693                 undef $ibx;
 694                 xsys([qw(/bin/cp -Rp), $dir, $tmpdir]) == 0 or
 695                         BAIL_OUT "cp $dir $tmpdir";
 696                 $opt{inboxdir} = $tmpdir;
 697                 $ibx = PublicInbox::InboxWritable->new(\%opt);
 698         }
 699         $ibx;
 700 }
 701
 702 sub test_httpd ($$;$) {
 703         my ($env, $client, $skip) = @_;
 704         for (qw(PI_CONFIG TMPDIR)) {
 705                 $env->{$_} or BAIL_OUT "$_ unset";
 706         }
 707         SKIP: {
 708                 require_mods(qw(Plack::Test::ExternalServer), $skip // 1);
 709                 my $sock = tcp_server() or die;
 710                 my ($out, $err) = map { "$env->{TMPDIR}/std$_.log" } qw(out err);
 711                 my $cmd = [ qw(-httpd -W0), "--stdout=$out", "--stderr=$err" ];
 712                 my $td = start_script($cmd, $env, { 3 => $sock });
 713                 my ($h, $p) = tcp_host_port($sock);
 714                 local $ENV{PLACK_TEST_EXTERNALSERVER_URI} = "http://$h:$p";
 715                 Plack::Test::ExternalServer::test_psgi(client => $client);
 716                 $td->join('TERM');
 717                 open my $fh, '<', $err or BAIL_OUT $!;
 718                 my $e = do { local $/; <$fh> };
 719                 if ($e =~ s/^Plack::Middleware::ReverseProxy missing,\n//gms) {
 720                         $e =~ s/^URL generation for redirects .*\n//gms;
 721                 }
 722                 is($e, '', 'no errors');
 723         }
 724 };
 725
 726
 727 package PublicInboxTestProcess;
 728 use strict;
 729
 730 # prevent new threads from inheriting these objects
 731 sub CLONE_SKIP { 1 }
 732
 733 sub new {
 734         my ($klass, $pid, $tail_pid) = @_;
 735         bless { pid => $pid, tail_pid => $tail_pid, owner => $$ }, $klass;
 736 }
 737
 738 sub kill {
 739         my ($self, $sig) = @_;
 740         CORE::kill($sig // 'TERM', $self->{pid});
 741 }
 742
 743 sub join {
 744         my ($self, $sig) = @_;
 745         my $pid = delete $self->{pid} or return;
 746         CORE::kill($sig, $pid) if defined $sig;
 747         my $ret = waitpid($pid, 0) // die "waitpid($pid): $!";
 748         $ret == $pid or die "waitpid($pid) != $ret";
 749 }
 750
 751 sub DESTROY {
 752         my ($self) = @_;
 753         return if $self->{owner} != $$;
 754         if (my $tail_pid = delete $self->{tail_pid}) {
 755                 PublicInbox::TestCommon::wait_for_tail($tail_pid, -1);
 756                 CORE::kill('TERM', $tail_pid);
 757         }
 758         $self->join('TERM');
 759 }
 760
 761 package PublicInbox::TestCommon::InboxWakeup;
 762 use strict;
 763 sub on_inbox_unlock { ${$_[0]}->($_[1]) }
 764
 765 1;