lib/PublicInbox/TestCommon.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # internal APIs used only for tests
   5 package PublicInbox::TestCommon;
   6 use strict;
   7 use parent qw(Exporter);
   8 use v5.10.1;
   9 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD :seek);
  10 use POSIX qw(dup2);
  11 use IO::Socket::INET;
  12 use File::Spec;
  13 our @EXPORT;
  14 my $lei_loud = $ENV{TEST_LEI_ERR_LOUD};
  15 our ($lei_opt, $lei_out, $lei_err, $lei_cwdfh);
  16 BEGIN {
  17         @EXPORT = qw(tmpdir tcp_server tcp_connect require_git require_mods
  18                 run_script start_script key2sub xsys xsys_e xqx eml_load tick
  19                 have_xapian_compact json_utf8 setup_public_inboxes create_inbox
  20                 tcp_host_port test_lei lei lei_ok $lei_out $lei_err $lei_opt
  21                 test_httpd xbail require_cmd is_xdeeply);
  22         require Test::More;
  23         my @methods = grep(!/\W/, @Test::More::EXPORT);
  24         eval(join('', map { "*$_=\\&Test::More::$_;" } @methods));
  25         die $@ if $@;
  26         push @EXPORT, @methods;
  27 }
  28
  29 sub xbail (@) { BAIL_OUT join(' ', map { ref() ? (explain($_)) : ($_) } @_) }
  30
  31 sub eml_load ($) {
  32         my ($path, $cb) = @_;
  33         open(my $fh, '<', $path) or die "open $path: $!";
  34         require PublicInbox::Eml;
  35         PublicInbox::Eml->new(\(do { local $/; <$fh> }));
  36 }
  37
  38 sub tmpdir (;$) {
  39         my ($base) = @_;
  40         require File::Temp;
  41         unless (defined $base) {
  42                 ($base) = ($0 =~ m!\b([^/]+)\.[^\.]+\z!);
  43         }
  44         my $tmpdir = File::Temp->newdir("pi-$base-$$-XXXX", TMPDIR => 1);
  45         ($tmpdir->dirname, $tmpdir);
  46 }
  47
  48 sub tcp_server () {
  49         my %opt = (
  50                 ReuseAddr => 1,
  51                 Proto => 'tcp',
  52                 Type => Socket::SOCK_STREAM(),
  53                 Listen => 1024,
  54                 Blocking => 0,
  55         );
  56         eval {
  57                 die 'IPv4-only' if $ENV{TEST_IPV4_ONLY};
  58                 require IO::Socket::INET6;
  59                 IO::Socket::INET6->new(%opt, LocalAddr => '[::1]')
  60         } || eval {
  61                 die 'IPv6-only' if $ENV{TEST_IPV6_ONLY};
  62                 IO::Socket::INET->new(%opt, LocalAddr => '127.0.0.1')
  63         } || BAIL_OUT "failed to create TCP server: $! ($@)";
  64 }
  65
  66 sub tcp_host_port ($) {
  67         my ($s) = @_;
  68         my ($h, $p) = ($s->sockhost, $s->sockport);
  69         my $ipv4 = $s->sockdomain == Socket::AF_INET();
  70         if (wantarray) {
  71                 $ipv4 ? ($h, $p) : ("[$h]", $p);
  72         } else {
  73                 $ipv4 ? "$h:$p" : "[$h]:$p";
  74         }
  75 }
  76
  77 sub tcp_connect {
  78         my ($dest, %opt) = @_;
  79         my $addr = tcp_host_port($dest);
  80         my $s = ref($dest)->new(
  81                 Proto => 'tcp',
  82                 Type => Socket::SOCK_STREAM(),
  83                 PeerAddr => $addr,
  84                 %opt,
  85         ) or BAIL_OUT "failed to connect to $addr: $!";
  86         $s->autoflush(1);
  87         $s;
  88 }
  89
  90 sub require_cmd ($;$) {
  91         my ($cmd, $maybe) = @_;
  92         require PublicInbox::Spawn;
  93         my $bin = PublicInbox::Spawn::which($cmd);
  94         return $bin if $bin;
  95         $maybe ? 0 : plan(skip_all => "$cmd missing from PATH for $0");
  96 }
  97
  98 sub have_xapian_compact () {
  99         require_cmd($ENV{XAPIAN_COMPACT} || 'xapian-compact', 1);
 100 }
 101
 102 sub require_git ($;$) {
 103         my ($req, $maybe) = @_;
 104         my ($req_maj, $req_min, $req_sub) = split(/\./, $req);
 105         my ($cur_maj, $cur_min, $cur_sub) = (xqx([qw(git --version)])
 106                         =~ /version (\d+)\.(\d+)(?:\.(\d+))?/);
 107
 108         my $req_int = ($req_maj << 24) | ($req_min << 16) | ($req_sub // 0);
 109         my $cur_int = ($cur_maj << 24) | ($cur_min << 16) | ($cur_sub // 0);
 110         if ($cur_int < $req_int) {
 111                 return 0 if $maybe;
 112                 plan skip_all =>
 113                         "git $req+ required, have $cur_maj.$cur_min.$cur_sub";
 114         }
 115         1;
 116 }
 117
 118 sub require_mods {
 119         my @mods = @_;
 120         my $maybe = pop @mods if $mods[-1] =~ /\A[0-9]+\z/;
 121         my @need;
 122         while (my $mod = shift(@mods)) {
 123                 if ($mod eq 'lei') {
 124                         require_git(2.6, $maybe ? $maybe : ());
 125                         push @mods, qw(DBD::SQLite Search::Xapian);
 126                         $mod = 'json'; # fall-through
 127                 }
 128                 if ($mod eq 'json') {
 129                         $mod = 'Cpanel::JSON::XS||JSON::MaybeXS||JSON||JSON::PP'
 130                 } elsif ($mod eq '-httpd') {
 131                         push @mods, qw(Plack::Builder Plack::Util);
 132                         next;
 133                 } elsif ($mod eq '-imapd') {
 134                         push @mods, qw(Parse::RecDescent DBD::SQLite
 135                                         Email::Address::XS||Mail::Address);
 136                         next;
 137                 } elsif ($mod eq '-nntpd') {
 138                         push @mods, qw(DBD::SQLite);
 139                         next;
 140                 }
 141                 if ($mod eq 'Search::Xapian') {
 142                         if (eval { require PublicInbox::Search } &&
 143                                 PublicInbox::Search::load_xapian()) {
 144                                 next;
 145                         }
 146                 } elsif (index($mod, '||') >= 0) { # "Foo||Bar"
 147                         my $ok;
 148                         for my $m (split(/\Q||\E/, $mod)) {
 149                                 eval "require $m";
 150                                 next if $@;
 151                                 $ok = $m;
 152                                 last;
 153                         }
 154                         next if $ok;
 155                 } else {
 156                         eval "require $mod";
 157                 }
 158                 if ($@) {
 159                         diag "require $mod: $@" if $mod =~ /Gcf2/;
 160                         push @need, $mod;
 161                 } elsif ($mod eq 'IO::Socket::SSL' &&
 162                         # old versions of IO::Socket::SSL aren't supported
 163                         # by libnet, at least:
 164                         # https://rt.cpan.org/Ticket/Display.html?id=100529
 165                                 !eval{ IO::Socket::SSL->VERSION(2.007); 1 }) {
 166                         push @need, $@;
 167                 }
 168         }
 169         return unless @need;
 170         my $m = join(', ', @need)." missing for $0";
 171         skip($m, $maybe) if $maybe;
 172         plan(skip_all => $m)
 173 }
 174
 175 sub key2script ($) {
 176         my ($key) = @_;
 177         return $key if ($key eq 'git' || index($key, '/') >= 0);
 178         # n.b. we may have scripts which don't start with "public-inbox" in
 179         # the future:
 180         $key =~ s/\A([-\.])/public-inbox$1/;
 181         'blib/script/'.$key;
 182 }
 183
 184 my @io_mode = ([ *STDIN{IO}, '+<&' ], [ *STDOUT{IO}, '+>&' ],
 185                 [ *STDERR{IO}, '+>&' ]);
 186
 187 sub _prepare_redirects ($) {
 188         my ($fhref) = @_;
 189         my $orig_io = [];
 190         for (my $fd = 0; $fd <= $#io_mode; $fd++) {
 191                 my $fh = $fhref->[$fd] or next;
 192                 my ($oldfh, $mode) = @{$io_mode[$fd]};
 193                 open my $orig, $mode, $oldfh or die "$oldfh $mode stash: $!";
 194                 $orig_io->[$fd] = $orig;
 195                 open $oldfh, $mode, $fh or die "$oldfh $mode redirect: $!";
 196         }
 197         $orig_io;
 198 }
 199
 200 sub _undo_redirects ($) {
 201         my ($orig_io) = @_;
 202         for (my $fd = 0; $fd <= $#io_mode; $fd++) {
 203                 my $fh = $orig_io->[$fd] or next;
 204                 my ($oldfh, $mode) = @{$io_mode[$fd]};
 205                 open $oldfh, $mode, $fh or die "$$oldfh $mode redirect: $!";
 206         }
 207 }
 208
 209 # $opt->{run_mode} (or $ENV{TEST_RUN_MODE}) allows choosing between
 210 # three ways to spawn our own short-lived Perl scripts for testing:
 211 #
 212 # 0 - (fork|vfork) + execve, the most realistic but slowest
 213 # 1 - (not currently implemented)
 214 # 2 - preloading and running in current process (slightly faster than 1)
 215 #
 216 # 2 is not compatible with scripts which use "exit" (which we'll try to
 217 # avoid in the future).
 218 # The default is 2.
 219 our $run_script_exit_code;
 220 sub RUN_SCRIPT_EXIT () { "RUN_SCRIPT_EXIT\n" };
 221 sub run_script_exit {
 222         $run_script_exit_code = $_[0] // 0;
 223         die RUN_SCRIPT_EXIT;
 224 }
 225
 226 our %cached_scripts;
 227 sub key2sub ($) {
 228         my ($key) = @_;
 229         $cached_scripts{$key} //= do {
 230                 my $f = key2script($key);
 231                 open my $fh, '<', $f or die "open $f: $!";
 232                 my $str = do { local $/; <$fh> };
 233                 my $pkg = (split(m!/!, $f))[-1];
 234                 $pkg =~ s/([a-z])([a-z0-9]+)(\.t)?\z/\U$1\E$2/;
 235                 $pkg .= "_T" if $3;
 236                 $pkg =~ tr/-.//d;
 237                 $pkg = "PublicInbox::TestScript::$pkg";
 238                 eval <<EOF;
 239 package $pkg;
 240 use strict;
 241 use subs qw(exit);
 242
 243 *exit = \\&PublicInbox::TestCommon::run_script_exit;
 244 sub main {
 245 # the below "line" directive is a magic comment, see perlsyn(1) manpage
 246 # line 1 "$f"
 247 $str
 248         0;
 249 }
 250 1;
 251 EOF
 252                 $pkg->can('main');
 253         }
 254 }
 255
 256 sub _run_sub ($$$) {
 257         my ($sub, $key, $argv) = @_;
 258         local @ARGV = @$argv;
 259         $run_script_exit_code = undef;
 260         my $exit_code = eval { $sub->(@$argv) };
 261         if ($@ eq RUN_SCRIPT_EXIT) {
 262                 $@ = '';
 263                 $exit_code = $run_script_exit_code;
 264                 $? = ($exit_code << 8);
 265         } elsif (defined($exit_code)) {
 266                 $? = ($exit_code << 8);
 267         } elsif ($@) { # mimic die() behavior when uncaught
 268                 warn "E: eval-ed $key: $@\n";
 269                 $? = ($! << 8) if $!;
 270                 $? = (255 << 8) if $? == 0;
 271         } else {
 272                 die "BUG: eval-ed $key: no exit code or \$@\n";
 273         }
 274 }
 275
 276 sub run_script ($;$$) {
 277         my ($cmd, $env, $opt) = @_;
 278         my ($key, @argv) = @$cmd;
 279         my $run_mode = $ENV{TEST_RUN_MODE} // $opt->{run_mode} // 1;
 280         my $sub = $run_mode == 0 ? undef : key2sub($key);
 281         my $fhref = [];
 282         my $spawn_opt = {};
 283         for my $fd (0..2) {
 284                 my $redir = $opt->{$fd};
 285                 my $ref = ref($redir);
 286                 if ($ref eq 'SCALAR') {
 287                         open my $fh, '+>', undef or die "open: $!";
 288                         $fhref->[$fd] = $fh;
 289                         $spawn_opt->{$fd} = $fh;
 290                         next if $fd > 0;
 291                         $fh->autoflush(1);
 292                         print $fh $$redir or die "print: $!";
 293                         seek($fh, 0, SEEK_SET) or die "seek: $!";
 294                 } elsif ($ref eq 'GLOB') {
 295                         $spawn_opt->{$fd} = $fhref->[$fd] = $redir;
 296                 } elsif ($ref) {
 297                         die "unable to deal with $ref $redir";
 298                 }
 299         }
 300         if ($key =~ /-(index|convert|extindex|convert|xcpdb)\z/) {
 301                 unshift @argv, '--no-fsync';
 302         }
 303         if ($run_mode == 0) {
 304                 # spawn an independent new process, like real-world use cases:
 305                 require PublicInbox::Spawn;
 306                 my $cmd = [ key2script($key), @argv ];
 307                 if (my $d = $opt->{'-C'}) {
 308                         $cmd->[0] = File::Spec->rel2abs($cmd->[0]);
 309                         $spawn_opt->{'-C'} = $d;
 310                 }
 311                 my $pid = PublicInbox::Spawn::spawn($cmd, $env, $spawn_opt);
 312                 if (defined $pid) {
 313                         my $r = waitpid($pid, 0) // die "waitpid: $!";
 314                         $r == $pid or die "waitpid: expected $pid, got $r";
 315                 }
 316         } else { # localize and run everything in the same process:
 317                 # note: "local *STDIN = *STDIN;" and so forth did not work in
 318                 # old versions of perl
 319                 my $umask = umask;
 320                 local %ENV = $env ? (%ENV, %$env) : %ENV;
 321                 local @SIG{keys %SIG} = map { undef } values %SIG;
 322                 local $SIG{FPE} = 'IGNORE'; # Perl default
 323                 local $0 = join(' ', @$cmd);
 324                 my $orig_io = _prepare_redirects($fhref);
 325                 my $cwdfh = $lei_cwdfh;
 326                 if (my $d = $opt->{'-C'}) {
 327                         unless ($cwdfh) {
 328                                 opendir $cwdfh, '.' or die "opendir .: $!";
 329                         }
 330                         chdir $d or die "chdir $d: $!";
 331                 }
 332                 _run_sub($sub, $key, \@argv);
 333                 eval { PublicInbox::Inbox::cleanup_task() };
 334                 die "fchdir(restore): $!" if $cwdfh && !chdir($cwdfh);
 335                 _undo_redirects($orig_io);
 336                 select STDOUT;
 337                 umask($umask);
 338         }
 339
 340         # slurp the redirects back into user-supplied strings
 341         for my $fd (1..2) {
 342                 my $fh = $fhref->[$fd] or next;
 343                 next unless -f $fh;
 344                 seek($fh, 0, SEEK_SET) or die "seek: $!";
 345                 my $redir = $opt->{$fd};
 346                 local $/;
 347                 $$redir = <$fh>;
 348         }
 349         $? == 0;
 350 }
 351
 352 sub tick (;$) {
 353         my $tick = shift // 0.1;
 354         select undef, undef, undef, $tick;
 355         1;
 356 }
 357
 358 sub wait_for_tail ($;$) {
 359         my ($tail_pid, $want) = @_;
 360         my $wait = 2;
 361         if ($^O eq 'linux') { # GNU tail may use inotify
 362                 state $tail_has_inotify;
 363                 return tick if $want < 0 && $tail_has_inotify;
 364                 my $end = time + $wait;
 365                 my @ino;
 366                 do {
 367                         @ino = grep {
 368                                 readlink($_) =~ /\binotify\b/
 369                         } glob("/proc/$tail_pid/fd/*");
 370                 } while (!@ino && time <= $end and tick);
 371                 return if !@ino;
 372                 $tail_has_inotify = 1;
 373                 $ino[0] =~ s!/fd/!/fdinfo/!;
 374                 my @info;
 375                 do {
 376                         if (open my $fh, '<', $ino[0]) {
 377                                 local $/ = "\n";
 378                                 @info = grep(/^inotify wd:/, <$fh>);
 379                         }
 380                 } while (scalar(@info) < $want && time <= $end and tick);
 381         } else {
 382                 sleep($wait);
 383         }
 384 }
 385
 386 # like system() built-in, but uses spawn() for env/rdr + vfork
 387 sub xsys {
 388         my ($cmd, $env, $rdr) = @_;
 389         if (ref($cmd)) {
 390                 $rdr ||= {};
 391         } else {
 392                 $cmd = [ @_ ];
 393                 $env = undef;
 394                 $rdr = {};
 395         }
 396         run_script($cmd, $env, { %$rdr, run_mode => 0 });
 397         $? >> 8
 398 }
 399
 400 sub xsys_e { # like "/bin/sh -e"
 401         xsys(@_) == 0 or
 402                 BAIL_OUT (ref $_[0] ? "@{$_[0]}" : "@_"). " failed \$?=$?"
 403 }
 404
 405 # like `backtick` or qx{} op, but uses spawn() for env/rdr + vfork
 406 sub xqx {
 407         my ($cmd, $env, $rdr) = @_;
 408         $rdr //= {};
 409         run_script($cmd, $env, { %$rdr, run_mode => 0, 1 => \(my $out) });
 410         wantarray ? split(/^/m, $out) : $out;
 411 }
 412
 413 sub start_script {
 414         my ($cmd, $env, $opt) = @_;
 415         my ($key, @argv) = @$cmd;
 416         my $run_mode = $ENV{TEST_RUN_MODE} // $opt->{run_mode} // 2;
 417         my $sub = $run_mode == 0 ? undef : key2sub($key);
 418         my $tail_pid;
 419         if (my $tail_cmd = $ENV{TAIL}) {
 420                 my @paths;
 421                 for (@argv) {
 422                         next unless /\A--std(?:err|out)=(.+)\z/;
 423                         push @paths, $1;
 424                 }
 425                 if ($opt) {
 426                         for (1, 2) {
 427                                 my $f = $opt->{$_} or next;
 428                                 if (!ref($f)) {
 429                                         push @paths, $f;
 430                                 } elsif (ref($f) eq 'GLOB' && $^O eq 'linux') {
 431                                         my $fd = fileno($f);
 432                                         my $f = readlink "/proc/$$/fd/$fd";
 433                                         push @paths, $f if -e $f;
 434                                 }
 435                         }
 436                 }
 437                 if (@paths) {
 438                         $tail_pid = fork // die "fork: $!";
 439                         if ($tail_pid == 0) {
 440                                 # make sure files exist, first
 441                                 open my $fh, '>>', $_ for @paths;
 442                                 open(STDOUT, '>&STDERR') or die "1>&2: $!";
 443                                 exec(split(' ', $tail_cmd), @paths);
 444                                 die "$tail_cmd failed: $!";
 445                         }
 446                         wait_for_tail($tail_pid, scalar @paths);
 447                 }
 448         }
 449         my $pid = fork // die "fork: $!\n";
 450         if ($pid == 0) {
 451                 eval { PublicInbox::DS->Reset };
 452                 # pretend to be systemd (cf. sd_listen_fds(3))
 453                 # 3 == SD_LISTEN_FDS_START
 454                 my $fd;
 455                 for ($fd = 0; 1; $fd++) {
 456                         my $s = $opt->{$fd};
 457                         last if $fd >= 3 && !defined($s);
 458                         next unless $s;
 459                         my $fl = fcntl($s, F_GETFD, 0);
 460                         if (($fl & FD_CLOEXEC) != FD_CLOEXEC) {
 461                                 warn "got FD:".fileno($s)." w/o CLOEXEC\n";
 462                         }
 463                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 464                         dup2(fileno($s), $fd) or die "dup2 failed: $!\n";
 465                 }
 466                 %ENV = (%ENV, %$env) if $env;
 467                 my $fds = $fd - 3;
 468                 if ($fds > 0) {
 469                         $ENV{LISTEN_PID} = $$;
 470                         $ENV{LISTEN_FDS} = $fds;
 471                 }
 472                 $0 = join(' ', @$cmd);
 473                 if ($sub) {
 474                         eval { PublicInbox::DS->Reset };
 475                         _run_sub($sub, $key, \@argv);
 476                         POSIX::_exit($? >> 8);
 477                 } else {
 478                         exec(key2script($key), @argv);
 479                         die "FAIL: ",join(' ', $key, @argv), ": $!\n";
 480                 }
 481         }
 482         PublicInboxTestProcess->new($pid, $tail_pid);
 483 }
 484
 485 # favor lei() or lei_ok() over $lei for new code
 486 sub lei (@) {
 487         my ($cmd, $env, $xopt) = @_;
 488         $lei_out = $lei_err = '';
 489         if (!ref($cmd)) {
 490                 ($env, $xopt) = grep { (!defined) || ref } @_;
 491                 $cmd = [ grep { defined && !ref } @_ ];
 492         }
 493         my $res = run_script(['lei', @$cmd], $env, $xopt // $lei_opt);
 494         if ($lei_err ne '') {
 495                 if ($lei_err =~ /Use of uninitialized/ ||
 496                         $lei_err =~ m!\bArgument .*? isn't numeric in !) {
 497                         fail "lei_err=$lei_err";
 498                 } else {
 499                         diag "lei_err=$lei_err" if $lei_loud;
 500                 }
 501         }
 502         $res;
 503 };
 504
 505 sub lei_ok (@) {
 506         state $PWD = $ENV{PWD} // Cwd::getcwd();
 507         my $msg = ref($_[-1]) eq 'SCALAR' ? pop(@_) : undef;
 508         my $tmpdir = quotemeta(File::Spec->tmpdir);
 509         # filter out anything that looks like a path name for consistent logs
 510         my @msg = ref($_[0]) eq 'ARRAY' ? @{$_[0]} : @_;
 511         if (!$lei_loud) {
 512                 for (@msg) {
 513                         s!\A([a-z0-9]+://)[^/]+/!$1\$HOST_PORT/!;
 514                         s!$tmpdir\b/(?:[^/]+/)?!\$TMPDIR/!g;
 515                         s!\Q$PWD\E\b!\$PWD!g;
 516                 }
 517         }
 518         ok(lei(@_), "lei @msg". ($msg ? " ($$msg)" : '')) or
 519                 diag "\$?=$? err=$lei_err";
 520 }
 521
 522 sub json_utf8 () {
 523         state $x = ref(PublicInbox::Config->json)->new->utf8->canonical;
 524 }
 525
 526 sub is_xdeeply ($$$) {
 527         my ($x, $y, $desc) = @_;
 528         my $ok = is_deeply($x, $y, $desc);
 529         diag explain([$x, '!=', $y]) if !$ok;
 530         $ok;
 531 }
 532
 533 sub test_lei {
 534 SKIP: {
 535         my ($cb) = pop @_;
 536         my $test_opt = shift // {};
 537         local $lei_cwdfh;
 538         opendir $lei_cwdfh, '.' or xbail "opendir .: $!";
 539         require_git(2.6, 1) or skip('git 2.6+ required for lei test', 2);
 540         my $mods = $test_opt->{mods} // [ 'lei' ];
 541         require_mods(@$mods, 2);
 542         require PublicInbox::Config;
 543         require File::Path;
 544         local %ENV = %ENV;
 545         delete $ENV{XDG_DATA_HOME};
 546         delete $ENV{XDG_CONFIG_HOME};
 547         $ENV{GIT_COMMITTER_EMAIL} = 'lei@example.com';
 548         $ENV{GIT_COMMITTER_NAME} = 'lei user';
 549         my (undef, $fn, $lineno) = caller(0);
 550         my $t = "$fn:$lineno";
 551         require PublicInbox::Spawn;
 552         state $lei_daemon = PublicInbox::Spawn->can('send_cmd4') ||
 553                                 eval { require Socket::MsgHdr; 1 };
 554         unless ($lei_daemon) {
 555                 skip('Inline::C unconfigured/missing '.
 556 '(mkdir -p ~/.cache/public-inbox/inline-c) OR Socket::MsgHdr missing',
 557                         1);
 558         }
 559         $lei_opt = { 1 => \$lei_out, 2 => \$lei_err };
 560         my ($daemon_pid, $for_destroy, $daemon_xrd);
 561         my $tmpdir = $test_opt->{tmpdir};
 562         File::Path::mkpath($tmpdir) if (defined $tmpdir && !-d $tmpdir);
 563         ($tmpdir, $for_destroy) = tmpdir unless $tmpdir;
 564         state $persist_xrd = $ENV{TEST_LEI_DAEMON_PERSIST_DIR};
 565         SKIP: {
 566                 $ENV{TEST_LEI_ONESHOT} and
 567                         xbail 'TEST_LEI_ONESHOT no longer supported';
 568                 my $home = "$tmpdir/lei-daemon";
 569                 mkdir($home, 0700) or BAIL_OUT "mkdir: $!";
 570                 local $ENV{HOME} = $home;
 571                 my $persist;
 572                 if ($persist_xrd && !$test_opt->{daemon_only}) {
 573                         $persist = $daemon_xrd = $persist_xrd;
 574                 } else {
 575                         $daemon_xrd = "$home/xdg_run";
 576                         mkdir($daemon_xrd, 0700) or BAIL_OUT "mkdir: $!";
 577                 }
 578                 local $ENV{XDG_RUNTIME_DIR} = $daemon_xrd;
 579                 $cb->();
 580                 if ($persist) { # remove before ~/.local gets removed
 581                         File::Path::rmtree([glob("$home/*")]);
 582                         File::Path::rmtree("$home/.config");
 583                 } else {
 584                         lei_ok(qw(daemon-pid), \"daemon-pid after $t");
 585                         chomp($daemon_pid = $lei_out);
 586                         if (!$daemon_pid) {
 587                                 fail("daemon not running after $t");
 588                                 skip 'daemon died unexpectedly', 2;
 589                         }
 590                         ok(kill(0, $daemon_pid), "daemon running after $t");
 591                         lei_ok(qw(daemon-kill), \"daemon-kill after $t");
 592                 }
 593         }; # SKIP for lei_daemon
 594         if ($daemon_pid) {
 595                 for (0..10) {
 596                         kill(0, $daemon_pid) or last;
 597                         tick;
 598                 }
 599                 ok(!kill(0, $daemon_pid), "$t daemon stopped");
 600                 my $f = "$daemon_xrd/lei/errors.log";
 601                 open my $fh, '<', $f or BAIL_OUT "$f: $!";
 602                 my @l = <$fh>;
 603                 is_xdeeply(\@l, [],
 604                         "$t daemon XDG_RUNTIME_DIR/lei/errors.log empty");
 605         }
 606 }; # SKIP if missing git 2.6+ || Xapian || SQLite || json
 607 } # /test_lei
 608
 609 # returns the pathname to a ~/.public-inbox/config in scalar context,
 610 # ($test_home, $pi_config_pathname) in list context
 611 sub setup_public_inboxes () {
 612         my $test_home = "t/home2";
 613         my $pi_config = "$test_home/.public-inbox/config";
 614         my $stamp = "$test_home/setup-stamp";
 615         my @ret = ($test_home, $pi_config);
 616         return @ret if -f $stamp;
 617
 618         require PublicInbox::Lock;
 619         my $lk = bless { lock_path => "$test_home/setup.lock" },
 620                         'PublicInbox::Lock';
 621         my $end = $lk->lock_for_scope;
 622         return @ret if -f $stamp;
 623
 624         local $ENV{PI_CONFIG} = $pi_config;
 625         for my $V (1, 2) {
 626                 run_script([qw(-init --skip-docdata), "-V$V",
 627                                 '--newsgroup', "t.v$V", "t$V",
 628                                 "$test_home/t$V", "http://example.com/t$V",
 629                                 "t$V\@example.com" ]) or xbail "init v$V";
 630                 unlink "$test_home/t$V/description" or xbail "unlink $!";
 631         }
 632         require PublicInbox::Config;
 633         require PublicInbox::InboxWritable;
 634         my $cfg = PublicInbox::Config->new;
 635         my $seen = 0;
 636         $cfg->each_inbox(sub {
 637                 my ($ibx) = @_;
 638                 $ibx->{-no_fsync} = 1;
 639                 my $im = PublicInbox::InboxWritable->new($ibx)->importer(0);
 640                 my $V = $ibx->version;
 641                 my @eml = (glob('t/*.eml'), 't/data/0001.patch');
 642                 for (@eml) {
 643                         next if $_ eq 't/psgi_v2-old.eml'; # dup mid
 644                         $im->add(eml_load($_)) or BAIL_OUT "v$V add $_";
 645                         $seen++;
 646                 }
 647                 $im->done;
 648         });
 649         $seen or BAIL_OUT 'no imports';
 650         open my $fh, '>', $stamp or BAIL_OUT "open $stamp: $!";
 651         @ret;
 652 }
 653
 654 sub create_inbox ($$;@) {
 655         my $ident = shift;
 656         my $cb = pop;
 657         my %opt = @_;
 658         require PublicInbox::Lock;
 659         require PublicInbox::InboxWritable;
 660         my ($base) = ($0 =~ m!\b([^/]+)\.[^\.]+\z!);
 661         my $dir = "t/data-gen/$base.$ident";
 662         my $new = !-d $dir;
 663         if ($new) {
 664                 mkdir $dir; # may race
 665                 -d $dir or BAIL_OUT "$dir could not be created: $!";
 666         }
 667         my $lk = bless { lock_path => "$dir/creat.lock" }, 'PublicInbox::Lock';
 668         $opt{inboxdir} = File::Spec->rel2abs($dir);
 669         $opt{name} //= $ident;
 670         my $scope = $lk->lock_for_scope;
 671         my $pre_cb = delete $opt{pre_cb};
 672         $pre_cb->($dir) if $pre_cb && $new;
 673         $opt{-no_fsync} = 1;
 674         my $no_gc = delete $opt{-no_gc};
 675         my $tmpdir = delete $opt{tmpdir};
 676         my $addr = $opt{address} // [];
 677         $opt{-primary_address} //= $addr->[0] // "$ident\@example.com";
 678         my $parallel = delete($opt{importer_parallel}) // 0;
 679         my $creat_opt = { nproc => delete($opt{nproc}) // 1 };
 680         my $ibx = PublicInbox::InboxWritable->new({ %opt }, $creat_opt);
 681         if (!-f "$dir/creat.stamp") {
 682                 my $im = $ibx->importer($parallel);
 683                 $cb->($im, $ibx);
 684                 $im->done if $im;
 685                 unless ($no_gc) {
 686                         my @to_gc = $ibx->version == 1 ? ($ibx->{inboxdir}) :
 687                                         glob("$ibx->{inboxdir}/git/*.git");
 688                         for my $dir (@to_gc) {
 689                                 xsys_e([ qw(git gc -q) ], { GIT_DIR => $dir });
 690                         }
 691                 }
 692                 open my $s, '>', "$dir/creat.stamp" or
 693                         BAIL_OUT "error creating $dir/creat.stamp: $!";
 694         }
 695         if ($tmpdir) {
 696                 undef $ibx;
 697                 xsys([qw(/bin/cp -Rp), $dir, $tmpdir]) == 0 or
 698                         BAIL_OUT "cp $dir $tmpdir";
 699                 $opt{inboxdir} = $tmpdir;
 700                 $ibx = PublicInbox::InboxWritable->new(\%opt);
 701         }
 702         $ibx;
 703 }
 704
 705 sub test_httpd ($$;$) {
 706         my ($env, $client, $skip) = @_;
 707         for (qw(PI_CONFIG TMPDIR)) {
 708                 $env->{$_} or BAIL_OUT "$_ unset";
 709         }
 710         SKIP: {
 711                 require_mods(qw(Plack::Test::ExternalServer), $skip // 1);
 712                 my $sock = tcp_server() or die;
 713                 my ($out, $err) = map { "$env->{TMPDIR}/std$_.log" } qw(out err);
 714                 my $cmd = [ qw(-httpd -W0), "--stdout=$out", "--stderr=$err" ];
 715                 my $td = start_script($cmd, $env, { 3 => $sock });
 716                 my ($h, $p) = tcp_host_port($sock);
 717                 local $ENV{PLACK_TEST_EXTERNALSERVER_URI} = "http://$h:$p";
 718                 Plack::Test::ExternalServer::test_psgi(client => $client);
 719                 $td->join('TERM');
 720                 open my $fh, '<', $err or BAIL_OUT $!;
 721                 my $e = do { local $/; <$fh> };
 722                 if ($e =~ s/^Plack::Middleware::ReverseProxy missing,\n//gms) {
 723                         $e =~ s/^URL generation for redirects .*\n//gms;
 724                 }
 725                 is($e, '', 'no errors');
 726         }
 727 };
 728
 729
 730 package PublicInboxTestProcess;
 731 use strict;
 732
 733 # prevent new threads from inheriting these objects
 734 sub CLONE_SKIP { 1 }
 735
 736 sub new {
 737         my ($klass, $pid, $tail_pid) = @_;
 738         bless { pid => $pid, tail_pid => $tail_pid, owner => $$ }, $klass;
 739 }
 740
 741 sub kill {
 742         my ($self, $sig) = @_;
 743         CORE::kill($sig // 'TERM', $self->{pid});
 744 }
 745
 746 sub join {
 747         my ($self, $sig) = @_;
 748         my $pid = delete $self->{pid} or return;
 749         CORE::kill($sig, $pid) if defined $sig;
 750         my $ret = waitpid($pid, 0) // die "waitpid($pid): $!";
 751         $ret == $pid or die "waitpid($pid) != $ret";
 752 }
 753
 754 sub DESTROY {
 755         my ($self) = @_;
 756         return if $self->{owner} != $$;
 757         if (my $tail_pid = delete $self->{tail_pid}) {
 758                 PublicInbox::TestCommon::wait_for_tail($tail_pid, -1);
 759                 CORE::kill('TERM', $tail_pid);
 760         }
 761         $self->join('TERM');
 762 }
 763
 764 package PublicInbox::TestCommon::InboxWakeup;
 765 use strict;
 766 sub on_inbox_unlock { ${$_[0]}->($_[1]) }
 767
 768 1;