lib/PublicInbox/TestCommon.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # internal APIs used only for tests
   5 package PublicInbox::TestCommon;
   6 use strict;
   7 use parent qw(Exporter);
   8 use Fcntl qw(FD_CLOEXEC F_SETFD F_GETFD :seek);
   9 use POSIX qw(dup2);
  10 use IO::Socket::INET;
  11 our @EXPORT = qw(tmpdir tcp_server tcp_connect require_git require_mods
  12         run_script start_script key2sub);
  13
  14 sub tmpdir (;$) {
  15         my ($base) = @_;
  16         require File::Temp;
  17         unless (defined $base) {
  18                 ($base) = ($0 =~ m!\b([^/]+)\.[^\.]+\z!);
  19         }
  20         my $tmpdir = File::Temp->newdir("pi-$base-$$-XXXXXX", TMPDIR => 1);
  21         ($tmpdir->dirname, $tmpdir);
  22 }
  23
  24 sub tcp_server () {
  25         IO::Socket::INET->new(
  26                 LocalAddr => '127.0.0.1',
  27                 ReuseAddr => 1,
  28                 Proto => 'tcp',
  29                 Type => Socket::SOCK_STREAM(),
  30                 Listen => 1024,
  31                 Blocking => 0,
  32         )
  33 }
  34
  35 sub tcp_connect {
  36         my ($dest, %opt) = @_;
  37         my $s = IO::Socket::INET->new(
  38                 Proto => 'tcp',
  39                 Type => Socket::SOCK_STREAM(),
  40                 PeerAddr => $dest->sockhost . ':' . $dest->sockport,
  41                 %opt,
  42         );
  43         $s->autoflush(1);
  44         $s;
  45 }
  46
  47 sub require_git ($;$) {
  48         my ($req, $maybe) = @_;
  49         my ($req_maj, $req_min) = split(/\./, $req);
  50         my ($cur_maj, $cur_min) = (`git --version` =~ /version (\d+)\.(\d+)/);
  51
  52         my $req_int = ($req_maj << 24) | ($req_min << 16);
  53         my $cur_int = ($cur_maj << 24) | ($cur_min << 16);
  54         if ($cur_int < $req_int) {
  55                 return 0 if $maybe;
  56                 Test::More::plan(skip_all =>
  57                                 "git $req+ required, have $cur_maj.$cur_min");
  58         }
  59         1;
  60 }
  61
  62 sub require_mods {
  63         my @mods = @_;
  64         my $maybe = pop @mods if $mods[-1] =~ /\A[0-9]+\z/;
  65         my @need;
  66         for my $mod (@mods) {
  67                 if ($mod eq 'Search::Xapian') {
  68                         require PublicInbox::Search;
  69                         PublicInbox::Search::load_xapian() and next;
  70                 } elsif ($mod eq 'Search::Xapian::WritableDatabase') {
  71                         require PublicInbox::SearchIdx;
  72                         PublicInbox::SearchIdx::load_xapian_writable() and next;
  73                 } else {
  74                         eval "require $mod";
  75                 }
  76                 push @need, $mod if $@;
  77         }
  78         return unless @need;
  79         my $m = join(', ', @need)." missing for $0";
  80         Test::More::skip($m, $maybe) if $maybe;
  81         Test::More::plan(skip_all => $m)
  82 }
  83
  84 sub key2script ($) {
  85         my ($key) = @_;
  86         return $key if (index($key, '/') >= 0);
  87         # n.b. we may have scripts which don't start with "public-inbox" in
  88         # the future:
  89         $key =~ s/\A([-\.])/public-inbox$1/;
  90         'blib/script/'.$key;
  91 }
  92
  93 my @io_mode = ([ *STDIN{IO}, '<&' ], [ *STDOUT{IO}, '>&' ],
  94                 [ *STDERR{IO}, '>&' ]);
  95
  96 sub _prepare_redirects ($) {
  97         my ($fhref) = @_;
  98         my $orig_io = [];
  99         for (my $fd = 0; $fd <= $#io_mode; $fd++) {
 100                 my $fh = $fhref->[$fd] or next;
 101                 my ($oldfh, $mode) = @{$io_mode[$fd]};
 102                 open my $orig, $mode, $oldfh or die "$$oldfh $mode stash: $!";
 103                 $orig_io->[$fd] = $orig;
 104                 open $oldfh, $mode, $fh or die "$$oldfh $mode redirect: $!";
 105         }
 106         $orig_io;
 107 }
 108
 109 sub _undo_redirects ($) {
 110         my ($orig_io) = @_;
 111         for (my $fd = 0; $fd <= $#io_mode; $fd++) {
 112                 my $fh = $orig_io->[$fd] or next;
 113                 my ($oldfh, $mode) = @{$io_mode[$fd]};
 114                 open $oldfh, $mode, $fh or die "$$oldfh $mode redirect: $!";
 115         }
 116 }
 117
 118 # $opt->{run_mode} (or $ENV{TEST_RUN_MODE}) allows chosing between
 119 # three ways to spawn our own short-lived Perl scripts for testing:
 120 #
 121 # 0 - (fork|vfork) + execve, the most realistic but slowest
 122 # 1 - preloading and running in a forked subprocess (fast)
 123 # 2 - preloading and running in current process (slightly faster than 1)
 124 #
 125 # 2 is not compatible with scripts which use "exit" (which we'll try to
 126 # avoid in the future).
 127 # The default is 2.
 128 our $run_script_exit_code;
 129 sub RUN_SCRIPT_EXIT () { "RUN_SCRIPT_EXIT\n" };
 130 sub run_script_exit (;$) {
 131         $run_script_exit_code = $_[0] // 0;
 132         die RUN_SCRIPT_EXIT;
 133 }
 134
 135 my %cached_scripts;
 136 sub key2sub ($) {
 137         my ($key) = @_;
 138         $cached_scripts{$key} //= do {
 139                 my $f = key2script($key);
 140                 open my $fh, '<', $f or die "open $f: $!";
 141                 my $str = do { local $/; <$fh> };
 142                 my $pkg = (split(m!/!, $f))[-1];
 143                 $pkg =~ s/([a-z])([a-z0-9]+)(\.t)?\z/\U$1\E$2/;
 144                 $pkg .= "_T" if $3;
 145                 $pkg =~ tr/-.//d;
 146                 $pkg = "PublicInbox::TestScript::$pkg";
 147                 eval <<EOF;
 148 package $pkg;
 149 use strict;
 150 use subs qw(exit);
 151
 152 *exit = *PublicInbox::TestCommon::run_script_exit;
 153 sub main {
 154 # the below "line" directive is a magic comment, see perlsyn(1) manpage
 155 # line 1 "$f"
 156 $str
 157         0;
 158 }
 159 1;
 160 EOF
 161                 $pkg->can('main');
 162         }
 163 }
 164
 165 sub _run_sub ($$$) {
 166         my ($sub, $key, $argv) = @_;
 167         local @ARGV = @$argv;
 168         $run_script_exit_code = undef;
 169         my $exit_code = eval { $sub->(@$argv) };
 170         if ($@ eq RUN_SCRIPT_EXIT) {
 171                 $@ = '';
 172                 $exit_code = $run_script_exit_code;
 173                 $? = ($exit_code << 8);
 174         } elsif (defined($exit_code)) {
 175                 $? = ($exit_code << 8);
 176         } elsif ($@) { # mimic die() behavior when uncaught
 177                 warn "E: eval-ed $key: $@\n";
 178                 $? = ($! << 8) if $!;
 179                 $? = (255 << 8) if $? == 0;
 180         } else {
 181                 die "BUG: eval-ed $key: no exit code or \$@\n";
 182         }
 183 }
 184
 185 sub run_script ($;$$) {
 186         my ($cmd, $env, $opt) = @_;
 187         my ($key, @argv) = @$cmd;
 188         my $run_mode = $ENV{TEST_RUN_MODE} // $opt->{run_mode} // 1;
 189         my $sub = $run_mode == 0 ? undef : key2sub($key);
 190         my $fhref = [];
 191         my $spawn_opt = {};
 192         for my $fd (0..2) {
 193                 my $redir = $opt->{$fd};
 194                 next unless ref($redir);
 195                 open my $fh, '+>', undef or die "open: $!";
 196                 $fhref->[$fd] = $fh;
 197                 $spawn_opt->{$fd} = $fh;
 198                 next if $fd > 0;
 199                 $fh->autoflush(1);
 200                 print $fh $$redir or die "print: $!";
 201                 seek($fh, 0, SEEK_SET) or die "seek: $!";
 202         }
 203         if ($run_mode == 0) {
 204                 # spawn an independent new process, like real-world use cases:
 205                 require PublicInbox::Spawn;
 206                 my $cmd = [ key2script($key), @argv ];
 207                 my $pid = PublicInbox::Spawn::spawn($cmd, $env, $spawn_opt);
 208                 defined($pid) or die "spawn: $!";
 209                 if (defined $pid) {
 210                         my $r = waitpid($pid, 0);
 211                         defined($r) or die "waitpid: $!";
 212                         $r == $pid or die "waitpid: expected $pid, got $r";
 213                 }
 214         } else { # localize and run everything in the same process:
 215                 # note: "local *STDIN = *STDIN;" and so forth did not work in
 216                 # old versions of perl
 217                 local %ENV = $env ? (%ENV, %$env) : %ENV;
 218                 local %SIG = %SIG;
 219                 local $0 = join(' ', @$cmd);
 220                 my $orig_io = _prepare_redirects($fhref);
 221                 _run_sub($sub, $key, \@argv);
 222                 _undo_redirects($orig_io);
 223         }
 224
 225         # slurp the redirects back into user-supplied strings
 226         for my $fd (1..2) {
 227                 my $fh = $fhref->[$fd] or next;
 228                 seek($fh, 0, SEEK_SET) or die "seek: $!";
 229                 my $redir = $opt->{$fd};
 230                 local $/;
 231                 $$redir = <$fh>;
 232         }
 233         $? == 0;
 234 }
 235
 236 sub wait_for_tail () { sleep(2) }
 237
 238 sub start_script {
 239         my ($cmd, $env, $opt) = @_;
 240         my ($key, @argv) = @$cmd;
 241         my $run_mode = $ENV{TEST_RUN_MODE} // $opt->{run_mode} // 1;
 242         my $sub = $run_mode == 0 ? undef : key2sub($key);
 243         my $tail_pid;
 244         if (my $tail_cmd = $ENV{TAIL}) {
 245                 my @paths;
 246                 for (@argv) {
 247                         next unless /\A--std(?:err|out)=(.+)\z/;
 248                         push @paths, $1;
 249                 }
 250                 if (@paths) {
 251                         defined($tail_pid = fork) or die "fork: $!\n";
 252                         if ($tail_pid == 0) {
 253                                 # make sure files exist, first
 254                                 open my $fh, '>>', $_ for @paths;
 255                                 open(STDOUT, '>&STDERR') or die "1>&2: $!";
 256                                 exec(split(' ', $tail_cmd), @paths);
 257                                 die "$tail_cmd failed: $!";
 258                         }
 259                         wait_for_tail();
 260                 }
 261         }
 262         defined(my $pid = fork) or die "fork: $!\n";
 263         if ($pid == 0) {
 264                 # pretend to be systemd (cf. sd_listen_fds(3))
 265                 # 3 == SD_LISTEN_FDS_START
 266                 my $fd;
 267                 for ($fd = 0; 1; $fd++) {
 268                         my $s = $opt->{$fd};
 269                         last if $fd >= 3 && !defined($s);
 270                         next unless $s;
 271                         my $fl = fcntl($s, F_GETFD, 0);
 272                         if (($fl & FD_CLOEXEC) != FD_CLOEXEC) {
 273                                 warn "got FD:".fileno($s)." w/o CLOEXEC\n";
 274                         }
 275                         fcntl($s, F_SETFD, $fl &= ~FD_CLOEXEC);
 276                         dup2(fileno($s), $fd) or die "dup2 failed: $!\n";
 277                 }
 278                 %ENV = (%ENV, %$env) if $env;
 279                 my $fds = $fd - 3;
 280                 if ($fds > 0) {
 281                         $ENV{LISTEN_PID} = $$;
 282                         $ENV{LISTEN_FDS} = $fds;
 283                 }
 284                 $0 = join(' ', @$cmd);
 285                 if ($sub) {
 286                         _run_sub($sub, $key, \@argv);
 287                         POSIX::_exit($? >> 8);
 288                 } else {
 289                         exec(key2script($key), @argv);
 290                         die "FAIL: ",join(' ', $key, @argv), ": $!\n";
 291                 }
 292         }
 293         PublicInboxTestProcess->new($pid, $tail_pid);
 294 }
 295
 296 package PublicInboxTestProcess;
 297 use strict;
 298
 299 # prevent new threads from inheriting these objects
 300 sub CLONE_SKIP { 1 }
 301
 302 sub new {
 303         my ($klass, $pid, $tail_pid) = @_;
 304         bless { pid => $pid, tail_pid => $tail_pid, owner => $$ }, $klass;
 305 }
 306
 307 sub kill {
 308         my ($self, $sig) = @_;
 309         CORE::kill($sig // 'TERM', $self->{pid});
 310 }
 311
 312 sub join {
 313         my ($self) = @_;
 314         my $pid = delete $self->{pid} or return;
 315         my $ret = waitpid($pid, 0);
 316         defined($ret) or die "waitpid($pid): $!";
 317         $ret == $pid or die "waitpid($pid) != $ret";
 318 }
 319
 320 sub DESTROY {
 321         my ($self) = @_;
 322         return if $self->{owner} != $$;
 323         if (my $tail = delete $self->{tail_pid}) {
 324                 PublicInbox::TestCommon::wait_for_tail();
 325                 CORE::kill('TERM', $tail);
 326         }
 327         my $pid = delete $self->{pid} or return;
 328         CORE::kill('TERM', $pid);
 329 }
 330
 331 1;