lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 # Used to write to V2 inboxes (see L<public-inbox-v2-format(5)>).
   6 package PublicInbox::V2Writable;
   7 use strict;
   8 use warnings;
   9 use base qw(PublicInbox::Lock);
  10 use 5.010_001;
  11 use PublicInbox::SearchIdxShard;
  12 use PublicInbox::MIME;
  13 use PublicInbox::Git;
  14 use PublicInbox::Import;
  15 use PublicInbox::MID qw(mids references);
  16 use PublicInbox::ContentId qw(content_id content_digest);
  17 use PublicInbox::Inbox;
  18 use PublicInbox::OverIdx;
  19 use PublicInbox::Msgmap;
  20 use PublicInbox::Spawn qw(spawn popen_rd);
  21 use PublicInbox::SearchIdx;
  22 use IO::Handle; # ->autoflush
  23 use File::Temp qw(tempfile);
  24
  25 # an estimate of the post-packed size to the raw uncompressed size
  26 my $PACKING_FACTOR = 0.4;
  27
  28 # SATA storage lags behind what CPUs are capable of, so relying on
  29 # nproc(1) can be misleading and having extra Xapian shards is a
  30 # waste of FDs and space.  It can also lead to excessive IO latency
  31 # and slow things down.  Users on NVME or other fast storage can
  32 # use the NPROC env or switches in our script/public-inbox-* programs
  33 # to increase Xapian shards
  34 our $NPROC_MAX_DEFAULT = 4;
  35
  36 sub detect_nproc () {
  37         for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
  38                 `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
  39         }
  40
  41         # getconf(1) is POSIX, but *NPROCESSORS* vars are not
  42         for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
  43                 `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
  44         }
  45
  46         # should we bother with `sysctl hw.ncpu`?  Those only give
  47         # us total processor count, not online processor count.
  48         undef
  49 }
  50
  51 sub nproc_shards ($) {
  52         my ($creat_opt) = @_;
  53         my $n = $creat_opt->{nproc} if ref($creat_opt) eq 'HASH';
  54         $n //= $ENV{NPROC};
  55         if (!$n) {
  56                 # assume 2 cores if not detectable or zero
  57                 state $NPROC_DETECTED = detect_nproc() || 2;
  58                 $n = $NPROC_DETECTED;
  59                 $n = $NPROC_MAX_DEFAULT if $n > $NPROC_MAX_DEFAULT;
  60         }
  61
  62         # subtract for the main process and git-fast-import
  63         $n -= 1;
  64         $n < 1 ? 1 : $n;
  65 }
  66
  67 sub count_shards ($) {
  68         my ($self) = @_;
  69         my $n = 0;
  70         my $xpfx = $self->{xpfx};
  71
  72         # always load existing shards in case core count changes:
  73         # Also, shard count may change while -watch is running
  74         # due to "xcpdb --reshard"
  75         if (-d $xpfx) {
  76                 require PublicInbox::Search;
  77                 PublicInbox::Search::load_xapian();
  78                 my $XapianDatabase = $PublicInbox::Search::X{Database};
  79                 foreach my $shard (<$xpfx/*>) {
  80                         -d $shard && $shard =~ m!/[0-9]+\z! or next;
  81                         eval {
  82                                 $XapianDatabase->new($shard)->close;
  83                                 $n++;
  84                         };
  85                 }
  86         }
  87         $n;
  88 }
  89
  90 sub new {
  91         # $creat may be any true value, or 0/undef.  A hashref is true,
  92         # and $creat->{nproc} may be set to an integer
  93         my ($class, $v2ibx, $creat) = @_;
  94         $v2ibx = PublicInbox::InboxWritable->new($v2ibx);
  95         my $dir = $v2ibx->assert_usable_dir;
  96         unless (-d $dir) {
  97                 if ($creat) {
  98                         require File::Path;
  99                         File::Path::mkpath($dir);
 100                 } else {
 101                         die "$dir does not exist\n";
 102                 }
 103         }
 104         $v2ibx->umask_prepare;
 105
 106         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
 107         my $self = {
 108                 -inbox => $v2ibx,
 109                 im => undef, #  PublicInbox::Import
 110                 parallel => 1,
 111                 transact_bytes => 0,
 112                 current_info => '',
 113                 xpfx => $xpfx,
 114                 over => PublicInbox::OverIdx->new("$xpfx/over.sqlite3", 1),
 115                 lock_path => "$dir/inbox.lock",
 116                 # limit each git repo (epoch) to 1GB or so
 117                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
 118                 last_commit => [], # git repo -> commit
 119         };
 120         $self->{shards} = count_shards($self) || nproc_shards($creat);
 121         bless $self, $class;
 122 }
 123
 124 # public (for now?)
 125 sub init_inbox {
 126         my ($self, $shards, $skip_epoch) = @_;
 127         if (defined $shards) {
 128                 $self->{parallel} = 0 if $shards == 0;
 129                 $self->{shards} = $shards if $shards > 0;
 130         }
 131         $self->idx_init;
 132         my $epoch_max = -1;
 133         git_dir_latest($self, \$epoch_max);
 134         if (defined $skip_epoch && $epoch_max == -1) {
 135                 $epoch_max = $skip_epoch;
 136         }
 137         $self->git_init($epoch_max >= 0 ? $epoch_max : 0);
 138         $self->done;
 139 }
 140
 141 # returns undef on duplicate or spam
 142 # mimics Import::add and wraps it for v2
 143 sub add {
 144         my ($self, $mime, $check_cb) = @_;
 145         $self->{-inbox}->with_umask(sub {
 146                 _add($self, $mime, $check_cb)
 147         });
 148 }
 149
 150 # indexes a message, returns true if checkpointing is needed
 151 sub do_idx ($$$$$$$) {
 152         my ($self, $msgref, $mime, $len, $num, $oid, $mid0) = @_;
 153         my $smsg = bless {
 154                 bytes => $len,
 155                 num => $num,
 156                 blob => $oid,
 157                 mid => $mid0,
 158         }, 'PublicInbox::Smsg';
 159         $self->{over}->add_overview($mime, $smsg, $self);
 160         my $idx = idx_shard($self, $num % $self->{shards});
 161         $idx->index_raw($len, $msgref, $num, $oid, $mid0, $mime, $self);
 162         my $n = $self->{transact_bytes} += $len;
 163         $n >= (PublicInbox::SearchIdx::BATCH_BYTES * $self->{shards});
 164 }
 165
 166 sub _add {
 167         my ($self, $mime, $check_cb) = @_;
 168
 169         # spam check:
 170         if ($check_cb) {
 171                 $mime = $check_cb->($mime) or return;
 172         }
 173
 174         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
 175         # as does SQLite 3.4.1+ (released in 2007-07-20), and
 176         # Xapian 1.3.2+ (released 2015-03-15).
 177         # For the most part, we can spawn git-fast-import without
 178         # leaking FDs to it...
 179         $self->idx_init;
 180
 181         my ($num, $mid0) = v2_num_for($self, $mime);
 182         defined $num or return; # duplicate
 183         defined $mid0 or die "BUG: $mid0 undefined\n";
 184         my $im = $self->importer;
 185         my $cmt = $im->add($mime, undef, $self); # sets $self->{(au|co)time}
 186         $cmt = $im->get_mark($cmt);
 187         $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 188
 189         my ($oid, $len, $msgref) = @{$im->{last_object}};
 190         if (do_idx($self, $msgref, $mime, $len, $num, $oid, $mid0)) {
 191                 $self->checkpoint;
 192         }
 193
 194         $cmt;
 195 }
 196
 197 sub v2_num_for {
 198         my ($self, $mime) = @_;
 199         my $mids = mids($mime->header_obj);
 200         if (@$mids) {
 201                 my $mid = $mids->[0];
 202                 my $num = $self->{mm}->mid_insert($mid);
 203                 if (defined $num) { # common case
 204                         return ($num, $mid);
 205                 }
 206
 207                 # crap, Message-ID is already known, hope somebody just resent:
 208                 foreach my $m (@$mids) {
 209                         # read-only lookup now safe to do after above barrier
 210                         # easy, don't store duplicates
 211                         # note: do not add more diagnostic info here since
 212                         # it gets noisy on public-inbox-watch restarts
 213                         return () if content_exists($self, $mime, $m);
 214                 }
 215
 216                 # AltId may pre-populate article numbers (e.g. X-Mail-Count
 217                 # or NNTP article number), use that article number if it's
 218                 # not in Over.
 219                 my $altid = $self->{-inbox}->{altid};
 220                 if ($altid && grep(/:file=msgmap\.sqlite3\z/, @$altid)) {
 221                         my $num = $self->{mm}->num_for($mid);
 222
 223                         if (defined $num && !$self->{over}->get_art($num)) {
 224                                 return ($num, $mid);
 225                         }
 226                 }
 227
 228                 # very unlikely:
 229                 warn "<$mid> reused for mismatched content\n";
 230
 231                 # try the rest of the mids
 232                 for(my $i = $#$mids; $i >= 1; $i--) {
 233                         my $m = $mids->[$i];
 234                         $num = $self->{mm}->mid_insert($m);
 235                         if (defined $num) {
 236                                 warn "alternative <$m> for <$mid> found\n";
 237                                 return ($num, $m);
 238                         }
 239                 }
 240         }
 241         # none of the existing Message-IDs are good, generate a new one:
 242         v2_num_for_harder($self, $mime);
 243 }
 244
 245 sub v2_num_for_harder {
 246         my ($self, $mime) = @_;
 247
 248         my $hdr = $mime->header_obj;
 249         my $dig = content_digest($mime);
 250         my $mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 251         my $num = $self->{mm}->mid_insert($mid0);
 252         unless (defined $num) {
 253                 # it's hard to spoof the last Received: header
 254                 my @recvd = $hdr->header_raw('Received');
 255                 $dig->add("Received: $_") foreach (@recvd);
 256                 $mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 257                 $num = $self->{mm}->mid_insert($mid0);
 258
 259                 # fall back to a random Message-ID and give up determinism:
 260                 until (defined($num)) {
 261                         $dig->add(rand);
 262                         $mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 263                         warn "using random Message-ID <$mid0> as fallback\n";
 264                         $num = $self->{mm}->mid_insert($mid0);
 265                 }
 266         }
 267         PublicInbox::Import::append_mid($hdr, $mid0);
 268         ($num, $mid0);
 269 }
 270
 271 sub idx_shard {
 272         my ($self, $shard_i) = @_;
 273         $self->{idx_shards}->[$shard_i];
 274 }
 275
 276 # idempotent
 277 sub idx_init {
 278         my ($self, $opt) = @_;
 279         return if $self->{idx_shards};
 280         my $ibx = $self->{-inbox};
 281
 282         # do not leak read-only FDs to child processes, we only have these
 283         # FDs for duplicate detection so they should not be
 284         # frequently activated.
 285         delete $ibx->{$_} foreach (qw(git mm search));
 286
 287         my $indexlevel = $ibx->{indexlevel};
 288         if ($indexlevel && $indexlevel eq 'basic') {
 289                 $self->{parallel} = 0;
 290         }
 291
 292         if ($self->{parallel}) {
 293                 pipe(my ($r, $w)) or die "pipe failed: $!";
 294                 # pipe for barrier notifications doesn't need to be big,
 295                 # 1031: F_SETPIPE_SZ
 296                 fcntl($w, 1031, 4096) if $^O eq 'linux';
 297                 $self->{bnote} = [ $r, $w ];
 298                 $w->autoflush(1);
 299         }
 300
 301         my $over = $self->{over};
 302         $ibx->umask_prepare;
 303         $ibx->with_umask(sub {
 304                 $self->lock_acquire unless ($opt && $opt->{-skip_lock});
 305                 $over->create;
 306
 307                 # xcpdb can change shard count while -watch is idle
 308                 my $nshards = count_shards($self);
 309                 if ($nshards && $nshards != $self->{shards}) {
 310                         $self->{shards} = $nshards;
 311                 }
 312
 313                 # need to create all shards before initializing msgmap FD
 314                 my $max = $self->{shards} - 1;
 315
 316                 # idx_shards must be visible to all forked processes
 317                 my $idx = $self->{idx_shards} = [];
 318                 for my $i (0..$max) {
 319                         push @$idx, PublicInbox::SearchIdxShard->new($self, $i);
 320                 }
 321
 322                 # Now that all subprocesses are up, we can open the FDs
 323                 # for SQLite:
 324                 my $mm = $self->{mm} = PublicInbox::Msgmap->new_file(
 325                         "$self->{-inbox}->{inboxdir}/msgmap.sqlite3", 1);
 326                 $mm->{dbh}->begin_work;
 327         });
 328 }
 329
 330 # returns an array mapping [ epoch => latest_commit ]
 331 # latest_commit may be undef if nothing was done to that epoch
 332 # $replace_map = { $object_id => $strref, ... }
 333 sub _replace_oids ($$$) {
 334         my ($self, $mime, $replace_map) = @_;
 335         $self->done;
 336         my $pfx = "$self->{-inbox}->{inboxdir}/git";
 337         my $rewrites = []; # epoch => commit
 338         my $max = $self->{epoch_max};
 339
 340         unless (defined($max)) {
 341                 defined(my $latest = git_dir_latest($self, \$max)) or return;
 342                 $self->{epoch_max} = $max;
 343         }
 344
 345         foreach my $i (0..$max) {
 346                 my $git_dir = "$pfx/$i.git";
 347                 -d $git_dir or next;
 348                 my $git = PublicInbox::Git->new($git_dir);
 349                 my $im = $self->import_init($git, 0, 1);
 350                 $rewrites->[$i] = $im->replace_oids($mime, $replace_map);
 351                 $im->done;
 352         }
 353         $rewrites;
 354 }
 355
 356 sub content_ids ($) {
 357         my ($mime) = @_;
 358         my @cids = ( content_id($mime) );
 359
 360         # Email::MIME->as_string doesn't always round-trip, so we may
 361         # use a second content_id
 362         my $rt = content_id(PublicInbox::MIME->new(\($mime->as_string)));
 363         push @cids, $rt if $cids[0] ne $rt;
 364         \@cids;
 365 }
 366
 367 sub content_matches ($$) {
 368         my ($cids, $existing) = @_;
 369         my $cid = content_id($existing);
 370         foreach (@$cids) {
 371                 return 1 if $_ eq $cid
 372         }
 373         0
 374 }
 375
 376 # used for removing or replacing (purging)
 377 sub rewrite_internal ($$;$$$) {
 378         my ($self, $old_mime, $cmt_msg, $new_mime, $sref) = @_;
 379         $self->idx_init;
 380         my ($im, $need_reindex, $replace_map);
 381         if ($sref) {
 382                 $replace_map = {}; # oid => sref
 383                 $need_reindex = [] if $new_mime;
 384         } else {
 385                 $im = $self->importer;
 386         }
 387         my $over = $self->{over};
 388         my $cids = content_ids($old_mime);
 389         my @removed;
 390         my $mids = mids($old_mime->header_obj);
 391
 392         # We avoid introducing new blobs into git since the raw content
 393         # can be slightly different, so we do not need the user-supplied
 394         # message now that we have the mids and content_id
 395         $old_mime = undef;
 396         my $mark;
 397
 398         foreach my $mid (@$mids) {
 399                 my %gone; # num => [ smsg, $mime, raw ]
 400                 my ($id, $prev);
 401                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 402                         my $msg = get_blob($self, $smsg);
 403                         if (!defined($msg)) {
 404                                 warn "broken smsg for $mid\n";
 405                                 next; # continue
 406                         }
 407                         my $orig = $$msg;
 408                         my $cur = PublicInbox::MIME->new($msg);
 409                         if (content_matches($cids, $cur)) {
 410                                 $gone{$smsg->{num}} = [ $smsg, $cur, \$orig ];
 411                         }
 412                 }
 413                 my $n = scalar keys %gone;
 414                 next unless $n;
 415                 if ($n > 1) {
 416                         warn "BUG: multiple articles linked to <$mid>\n",
 417                                 join(',', sort keys %gone), "\n";
 418                 }
 419                 foreach my $num (keys %gone) {
 420                         my ($smsg, $mime, $orig) = @{$gone{$num}};
 421                         # @removed should only be set once assuming
 422                         # no bugs in our deduplication code:
 423                         @removed = (undef, $mime, $smsg);
 424                         my $oid = $smsg->{blob};
 425                         if ($replace_map) {
 426                                 $replace_map->{$oid} = $sref;
 427                         } else {
 428                                 ($mark, undef) = $im->remove($orig, $cmt_msg);
 429                                 $removed[0] = $mark;
 430                         }
 431                         $orig = undef;
 432                         if ($need_reindex) { # ->replace
 433                                 push @$need_reindex, $smsg;
 434                         } else { # ->purge or ->remove
 435                                 $self->{mm}->num_delete($num);
 436                         }
 437                         unindex_oid_remote($self, $oid, $mid);
 438                 }
 439         }
 440
 441         if (defined $mark) {
 442                 my $cmt = $im->get_mark($mark);
 443                 $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 444         }
 445         if ($replace_map && scalar keys %$replace_map) {
 446                 my $rewrites = _replace_oids($self, $new_mime, $replace_map);
 447                 return { rewrites => $rewrites, need_reindex => $need_reindex };
 448         }
 449         defined($mark) ? @removed : undef;
 450 }
 451
 452 # public (see PublicInbox::Import->remove), but note the 3rd element
 453 # (retval[2]) is not part of the stable API shared with Import->remove
 454 sub remove {
 455         my ($self, $mime, $cmt_msg) = @_;
 456         my @ret;
 457         $self->{-inbox}->with_umask(sub {
 458                 @ret = rewrite_internal($self, $mime, $cmt_msg);
 459         });
 460         defined($ret[0]) ? @ret : undef;
 461 }
 462
 463 sub _replace ($$;$$) {
 464         my ($self, $old_mime, $new_mime, $sref) = @_;
 465         my $rewritten = $self->{-inbox}->with_umask(sub {
 466                 rewrite_internal($self, $old_mime, undef, $new_mime, $sref);
 467         }) or return;
 468
 469         my $rewrites = $rewritten->{rewrites};
 470         # ->done is called if there are rewrites since we gc+prune from git
 471         $self->idx_init if @$rewrites;
 472
 473         for my $i (0..$#$rewrites) {
 474                 defined(my $cmt = $rewrites->[$i]) or next;
 475                 $self->{last_commit}->[$i] = $cmt;
 476         }
 477         $rewritten;
 478 }
 479
 480 # public
 481 sub purge {
 482         my ($self, $mime) = @_;
 483         my $rewritten = _replace($self, $mime, undef, \'') or return;
 484         $rewritten->{rewrites}
 485 }
 486
 487 # returns the git object_id of $fh, does not write the object to FS
 488 sub git_hash_raw ($$) {
 489         my ($self, $raw) = @_;
 490         # grab the expected OID we have to reindex:
 491         open my $tmp_fh, '+>', undef or die "failed to open tmp: $!";
 492         $tmp_fh->autoflush(1);
 493         print $tmp_fh $$raw or die "print \$tmp_fh: $!";
 494         sysseek($tmp_fh, 0, 0) or die "seek failed: $!";
 495
 496         my $git_dir = $self->{-inbox}->git->{git_dir};
 497         my $cmd = ['git', "--git-dir=$git_dir", qw(hash-object --stdin)];
 498         my $r = popen_rd($cmd, undef, { 0 => $tmp_fh });
 499         local $/ = "\n";
 500         chomp(my $oid = <$r>);
 501         close $r or die "git hash-object failed: $?";
 502         $oid =~ /\A[a-f0-9]{40}\z/ or die "OID not expected: $oid";
 503         $oid;
 504 }
 505
 506 sub _check_mids_match ($$$) {
 507         my ($old_list, $new_list, $hdrs) = @_;
 508         my %old_mids = map { $_ => 1 } @$old_list;
 509         my %new_mids = map { $_ => 1 } @$new_list;
 510         my @old = keys %old_mids;
 511         my @new = keys %new_mids;
 512         my $err = "$hdrs may not be changed when replacing\n";
 513         die $err if scalar(@old) != scalar(@new);
 514         delete @new_mids{@old};
 515         delete @old_mids{@new};
 516         die $err if (scalar(keys %old_mids) || scalar(keys %new_mids));
 517 }
 518
 519 # Changing Message-IDs or References with ->replace isn't supported.
 520 # The rules for dealing with messages with multiple or conflicting
 521 # Message-IDs are pretty complex and rethreading hasn't been fully
 522 # implemented, yet.
 523 sub check_mids_match ($$) {
 524         my ($old_mime, $new_mime) = @_;
 525         my $old = $old_mime->header_obj;
 526         my $new = $new_mime->header_obj;
 527         _check_mids_match(mids($old), mids($new), 'Message-ID(s)');
 528         _check_mids_match(references($old), references($new),
 529                         'References/In-Reply-To');
 530 }
 531
 532 # public
 533 sub replace ($$$) {
 534         my ($self, $old_mime, $new_mime) = @_;
 535
 536         check_mids_match($old_mime, $new_mime);
 537
 538         # mutt will always add Content-Length:, Status:, Lines: when editing
 539         PublicInbox::Import::drop_unwanted_headers($new_mime);
 540
 541         my $raw = $new_mime->as_string;
 542         my $expect_oid = git_hash_raw($self, \$raw);
 543         my $rewritten = _replace($self, $old_mime, $new_mime, \$raw) or return;
 544         my $need_reindex = $rewritten->{need_reindex};
 545
 546         # just in case we have bugs in deduplication code:
 547         my $n = scalar(@$need_reindex);
 548         if ($n > 1) {
 549                 my $list = join(', ', map {
 550                                         "$_->{num}: <$_->{mid}>"
 551                                 } @$need_reindex);
 552                 warn <<"";
 553 W: rewritten $n messages matching content of original message (expected: 1).
 554 W: possible bug in public-inbox, NNTP article IDs and Message-IDs follow:
 555 W: $list
 556
 557         }
 558
 559         # make sure we really got the OID:
 560         my ($oid, $type, $len) = $self->{-inbox}->git->check($expect_oid);
 561         $oid eq $expect_oid or die "BUG: $expect_oid not found after replace";
 562
 563         # don't leak FDs to Xapian:
 564         $self->{-inbox}->git->cleanup;
 565
 566         # reindex modified messages:
 567         for my $smsg (@$need_reindex) {
 568                 my $num = $smsg->{num};
 569                 my $mid0 = $smsg->{mid};
 570                 do_idx($self, \$raw, $new_mime, $len, $num, $oid, $mid0);
 571         }
 572         $rewritten->{rewrites};
 573 }
 574
 575 sub last_epoch_commit ($$;$) {
 576         my ($self, $i, $cmt) = @_;
 577         my $v = PublicInbox::Search::SCHEMA_VERSION();
 578         $self->{mm}->last_commit_xap($v, $i, $cmt);
 579 }
 580
 581 sub set_last_commits ($) {
 582         my ($self) = @_;
 583         defined(my $epoch_max = $self->{epoch_max}) or return;
 584         my $last_commit = $self->{last_commit};
 585         foreach my $i (0..$epoch_max) {
 586                 defined(my $cmt = $last_commit->[$i]) or next;
 587                 $last_commit->[$i] = undef;
 588                 last_epoch_commit($self, $i, $cmt);
 589         }
 590 }
 591
 592 sub barrier_init {
 593         my ($self, $n) = @_;
 594         $self->{bnote} or return;
 595         --$n;
 596         my $barrier = { map { $_ => 1 } (0..$n) };
 597 }
 598
 599 sub barrier_wait {
 600         my ($self, $barrier) = @_;
 601         my $bnote = $self->{bnote} or return;
 602         my $r = $bnote->[0];
 603         while (scalar keys %$barrier) {
 604                 defined(my $l = $r->getline) or die "EOF on barrier_wait: $!";
 605                 $l =~ /\Abarrier (\d+)/ or die "bad line on barrier_wait: $l";
 606                 delete $barrier->{$1} or die "bad shard[$1] on barrier wait";
 607         }
 608 }
 609
 610 # public
 611 sub checkpoint ($;$) {
 612         my ($self, $wait) = @_;
 613
 614         if (my $im = $self->{im}) {
 615                 if ($wait) {
 616                         $im->barrier;
 617                 } else {
 618                         $im->checkpoint;
 619                 }
 620         }
 621         my $shards = $self->{idx_shards};
 622         if ($shards) {
 623                 my $dbh = $self->{mm}->{dbh};
 624
 625                 # SQLite msgmap data is second in importance
 626                 $dbh->commit;
 627
 628                 # SQLite overview is third
 629                 $self->{over}->commit_lazy;
 630
 631                 # Now deal with Xapian
 632                 if ($wait) {
 633                         my $barrier = $self->barrier_init(scalar @$shards);
 634
 635                         # each shard needs to issue a barrier command
 636                         $_->remote_barrier for @$shards;
 637
 638                         # wait for each Xapian shard
 639                         $self->barrier_wait($barrier);
 640                 } else {
 641                         $_->remote_commit for @$shards;
 642                 }
 643
 644                 # last_commit is special, don't commit these until
 645                 # remote shards are done:
 646                 $dbh->begin_work;
 647                 set_last_commits($self);
 648                 $dbh->commit;
 649
 650                 $dbh->begin_work;
 651         }
 652         $self->{transact_bytes} = 0;
 653 }
 654
 655 # issue a write barrier to ensure all data is visible to other processes
 656 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 657 # public
 658 sub barrier { checkpoint($_[0], 1) };
 659
 660 # public
 661 sub done {
 662         my ($self) = @_;
 663         my $im = delete $self->{im};
 664         $im->done if $im; # PublicInbox::Import::done
 665         checkpoint($self);
 666         my $mm = delete $self->{mm};
 667         $mm->{dbh}->commit if $mm;
 668         my $shards = delete $self->{idx_shards};
 669         if ($shards) {
 670                 $_->remote_close for @$shards;
 671         }
 672         $self->{over}->disconnect;
 673         delete $self->{bnote};
 674         $self->{transact_bytes} = 0;
 675         $self->lock_release if $shards;
 676         $self->{-inbox}->git->cleanup;
 677 }
 678
 679 sub fill_alternates ($$) {
 680         my ($self, $epoch) = @_;
 681
 682         my $pfx = "$self->{-inbox}->{inboxdir}/git";
 683         my $all = "$self->{-inbox}->{inboxdir}/all.git";
 684
 685         unless (-d $all) {
 686                 PublicInbox::Import::init_bare($all);
 687         }
 688         my $info_dir = "$all/objects/info";
 689         my $alt = "$info_dir/alternates";
 690         my (%alt, $new);
 691         my $mode = 0644;
 692         if (-e $alt) {
 693                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 694                 $mode = (stat($fh))[2] & 07777;
 695
 696                 # we assign a sort score to every alternate and favor
 697                 # the newest (highest numbered) one when we
 698                 my $score;
 699                 my $other = 0; # in case admin adds non-epoch repos
 700                 %alt = map {;
 701                         if (m!\A\Q../../\E([0-9]+)\.git/objects\z!) {
 702                                 $score = $1 + 0;
 703                         } else {
 704                                 $score = --$other;
 705                         }
 706                         $_ => $score;
 707                 } split(/\n+/, do { local $/; <$fh> });
 708         }
 709
 710         foreach my $i (0..$epoch) {
 711                 my $dir = "../../git/$i.git/objects";
 712                 if (!exists($alt{$dir}) && -d "$pfx/$i.git") {
 713                         $alt{$dir} = $i;
 714                         $new = 1;
 715                 }
 716         }
 717         return unless $new;
 718
 719         my ($fh, $tmp) = tempfile('alt-XXXXXXXX', DIR => $info_dir);
 720         print $fh join("\n", sort { $alt{$b} <=> $alt{$a} } keys %alt), "\n"
 721                 or die "print $tmp: $!\n";
 722         chmod($mode, $fh) or die "fchmod $tmp: $!\n";
 723         close $fh or die "close $tmp $!\n";
 724         rename($tmp, $alt) or die "rename $tmp => $alt: $!\n";
 725 }
 726
 727 sub git_init {
 728         my ($self, $epoch) = @_;
 729         my $git_dir = "$self->{-inbox}->{inboxdir}/git/$epoch.git";
 730         my @cmd = (qw(git init --bare -q), $git_dir);
 731         PublicInbox::Import::run_die(\@cmd);
 732         @cmd = (qw/git config/, "--file=$git_dir/config",
 733                         'include.path', '../../all.git/config');
 734         PublicInbox::Import::run_die(\@cmd);
 735         fill_alternates($self, $epoch);
 736         $git_dir
 737 }
 738
 739 sub git_dir_latest {
 740         my ($self, $max) = @_;
 741         $$max = -1;
 742         my $pfx = "$self->{-inbox}->{inboxdir}/git";
 743         return unless -d $pfx;
 744         my $latest;
 745         opendir my $dh, $pfx or die "opendir $pfx: $!\n";
 746         while (defined(my $git_dir = readdir($dh))) {
 747                 $git_dir =~ m!\A([0-9]+)\.git\z! or next;
 748                 if ($1 > $$max) {
 749                         $$max = $1;
 750                         $latest = "$pfx/$git_dir";
 751                 }
 752         }
 753         $latest;
 754 }
 755
 756 sub importer {
 757         my ($self) = @_;
 758         my $im = $self->{im};
 759         if ($im) {
 760                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 761                         return $im;
 762                 } else {
 763                         $self->{im} = undef;
 764                         $im->done;
 765                         $im = undef;
 766                         $self->checkpoint;
 767                         my $git_dir = $self->git_init(++$self->{epoch_max});
 768                         my $git = PublicInbox::Git->new($git_dir);
 769                         return $self->import_init($git, 0);
 770                 }
 771         }
 772         my $epoch = 0;
 773         my $max;
 774         my $latest = git_dir_latest($self, \$max);
 775         if (defined $latest) {
 776                 my $git = PublicInbox::Git->new($latest);
 777                 my $packed_bytes = $git->packed_bytes;
 778                 my $unpacked_bytes = $packed_bytes / $PACKING_FACTOR;
 779
 780                 if ($unpacked_bytes >= $self->{rotate_bytes}) {
 781                         $epoch = $max + 1;
 782                 } else {
 783                         $self->{epoch_max} = $max;
 784                         return $self->import_init($git, $packed_bytes);
 785                 }
 786         }
 787         $self->{epoch_max} = $epoch;
 788         $latest = $self->git_init($epoch);
 789         $self->import_init(PublicInbox::Git->new($latest), 0);
 790 }
 791
 792 sub import_init {
 793         my ($self, $git, $packed_bytes, $tmp) = @_;
 794         my $im = PublicInbox::Import->new($git, undef, undef, $self->{-inbox});
 795         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 796         $im->{want_object_info} = 1;
 797         $im->{lock_path} = undef;
 798         $im->{path_type} = 'v2';
 799         $self->{im} = $im unless $tmp;
 800         $im;
 801 }
 802
 803 # XXX experimental
 804 sub diff ($$$) {
 805         my ($mid, $cur, $new) = @_;
 806
 807         my ($ah, $an) = tempfile('email-cur-XXXXXXXX', TMPDIR => 1);
 808         print $ah $cur->as_string or die "print: $!";
 809         close $ah or die "close: $!";
 810         my ($bh, $bn) = tempfile('email-new-XXXXXXXX', TMPDIR => 1);
 811         PublicInbox::Import::drop_unwanted_headers($new);
 812         print $bh $new->as_string or die "print: $!";
 813         close $bh or die "close: $!";
 814         my $cmd = [ qw(diff -u), $an, $bn ];
 815         print STDERR "# MID conflict <$mid>\n";
 816         my $pid = spawn($cmd, undef, { 1 => 2 });
 817         waitpid($pid, 0) == $pid or die "diff did not finish";
 818         unlink($an, $bn);
 819 }
 820
 821 sub get_blob ($$) {
 822         my ($self, $smsg) = @_;
 823         if (my $im = $self->{im}) {
 824                 my $msg = $im->cat_blob($smsg->{blob});
 825                 return $msg if $msg;
 826         }
 827         # older message, should be in alternates
 828         my $ibx = $self->{-inbox};
 829         $ibx->msg_by_smsg($smsg);
 830 }
 831
 832 sub content_exists ($$$) {
 833         my ($self, $mime, $mid) = @_;
 834         my $over = $self->{over};
 835         my $cids = content_ids($mime);
 836         my ($id, $prev);
 837         while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 838                 my $msg = get_blob($self, $smsg);
 839                 if (!defined($msg)) {
 840                         warn "broken smsg for $mid\n";
 841                         next;
 842                 }
 843                 my $cur = PublicInbox::MIME->new($msg);
 844                 return 1 if content_matches($cids, $cur);
 845
 846                 # XXX DEBUG_DIFF is experimental and may be removed
 847                 diff($mid, $cur, $mime) if $ENV{DEBUG_DIFF};
 848         }
 849         undef;
 850 }
 851
 852 sub atfork_child {
 853         my ($self) = @_;
 854         my $fh = delete $self->{reindex_pipe};
 855         close $fh if $fh;
 856         if (my $shards = $self->{idx_shards}) {
 857                 $_->atfork_child foreach @$shards;
 858         }
 859         if (my $im = $self->{im}) {
 860                 $im->atfork_child;
 861         }
 862         die "unexpected mm" if $self->{mm};
 863         close $self->{bnote}->[0] or die "close bnote[0]: $!\n";
 864         $self->{bnote}->[1];
 865 }
 866
 867 sub mark_deleted ($$$$) {
 868         my ($self, $sync, $git, $oid) = @_;
 869         my $msgref = $git->cat_file($oid);
 870         my $mime = PublicInbox::MIME->new($$msgref);
 871         my $mids = mids($mime->header_obj);
 872         my $cid = content_id($mime);
 873         foreach my $mid (@$mids) {
 874                 $sync->{D}->{"$mid\0$cid"} = $oid;
 875         }
 876 }
 877
 878 sub reindex_checkpoint ($$$) {
 879         my ($self, $sync, $git) = @_;
 880
 881         $git->cleanup;
 882         $sync->{mm_tmp}->atfork_prepare;
 883         $self->done; # release lock
 884
 885         if (my $pr = $sync->{-opt}->{-progress}) {
 886                 my ($bn) = (split('/', $git->{git_dir}))[-1];
 887                 $pr->("$bn ".sprintf($sync->{-regen_fmt}, $sync->{nr}));
 888         }
 889
 890         # allow -watch or -mda to write...
 891         $self->idx_init; # reacquire lock
 892         $sync->{mm_tmp}->atfork_parent;
 893 }
 894
 895 # only for a few odd messages with multiple Message-IDs
 896 sub reindex_oid_m ($$$$;$) {
 897         my ($self, $sync, $git, $oid, $regen_num) = @_;
 898         $self->{current_info} = "multi_mid $oid";
 899         my ($num, $mid0, $len);
 900         my $msgref = $git->cat_file($oid, \$len);
 901         my $mime = PublicInbox::MIME->new($$msgref);
 902         my $mids = mids($mime->header_obj);
 903         my $cid = content_id($mime);
 904         die "BUG: reindex_oid_m called for <=1 mids" if scalar(@$mids) <= 1;
 905
 906         for my $mid (reverse @$mids) {
 907                 delete($sync->{D}->{"$mid\0$cid"}) and
 908                         die "BUG: reindex_oid should handle <$mid> delete";
 909         }
 910         my $over = $self->{over};
 911         for my $mid (reverse @$mids) {
 912                 ($num, $mid0) = $over->num_mid0_for_oid($oid, $mid);
 913                 next unless defined $num;
 914                 if (defined($regen_num) && $regen_num != $num) {
 915                         die "BUG: regen(#$regen_num) != over(#$num)";
 916                 }
 917         }
 918         unless (defined($num)) {
 919                 for my $mid (reverse @$mids) {
 920                         # is this a number we got before?
 921                         my $n = $sync->{mm_tmp}->num_for($mid);
 922                         next unless defined $n;
 923                         next if defined($regen_num) && $regen_num != $n;
 924                         ($num, $mid0) = ($n, $mid);
 925                         last;
 926                 }
 927         }
 928         if (defined($num)) {
 929                 $sync->{mm_tmp}->num_delete($num);
 930         } elsif (defined $regen_num) {
 931                 $num = $regen_num;
 932                 for my $mid (reverse @$mids) {
 933                         $self->{mm}->mid_set($num, $mid) == 1 or next;
 934                         $mid0 = $mid;
 935                         last;
 936                 }
 937                 unless (defined $mid0) {
 938                         warn "E: cannot regen #$num\n";
 939                         return;
 940                 }
 941         } else { # fixup bugs in old mirrors on reindex
 942                 for my $mid (reverse @$mids) {
 943                         $num = $self->{mm}->mid_insert($mid);
 944                         next unless defined $num;
 945                         $mid0 = $mid;
 946                         last;
 947                 }
 948                 if (defined $mid0) {
 949                         if ($sync->{reindex}) {
 950                                 warn "reindex added #$num <$mid0>\n";
 951                         }
 952                 } else {
 953                         warn "E: cannot find article #\n";
 954                         return;
 955                 }
 956         }
 957         $sync->{nr}++;
 958         if (do_idx($self, $msgref, $mime, $len, $num, $oid, $mid0)) {
 959                 reindex_checkpoint($self, $sync, $git);
 960         }
 961 }
 962
 963 sub check_unindexed ($$$) {
 964         my ($self, $num, $mid0) = @_;
 965         my $unindexed = $self->{unindexed} // {};
 966         my $n = delete($unindexed->{$mid0});
 967         defined $n or return;
 968         if ($n != $num) {
 969                 die "BUG: unindexed $n != $num <$mid0>\n";
 970         } else {
 971                 $self->{mm}->mid_set($num, $mid0);
 972         }
 973 }
 974
 975 # reuse Msgmap to store num => oid mapping (rather than num => mid)
 976 sub multi_mid_q_new () {
 977         my ($fh, $fn) = tempfile('multi_mid-XXXXXXX', EXLOCK => 0, TMPDIR => 1);
 978         my $multi_mid = PublicInbox::Msgmap->new_file($fn, 1);
 979         $multi_mid->{dbh}->do('PRAGMA synchronous = OFF');
 980         # for Msgmap->DESTROY:
 981         $multi_mid->{tmp_name} = $fn;
 982         $multi_mid->{pid} = $$;
 983         close $fh or die "failed to close $fn: $!";
 984         $multi_mid
 985 }
 986
 987 sub multi_mid_q_push ($$) {
 988         my ($sync, $oid) = @_;
 989         my $multi_mid = $sync->{multi_mid} //= multi_mid_q_new();
 990         if ($sync->{reindex}) { # no regen on reindex
 991                 $multi_mid->mid_insert($oid);
 992         } else {
 993                 my $num = $sync->{regen}--;
 994                 die "BUG: ran out of article numbers" if $num <= 0;
 995                 $multi_mid->mid_set($num, $oid);
 996         }
 997 }
 998
 999 sub reindex_oid ($$$$) {
1000         my ($self, $sync, $git, $oid) = @_;
1001         my ($num, $mid0, $len);
1002         my $msgref = $git->cat_file($oid, \$len);
1003         return if $len == 0; # purged
1004         my $mime = PublicInbox::MIME->new($$msgref);
1005         my $mids = mids($mime->header_obj);
1006         my $cid = content_id($mime);
1007
1008         if (scalar(@$mids) == 0) {
1009                 warn "E: $oid has no Message-ID, skipping\n";
1010                 return;
1011         } elsif (scalar(@$mids) == 1) {
1012                 my $mid = $mids->[0];
1013
1014                 # was the file previously marked as deleted?, skip if so
1015                 if (delete($sync->{D}->{"$mid\0$cid"})) {
1016                         if (!$sync->{reindex}) {
1017                                 $num = $sync->{regen}--;
1018                                 $self->{mm}->num_highwater($num);
1019                         }
1020                         return;
1021                 }
1022
1023                 # is this a number we got before?
1024                 $num = $sync->{mm_tmp}->num_for($mid);
1025                 if (defined $num) {
1026                         $mid0 = $mid;
1027                         check_unindexed($self, $num, $mid0);
1028                 } else {
1029                         $num = $sync->{regen}--;
1030                         die "BUG: ran out of article numbers" if $num <= 0;
1031                         if ($self->{mm}->mid_set($num, $mid) != 1) {
1032                                 warn "E: unable to assign $num => <$mid>\n";
1033                                 return;
1034                         }
1035                         $mid0 = $mid;
1036                 }
1037         } else { # multiple MIDs are a weird case:
1038                 my $del = 0;
1039                 for (@$mids) {
1040                         $del += delete($sync->{D}->{"$_\0$cid"}) // 0;
1041                 }
1042                 if ($del) {
1043                         unindex_oid_remote($self, $oid, $_) for @$mids;
1044                         # do not delete from {mm_tmp}, since another
1045                         # single-MID message may use it.
1046                 } else { # handle them at the end:
1047                         multi_mid_q_push($sync, $oid);
1048                 }
1049                 return;
1050         }
1051         $sync->{mm_tmp}->mid_delete($mid0) or
1052                 die "failed to delete <$mid0> for article #$num\n";
1053         $sync->{nr}++;
1054         if (do_idx($self, $msgref, $mime, $len, $num, $oid, $mid0)) {
1055                 reindex_checkpoint($self, $sync, $git);
1056         }
1057 }
1058
1059 # only update last_commit for $i on reindex iff newer than current
1060 sub update_last_commit ($$$$) {
1061         my ($self, $git, $i, $cmt) = @_;
1062         my $last = last_epoch_commit($self, $i);
1063         if (defined $last && is_ancestor($git, $last, $cmt)) {
1064                 my @cmd = (qw(rev-list --count), "$last..$cmt");
1065                 chomp(my $n = $git->qx(@cmd));
1066                 return if $n ne '' && $n == 0;
1067         }
1068         last_epoch_commit($self, $i, $cmt);
1069 }
1070
1071 sub git_dir_n ($$) { "$_[0]->{-inbox}->{inboxdir}/git/$_[1].git" }
1072
1073 sub last_commits ($$) {
1074         my ($self, $epoch_max) = @_;
1075         my $heads = [];
1076         for (my $i = $epoch_max; $i >= 0; $i--) {
1077                 $heads->[$i] = last_epoch_commit($self, $i);
1078         }
1079         $heads;
1080 }
1081
1082 *is_ancestor = *PublicInbox::SearchIdx::is_ancestor;
1083
1084 # returns a revision range for git-log(1)
1085 sub log_range ($$$$$) {
1086         my ($self, $sync, $git, $i, $tip) = @_;
1087         my $opt = $sync->{-opt};
1088         my $pr = $opt->{-progress} if (($opt->{verbose} || 0) > 1);
1089         my $cur = $sync->{ranges}->[$i] or do {
1090                 $pr->("$i.git indexing all of $tip") if $pr;
1091                 return $tip; # all of it
1092         };
1093
1094         # fast equality check to avoid (v)fork+execve overhead
1095         if ($cur eq $tip) {
1096                 $sync->{ranges}->[$i] = undef;
1097                 return;
1098         }
1099
1100         my $range = "$cur..$tip";
1101         $pr->("$i.git checking contiguity... ") if $pr;
1102         if (is_ancestor($git, $cur, $tip)) { # common case
1103                 $pr->("OK\n") if $pr;
1104                 my $n = $git->qx(qw(rev-list --count), $range);
1105                 chomp($n);
1106                 if ($n == 0) {
1107                         $sync->{ranges}->[$i] = undef;
1108                         $pr->("$i.git has nothing new\n") if $pr;
1109                         return; # nothing to do
1110                 }
1111                 $pr->("$i.git has $n changes since $cur\n") if $pr;
1112         } else {
1113                 $pr->("FAIL\n") if $pr;
1114                 warn <<"";
1115 discontiguous range: $range
1116 Rewritten history? (in $git->{git_dir})
1117
1118                 chomp(my $base = $git->qx('merge-base', $tip, $cur));
1119                 if ($base) {
1120                         $range = "$base..$tip";
1121                         warn "found merge-base: $base\n"
1122                 } else {
1123                         $range = $tip;
1124                         warn "discarding history at $cur\n";
1125                 }
1126                 warn <<"";
1127 reindexing $git->{git_dir} starting at
1128 $range
1129
1130                 $sync->{unindex_range}->{$i} = "$base..$cur";
1131         }
1132         $range;
1133 }
1134
1135 sub sync_prepare ($$$) {
1136         my ($self, $sync, $epoch_max) = @_;
1137         my $pr = $sync->{-opt}->{-progress};
1138         my $regen_max = 0;
1139         my $head = $self->{-inbox}->{ref_head} || 'refs/heads/master';
1140
1141         # reindex stops at the current heads and we later rerun index_sync
1142         # without {reindex}
1143         my $reindex_heads = last_commits($self, $epoch_max) if $sync->{reindex};
1144
1145         for (my $i = $epoch_max; $i >= 0; $i--) {
1146                 die 'BUG: already indexing!' if $self->{reindex_pipe};
1147                 my $git_dir = git_dir_n($self, $i);
1148                 -d $git_dir or next; # missing epochs are fine
1149                 my $git = PublicInbox::Git->new($git_dir);
1150                 if ($reindex_heads) {
1151                         $head = $reindex_heads->[$i] or next;
1152                 }
1153                 chomp(my $tip = $git->qx(qw(rev-parse -q --verify), $head));
1154
1155                 next if $?; # new repo
1156                 my $range = log_range($self, $sync, $git, $i, $tip) or next;
1157                 $sync->{ranges}->[$i] = $range;
1158
1159                 # can't use 'rev-list --count' if we use --diff-filter
1160                 $pr->("$i.git counting $range ... ") if $pr;
1161                 my $n = 0;
1162                 my $fh = $git->popen(qw(log --pretty=tformat:%H
1163                                 --no-notes --no-color --no-renames
1164                                 --diff-filter=AM), $range, '--', 'm');
1165                 ++$n while <$fh>;
1166                 close $fh or die "git log failed: \$?=$?";
1167                 $pr->("$n\n") if $pr;
1168                 $regen_max += $n;
1169         }
1170
1171         return 0 if (!$regen_max && !keys(%{$self->{unindex_range}}));
1172
1173         # reindex should NOT see new commits anymore, if we do,
1174         # it's a problem and we need to notice it via die()
1175         my $pad = length($regen_max) + 1;
1176         $sync->{-regen_fmt} = "% ${pad}u/$regen_max\n";
1177         $sync->{nr} = 0;
1178         return -1 if $sync->{reindex};
1179         $regen_max + $self->{mm}->num_highwater() || 0;
1180 }
1181
1182 sub unindex_oid_remote ($$$) {
1183         my ($self, $oid, $mid) = @_;
1184         $_->remote_remove($oid, $mid) foreach @{$self->{idx_shards}};
1185         $self->{over}->remove_oid($oid, $mid);
1186 }
1187
1188 sub unindex_oid ($$$;$) {
1189         my ($self, $git, $oid, $unindexed) = @_;
1190         my $mm = $self->{mm};
1191         my $msgref = $git->cat_file($oid);
1192         my $mime = PublicInbox::MIME->new($msgref);
1193         my $mids = mids($mime->header_obj);
1194         $mime = $msgref = undef;
1195         my $over = $self->{over};
1196         foreach my $mid (@$mids) {
1197                 my %gone;
1198                 my ($id, $prev);
1199                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
1200                         $gone{$smsg->{num}} = 1 if $oid eq $smsg->{blob};
1201                         1; # continue
1202                 }
1203                 my $n = scalar keys %gone;
1204                 next unless $n;
1205                 if ($n > 1) {
1206                         warn "BUG: multiple articles linked to $oid\n",
1207                                 join(',',sort keys %gone), "\n";
1208                 }
1209                 foreach my $num (keys %gone) {
1210                         if ($unindexed) {
1211                                 my $mid0 = $mm->mid_for($num);
1212                                 $unindexed->{$mid0} = $num;
1213                         }
1214                         $mm->num_delete($num);
1215                 }
1216                 unindex_oid_remote($self, $oid, $mid);
1217         }
1218 }
1219
1220 my $x40 = qr/[a-f0-9]{40}/;
1221 sub unindex ($$$$) {
1222         my ($self, $sync, $git, $unindex_range) = @_;
1223         my $unindexed = $self->{unindexed} ||= {}; # $mid0 => $num
1224         my $before = scalar keys %$unindexed;
1225         # order does not matter, here:
1226         my @cmd = qw(log --raw -r
1227                         --no-notes --no-color --no-abbrev --no-renames);
1228         my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $unindex_range);
1229         while (<$fh>) {
1230                 /\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o or next;
1231                 unindex_oid($self, $git, $1, $unindexed);
1232         }
1233         delete $self->{reindex_pipe};
1234         close $fh or die "git log failed: \$?=$?";
1235
1236         return unless $sync->{-opt}->{prune};
1237         my $after = scalar keys %$unindexed;
1238         return if $before == $after;
1239
1240         # ensure any blob can not longer be accessed via dumb HTTP
1241         PublicInbox::Import::run_die(['git', "--git-dir=$git->{git_dir}",
1242                 qw(-c gc.reflogExpire=now gc --prune=all --quiet)]);
1243 }
1244
1245 sub sync_ranges ($$$) {
1246         my ($self, $sync, $epoch_max) = @_;
1247         my $reindex = $sync->{reindex};
1248
1249         return last_commits($self, $epoch_max) unless $reindex;
1250         return [] if ref($reindex) ne 'HASH';
1251
1252         my $ranges = $reindex->{from}; # arrayref;
1253         if (ref($ranges) ne 'ARRAY') {
1254                 die 'BUG: $reindex->{from} not an ARRAY';
1255         }
1256         $ranges;
1257 }
1258
1259 sub index_epoch ($$$) {
1260         my ($self, $sync, $i) = @_;
1261
1262         my $git_dir = git_dir_n($self, $i);
1263         die 'BUG: already reindexing!' if $self->{reindex_pipe};
1264         -d $git_dir or return; # missing epochs are fine
1265         fill_alternates($self, $i);
1266         my $git = PublicInbox::Git->new($git_dir);
1267         if (my $unindex_range = delete $sync->{unindex_range}->{$i}) {
1268                 unindex($self, $sync, $git, $unindex_range);
1269         }
1270         defined(my $range = $sync->{ranges}->[$i]) or return;
1271         if (my $pr = $sync->{-opt}->{-progress}) {
1272                 $pr->("$i.git indexing $range\n");
1273         }
1274
1275         my @cmd = qw(log --raw -r --pretty=tformat:%H.%at.%ct
1276                         --no-notes --no-color --no-abbrev --no-renames);
1277         my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $range);
1278         my $cmt;
1279         while (<$fh>) {
1280                 chomp;
1281                 $self->{current_info} = "$i.git $_";
1282                 if (/\A($x40)\.([0-9]+)\.([0-9]+)$/o) {
1283                         $cmt //= $1;
1284                         $self->{autime} = $2;
1285                         $self->{cotime} = $3;
1286                 } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o) {
1287                         reindex_oid($self, $sync, $git, $1);
1288                 } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\td$/o) {
1289                         mark_deleted($self, $sync, $git, $1);
1290                 }
1291         }
1292         close $fh or die "git log failed: \$?=$?";
1293         delete $self->{reindex_pipe};
1294         update_last_commit($self, $git, $i, $cmt) if defined $cmt;
1295 }
1296
1297 # public, called by public-inbox-index
1298 sub index_sync {
1299         my ($self, $opt) = @_;
1300         $opt ||= {};
1301         my $pr = $opt->{-progress};
1302         my $epoch_max;
1303         my $latest = git_dir_latest($self, \$epoch_max);
1304         return unless defined $latest;
1305         $self->idx_init($opt); # acquire lock
1306         my $sync = {
1307                 D => {}, # "$mid\0$cid" => $oid
1308                 unindex_range => {}, # EPOCH => oid_old..oid_new
1309                 reindex => $opt->{reindex},
1310                 -opt => $opt
1311         };
1312         $sync->{ranges} = sync_ranges($self, $sync, $epoch_max);
1313         $sync->{regen} = sync_prepare($self, $sync, $epoch_max);
1314
1315         if ($sync->{regen}) {
1316                 # tmp_clone seems to fail if inside a transaction, so
1317                 # we rollback here (because we opened {mm} for reading)
1318                 # Note: we do NOT rely on DBI transactions for atomicity;
1319                 # only for batch performance.
1320                 $self->{mm}->{dbh}->rollback;
1321                 $self->{mm}->{dbh}->begin_work;
1322                 $sync->{mm_tmp} = $self->{mm}->tmp_clone;
1323         }
1324
1325         # work backwards through history
1326         for (my $i = $epoch_max; $i >= 0; $i--) {
1327                 index_epoch($self, $sync, $i);
1328         }
1329
1330         # unindex is required for leftovers if "deletes" affect messages
1331         # in a previous fetch+index window:
1332         my $git;
1333         if (my @leftovers = values %{delete $sync->{D}}) {
1334                 $git = $self->{-inbox}->git;
1335                 for my $oid (@leftovers) {
1336                         $self->{current_info} = "leftover $oid";
1337                         unindex_oid($self, $git, $oid);
1338                 }
1339         }
1340         if (my $multi_mid = delete $sync->{multi_mid}) {
1341                 $git //= $self->{-inbox}->git;
1342                 my ($min, $max) = $multi_mid->minmax;
1343                 if ($sync->{reindex}) {
1344                         # we may need to create new Message-IDs if mirrors
1345                         # were initially indexed with old versions
1346                         for (my $i = $max; $i >= $min; $i--) {
1347                                 my $oid = $multi_mid->mid_for($i);
1348                                 next unless defined $oid;
1349                                 reindex_oid_m($self, $sync, $git, $oid);
1350                         }
1351                 } else { # regen on initial index
1352                         for my $num ($min..$max) {
1353                                 my $oid = $multi_mid->mid_for($num);
1354                                 next unless defined $oid;
1355                                 reindex_oid_m($self, $sync, $git, $oid, $num);
1356                         }
1357                 }
1358         }
1359         $git->cleanup if $git;
1360         $self->done;
1361
1362         if (my $nr = $sync->{nr}) {
1363                 my $pr = $sync->{-opt}->{-progress};
1364                 $pr->('all.git '.sprintf($sync->{-regen_fmt}, $nr)) if $pr;
1365         }
1366
1367         # reindex does not pick up new changes, so we rerun w/o it:
1368         if ($opt->{reindex}) {
1369                 my %again = %$opt;
1370                 $sync = undef;
1371                 delete @again{qw(reindex -skip_lock)};
1372                 index_sync($self, \%again);
1373         }
1374 }
1375
1376 1;