lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 package PublicInbox::V2Writable;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::Lock);
   9 use PublicInbox::SearchIdxPart;
  10 use PublicInbox::MIME;
  11 use PublicInbox::Git;
  12 use PublicInbox::Import;
  13 use PublicInbox::MID qw(mids);
  14 use PublicInbox::ContentId qw(content_id content_digest);
  15 use PublicInbox::Inbox;
  16 use PublicInbox::OverIdxFork;
  17 use PublicInbox::Msgmap;
  18 use PublicInbox::Spawn;
  19 use IO::Handle;
  20
  21 # an estimate of the post-packed size to the raw uncompressed size
  22 my $PACKING_FACTOR = 0.4;
  23
  24 # assume 2 cores if GNU nproc(1) is not available
  25 sub nproc () {
  26         int($ENV{NPROC} || `nproc 2>/dev/null` || 2);
  27 }
  28
  29 sub count_partitions ($) {
  30         my ($self) = @_;
  31         my $nparts = 0;
  32         my $xpfx = $self->{xpfx};
  33
  34         # always load existing partitions in case core count changes:
  35         # Also, partition count may change while -watch is running
  36         # due to -compact
  37         if (-d $xpfx) {
  38                 foreach my $part (<$xpfx/*>) {
  39                         -d $part && $part =~ m!/\d+\z! or next;
  40                         eval {
  41                                 Search::Xapian::Database->new($part)->close;
  42                                 $nparts++;
  43                         };
  44                 }
  45         }
  46         $nparts;
  47 }
  48
  49 sub new {
  50         my ($class, $v2ibx, $creat) = @_;
  51         my $dir = $v2ibx->{mainrepo} or die "no mainrepo in inbox\n";
  52         unless (-d $dir) {
  53                 if ($creat) {
  54                         require File::Path;
  55                         File::Path::mkpath($dir);
  56                 } else {
  57                         die "$dir does not exist\n";
  58                 }
  59         }
  60
  61         $v2ibx = PublicInbox::InboxWritable->new($v2ibx);
  62
  63         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
  64         my $self = {
  65                 -inbox => $v2ibx,
  66                 im => undef, #  PublicInbox::Import
  67                 parallel => 1,
  68                 transact_bytes => 0,
  69                 xpfx => $xpfx,
  70                 over => PublicInbox::OverIdxFork->new("$xpfx/over.sqlite3"),
  71                 lock_path => "$dir/inbox.lock",
  72                 # limit each git repo (epoch) to 1GB or so
  73                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
  74                 last_commit => [], # git repo -> commit
  75         };
  76         $self->{partitions} = count_partitions($self) || nproc();
  77         bless $self, $class;
  78 }
  79
  80 sub init_inbox {
  81         my ($self, $parallel) = @_;
  82         $self->{parallel} = $parallel;
  83         $self->idx_init;
  84         my $epoch_max = -1;
  85         git_dir_latest($self, \$epoch_max);
  86         $self->git_init($epoch_max >= 0 ? $epoch_max : 0);
  87         $self->done;
  88 }
  89
  90 # returns undef on duplicate or spam
  91 # mimics Import::add and wraps it for v2
  92 sub add {
  93         my ($self, $mime, $check_cb) = @_;
  94
  95         # spam check:
  96         if ($check_cb) {
  97                 $mime = $check_cb->($mime) or return;
  98         }
  99
 100         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
 101         # as does SQLite 3.4.1+ (released in 2007-07-20), and
 102         # Xapian 1.3.2+ (released 2015-03-15).
 103         # For the most part, we can spawn git-fast-import without
 104         # leaking FDs to it...
 105         $self->idx_init;
 106
 107         my $mid0;
 108         my $num = num_for($self, $mime, \$mid0);
 109         defined $num or return; # duplicate
 110         defined $mid0 or die "BUG: $mid0 undefined\n";
 111         my $im = $self->importer;
 112         my $cmt = $im->add($mime);
 113         $cmt = $im->get_mark($cmt);
 114         my ($oid, $len, $msgref) = @{$im->{last_object}};
 115
 116         my $nparts = $self->{partitions};
 117         my $part = $num % $nparts;
 118         $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 119         my $idx = $self->idx_part($part);
 120         $idx->index_raw($len, $msgref, $num, $oid, $mid0, $mime);
 121         my $n = $self->{transact_bytes} += $len;
 122         if ($n > (PublicInbox::SearchIdx::BATCH_BYTES * $nparts)) {
 123                 $self->checkpoint;
 124         }
 125
 126         $cmt;
 127 }
 128
 129 sub num_for {
 130         my ($self, $mime, $mid0) = @_;
 131         my $mids = mids($mime->header_obj);
 132         if (@$mids) {
 133                 my $mid = $mids->[0];
 134                 my $num = $self->{mm}->mid_insert($mid);
 135                 if (defined $num) { # common case
 136                         $$mid0 = $mid;
 137                         return $num;
 138                 };
 139
 140                 # crap, Message-ID is already known, hope somebody just resent:
 141                 $self->barrier;
 142                 foreach my $m (@$mids) {
 143                         # read-only lookup now safe to do after above barrier
 144                         my $existing = $self->lookup_content($mime, $m);
 145                         # easy, don't store duplicates
 146                         # note: do not add more diagnostic info here since
 147                         # it gets noisy on public-inbox-watch restarts
 148                         return if $existing;
 149                 }
 150
 151                 # very unlikely:
 152                 warn "<$mid> reused for mismatched content\n";
 153
 154                 # try the rest of the mids
 155                 for(my $i = $#$mids; $i >= 1; $i--) {
 156                         my $m = $mids->[$i];
 157                         $num = $self->{mm}->mid_insert($m);
 158                         if (defined $num) {
 159                                 warn "alternative <$m> for <$mid> found\n";
 160                                 $$mid0 = $m;
 161                                 return $num;
 162                         }
 163                 }
 164         }
 165         # none of the existing Message-IDs are good, generate a new one:
 166         num_for_harder($self, $mime, $mid0);
 167 }
 168
 169 sub num_for_harder {
 170         my ($self, $mime, $mid0) = @_;
 171
 172         my $hdr = $mime->header_obj;
 173         my $dig = content_digest($mime);
 174         $$mid0 = PublicInbox::Import::digest2mid($dig);
 175         my $num = $self->{mm}->mid_insert($$mid0);
 176         unless (defined $num) {
 177                 # it's hard to spoof the last Received: header
 178                 my @recvd = $hdr->header_raw('Received');
 179                 $dig->add("Received: $_") foreach (@recvd);
 180                 $$mid0 = PublicInbox::Import::digest2mid($dig);
 181                 $num = $self->{mm}->mid_insert($$mid0);
 182
 183                 # fall back to a random Message-ID and give up determinism:
 184                 until (defined($num)) {
 185                         $dig->add(rand);
 186                         $$mid0 = PublicInbox::Import::digest2mid($dig);
 187                         warn "using random Message-ID <$$mid0> as fallback\n";
 188                         $num = $self->{mm}->mid_insert($$mid0);
 189                 }
 190         }
 191         PublicInbox::Import::append_mid($hdr, $$mid0);
 192         $num;
 193 }
 194
 195 sub idx_part {
 196         my ($self, $part) = @_;
 197         $self->{idx_parts}->[$part];
 198 }
 199
 200 # idempotent
 201 sub idx_init {
 202         my ($self) = @_;
 203         return if $self->{idx_parts};
 204         my $ibx = $self->{-inbox};
 205
 206         # do not leak read-only FDs to child processes, we only have these
 207         # FDs for duplicate detection so they should not be
 208         # frequently activated.
 209         delete $ibx->{$_} foreach (qw(git mm search));
 210
 211         my $over = $self->{over};
 212         $ibx->umask_prepare;
 213         $ibx->with_umask(sub {
 214                 $self->lock_acquire;
 215                 $over->create($self);
 216
 217                 # -compact can change partition count while -watch is idle
 218                 my $nparts = count_partitions($self);
 219                 if ($nparts && $nparts != $self->{partitions}) {
 220                         $self->{partitions} = $nparts;
 221                 }
 222
 223                 # need to create all parts before initializing msgmap FD
 224                 my $max = $self->{partitions} - 1;
 225
 226                 # idx_parts must be visible to all forked processes
 227                 my $idx = $self->{idx_parts} = [];
 228                 for my $i (0..$max) {
 229                         push @$idx, PublicInbox::SearchIdxPart->new($self, $i);
 230                 }
 231
 232                 # Now that all subprocesses are up, we can open the FDs
 233                 # for SQLite:
 234                 my $mm = $self->{mm} = PublicInbox::Msgmap->new_file(
 235                         "$self->{-inbox}->{mainrepo}/msgmap.sqlite3", 1);
 236                 $mm->{dbh}->begin_work;
 237         });
 238 }
 239
 240 sub purge_oids {
 241         my ($self, $purge) = @_; # $purge = { $object_id => 1, ... }
 242         $self->done;
 243         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 244         my $purges = [];
 245         foreach my $i (0..$self->{epoch_max}) {
 246                 my $git = PublicInbox::Git->new("$pfx/$i.git");
 247                 my $im = $self->import_init($git, 0, 1);
 248                 $purges->[$i] = $im->purge_oids($purge);
 249         }
 250         $purges;
 251 }
 252
 253 sub remove_internal {
 254         my ($self, $mime, $cmt_msg, $purge) = @_;
 255         $self->barrier;
 256         $self->idx_init;
 257         my $im = $self->importer unless $purge;
 258         my $ibx = $self->{-inbox};
 259         my $srch = $ibx->search;
 260         my $cid = content_id($mime);
 261         my $parts = $self->{idx_parts};
 262         my $mm = $self->{mm};
 263         my $removed;
 264         my $mids = mids($mime->header_obj);
 265
 266         # We avoid introducing new blobs into git since the raw content
 267         # can be slightly different, so we do not need the user-supplied
 268         # message now that we have the mids and content_id
 269         $mime = undef;
 270         my $mark;
 271
 272         foreach my $mid (@$mids) {
 273                 my %gone;
 274                 $srch->reopen->each_smsg_by_mid($mid, sub {
 275                         my ($smsg) = @_;
 276                         $smsg->load_expand;
 277                         my $msg = $ibx->msg_by_smsg($smsg);
 278                         if (!defined($msg)) {
 279                                 warn "broken smsg for $mid\n";
 280                                 return 1; # continue
 281                         }
 282                         my $orig = $$msg;
 283                         my $cur = PublicInbox::MIME->new($msg);
 284                         if (content_id($cur) eq $cid) {
 285                                 $smsg->{mime} = $cur;
 286                                 $gone{$smsg->num} = [ $smsg, \$orig ];
 287                         }
 288                         1; # continue
 289                 });
 290                 my $n = scalar keys %gone;
 291                 next unless $n;
 292                 if ($n > 1) {
 293                         warn "BUG: multiple articles linked to <$mid>\n",
 294                                 join(',', sort keys %gone), "\n";
 295                 }
 296                 foreach my $num (keys %gone) {
 297                         my ($smsg, $orig) = @{$gone{$num}};
 298                         $mm->num_delete($num);
 299                         # $removed should only be set once assuming
 300                         # no bugs in our deduplication code:
 301                         $removed = $smsg;
 302                         my $oid = $smsg->{blob};
 303                         if ($purge) {
 304                                 $purge->{$oid} = 1;
 305                         } else {
 306                                 ($mark, undef) = $im->remove($orig, $cmt_msg);
 307                         }
 308                         $orig = undef;
 309                         foreach my $idx (@$parts) {
 310                                 $idx->remote_remove($oid, $mid);
 311                         }
 312                 }
 313                 $self->barrier;
 314         }
 315
 316         if (defined $mark) {
 317                 my $cmt = $im->get_mark($mark);
 318                 $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 319         }
 320         if ($purge && scalar keys %$purge) {
 321                 return purge_oids($self, $purge);
 322         }
 323         $removed;
 324 }
 325
 326 sub remove {
 327         my ($self, $mime, $cmt_msg) = @_;
 328         remove_internal($self, $mime, $cmt_msg);
 329 }
 330
 331 sub purge {
 332         my ($self, $mime) = @_;
 333         my $purges = remove_internal($self, $mime, undef, {});
 334         $self->idx_init if @$purges; # ->done is called on purges
 335         for my $i (0..$#$purges) {
 336                 defined(my $cmt = $purges->[$i]) or next;
 337                 $self->{last_commit}->[$i] = $cmt;
 338         }
 339         $purges;
 340 }
 341
 342 sub last_commit_part ($$;$) {
 343         my ($self, $i, $cmt) = @_;
 344         my $v = PublicInbox::Search::SCHEMA_VERSION();
 345         $self->{mm}->last_commit_xap($v, $i, $cmt);
 346 }
 347
 348 sub set_last_commits ($) {
 349         my ($self) = @_;
 350         defined(my $epoch_max = $self->{epoch_max}) or return;
 351         my $last_commit = $self->{last_commit};
 352         foreach my $i (0..$epoch_max) {
 353                 defined(my $cmt = $last_commit->[$i]) or next;
 354                 $last_commit->[$i] = undef;
 355                 last_commit_part($self, $i, $cmt);
 356         }
 357 }
 358
 359 sub done {
 360         my ($self) = @_;
 361         my $im = delete $self->{im};
 362         $im->done if $im; # PublicInbox::Import::done
 363
 364         my $mm = $self->{mm};
 365         $mm->{dbh}->commit if $mm;
 366
 367         # order matters, we can only close {over} after all partitions
 368         # are done because the partitions also write to {over}
 369         my $parts = delete $self->{idx_parts};
 370         if ($parts) {
 371                 $_->remote_commit for @$parts;
 372                 $_->remote_close for @$parts;
 373         }
 374
 375         my $over = $self->{over};
 376         $over->remote_commit;
 377         $over->remote_close;
 378
 379         if ($mm) {
 380                 $mm->{dbh}->begin_work;
 381                 set_last_commits($self);
 382                 $mm->{dbh}->commit;
 383                 delete $self->{mm};
 384         }
 385
 386         $self->{transact_bytes} = 0;
 387         $self->lock_release if $parts;
 388 }
 389
 390 sub checkpoint {
 391         my ($self) = @_;
 392         my $im = $self->{im};
 393         $im->checkpoint if $im; # PublicInbox::Import::checkpoint
 394         $self->barrier(1);
 395 }
 396
 397 # issue a write barrier to ensure all data is visible to other processes
 398 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 399 sub barrier {
 400         my ($self) = @_;
 401
 402         if (my $im = $self->{im}) {
 403                 $im->barrier;
 404         }
 405         my $parts = $self->{idx_parts};
 406         if ($parts) {
 407                 my $dbh = $self->{mm}->{dbh};
 408                 $dbh->commit; # SQLite msgmap data is second in importance
 409
 410                 my $over = $self->{over};
 411
 412                 # Now deal with Xapian and overview DB
 413                 $over->barrier_init(scalar(@$parts));
 414
 415                 # each partition needs to issue a barrier command to over
 416                 $_->remote_barrier foreach @$parts;
 417
 418                 $over->barrier_wait; # wait for each Xapian partition
 419
 420                 # last_commit is special, don't commit these until
 421                 # remote partitions are done:
 422                 $dbh->begin_work;
 423                 set_last_commits($self);
 424                 $dbh->commit;
 425
 426                 $dbh->begin_work;
 427         }
 428         $self->{transact_bytes} = 0;
 429 }
 430
 431 sub git_init {
 432         my ($self, $epoch) = @_;
 433         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 434         my $git_dir = "$pfx/$epoch.git";
 435         my @cmd = (qw(git init --bare -q), $git_dir);
 436         PublicInbox::Import::run_die(\@cmd);
 437
 438         my $all = "$self->{-inbox}->{mainrepo}/all.git";
 439         unless (-d $all) {
 440                 @cmd = (qw(git init --bare -q), $all);
 441                 PublicInbox::Import::run_die(\@cmd);
 442                 @cmd = (qw/git config/, "--file=$all/config",
 443                                 'repack.writeBitmaps', 'true');
 444                 PublicInbox::Import::run_die(\@cmd);
 445         }
 446
 447         @cmd = (qw/git config/, "--file=$git_dir/config",
 448                         'include.path', '../../all.git/config');
 449         PublicInbox::Import::run_die(\@cmd);
 450
 451         my $alt = "$all/objects/info/alternates";
 452         my $new_obj_dir = "../../git/$epoch.git/objects";
 453         my %alts;
 454         if (-e $alt) {
 455                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 456                 %alts = map { chomp; $_ => 1 } (<$fh>);
 457         }
 458         return $git_dir if $alts{$new_obj_dir};
 459         open my $fh, '>>', $alt or die "open >> $alt: $!\n";
 460         print $fh "$new_obj_dir\n" or die "print >> $alt: $!\n";
 461         close $fh or die "close $alt: $!\n";
 462         $git_dir
 463 }
 464
 465 sub git_dir_latest {
 466         my ($self, $max) = @_;
 467         $$max = -1;
 468         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 469         return unless -d $pfx;
 470         my $latest;
 471         opendir my $dh, $pfx or die "opendir $pfx: $!\n";
 472         while (defined(my $git_dir = readdir($dh))) {
 473                 $git_dir =~ m!\A(\d+)\.git\z! or next;
 474                 if ($1 > $$max) {
 475                         $$max = $1;
 476                         $latest = "$pfx/$git_dir";
 477                 }
 478         }
 479         $latest;
 480 }
 481
 482 sub importer {
 483         my ($self) = @_;
 484         my $im = $self->{im};
 485         if ($im) {
 486                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 487                         return $im;
 488                 } else {
 489                         $self->{im} = undef;
 490                         $im->done;
 491                         $self->barrier(1);
 492                         $im = undef;
 493                         my $git_dir = $self->git_init(++$self->{epoch_max});
 494                         my $git = PublicInbox::Git->new($git_dir);
 495                         return $self->import_init($git, 0);
 496                 }
 497         }
 498         my $epoch = 0;
 499         my $max;
 500         my $latest = git_dir_latest($self, \$max);
 501         if (defined $latest) {
 502                 my $git = PublicInbox::Git->new($latest);
 503                 my $packed_bytes = $git->packed_bytes;
 504                 if ($packed_bytes >= $self->{rotate_bytes}) {
 505                         $epoch = $max + 1;
 506                 } else {
 507                         $self->{epoch_max} = $max;
 508                         return $self->import_init($git, $packed_bytes);
 509                 }
 510         }
 511         $self->{epoch_max} = $epoch;
 512         $latest = $self->git_init($epoch);
 513         $self->import_init(PublicInbox::Git->new($latest), 0);
 514 }
 515
 516 sub import_init {
 517         my ($self, $git, $packed_bytes, $tmp) = @_;
 518         my $im = PublicInbox::Import->new($git, undef, undef, $self->{-inbox});
 519         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 520         $im->{want_object_info} = 1;
 521         $im->{lock_path} = undef;
 522         $im->{path_type} = 'v2';
 523         $self->{im} = $im unless $tmp;
 524         $im;
 525 }
 526
 527 # XXX experimental
 528 sub diff ($$$) {
 529         my ($mid, $cur, $new) = @_;
 530         use File::Temp qw(tempfile);
 531         use PublicInbox::Spawn qw(spawn);
 532
 533         my ($ah, $an) = tempfile('email-cur-XXXXXXXX', TMPDIR => 1);
 534         print $ah $cur->as_string or die "print: $!";
 535         close $ah or die "close: $!";
 536         my ($bh, $bn) = tempfile('email-new-XXXXXXXX', TMPDIR => 1);
 537         PublicInbox::Import::drop_unwanted_headers($new);
 538         print $bh $new->as_string or die "print: $!";
 539         close $bh or die "close: $!";
 540         my $cmd = [ qw(diff -u), $an, $bn ];
 541         print STDERR "# MID conflict <$mid>\n";
 542         my $pid = spawn($cmd, undef, { 1 => 2 });
 543         defined $pid or die "diff failed to spawn $!";
 544         waitpid($pid, 0) == $pid or die "diff did not finish";
 545         unlink($an, $bn);
 546 }
 547
 548 sub lookup_content {
 549         my ($self, $mime, $mid) = @_;
 550         my $ibx = $self->{-inbox};
 551
 552         my $srch = $ibx->search->reopen;
 553         my $cid = content_id($mime);
 554         my $found;
 555         $srch->each_smsg_by_mid($mid, sub {
 556                 my ($smsg) = @_;
 557                 $smsg->load_expand;
 558                 my $msg = $ibx->msg_by_smsg($smsg);
 559                 if (!defined($msg)) {
 560                         warn "broken smsg for $mid\n";
 561                         return 1; # continue
 562                 }
 563                 my $cur = PublicInbox::MIME->new($msg);
 564                 if (content_id($cur) eq $cid) {
 565                         $smsg->{mime} = $cur;
 566                         $found = $smsg;
 567                         return 0; # break out of loop
 568                 }
 569
 570                 # XXX DEBUG_DIFF is experimental and may be removed
 571                 diff($mid, $cur, $mime) if $ENV{DEBUG_DIFF};
 572
 573                 1; # continue
 574         });
 575         $found;
 576 }
 577
 578 sub atfork_child {
 579         my ($self) = @_;
 580         my $fh = delete $self->{reindex_pipe};
 581         close $fh if $fh;
 582         if (my $parts = $self->{idx_parts}) {
 583                 $_->atfork_child foreach @$parts;
 584         }
 585         if (my $im = $self->{im}) {
 586                 $im->atfork_child;
 587         }
 588         die "unexpected mm" if $self->{mm};
 589 }
 590
 591 sub mark_deleted {
 592         my ($self, $D, $git, $oid) = @_;
 593         my $msgref = $git->cat_file($oid);
 594         my $mime = PublicInbox::MIME->new($$msgref);
 595         my $mids = mids($mime->header_obj);
 596         my $cid = content_id($mime);
 597         foreach my $mid (@$mids) {
 598                 $D->{"$mid\0$cid"} = 1;
 599         }
 600 }
 601
 602 sub reindex_oid {
 603         my ($self, $mm_tmp, $D, $git, $oid, $regen) = @_;
 604         my $len;
 605         my $msgref = $git->cat_file($oid, \$len);
 606         my $mime = PublicInbox::MIME->new($$msgref);
 607         my $mids = mids($mime->header_obj);
 608         my $cid = content_id($mime);
 609
 610         # get the NNTP article number we used before, highest number wins
 611         # and gets deleted from mm_tmp;
 612         my $mid0;
 613         my $num = -1;
 614         my $del = 0;
 615         foreach my $mid (@$mids) {
 616                 $del += (delete $D->{"$mid\0$cid"} || 0);
 617                 my $n = $mm_tmp->num_for($mid);
 618                 if (defined $n && $n > $num) {
 619                         $mid0 = $mid;
 620                         $num = $n;
 621                 }
 622         }
 623         if (!defined($mid0) && $regen && !$del) {
 624                 $num = $$regen--;
 625                 die "BUG: ran out of article numbers\n" if $num <= 0;
 626                 my $mm = $self->{mm};
 627                 foreach my $mid (reverse @$mids) {
 628                         if ($mm->mid_set($num, $mid) == 1) {
 629                                 $mid0 = $mid;
 630                                 last;
 631                         }
 632                 }
 633                 if (!defined($mid0)) {
 634                         my $id = '<' . join('> <', @$mids) . '>';
 635                         warn "Message-ID $id unusable for $num\n";
 636                         foreach my $mid (@$mids) {
 637                                 defined(my $n = $mm->num_for($mid)) or next;
 638                                 warn "#$n previously mapped for <$mid>\n";
 639                         }
 640                 }
 641         }
 642
 643         if (!defined($mid0) || $del) {
 644                 if (!defined($mid0) && $del) { # expected for deletes
 645                         $$regen--;
 646                         return
 647                 }
 648
 649                 my $id = '<' . join('> <', @$mids) . '>';
 650                 defined($mid0) or
 651                         warn "Skipping $id, no article number found\n";
 652                 if ($del && defined($mid0)) {
 653                         warn "$id was deleted $del " .
 654                                 "time(s) but mapped to article #$num\n";
 655                 }
 656                 return;
 657
 658         }
 659         $mm_tmp->mid_delete($mid0) or
 660                 die "failed to delete <$mid0> for article #$num\n";
 661
 662         my $nparts = $self->{partitions};
 663         my $part = $num % $nparts;
 664         my $idx = $self->idx_part($part);
 665         $idx->index_raw($len, $msgref, $num, $oid, $mid0, $mime);
 666         my $n = $self->{transact_bytes} += $len;
 667         if ($n > (PublicInbox::SearchIdx::BATCH_BYTES * $nparts)) {
 668                 $git->cleanup;
 669                 $mm_tmp->atfork_prepare;
 670                 $self->done; # release lock
 671                 # allow -watch or -mda to write...
 672                 $self->idx_init; # reacquire lock
 673                 $mm_tmp->atfork_parent;
 674         }
 675 }
 676
 677 # only update last_commit for $i on reindex iff newer than current
 678 sub update_last_commit {
 679         my ($self, $git, $i, $cmt) = @_;
 680         my $last = last_commit_part($self, $i);
 681         if (defined $last && is_ancestor($git, $last, $cmt)) {
 682                 my @cmd = (qw(rev-list --count), "$last..$cmt");
 683                 chomp(my $n = $git->qx(@cmd));
 684                 return if $n ne '' && $n == 0;
 685         }
 686         last_commit_part($self, $i, $cmt);
 687 }
 688
 689 sub git_dir_n ($$) { "$_[0]->{-inbox}->{mainrepo}/git/$_[1].git" }
 690
 691 sub last_commits {
 692         my ($self, $epoch_max) = @_;
 693         my $heads = [];
 694         for (my $i = $epoch_max; $i >= 0; $i--) {
 695                 $heads->[$i] = last_commit_part($self, $i);
 696         }
 697         $heads;
 698 }
 699
 700 sub is_ancestor ($$$) {
 701         my ($git, $cur, $tip) = @_;
 702         return 0 unless $git->check($cur);
 703         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 704                 qw(merge-base --is-ancestor), $cur, $tip ];
 705         my $pid = spawn($cmd);
 706         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 707         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 708         $? == 0;
 709 }
 710
 711 sub index_prepare {
 712         my ($self, $opts, $epoch_max, $ranges) = @_;
 713         my $regen_max = 0;
 714         my $head = $self->{-inbox}->{ref_head} || 'refs/heads/master';
 715         for (my $i = $epoch_max; $i >= 0; $i--) {
 716                 die "already indexing!\n" if $self->{index_pipe};
 717                 my $git_dir = git_dir_n($self, $i);
 718                 -d $git_dir or next; # missing parts are fine
 719                 my $git = PublicInbox::Git->new($git_dir);
 720                 chomp(my $tip = $git->qx('rev-parse', $head));
 721                 my $range;
 722                 if (defined(my $cur = $ranges->[$i])) {
 723                         $range = "$cur..$tip";
 724                         if (is_ancestor($git, $cur, $tip)) { # common case
 725                                 my $n = $git->qx(qw(rev-list --count), $range);
 726                                 chomp($n);
 727                                 if ($n == 0) {
 728                                         $ranges->[$i] = undef;
 729                                         next;
 730                                 }
 731                         } else {
 732                                 warn <<"";
 733 discontiguous range: $range
 734 Rewritten history? (in $git_dir)
 735
 736                                 my $base = $git->qx('merge-base', $tip, $cur);
 737                                 chomp $base;
 738                                 if ($base) {
 739                                         $range = "$base..$tip";
 740                                         warn "found merge-base: $base\n"
 741                                 } else {
 742                                         $range = $tip;
 743                                         warn <<"";
 744 discarding history at $cur
 745
 746                                 }
 747                                 warn <<"";
 748 reindexing $git_dir starting at
 749 $range
 750
 751                                 $self->{"unindex-range.$i"} = "$base..$cur";
 752                         }
 753                 } else {
 754                         $range = $tip; # all of it
 755                 }
 756                 $ranges->[$i] = $range;
 757
 758                 # can't use 'rev-list --count' if we use --diff-filter
 759                 my $fh = $git->popen(qw(log --pretty=tformat:%h
 760                                 --no-notes --no-color --no-renames
 761                                 --diff-filter=AM), $range, '--', 'm');
 762                 ++$regen_max while <$fh>;
 763         }
 764         \$regen_max;
 765 }
 766
 767 sub unindex_oid {
 768         my ($self, $git, $oid) = @_;
 769         my $msgref = $git->cat_file($oid);
 770         my $mime = PublicInbox::MIME->new($msgref);
 771         my $mids = mids($mime->header_obj);
 772         $mime = $msgref = undef;
 773
 774         foreach my $mid (@$mids) {
 775                 my %gone;
 776                 $self->{-inbox}->search->reopen->each_smsg_by_mid($mid, sub {
 777                         my ($smsg) = @_;
 778                         $smsg->load_expand;
 779                         $gone{$smsg->num} = 1 if $oid eq $smsg->{blob};
 780                         1; # continue
 781                 });
 782                 my $n = scalar keys %gone;
 783                 next unless $n;
 784                 if ($n > 1) {
 785                         warn "BUG: multiple articles linked to $oid\n",
 786                                 join(',',sort keys %gone), "\n";
 787                 }
 788                 $self->{unindexed}->{$_}++ foreach keys %gone;
 789                 $_->remote_remove($oid, $mid) foreach @{$self->{idx_parts}};
 790                 $self->{over}->remove_oid($oid, $mid);
 791                 $self->barrier;
 792         }
 793 }
 794
 795 my $x40 = qr/[a-f0-9]{40}/;
 796 sub unindex {
 797         my ($self, $opts, $git, $unindex_range) = @_;
 798         my $un = $self->{unindexed} ||= {}; # num => removal count
 799         $self->barrier;
 800         my $before = scalar keys %$un;
 801         my @cmd = qw(log --raw -r
 802                         --no-notes --no-color --no-abbrev --no-renames);
 803         my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $unindex_range);
 804         while (<$fh>) {
 805                 /\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o or next;
 806                 $self->unindex_oid($git, $1);
 807         }
 808         delete $self->{reindex_pipe};
 809         $fh = undef;
 810
 811         return unless $opts->{prune};
 812         my $after = scalar keys %$un;
 813         return if $before == $after;
 814
 815         # ensure any blob can not longer be accessed via dumb HTTP
 816         PublicInbox::Import::run_die(['git', "--git-dir=$git->{git_dir}",
 817                 qw(-c gc.reflogExpire=now gc --prune=all)]);
 818 }
 819
 820 sub index_sync {
 821         my ($self, $opts) = @_;
 822         $opts ||= {};
 823         my $ibx = $self->{-inbox};
 824         my $epoch_max;
 825         my $latest = git_dir_latest($self, \$epoch_max);
 826         return unless defined $latest;
 827         $self->idx_init; # acquire lock
 828         my $mm_tmp = $self->{mm}->tmp_clone;
 829         my $ranges = $opts->{reindex} ? [] : $self->last_commits($epoch_max);
 830
 831         my ($min, $max) = $mm_tmp->minmax;
 832         my $regen = $self->index_prepare($opts, $epoch_max, $ranges);
 833         $$regen += $max if $max;
 834         my $D = {};
 835         my @cmd = qw(log --raw -r --pretty=tformat:%h
 836                         --no-notes --no-color --no-abbrev --no-renames);
 837
 838         # work backwards through history
 839         my $last_commit = [];
 840         for (my $i = $epoch_max; $i >= 0; $i--) {
 841                 my $git_dir = git_dir_n($self, $i);
 842                 die "already reindexing!\n" if delete $self->{reindex_pipe};
 843                 -d $git_dir or next; # missing parts are fine
 844                 my $git = PublicInbox::Git->new($git_dir);
 845                 my $unindex = delete $self->{"unindex-range.$i"};
 846                 $self->unindex($opts, $git, $unindex) if $unindex;
 847                 defined(my $range = $ranges->[$i]) or next;
 848                 my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $range);
 849                 my $cmt;
 850                 while (<$fh>) {
 851                         if (/\A$x40$/o && !defined($cmt)) {
 852                                 chomp($cmt = $_);
 853                         } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o) {
 854                                 $self->reindex_oid($mm_tmp, $D, $git, $1,
 855                                                 $regen);
 856                         } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\td$/o) {
 857                                 $self->mark_deleted($D, $git, $1);
 858                         }
 859                 }
 860                 $fh = undef;
 861                 delete $self->{reindex_pipe};
 862                 $self->update_last_commit($git, $i, $cmt) if defined $cmt;
 863         }
 864         my @d = sort keys %$D;
 865         if (@d) {
 866                 warn "BUG: ", scalar(@d)," unseen deleted messages marked\n";
 867                 foreach (@d) {
 868                         my ($mid, undef) = split(/\0/, $_, 2);
 869                         warn "<$mid>\n";
 870                 }
 871         }
 872         $self->done;
 873 }
 874
 875 1;