lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 # Used to write to V2 inboxes (see L<public-inbox-v2-format(5)>).
   6 package PublicInbox::V2Writable;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::Lock PublicInbox::IPC);
  10 use PublicInbox::SearchIdxShard;
  11 use PublicInbox::IPC;
  12 use PublicInbox::Eml;
  13 use PublicInbox::Git;
  14 use PublicInbox::Import;
  15 use PublicInbox::MultiGit;
  16 use PublicInbox::MID qw(mids references);
  17 use PublicInbox::ContentHash qw(content_hash content_digest git_sha);
  18 use PublicInbox::InboxWritable;
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Msgmap;
  21 use PublicInbox::Spawn qw(spawn popen_rd run_die);
  22 use PublicInbox::Search;
  23 use PublicInbox::SearchIdx qw(log2stack is_ancestor check_size is_bad_blob);
  24 use IO::Handle; # ->autoflush
  25 use File::Temp ();
  26 use POSIX ();
  27
  28 my $OID = qr/[a-f0-9]{40,}/;
  29 # an estimate of the post-packed size to the raw uncompressed size
  30 our $PACKING_FACTOR = 0.4;
  31
  32 # SATA storage lags behind what CPUs are capable of, so relying on
  33 # nproc(1) can be misleading and having extra Xapian shards is a
  34 # waste of FDs and space.  It can also lead to excessive IO latency
  35 # and slow things down.  Users on NVME or other fast storage can
  36 # use the NPROC env or switches in our script/public-inbox-* programs
  37 # to increase Xapian shards
  38 our $NPROC_MAX_DEFAULT = 4;
  39
  40 sub nproc_shards ($) {
  41         my ($creat_opt) = @_;
  42         my $n = $creat_opt->{nproc} if ref($creat_opt) eq 'HASH';
  43         $n //= $ENV{NPROC};
  44         if (!$n) {
  45                 # assume 2 cores if not detectable or zero
  46                 state $NPROC_DETECTED = PublicInbox::IPC::detect_nproc() || 2;
  47                 $n = $NPROC_DETECTED;
  48                 $n = $NPROC_MAX_DEFAULT if $n > $NPROC_MAX_DEFAULT;
  49         }
  50
  51         # subtract for the main process and git-fast-import
  52         $n -= 1;
  53         $n < 1 ? 1 : $n;
  54 }
  55
  56 sub count_shards ($) {
  57         my ($self) = @_;
  58         # always load existing shards in case core count changes:
  59         # Also, shard count may change while -watch is running
  60         if (my $ibx = $self->{ibx}) {
  61                 my $srch = $ibx->search or return 0;
  62                 delete $ibx->{search};
  63                 $srch->{nshard} // 0
  64         } else { # ExtSearchIdx
  65                 $self->{nshard} = scalar($self->xdb_shards_flat);
  66         }
  67 }
  68
  69 sub new {
  70         # $creat may be any true value, or 0/undef.  A hashref is true,
  71         # and $creat->{nproc} may be set to an integer
  72         my ($class, $v2ibx, $creat) = @_;
  73         $v2ibx = PublicInbox::InboxWritable->new($v2ibx);
  74         my $dir = $v2ibx->assert_usable_dir;
  75         unless (-d $dir) {
  76                 die "$dir does not exist\n" if !$creat;
  77                 require File::Path;
  78                 File::Path::mkpath($dir);
  79         }
  80         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
  81         my $self = {
  82                 ibx => $v2ibx,
  83                 mg => PublicInbox::MultiGit->new($dir, 'all.git', 'git'),
  84                 im => undef, #  PublicInbox::Import
  85                 parallel => 1,
  86                 transact_bytes => 0,
  87                 total_bytes => 0,
  88                 current_info => '',
  89                 xpfx => $xpfx,
  90                 oidx => PublicInbox::OverIdx->new("$xpfx/over.sqlite3"),
  91                 lock_path => "$dir/inbox.lock",
  92                 # limit each git repo (epoch) to 1GB or so
  93                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
  94                 last_commit => [], # git epoch -> commit
  95         };
  96         $self->{oidx}->{-no_fsync} = 1 if $v2ibx->{-no_fsync};
  97         $self->{shards} = count_shards($self) || nproc_shards($creat);
  98         bless $self, $class;
  99 }
 100
 101 # public (for now?)
 102 sub init_inbox {
 103         my ($self, $shards, $skip_epoch, $skip_artnum) = @_;
 104         if (defined $shards) {
 105                 $self->{parallel} = 0 if $shards == 0;
 106                 $self->{shards} = $shards if $shards > 0;
 107         }
 108         $self->idx_init;
 109         $self->{mm}->skip_artnum($skip_artnum) if defined $skip_artnum;
 110         my $max = $self->{ibx}->max_git_epoch;
 111         $max = $skip_epoch if (defined($skip_epoch) && !defined($max));
 112         $self->{mg}->add_epoch($max // 0);
 113         $self->done;
 114 }
 115
 116 # returns undef on duplicate or spam
 117 # mimics Import::add and wraps it for v2
 118 sub add {
 119         my ($self, $eml, $check_cb) = @_;
 120         $self->{ibx}->with_umask(\&_add, $self, $eml, $check_cb);
 121 }
 122
 123 sub idx_shard ($$) {
 124         my ($self, $num) = @_;
 125         $self->{idx_shards}->[$num % scalar(@{$self->{idx_shards}})];
 126 }
 127
 128 # indexes a message, returns true if checkpointing is needed
 129 sub do_idx ($$$) {
 130         my ($self, $eml, $smsg) = @_;
 131         $self->{oidx}->add_overview($eml, $smsg);
 132         if ($self->{-need_xapian}) {
 133                 my $idx = idx_shard($self, $smsg->{num});
 134                 $idx->index_eml($eml, $smsg);
 135         }
 136         my $n = $self->{transact_bytes} += $smsg->{bytes};
 137         $n >= $self->{batch_bytes};
 138 }
 139
 140 sub _add {
 141         my ($self, $mime, $check_cb) = @_;
 142
 143         # spam check:
 144         if ($check_cb) {
 145                 $mime = $check_cb->($mime, $self->{ibx}) or return;
 146         }
 147
 148         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
 149         # as does SQLite 3.4.1+ (released in 2007-07-20), and
 150         # Xapian 1.3.2+ (released 2015-03-15).
 151         # For the most part, we can spawn git-fast-import without
 152         # leaking FDs to it...
 153         $self->idx_init;
 154
 155         my ($num, $mid0) = v2_num_for($self, $mime);
 156         defined $num or return; # duplicate
 157         defined $mid0 or die "BUG: \$mid0 undefined\n";
 158         my $im = $self->importer;
 159         my $smsg = bless { mid => $mid0, num => $num }, 'PublicInbox::Smsg';
 160         my $cmt = $im->add($mime, undef, $smsg); # sets $smsg->{ds|ts|blob}
 161         $cmt = $im->get_mark($cmt);
 162         $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 163
 164         if (do_idx($self, $mime, $smsg)) {
 165                 $self->checkpoint;
 166         }
 167
 168         $cmt;
 169 }
 170
 171 sub v2_num_for {
 172         my ($self, $mime) = @_;
 173         my $mids = mids($mime);
 174         if (@$mids) {
 175                 my $mid = $mids->[0];
 176                 my $num = $self->{mm}->mid_insert($mid);
 177                 if (defined $num) { # common case
 178                         return ($num, $mid);
 179                 }
 180
 181                 # crap, Message-ID is already known, hope somebody just resent:
 182                 foreach my $m (@$mids) {
 183                         # read-only lookup now safe to do after above barrier
 184                         # easy, don't store duplicates
 185                         # note: do not add more diagnostic info here since
 186                         # it gets noisy on public-inbox-watch restarts
 187                         return () if content_exists($self, $mime, $m);
 188                 }
 189
 190                 # AltId may pre-populate article numbers (e.g. X-Mail-Count
 191                 # or NNTP article number), use that article number if it's
 192                 # not in Over.
 193                 my $altid = $self->{ibx}->{altid};
 194                 if ($altid && grep(/:file=msgmap\.sqlite3\z/, @$altid)) {
 195                         my $num = $self->{mm}->num_for($mid);
 196
 197                         if (defined $num && !$self->{oidx}->get_art($num)) {
 198                                 return ($num, $mid);
 199                         }
 200                 }
 201
 202                 # very unlikely:
 203                 warn "<$mid> reused for mismatched content\n";
 204
 205                 # try the rest of the mids
 206                 for(my $i = $#$mids; $i >= 1; $i--) {
 207                         my $m = $mids->[$i];
 208                         $num = $self->{mm}->mid_insert($m);
 209                         if (defined $num) {
 210                                 warn "alternative <$m> for <$mid> found\n";
 211                                 return ($num, $m);
 212                         }
 213                 }
 214         }
 215         # none of the existing Message-IDs are good, generate a new one:
 216         v2_num_for_harder($self, $mime);
 217 }
 218
 219 sub v2_num_for_harder {
 220         my ($self, $eml) = @_;
 221
 222         my $dig = content_digest($eml);
 223         my $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 224         my $num = $self->{mm}->mid_insert($mid0);
 225         unless (defined $num) {
 226                 # it's hard to spoof the last Received: header
 227                 my @recvd = $eml->header_raw('Received');
 228                 $dig->add("Received: $_") foreach (@recvd);
 229                 $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 230                 $num = $self->{mm}->mid_insert($mid0);
 231
 232                 # fall back to a random Message-ID and give up determinism:
 233                 until (defined($num)) {
 234                         $dig->add(rand);
 235                         $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 236                         warn "using random Message-ID <$mid0> as fallback\n";
 237                         $num = $self->{mm}->mid_insert($mid0);
 238                 }
 239         }
 240         PublicInbox::Import::append_mid($eml, $mid0);
 241         ($num, $mid0);
 242 }
 243
 244 sub _idx_init { # with_umask callback
 245         my ($self, $opt) = @_;
 246         $self->lock_acquire unless $opt && $opt->{-skip_lock};
 247         $self->{oidx}->create;
 248
 249         # xcpdb can change shard count while -watch is idle
 250         my $nshards = count_shards($self);
 251         $self->{shards} = $nshards if $nshards && $nshards != $self->{shards};
 252         $self->{batch_bytes} = $opt->{batch_size} //
 253                                 $PublicInbox::SearchIdx::BATCH_BYTES;
 254
 255         # need to create all shards before initializing msgmap FD
 256         # idx_shards must be visible to all forked processes
 257         my $max = $self->{shards} - 1;
 258         my $idx = $self->{idx_shards} = [];
 259         push @$idx, PublicInbox::SearchIdxShard->new($self, $_) for (0..$max);
 260         $self->{-need_xapian} = $idx->[0]->need_xapian;
 261
 262         # SearchIdxShard may do their own flushing, so don't scale
 263         # until after forking
 264         $self->{batch_bytes} *= $self->{shards} if $self->{parallel};
 265
 266         my $ibx = $self->{ibx} or return; # ExtIdxSearch
 267
 268         # Now that all subprocesses are up, we can open the FDs
 269         # for SQLite:
 270         my $mm = $self->{mm} = PublicInbox::Msgmap->new_file($ibx, 1);
 271         $mm->{dbh}->begin_work;
 272 }
 273
 274 sub parallel_init ($$) {
 275         my ($self, $indexlevel) = @_;
 276         $self->{parallel} = 0 if ($indexlevel // 'full') eq 'basic';
 277 }
 278
 279 # idempotent
 280 sub idx_init {
 281         my ($self, $opt) = @_;
 282         return if $self->{idx_shards};
 283         my $ibx = $self->{ibx};
 284
 285         # do not leak read-only FDs to child processes, we only have these
 286         # FDs for duplicate detection so they should not be
 287         # frequently activated.
 288         delete @$ibx{qw(mm search)};
 289         $ibx->git->cleanup;
 290
 291         parallel_init($self, $ibx->{indexlevel});
 292         $ibx->with_umask(\&_idx_init, $self, $opt);
 293 }
 294
 295 # returns an array mapping [ epoch => latest_commit ]
 296 # latest_commit may be undef if nothing was done to that epoch
 297 # $replace_map = { $object_id => $strref, ... }
 298 sub _replace_oids ($$$) {
 299         my ($self, $mime, $replace_map) = @_;
 300         $self->done;
 301         my $ibx = $self->{ibx};
 302         my $pfx = "$ibx->{inboxdir}/git";
 303         my $rewrites = []; # epoch => commit
 304         my $max = $self->{epoch_max} //= $ibx->max_git_epoch // return;
 305
 306         foreach my $i (0..$max) {
 307                 my $git_dir = "$pfx/$i.git";
 308                 -d $git_dir or next;
 309                 my $git = PublicInbox::Git->new($git_dir);
 310                 my $im = $self->import_init($git, 0, 1);
 311                 $rewrites->[$i] = $im->replace_oids($mime, $replace_map);
 312                 $im->done;
 313         }
 314         $rewrites;
 315 }
 316
 317 sub content_hashes ($) {
 318         my ($mime) = @_;
 319         my @chashes = ( content_hash($mime) );
 320
 321         # We still support Email::MIME, here, and
 322         # Email::MIME->as_string doesn't always round-trip, so we may
 323         # use a second content_hash
 324         my $rt = content_hash(PublicInbox::Eml->new(\($mime->as_string)));
 325         push @chashes, $rt if $chashes[0] ne $rt;
 326         \@chashes;
 327 }
 328
 329 sub content_matches ($$) {
 330         my ($chashes, $existing) = @_;
 331         my $chash = content_hash($existing);
 332         foreach (@$chashes) {
 333                 return 1 if $_ eq $chash
 334         }
 335         0
 336 }
 337
 338 # used for removing or replacing (purging)
 339 sub rewrite_internal ($$;$$$) {
 340         my ($self, $old_eml, $cmt_msg, $new_eml, $sref) = @_;
 341         $self->idx_init;
 342         my ($im, $need_reindex, $replace_map);
 343         if ($sref) {
 344                 $replace_map = {}; # oid => sref
 345                 $need_reindex = [] if $new_eml;
 346         } else {
 347                 $im = $self->importer;
 348         }
 349         my $oidx = $self->{oidx};
 350         my $chashes = content_hashes($old_eml);
 351         my $removed = [];
 352         my $mids = mids($old_eml);
 353
 354         # We avoid introducing new blobs into git since the raw content
 355         # can be slightly different, so we do not need the user-supplied
 356         # message now that we have the mids and content_hash
 357         $old_eml = undef;
 358         my $mark;
 359
 360         foreach my $mid (@$mids) {
 361                 my %gone; # num => [ smsg, $mime, raw ]
 362                 my ($id, $prev);
 363                 while (my $smsg = $oidx->next_by_mid($mid, \$id, \$prev)) {
 364                         my $msg = get_blob($self, $smsg);
 365                         if (!defined($msg)) {
 366                                 warn "broken smsg for $mid\n";
 367                                 next; # continue
 368                         }
 369                         my $orig = $$msg;
 370                         my $cur = PublicInbox::Eml->new($msg);
 371                         if (content_matches($chashes, $cur)) {
 372                                 $gone{$smsg->{num}} = [ $smsg, $cur, \$orig ];
 373                         }
 374                 }
 375                 my $n = scalar keys %gone;
 376                 next unless $n;
 377                 if ($n > 1) {
 378                         warn "BUG: multiple articles linked to <$mid>\n",
 379                                 join(',', sort keys %gone), "\n";
 380                 }
 381                 foreach my $num (keys %gone) {
 382                         my ($smsg, $mime, $orig) = @{$gone{$num}};
 383                         # $removed should only be set once assuming
 384                         # no bugs in our deduplication code:
 385                         $removed = [ undef, $mime, $smsg ];
 386                         my $oid = $smsg->{blob};
 387                         if ($replace_map) {
 388                                 $replace_map->{$oid} = $sref;
 389                         } else {
 390                                 ($mark, undef) = $im->remove($orig, $cmt_msg);
 391                                 $removed->[0] = $mark;
 392                         }
 393                         $orig = undef;
 394                         if ($need_reindex) { # ->replace
 395                                 push @$need_reindex, $smsg;
 396                         } else { # ->purge or ->remove
 397                                 $self->{mm}->num_delete($num);
 398                         }
 399                         unindex_oid_aux($self, $oid, $mid);
 400                 }
 401         }
 402
 403         if (defined $mark) {
 404                 my $cmt = $im->get_mark($mark);
 405                 $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 406         }
 407         if ($replace_map && scalar keys %$replace_map) {
 408                 my $rewrites = _replace_oids($self, $new_eml, $replace_map);
 409                 return { rewrites => $rewrites, need_reindex => $need_reindex };
 410         }
 411         defined($mark) ? $removed : undef;
 412 }
 413
 414 # public (see PublicInbox::Import->remove), but note the 3rd element
 415 # (retval[2]) is not part of the stable API shared with Import->remove
 416 sub remove {
 417         my ($self, $eml, $cmt_msg) = @_;
 418         my $r = $self->{ibx}->with_umask(\&rewrite_internal,
 419                                                 $self, $eml, $cmt_msg);
 420         defined($r) && defined($r->[0]) ? @$r: undef;
 421 }
 422
 423 sub _replace ($$;$$) {
 424         my ($self, $old_eml, $new_eml, $sref) = @_;
 425         my $arg = [ $self, $old_eml, undef, $new_eml, $sref ];
 426         my $rewritten = $self->{ibx}->with_umask(\&rewrite_internal,
 427                         $self, $old_eml, undef, $new_eml, $sref) or return;
 428
 429         my $rewrites = $rewritten->{rewrites};
 430         # ->done is called if there are rewrites since we gc+prune from git
 431         $self->idx_init if @$rewrites;
 432
 433         for my $i (0..$#$rewrites) {
 434                 defined(my $cmt = $rewrites->[$i]) or next;
 435                 $self->{last_commit}->[$i] = $cmt;
 436         }
 437         $rewritten;
 438 }
 439
 440 # public
 441 sub purge {
 442         my ($self, $mime) = @_;
 443         my $rewritten = _replace($self, $mime, undef, \'') or return;
 444         $rewritten->{rewrites}
 445 }
 446
 447 sub _check_mids_match ($$$) {
 448         my ($old_list, $new_list, $hdrs) = @_;
 449         my %old_mids = map { $_ => 1 } @$old_list;
 450         my %new_mids = map { $_ => 1 } @$new_list;
 451         my @old = keys %old_mids;
 452         my @new = keys %new_mids;
 453         my $err = "$hdrs may not be changed when replacing\n";
 454         die $err if scalar(@old) != scalar(@new);
 455         delete @new_mids{@old};
 456         delete @old_mids{@new};
 457         die $err if (scalar(keys %old_mids) || scalar(keys %new_mids));
 458 }
 459
 460 # Changing Message-IDs or References with ->replace isn't supported.
 461 # The rules for dealing with messages with multiple or conflicting
 462 # Message-IDs are pretty complex and rethreading hasn't been fully
 463 # implemented, yet.
 464 sub check_mids_match ($$) {
 465         my ($old, $new) = @_;
 466         _check_mids_match(mids($old), mids($new), 'Message-ID(s)');
 467         _check_mids_match(references($old), references($new),
 468                         'References/In-Reply-To');
 469 }
 470
 471 # public
 472 sub replace ($$$) {
 473         my ($self, $old_mime, $new_mime) = @_;
 474
 475         check_mids_match($old_mime, $new_mime);
 476
 477         # mutt will always add Content-Length:, Status:, Lines: when editing
 478         PublicInbox::Import::drop_unwanted_headers($new_mime);
 479
 480         my $raw = $new_mime->as_string;
 481         my $expect_oid = git_sha(1, \$raw)->hexdigest;
 482         my $rewritten = _replace($self, $old_mime, $new_mime, \$raw) or return;
 483         my $need_reindex = $rewritten->{need_reindex};
 484
 485         # just in case we have bugs in deduplication code:
 486         my $n = scalar(@$need_reindex);
 487         if ($n > 1) {
 488                 my $list = join(', ', map {
 489                                         "$_->{num}: <$_->{mid}>"
 490                                 } @$need_reindex);
 491                 warn <<"";
 492 W: rewritten $n messages matching content of original message (expected: 1).
 493 W: possible bug in public-inbox, NNTP article IDs and Message-IDs follow:
 494 W: $list
 495
 496         }
 497
 498         # make sure we really got the OID:
 499         my ($blob, $type, $bytes) = $self->git->check($expect_oid);
 500         $blob eq $expect_oid or die "BUG: $expect_oid not found after replace";
 501
 502         # don't leak FDs to Xapian:
 503         $self->git->cleanup;
 504
 505         # reindex modified messages:
 506         for my $smsg (@$need_reindex) {
 507                 my $new_smsg = bless {
 508                         blob => $blob,
 509                         num => $smsg->{num},
 510                         mid => $smsg->{mid},
 511                 }, 'PublicInbox::Smsg';
 512                 my $sync = { autime => $smsg->{ds}, cotime => $smsg->{ts} };
 513                 $new_smsg->populate($new_mime, $sync);
 514                 $new_smsg->set_bytes($raw, $bytes);
 515                 do_idx($self, $new_mime, $new_smsg);
 516         }
 517         $rewritten->{rewrites};
 518 }
 519
 520 sub last_epoch_commit ($$;$) {
 521         my ($self, $i, $cmt) = @_;
 522         my $v = PublicInbox::Search::SCHEMA_VERSION();
 523         $self->{mm}->last_commit_xap($v, $i, $cmt);
 524 }
 525
 526 sub set_last_commits ($) { # this is NOT for ExtSearchIdx
 527         my ($self) = @_;
 528         defined(my $epoch_max = $self->{epoch_max}) or return;
 529         my $last_commit = $self->{last_commit};
 530         foreach my $i (0..$epoch_max) {
 531                 defined(my $cmt = $last_commit->[$i]) or next;
 532                 $last_commit->[$i] = undef;
 533                 last_epoch_commit($self, $i, $cmt);
 534         }
 535 }
 536
 537 # public
 538 sub checkpoint ($;$) {
 539         my ($self, $wait) = @_;
 540
 541         if (my $im = $self->{im}) {
 542                 if ($wait) {
 543                         $im->barrier;
 544                 } else {
 545                         $im->checkpoint;
 546                 }
 547         }
 548         my $shards = $self->{idx_shards};
 549         if ($shards) {
 550                 my $dbh = $self->{mm}->{dbh} if $self->{mm};
 551
 552                 # SQLite msgmap data is second in importance
 553                 $dbh->commit if $dbh;
 554                 eval { $dbh->do('PRAGMA optimize') };
 555
 556                 # SQLite overview is third
 557                 $self->{oidx}->commit_lazy;
 558
 559                 # Now deal with Xapian
 560
 561                 # start commit_txn_lazy asynchronously on all parallel shards
 562                 # (non-parallel waits here)
 563                 $_->ipc_do('commit_txn_lazy') for @$shards;
 564
 565                 # transactions started on parallel shards,
 566                 # wait for them by issuing an echo command (echo can only
 567                 # run after commit_txn_lazy is done)
 568                 if ($wait && $self->{parallel}) {
 569                         my $i = 0;
 570                         for my $shard (@$shards) {
 571                                 my $echo = $shard->ipc_do('echo', $i);
 572                                 $echo == $i or die <<"";
 573 shard[$i] bad echo:$echo != $i waiting for txn commit
 574
 575                                 ++$i;
 576                         }
 577                 }
 578
 579                 my $midx = $self->{midx}; # misc index
 580                 if ($midx) {
 581                         $midx->commit_txn;
 582                         $PublicInbox::Search::X{CLOEXEC_UNSET} and
 583                                 $self->git->cleanup;
 584                 }
 585
 586                 # last_commit is special, don't commit these until
 587                 # Xapian shards are done:
 588                 $dbh->begin_work if $dbh;
 589                 set_last_commits($self);
 590                 if ($dbh) {
 591                         $dbh->commit;
 592                         $dbh->begin_work;
 593                 }
 594         }
 595         $self->{total_bytes} += $self->{transact_bytes};
 596         $self->{transact_bytes} = 0;
 597 }
 598
 599 # issue a write barrier to ensure all data is visible to other processes
 600 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 601 # public
 602 sub barrier { checkpoint($_[0], 1) };
 603
 604 # true if locked and active
 605 sub active { !!$_[0]->{im} }
 606
 607 # public
 608 sub done {
 609         my ($self) = @_;
 610         my $err = '';
 611         if (my $im = delete $self->{im}) {
 612                 eval { $im->done }; # PublicInbox::Import::done
 613                 $err .= "import done: $@\n" if $@;
 614         }
 615         if (!$err) {
 616                 eval { checkpoint($self) };
 617                 $err .= "checkpoint: $@\n" if $@;
 618         }
 619         if (my $mm = delete $self->{mm}) {
 620                 my $m = $err ? 'rollback' : 'commit';
 621                 eval { $mm->{dbh}->$m };
 622                 $err .= "msgmap $m: $@\n" if $@;
 623         }
 624         if ($self->{oidx} && $self->{oidx}->{dbh} && $err) {
 625                 eval { $self->{oidx}->rollback_lazy };
 626                 $err .= "overview rollback: $@\n" if $@;
 627         }
 628
 629         my $shards = delete $self->{idx_shards};
 630         if ($shards) {
 631                 for (@$shards) {
 632                         eval { $_->shard_close };
 633                         $err .= "shard close: $@\n" if $@;
 634                 }
 635         }
 636         eval { $self->{oidx}->dbh_close };
 637         $err .= "over close: $@\n" if $@;
 638         delete $self->{midx};
 639         my $nbytes = $self->{total_bytes};
 640         $self->{total_bytes} = 0;
 641         $self->lock_release(!!$nbytes) if $shards;
 642         $self->git->cleanup;
 643         die $err if $err;
 644 }
 645
 646 sub importer {
 647         my ($self) = @_;
 648         my $im = $self->{im};
 649         if ($im) {
 650                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 651                         return $im;
 652                 } else {
 653                         $self->{im} = undef;
 654                         $im->done;
 655                         $im = undef;
 656                         $self->checkpoint;
 657                         my $dir = $self->{mg}->add_epoch(++$self->{epoch_max});
 658                         my $git = PublicInbox::Git->new($dir);
 659                         return $self->import_init($git, 0);
 660                 }
 661         }
 662         my $epoch = 0;
 663         my $max;
 664         my $latest = $self->{ibx}->git_dir_latest(\$max);
 665         if (defined $latest) {
 666                 my $git = PublicInbox::Git->new($latest);
 667                 my $packed_bytes = $git->packed_bytes;
 668                 my $unpacked_bytes = $packed_bytes / $PACKING_FACTOR;
 669
 670                 if ($unpacked_bytes >= $self->{rotate_bytes}) {
 671                         $epoch = $max + 1;
 672                 } else {
 673                         $self->{epoch_max} = $max;
 674                         return $self->import_init($git, $packed_bytes);
 675                 }
 676         }
 677         $self->{epoch_max} = $epoch;
 678         my $dir = $self->{mg}->add_epoch($epoch);
 679         $self->import_init(PublicInbox::Git->new($dir), 0);
 680 }
 681
 682 sub import_init {
 683         my ($self, $git, $packed_bytes, $tmp) = @_;
 684         my $im = PublicInbox::Import->new($git, undef, undef, $self->{ibx});
 685         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 686         $im->{lock_path} = undef;
 687         $im->{path_type} = 'v2';
 688         $self->{im} = $im unless $tmp;
 689         $im;
 690 }
 691
 692 # XXX experimental
 693 sub diff ($$$) {
 694         my ($mid, $cur, $new) = @_;
 695
 696         my $ah = File::Temp->new(TEMPLATE => 'email-cur-XXXX', TMPDIR => 1);
 697         print $ah $cur->as_string or die "print: $!";
 698         $ah->flush or die "flush: $!";
 699         PublicInbox::Import::drop_unwanted_headers($new);
 700         my $bh = File::Temp->new(TEMPLATE => 'email-new-XXXX', TMPDIR => 1);
 701         print $bh $new->as_string or die "print: $!";
 702         $bh->flush or die "flush: $!";
 703         my $cmd = [ qw(diff -u), $ah->filename, $bh->filename ];
 704         print STDERR "# MID conflict <$mid>\n";
 705         my $pid = spawn($cmd, undef, { 1 => 2 });
 706         waitpid($pid, 0) == $pid or die "diff did not finish";
 707 }
 708
 709 sub get_blob ($$) {
 710         my ($self, $smsg) = @_;
 711         if (my $im = $self->{im}) {
 712                 my $msg = $im->cat_blob($smsg->{blob});
 713                 return $msg if $msg;
 714         }
 715         # older message, should be in alternates
 716         $self->{ibx}->msg_by_smsg($smsg);
 717 }
 718
 719 sub content_exists ($$$) {
 720         my ($self, $mime, $mid) = @_;
 721         my $oidx = $self->{oidx};
 722         my $chashes = content_hashes($mime);
 723         my ($id, $prev);
 724         while (my $smsg = $oidx->next_by_mid($mid, \$id, \$prev)) {
 725                 my $msg = get_blob($self, $smsg);
 726                 if (!defined($msg)) {
 727                         warn "broken smsg for $mid\n";
 728                         next;
 729                 }
 730                 my $cur = PublicInbox::Eml->new($msg);
 731                 return 1 if content_matches($chashes, $cur);
 732
 733                 # XXX DEBUG_DIFF is experimental and may be removed
 734                 diff($mid, $cur, $mime) if $ENV{DEBUG_DIFF};
 735         }
 736         undef;
 737 }
 738
 739 sub atfork_child {
 740         my ($self) = @_;
 741         if (my $older_siblings = $self->{idx_shards}) {
 742                 $_->ipc_sibling_atfork_child for @$older_siblings;
 743         }
 744         if (my $im = $self->{im}) {
 745                 $im->atfork_child;
 746         }
 747         die "BUG: unexpected mm" if $self->{mm};
 748 }
 749
 750 sub reindex_checkpoint ($$) {
 751         my ($self, $sync) = @_;
 752
 753         $self->git->async_wait_all;
 754         $self->update_last_commit($sync);
 755         ${$sync->{need_checkpoint}} = 0;
 756         my $mm_tmp = $sync->{mm_tmp};
 757         $mm_tmp->atfork_prepare if $mm_tmp;
 758         die 'BUG: {im} during reindex' if $self->{im};
 759         if ($self->{ibx_map} && !$sync->{checkpoint_unlocks}) {
 760                 checkpoint($self, 1); # no need to release lock on pure index
 761         } else {
 762                 $self->done; # release lock
 763         }
 764
 765         if (my $pr = $sync->{-regen_fmt} ? $sync->{-opt}->{-progress} : undef) {
 766                 $pr->(sprintf($sync->{-regen_fmt}, ${$sync->{nr}}));
 767         }
 768
 769         # allow -watch or -mda to write...
 770         $self->idx_init($sync->{-opt}); # reacquire lock
 771         if (my $intvl = $sync->{check_intvl}) { # eidx
 772                 $sync->{next_check} = PublicInbox::DS::now() + $intvl;
 773         }
 774         $mm_tmp->atfork_parent if $mm_tmp;
 775 }
 776
 777 sub index_finalize ($$) {
 778         my ($arg, $index) = @_;
 779         ++$arg->{self}->{nidx};
 780         if (defined(my $cur = $arg->{cur_cmt})) {
 781                 ${$arg->{latest_cmt}} = $cur;
 782         } elsif ($index) {
 783                 die 'BUG: {cur_cmt} missing';
 784         } # else { unindexing @leftovers doesn't set {cur_cmt}
 785 }
 786
 787 sub index_oid { # cat_async callback
 788         my ($bref, $oid, $type, $size, $arg) = @_;
 789         is_bad_blob($oid, $type, $size, $arg->{oid}) and
 790                 return index_finalize($arg, 1); # size == 0 purged returns here
 791         my $self = $arg->{self};
 792         local $self->{current_info} = "$self->{current_info} $oid";
 793         my ($num, $mid0);
 794         my $eml = PublicInbox::Eml->new($$bref);
 795         my $mids = mids($eml);
 796         my $chash = content_hash($eml);
 797
 798         if (scalar(@$mids) == 0) {
 799                 warn "E: $oid has no Message-ID, skipping\n";
 800                 return;
 801         }
 802
 803         # {unindexed} is unlikely
 804         if (my $unindexed = $arg->{unindexed}) {
 805                 my $oidbin = pack('H*', $oid);
 806                 my $u = $unindexed->{$oidbin};
 807                 ($num, $mid0) = splice(@$u, 0, 2) if $u;
 808                 if (defined $num) {
 809                         $self->{mm}->mid_set($num, $mid0);
 810                         if (scalar(@$u) == 0) { # done with current OID
 811                                 delete $unindexed->{$oidbin};
 812                                 delete($arg->{unindexed}) if !keys(%$unindexed);
 813                         }
 814                 }
 815         }
 816         my $oidx = $self->{oidx};
 817         if (!defined($num)) { # reuse if reindexing (or duplicates)
 818                 for my $mid (@$mids) {
 819                         ($num, $mid0) = $oidx->num_mid0_for_oid($oid, $mid);
 820                         last if defined $num;
 821                 }
 822         }
 823         $mid0 //= do { # is this a number we got before?
 824                 $num = $arg->{mm_tmp}->num_for($mids->[0]);
 825
 826                 # don't clobber existing if Message-ID is reused:
 827                 if (my $x = defined($num) ? $oidx->get_art($num) : undef) {
 828                         undef($num) if $x->{blob} ne $oid;
 829                 }
 830                 defined($num) ? $mids->[0] : undef;
 831         };
 832         if (!defined($num)) {
 833                 for (my $i = $#$mids; $i >= 1; $i--) {
 834                         $num = $arg->{mm_tmp}->num_for($mids->[$i]);
 835                         if (defined($num)) {
 836                                 $mid0 = $mids->[$i];
 837                                 last;
 838                         }
 839                 }
 840         }
 841         if (defined($num)) {
 842                 $arg->{mm_tmp}->num_delete($num);
 843         } else { # never seen
 844                 $num = $self->{mm}->mid_insert($mids->[0]);
 845                 if (defined($num)) {
 846                         $mid0 = $mids->[0];
 847                 } else { # rare, try the rest of them, backwards
 848                         for (my $i = $#$mids; $i >= 1; $i--) {
 849                                 $num = $self->{mm}->mid_insert($mids->[$i]);
 850                                 if (defined($num)) {
 851                                         $mid0 = $mids->[$i];
 852                                         last;
 853                                 }
 854                         }
 855                 }
 856         }
 857         if (!defined($num)) {
 858                 warn "E: $oid <", join('> <', @$mids), "> is a duplicate\n";
 859                 return;
 860         }
 861         ++${$arg->{nr}};
 862         my $smsg = bless {
 863                 num => $num,
 864                 blob => $oid,
 865                 mid => $mid0,
 866         }, 'PublicInbox::Smsg';
 867         $smsg->populate($eml, $arg);
 868         $smsg->set_bytes($$bref, $size);
 869         if (do_idx($self, $eml, $smsg)) {
 870                 ${$arg->{need_checkpoint}} = 1;
 871         }
 872         index_finalize($arg, 1);
 873 }
 874
 875 # only update last_commit for $i on reindex iff newer than current
 876 sub update_last_commit {
 877         my ($self, $sync, $stk) = @_;
 878         my $unit = $sync->{unit} // return;
 879         my $latest_cmt = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 880         defined($latest_cmt) or return;
 881         my $last = last_epoch_commit($self, $unit->{epoch});
 882         if (defined $last && is_ancestor($self->git, $last, $latest_cmt)) {
 883                 my @cmd = (qw(rev-list --count), "$last..$latest_cmt");
 884                 chomp(my $n = $unit->{git}->qx(@cmd));
 885                 return if $n ne '' && $n == 0;
 886         }
 887         # don't rewind if --{since,until,before,after} are in use
 888         return if (defined($last) &&
 889                         grep(defined, @{$sync->{-opt}}{qw(since until)}) &&
 890                         is_ancestor($self->git, $latest_cmt, $last));
 891
 892         last_epoch_commit($self, $unit->{epoch}, $latest_cmt);
 893 }
 894
 895 sub last_commits {
 896         my ($self, $sync) = @_;
 897         my $heads = [];
 898         for (my $i = $sync->{epoch_max}; $i >= 0; $i--) {
 899                 $heads->[$i] = last_epoch_commit($self, $i);
 900         }
 901         $heads;
 902 }
 903
 904 # returns a revision range for git-log(1)
 905 sub log_range ($$$) {
 906         my ($sync, $unit, $tip) = @_;
 907         my $opt = $sync->{-opt};
 908         my $pr = $opt->{-progress} if (($opt->{verbose} || 0) > 1);
 909         my $i = $unit->{epoch};
 910         my $cur = $sync->{ranges}->[$i] or do {
 911                 $pr->("$i.git indexing all of $tip\n") if $pr;
 912                 return $tip; # all of it
 913         };
 914
 915         # fast equality check to avoid (v)fork+execve overhead
 916         if ($cur eq $tip) {
 917                 $sync->{ranges}->[$i] = undef;
 918                 return;
 919         }
 920
 921         my $range = "$cur..$tip";
 922         $pr->("$i.git checking contiguity... ") if $pr;
 923         my $git = $unit->{git};
 924         if (is_ancestor($sync->{self}->git, $cur, $tip)) { # common case
 925                 $pr->("OK\n") if $pr;
 926                 my $n = $git->qx(qw(rev-list --count), $range);
 927                 chomp($n);
 928                 if ($n == 0) {
 929                         $sync->{ranges}->[$i] = undef;
 930                         $pr->("$i.git has nothing new\n") if $pr;
 931                         return; # nothing to do
 932                 }
 933                 $pr->("$i.git has $n changes since $cur\n") if $pr;
 934         } else {
 935                 $pr->("FAIL\n") if $pr;
 936                 warn <<"";
 937 discontiguous range: $range
 938 Rewritten history? (in $git->{git_dir})
 939
 940                 chomp(my $base = $git->qx('merge-base', $tip, $cur));
 941                 if ($base) {
 942                         $range = "$base..$tip";
 943                         warn "found merge-base: $base\n"
 944                 } else {
 945                         $range = $tip;
 946                         warn "discarding history at $cur\n";
 947                 }
 948                 warn <<"";
 949 reindexing $git->{git_dir}
 950 starting at $range
 951
 952                 # $cur^0 may no longer exist if pruned by git
 953                 if ($git->qx(qw(rev-parse -q --verify), "$cur^0")) {
 954                         $unit->{unindex_range} = "$base..$cur";
 955                 } elsif ($base && $git->qx(qw(rev-parse -q --verify), $base)) {
 956                         $unit->{unindex_range} = "$base..";
 957                 } else {
 958                         warn "W: unable to unindex before $range\n";
 959                 }
 960         }
 961         $range;
 962 }
 963
 964 # overridden by ExtSearchIdx
 965 sub artnum_max { $_[0]->{mm}->num_highwater }
 966
 967 sub sync_prepare ($$) {
 968         my ($self, $sync) = @_;
 969         $sync->{ranges} = sync_ranges($self, $sync);
 970         my $pr = $sync->{-opt}->{-progress};
 971         my $regen_max = 0;
 972         my $head = $sync->{ibx}->{ref_head} || 'HEAD';
 973         my $pfx;
 974         if ($pr) {
 975                 ($pfx) = ($sync->{ibx}->{inboxdir} =~ m!([^/]+)\z!g);
 976                 $pfx //= $sync->{ibx}->{inboxdir};
 977         }
 978
 979         my $reindex_heads;
 980         if ($self->{ibx_map}) {
 981                 # ExtSearchIdx won't index messages unless they're in
 982                 # over.sqlite3 for a given inbox, so don't read beyond
 983                 # what's in the per-inbox index.
 984                 $reindex_heads = [];
 985                 my $v = PublicInbox::Search::SCHEMA_VERSION;
 986                 my $mm = $sync->{ibx}->mm;
 987                 for my $i (0..$sync->{epoch_max}) {
 988                         $reindex_heads->[$i] = $mm->last_commit_xap($v, $i);
 989                 }
 990         } elsif ($sync->{reindex}) { # V2 inbox
 991                 # reindex stops at the current heads and we later
 992                 # rerun index_sync without {reindex}
 993                 $reindex_heads = $self->last_commits($sync);
 994         }
 995         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
 996                 $sync->{index_oid} = $self->can('index_oid');
 997         }
 998         my $git_pfx = "$sync->{ibx}->{inboxdir}/git";
 999         for (my $i = $sync->{epoch_max}; $i >= 0; $i--) {
1000                 my $git_dir = "$git_pfx/$i.git";
1001                 -d $git_dir or next; # missing epochs are fine
1002                 my $git = PublicInbox::Git->new($git_dir);
1003                 my $unit = { git => $git, epoch => $i };
1004                 my $tip;
1005                 if ($reindex_heads) {
1006                         $tip = $head = $reindex_heads->[$i] or next;
1007                 } else {
1008                         $tip = $git->qx(qw(rev-parse -q --verify), $head);
1009                         next if $?; # new repo
1010                         chomp $tip;
1011                 }
1012                 my $range = log_range($sync, $unit, $tip) or next;
1013                 # can't use 'rev-list --count' if we use --diff-filter
1014                 $pr->("$pfx $i.git counting $range ... ") if $pr;
1015                 # Don't bump num_highwater on --reindex by using {D}.
1016                 # We intentionally do NOT use {D} in the non-reindex case
1017                 # because we want NNTP article number gaps from unindexed
1018                 # messages to show up in mirrors, too.
1019                 $sync->{D} //= $sync->{reindex} ? {} : undef; # OID_BIN => NR
1020                 my $stk = log2stack($sync, $git, $range);
1021                 return 0 if $sync->{quit};
1022                 my $nr = $stk ? $stk->num_records : 0;
1023                 $pr->("$nr\n") if $pr;
1024                 $unit->{stack} = $stk; # may be undef
1025                 unshift @{$sync->{todo}}, $unit;
1026                 $regen_max += $nr;
1027         }
1028         return 0 if $sync->{quit};
1029
1030         # XXX this should not happen unless somebody bypasses checks in
1031         # our code and blindly injects "d" file history into git repos
1032         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
1033                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
1034                 local $self->{current_info} = 'leftover ';
1035                 my $unindex_oid = $self->can('unindex_oid');
1036                 for my $oid (@leftovers) {
1037                         last if $sync->{quit};
1038                         $oid = unpack('H*', $oid);
1039                         my $req = { %$sync, oid => $oid };
1040                         $self->git->cat_async($oid, $unindex_oid, $req);
1041                 }
1042                 $self->git->async_wait_all;
1043         }
1044         return 0 if $sync->{quit};
1045         if (!$regen_max) {
1046                 $sync->{-regen_fmt} = "%u/?\n";
1047                 return 0;
1048         }
1049
1050         # reindex should NOT see new commits anymore, if we do,
1051         # it's a problem and we need to notice it via die()
1052         my $pad = length($regen_max) + 1;
1053         $sync->{-regen_fmt} = "% ${pad}u/$regen_max\n";
1054         $sync->{nr} = \(my $nr = 0);
1055         return -1 if $sync->{reindex};
1056         $regen_max + $self->artnum_max || 0;
1057 }
1058
1059 sub unindex_oid_aux ($$$) {
1060         my ($self, $oid, $mid) = @_;
1061         my @removed = $self->{oidx}->remove_oid($oid, $mid);
1062         return unless $self->{-need_xapian};
1063         for my $num (@removed) {
1064                 idx_shard($self, $num)->ipc_do('xdb_remove', $num);
1065         }
1066 }
1067
1068 sub unindex_oid ($$;$) { # git->cat_async callback
1069         my ($bref, $oid, $type, $size, $arg) = @_;
1070         is_bad_blob($oid, $type, $size, $arg->{oid}) and
1071                 return index_finalize($arg, 0);
1072         my $self = $arg->{self};
1073         local $self->{current_info} = "$self->{current_info} $oid";
1074         my $unindexed = $arg->{in_unindex} ? $arg->{unindexed} : undef;
1075         my $mm = $self->{mm};
1076         my $mids = mids(PublicInbox::Eml->new($bref));
1077         undef $$bref;
1078         my $oidx = $self->{oidx};
1079         foreach my $mid (@$mids) {
1080                 my %gone;
1081                 my ($id, $prev);
1082                 while (my $smsg = $oidx->next_by_mid($mid, \$id, \$prev)) {
1083                         $gone{$smsg->{num}} = 1 if $oid eq $smsg->{blob};
1084                 }
1085                 my $n = scalar(keys(%gone)) or next;
1086                 if ($n > 1) {
1087                         warn "BUG: multiple articles linked to $oid\n",
1088                                 join(',',sort keys %gone), "\n";
1089                 }
1090                 # reuse (num => mid) mapping in ascending numeric order
1091                 for my $num (sort { $a <=> $b } keys %gone) {
1092                         $num += 0;
1093                         if ($unindexed) {
1094                                 my $mid0 = $mm->mid_for($num);
1095                                 my $oidbin = pack('H*', $oid);
1096                                 push @{$unindexed->{$oidbin}}, $num, $mid0;
1097                         }
1098                         $mm->num_delete($num);
1099                 }
1100                 unindex_oid_aux($self, $oid, $mid);
1101         }
1102         index_finalize($arg, 0);
1103 }
1104
1105 sub git { $_[0]->{ibx}->git }
1106
1107 # this is rare, it only happens when we get discontiguous history in
1108 # a mirror because the source used -purge or -edit
1109 sub unindex_todo ($$$) {
1110         my ($self, $sync, $unit) = @_;
1111         my $unindex_range = delete($unit->{unindex_range}) // return;
1112         my $unindexed = $sync->{unindexed} //= {}; # $oidbin => [$num, $mid0]
1113         my $before = scalar keys %$unindexed;
1114         # order does not matter, here:
1115         my $fh = $unit->{git}->popen(qw(log --raw -r --no-notes --no-color
1116                                 --no-abbrev --no-renames), $unindex_range);
1117         local $sync->{in_unindex} = 1;
1118         my $unindex_oid = $self->can('unindex_oid');
1119         while (<$fh>) {
1120                 /\A:\d{6} 100644 $OID ($OID) [AM]\tm$/o or next;
1121                 $self->git->cat_async($1, $unindex_oid, { %$sync, oid => $1 });
1122         }
1123         close $fh or die "git log failed: \$?=$?";
1124         $self->git->async_wait_all;
1125
1126         return unless $sync->{-opt}->{prune};
1127         my $after = scalar keys %$unindexed;
1128         return if $before == $after;
1129
1130         # ensure any blob can not longer be accessed via dumb HTTP
1131         run_die(['git', "--git-dir=$unit->{git}->{git_dir}",
1132                 qw(-c gc.reflogExpire=now gc --prune=all --quiet)]);
1133 }
1134
1135 sub sync_ranges ($$) {
1136         my ($self, $sync) = @_;
1137         my $reindex = $sync->{reindex};
1138         return $self->last_commits($sync) unless $reindex;
1139         return [] if ref($reindex) ne 'HASH';
1140
1141         my $ranges = $reindex->{from}; # arrayref;
1142         if (ref($ranges) ne 'ARRAY') {
1143                 die 'BUG: $reindex->{from} not an ARRAY';
1144         }
1145         $ranges;
1146 }
1147
1148 sub index_xap_only { # git->cat_async callback
1149         my ($bref, $oid, $type, $size, $smsg) = @_;
1150         my $self = delete $smsg->{self};
1151         my $idx = idx_shard($self, $smsg->{num});
1152         $idx->index_eml(PublicInbox::Eml->new($bref), $smsg);
1153         $self->{transact_bytes} += $smsg->{bytes};
1154 }
1155
1156 sub index_xap_step ($$$;$) {
1157         my ($self, $sync, $beg, $step) = @_;
1158         my $end = $sync->{art_end};
1159         return if $beg > $end; # nothing to do
1160
1161         $step //= $self->{shards};
1162         my $ibx = $self->{ibx};
1163         if (my $pr = $sync->{-opt}->{-progress}) {
1164                 $pr->("Xapian indexlevel=$ibx->{indexlevel} ".
1165                         "$beg..$end (% $step)\n");
1166         }
1167         for (my $num = $beg; $num <= $end; $num += $step) {
1168                 last if $sync->{quit};
1169                 my $smsg = $ibx->over->get_art($num) or next;
1170                 $smsg->{self} = $self;
1171                 $ibx->git->cat_async($smsg->{blob}, \&index_xap_only, $smsg);
1172                 if ($self->{transact_bytes} >= $self->{batch_bytes}) {
1173                         ${$sync->{nr}} = $num;
1174                         reindex_checkpoint($self, $sync);
1175                 }
1176         }
1177 }
1178
1179 sub index_todo ($$$) {
1180         my ($self, $sync, $unit) = @_;
1181         return if $sync->{quit};
1182         unindex_todo($self, $sync, $unit);
1183         my $stk = delete($unit->{stack}) or return;
1184         my $all = $self->git;
1185         my $index_oid = $self->can('index_oid');
1186         my $unindex_oid = $self->can('unindex_oid');
1187         my $pfx;
1188         if ($unit->{git}->{git_dir} =~ m!/([^/]+)/git/([0-9]+\.git)\z!) {
1189                 $pfx = "$1 $2"; # v2
1190         } else { # v1
1191                 ($pfx) = ($unit->{git}->{git_dir} =~ m!/([^/]+)\z!g);
1192                 $pfx //= $unit->{git}->{git_dir};
1193         }
1194         local $self->{current_info} = "$pfx ";
1195         local $sync->{latest_cmt} = \(my $latest_cmt);
1196         local $sync->{unit} = $unit;
1197         while (my ($f, $at, $ct, $oid, $cmt) = $stk->pop_rec) {
1198                 if ($sync->{quit}) {
1199                         warn "waiting to quit...\n";
1200                         $all->async_wait_all;
1201                         $self->update_last_commit($sync);
1202                         return;
1203                 }
1204                 my $req = {
1205                         %$sync,
1206                         autime => $at,
1207                         cotime => $ct,
1208                         oid => $oid,
1209                         cur_cmt => $cmt
1210                 };
1211                 if ($f eq 'm') {
1212                         if ($sync->{max_size}) {
1213                                 $all->check_async($oid, \&check_size, $req);
1214                         } else {
1215                                 $all->cat_async($oid, $index_oid, $req);
1216                         }
1217                 } elsif ($f eq 'd') {
1218                         $all->cat_async($oid, $unindex_oid, $req);
1219                 }
1220                 if (${$sync->{need_checkpoint}}) {
1221                         reindex_checkpoint($self, $sync);
1222                 }
1223         }
1224         $all->async_wait_all;
1225         $self->update_last_commit($sync, $stk);
1226 }
1227
1228 sub xapian_only {
1229         my ($self, $opt, $sync, $art_beg) = @_;
1230         my $seq = $opt->{'sequential-shard'};
1231         $art_beg //= 0;
1232         local $self->{parallel} = 0 if $seq;
1233         $self->idx_init($opt); # acquire lock
1234         if (my $art_end = $self->{ibx}->mm->max) {
1235                 $sync //= {
1236                         need_checkpoint => \(my $bool = 0),
1237                         -opt => $opt,
1238                         self => $self,
1239                         nr => \(my $nr = 0),
1240                         -regen_fmt => "%u/?\n",
1241                 };
1242                 $sync->{art_end} = $art_end;
1243                 if ($seq || !$self->{parallel}) {
1244                         my $shard_end = $self->{shards} - 1;
1245                         for my $i (0..$shard_end) {
1246                                 last if $sync->{quit};
1247                                 index_xap_step($self, $sync, $art_beg + $i);
1248                                 if ($i != $shard_end) {
1249                                         reindex_checkpoint($self, $sync);
1250                                 }
1251                         }
1252                 } else { # parallel (maybe)
1253                         index_xap_step($self, $sync, $art_beg, 1);
1254                 }
1255         }
1256         $self->git->async_wait_all;
1257         $self->{ibx}->cleanup;
1258         $self->done;
1259 }
1260
1261 # public, called by public-inbox-index
1262 sub index_sync {
1263         my ($self, $opt) = @_;
1264         $opt //= {};
1265         return xapian_only($self, $opt) if $opt->{xapian_only};
1266
1267         my $epoch_max;
1268         my $latest = $self->{ibx}->git_dir_latest(\$epoch_max) // return;
1269         if ($opt->{'fast-noop'}) { # nanosecond (st_ctim) comparison
1270                 use Time::HiRes qw(stat);
1271                 if (my @mm = stat("$self->{ibx}->{inboxdir}/msgmap.sqlite3")) {
1272                         my $c = $mm[10]; # 10 = ctime (nsec NV)
1273                         my @hd = stat("$latest/refs/heads");
1274                         my @pr = stat("$latest/packed-refs");
1275                         return if $c > ($hd[10] // 0) && $c > ($pr[10] // 0);
1276                 }
1277         }
1278
1279         my $pr = $opt->{-progress};
1280         my $seq = $opt->{'sequential-shard'};
1281         my $art_beg; # the NNTP article number we start xapian_only at
1282         my $idxlevel = $self->{ibx}->{indexlevel};
1283         local $self->{ibx}->{indexlevel} = 'basic' if $seq;
1284
1285         $self->idx_init($opt); # acquire lock
1286         $self->{mg}->fill_alternates;
1287         $self->{oidx}->rethread_prepare($opt);
1288         my $sync = {
1289                 need_checkpoint => \(my $bool = 0),
1290                 reindex => $opt->{reindex},
1291                 -opt => $opt,
1292                 self => $self,
1293                 ibx => $self->{ibx},
1294                 epoch_max => $epoch_max,
1295         };
1296         my $quit = PublicInbox::SearchIdx::quit_cb($sync);
1297         local $SIG{QUIT} = $quit;
1298         local $SIG{INT} = $quit;
1299         local $SIG{TERM} = $quit;
1300
1301         if (sync_prepare($self, $sync)) {
1302                 # tmp_clone seems to fail if inside a transaction, so
1303                 # we rollback here (because we opened {mm} for reading)
1304                 # Note: we do NOT rely on DBI transactions for atomicity;
1305                 # only for batch performance.
1306                 $self->{mm}->{dbh}->rollback;
1307                 $self->{mm}->{dbh}->begin_work;
1308                 $sync->{mm_tmp} =
1309                         $self->{mm}->tmp_clone($self->{ibx}->{inboxdir});
1310
1311                 # xapian_only works incrementally w/o --reindex
1312                 if ($seq && !$opt->{reindex}) {
1313                         $art_beg = $sync->{mm_tmp}->max || -1;
1314                         $art_beg++;
1315                 }
1316         }
1317         # work forwards through history
1318         index_todo($self, $sync, $_) for @{delete($sync->{todo}) // []};
1319         $self->{oidx}->rethread_done($opt) unless $sync->{quit};
1320         $self->done;
1321
1322         if (my $nr = $sync->{nr}) {
1323                 my $pr = $sync->{-opt}->{-progress};
1324                 $pr->('all.git '.sprintf($sync->{-regen_fmt}, $$nr)) if $pr;
1325         }
1326
1327         my $quit_warn;
1328         # deal with Xapian shards sequentially
1329         if ($seq && delete($sync->{mm_tmp})) {
1330                 if ($sync->{quit}) {
1331                         $quit_warn = 1;
1332                 } else {
1333                         $self->{ibx}->{indexlevel} = $idxlevel;
1334                         xapian_only($self, $opt, $sync, $art_beg);
1335                         $quit_warn = 1 if $sync->{quit};
1336                 }
1337         }
1338
1339         # --reindex on the command-line
1340         if (!$sync->{quit} && $opt->{reindex} &&
1341                         !ref($opt->{reindex}) && $idxlevel ne 'basic') {
1342                 $self->lock_acquire;
1343                 my $s0 = PublicInbox::SearchIdx->new($self->{ibx}, 0, 0);
1344                 if (my $xdb = $s0->idx_acquire) {
1345                         my $n = $xdb->get_metadata('has_threadid');
1346                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
1347                 }
1348                 $s0->idx_release;
1349                 $self->lock_release;
1350         }
1351
1352         # reindex does not pick up new changes, so we rerun w/o it:
1353         if ($opt->{reindex} && !$sync->{quit} &&
1354                         !grep(defined, @$opt{qw(since until)})) {
1355                 my %again = %$opt;
1356                 $sync = undef;
1357                 delete @again{qw(rethread reindex -skip_lock)};
1358                 index_sync($self, \%again);
1359                 $opt->{quit} = $again{quit}; # propagate to caller
1360         }
1361         warn <<EOF if $quit_warn;
1362 W: interrupted, --xapian-only --reindex required upon restart
1363 EOF
1364 }
1365
1366 sub ipc_atfork_child {
1367         my ($self) = @_;
1368         if (my $lei = delete $self->{lei}) {
1369                 $lei->_lei_atfork_child;
1370                 my $pkt_op_p = delete $lei->{pkt_op_p};
1371                 close($pkt_op_p->{op_p});
1372         }
1373         $self->SUPER::ipc_atfork_child;
1374 }
1375
1376 1;