lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 # Used to write to V2 inboxes (see L<public-inbox-v2-format(5)>).
   6 package PublicInbox::V2Writable;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::Lock);
  10 use PublicInbox::SearchIdxShard;
  11 use PublicInbox::IdxStack;
  12 use PublicInbox::Eml;
  13 use PublicInbox::Git;
  14 use PublicInbox::Import;
  15 use PublicInbox::MID qw(mids references);
  16 use PublicInbox::ContentHash qw(content_hash content_digest);
  17 use PublicInbox::InboxWritable;
  18 use PublicInbox::OverIdx;
  19 use PublicInbox::Msgmap;
  20 use PublicInbox::Spawn qw(spawn popen_rd);
  21 use PublicInbox::SearchIdx qw(log2stack crlf_adjust is_ancestor check_size);
  22 use IO::Handle; # ->autoflush
  23 use File::Temp qw(tempfile);
  24
  25 my $OID = qr/[a-f0-9]{40,}/;
  26 # an estimate of the post-packed size to the raw uncompressed size
  27 my $PACKING_FACTOR = 0.4;
  28
  29 # SATA storage lags behind what CPUs are capable of, so relying on
  30 # nproc(1) can be misleading and having extra Xapian shards is a
  31 # waste of FDs and space.  It can also lead to excessive IO latency
  32 # and slow things down.  Users on NVME or other fast storage can
  33 # use the NPROC env or switches in our script/public-inbox-* programs
  34 # to increase Xapian shards
  35 our $NPROC_MAX_DEFAULT = 4;
  36
  37 sub detect_nproc () {
  38         for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
  39                 `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
  40         }
  41
  42         # getconf(1) is POSIX, but *NPROCESSORS* vars are not
  43         for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
  44                 `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
  45         }
  46
  47         # should we bother with `sysctl hw.ncpu`?  Those only give
  48         # us total processor count, not online processor count.
  49         undef
  50 }
  51
  52 sub nproc_shards ($) {
  53         my ($creat_opt) = @_;
  54         my $n = $creat_opt->{nproc} if ref($creat_opt) eq 'HASH';
  55         $n //= $ENV{NPROC};
  56         if (!$n) {
  57                 # assume 2 cores if not detectable or zero
  58                 state $NPROC_DETECTED = detect_nproc() || 2;
  59                 $n = $NPROC_DETECTED;
  60                 $n = $NPROC_MAX_DEFAULT if $n > $NPROC_MAX_DEFAULT;
  61         }
  62
  63         # subtract for the main process and git-fast-import
  64         $n -= 1;
  65         $n < 1 ? 1 : $n;
  66 }
  67
  68 sub count_shards ($) {
  69         my ($self) = @_;
  70         my $n = 0;
  71         my $xpfx = $self->{xpfx};
  72
  73         # always load existing shards in case core count changes:
  74         # Also, shard count may change while -watch is running
  75         # due to "xcpdb --reshard"
  76         if (-d $xpfx) {
  77                 my $XapianDatabase;
  78                 foreach my $shard (<$xpfx/*>) {
  79                         -d $shard && $shard =~ m!/[0-9]+\z! or next;
  80                         $XapianDatabase //= do {
  81                                 require PublicInbox::Search;
  82                                 PublicInbox::Search::load_xapian();
  83                                 $PublicInbox::Search::X{Database};
  84                         };
  85                         eval {
  86                                 $XapianDatabase->new($shard)->close;
  87                                 $n++;
  88                         };
  89                 }
  90         }
  91         $n;
  92 }
  93
  94 sub new {
  95         # $creat may be any true value, or 0/undef.  A hashref is true,
  96         # and $creat->{nproc} may be set to an integer
  97         my ($class, $v2ibx, $creat) = @_;
  98         $v2ibx = PublicInbox::InboxWritable->new($v2ibx);
  99         my $dir = $v2ibx->assert_usable_dir;
 100         unless (-d $dir) {
 101                 if ($creat) {
 102                         require File::Path;
 103                         File::Path::mkpath($dir);
 104                 } else {
 105                         die "$dir does not exist\n";
 106                 }
 107         }
 108         $v2ibx->umask_prepare;
 109
 110         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
 111         my $self = {
 112                 ibx => $v2ibx,
 113                 im => undef, #  PublicInbox::Import
 114                 parallel => 1,
 115                 transact_bytes => 0,
 116                 total_bytes => 0,
 117                 current_info => '',
 118                 xpfx => $xpfx,
 119                 over => PublicInbox::OverIdx->new("$xpfx/over.sqlite3"),
 120                 lock_path => "$dir/inbox.lock",
 121                 # limit each git repo (epoch) to 1GB or so
 122                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
 123                 last_commit => [], # git epoch -> commit
 124         };
 125         $self->{over}->{-no_sync} = 1 if $v2ibx->{-no_sync};
 126         $self->{shards} = count_shards($self) || nproc_shards($creat);
 127         bless $self, $class;
 128 }
 129
 130 # public (for now?)
 131 sub init_inbox {
 132         my ($self, $shards, $skip_epoch, $skip_artnum) = @_;
 133         if (defined $shards) {
 134                 $self->{parallel} = 0 if $shards == 0;
 135                 $self->{shards} = $shards if $shards > 0;
 136         }
 137         $self->idx_init;
 138         $self->{mm}->skip_artnum($skip_artnum) if defined $skip_artnum;
 139         my $epoch_max = -1;
 140         git_dir_latest($self, \$epoch_max);
 141         if (defined $skip_epoch && $epoch_max == -1) {
 142                 $epoch_max = $skip_epoch;
 143         }
 144         $self->git_init($epoch_max >= 0 ? $epoch_max : 0);
 145         $self->done;
 146 }
 147
 148 # returns undef on duplicate or spam
 149 # mimics Import::add and wraps it for v2
 150 sub add {
 151         my ($self, $eml, $check_cb) = @_;
 152         $self->{ibx}->with_umask(\&_add, $self, $eml, $check_cb);
 153 }
 154
 155 # indexes a message, returns true if checkpointing is needed
 156 sub do_idx ($$$$) {
 157         my ($self, $msgref, $mime, $smsg) = @_;
 158         $smsg->{bytes} = $smsg->{raw_bytes} + crlf_adjust($$msgref);
 159         $self->{over}->add_overview($mime, $smsg);
 160         my $idx = idx_shard($self, $smsg->{num} % $self->{shards});
 161         $idx->index_raw($msgref, $mime, $smsg);
 162         my $n = $self->{transact_bytes} += $smsg->{raw_bytes};
 163         $n >= ($PublicInbox::SearchIdx::BATCH_BYTES * $self->{shards});
 164 }
 165
 166 sub _add {
 167         my ($self, $mime, $check_cb) = @_;
 168
 169         # spam check:
 170         if ($check_cb) {
 171                 $mime = $check_cb->($mime, $self->{ibx}) or return;
 172         }
 173
 174         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
 175         # as does SQLite 3.4.1+ (released in 2007-07-20), and
 176         # Xapian 1.3.2+ (released 2015-03-15).
 177         # For the most part, we can spawn git-fast-import without
 178         # leaking FDs to it...
 179         $self->idx_init;
 180
 181         my ($num, $mid0) = v2_num_for($self, $mime);
 182         defined $num or return; # duplicate
 183         defined $mid0 or die "BUG: \$mid0 undefined\n";
 184         my $im = $self->importer;
 185         my $smsg = bless { mid => $mid0, num => $num }, 'PublicInbox::Smsg';
 186         my $cmt = $im->add($mime, undef, $smsg); # sets $smsg->{ds|ts|blob}
 187         $cmt = $im->get_mark($cmt);
 188         $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 189
 190         my $msgref = delete $smsg->{-raw_email};
 191         if (do_idx($self, $msgref, $mime, $smsg)) {
 192                 $self->checkpoint;
 193         }
 194
 195         $cmt;
 196 }
 197
 198 sub v2_num_for {
 199         my ($self, $mime) = @_;
 200         my $mids = mids($mime);
 201         if (@$mids) {
 202                 my $mid = $mids->[0];
 203                 my $num = $self->{mm}->mid_insert($mid);
 204                 if (defined $num) { # common case
 205                         return ($num, $mid);
 206                 }
 207
 208                 # crap, Message-ID is already known, hope somebody just resent:
 209                 foreach my $m (@$mids) {
 210                         # read-only lookup now safe to do after above barrier
 211                         # easy, don't store duplicates
 212                         # note: do not add more diagnostic info here since
 213                         # it gets noisy on public-inbox-watch restarts
 214                         return () if content_exists($self, $mime, $m);
 215                 }
 216
 217                 # AltId may pre-populate article numbers (e.g. X-Mail-Count
 218                 # or NNTP article number), use that article number if it's
 219                 # not in Over.
 220                 my $altid = $self->{ibx}->{altid};
 221                 if ($altid && grep(/:file=msgmap\.sqlite3\z/, @$altid)) {
 222                         my $num = $self->{mm}->num_for($mid);
 223
 224                         if (defined $num && !$self->{over}->get_art($num)) {
 225                                 return ($num, $mid);
 226                         }
 227                 }
 228
 229                 # very unlikely:
 230                 warn "<$mid> reused for mismatched content\n";
 231
 232                 # try the rest of the mids
 233                 for(my $i = $#$mids; $i >= 1; $i--) {
 234                         my $m = $mids->[$i];
 235                         $num = $self->{mm}->mid_insert($m);
 236                         if (defined $num) {
 237                                 warn "alternative <$m> for <$mid> found\n";
 238                                 return ($num, $m);
 239                         }
 240                 }
 241         }
 242         # none of the existing Message-IDs are good, generate a new one:
 243         v2_num_for_harder($self, $mime);
 244 }
 245
 246 sub v2_num_for_harder {
 247         my ($self, $eml) = @_;
 248
 249         my $dig = content_digest($eml);
 250         my $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 251         my $num = $self->{mm}->mid_insert($mid0);
 252         unless (defined $num) {
 253                 # it's hard to spoof the last Received: header
 254                 my @recvd = $eml->header_raw('Received');
 255                 $dig->add("Received: $_") foreach (@recvd);
 256                 $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 257                 $num = $self->{mm}->mid_insert($mid0);
 258
 259                 # fall back to a random Message-ID and give up determinism:
 260                 until (defined($num)) {
 261                         $dig->add(rand);
 262                         $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 263                         warn "using random Message-ID <$mid0> as fallback\n";
 264                         $num = $self->{mm}->mid_insert($mid0);
 265                 }
 266         }
 267         PublicInbox::Import::append_mid($eml, $mid0);
 268         ($num, $mid0);
 269 }
 270
 271 sub idx_shard {
 272         my ($self, $shard_i) = @_;
 273         $self->{idx_shards}->[$shard_i];
 274 }
 275
 276 sub _idx_init { # with_umask callback
 277         my ($self, $opt) = @_;
 278         $self->lock_acquire unless $opt && $opt->{-skip_lock};
 279         $self->{over}->create;
 280
 281         # xcpdb can change shard count while -watch is idle
 282         my $nshards = count_shards($self);
 283         $self->{shards} = $nshards if $nshards && $nshards != $self->{shards};
 284
 285         # need to create all shards before initializing msgmap FD
 286         # idx_shards must be visible to all forked processes
 287         my $max = $self->{shards} - 1;
 288         my $idx = $self->{idx_shards} = [];
 289         push @$idx, PublicInbox::SearchIdxShard->new($self, $_) for (0..$max);
 290
 291         # Now that all subprocesses are up, we can open the FDs
 292         # for SQLite:
 293         my $mm = $self->{mm} = PublicInbox::Msgmap->new_file(
 294                                 "$self->{ibx}->{inboxdir}/msgmap.sqlite3",
 295                                 $self->{ibx}->{-no_sync} ? 2 : 1);
 296         $mm->{dbh}->begin_work;
 297 }
 298
 299 # idempotent
 300 sub idx_init {
 301         my ($self, $opt) = @_;
 302         return if $self->{idx_shards};
 303         my $ibx = $self->{ibx};
 304
 305         # do not leak read-only FDs to child processes, we only have these
 306         # FDs for duplicate detection so they should not be
 307         # frequently activated.
 308         delete @$ibx{qw(mm search)};
 309         $ibx->git->cleanup;
 310
 311         $self->{parallel} = 0 if ($ibx->{indexlevel}//'') eq 'basic';
 312         if ($self->{parallel}) {
 313                 pipe(my ($r, $w)) or die "pipe failed: $!";
 314                 # pipe for barrier notifications doesn't need to be big,
 315                 # 1031: F_SETPIPE_SZ
 316                 fcntl($w, 1031, 4096) if $^O eq 'linux';
 317                 $self->{bnote} = [ $r, $w ];
 318                 $w->autoflush(1);
 319         }
 320
 321         $ibx->umask_prepare;
 322         $ibx->with_umask(\&_idx_init, $self, $opt);
 323 }
 324
 325 # returns an array mapping [ epoch => latest_commit ]
 326 # latest_commit may be undef if nothing was done to that epoch
 327 # $replace_map = { $object_id => $strref, ... }
 328 sub _replace_oids ($$$) {
 329         my ($self, $mime, $replace_map) = @_;
 330         $self->done;
 331         my $pfx = "$self->{ibx}->{inboxdir}/git";
 332         my $rewrites = []; # epoch => commit
 333         my $max = $self->{epoch_max};
 334
 335         unless (defined($max)) {
 336                 defined(my $latest = git_dir_latest($self, \$max)) or return;
 337                 $self->{epoch_max} = $max;
 338         }
 339
 340         foreach my $i (0..$max) {
 341                 my $git_dir = "$pfx/$i.git";
 342                 -d $git_dir or next;
 343                 my $git = PublicInbox::Git->new($git_dir);
 344                 my $im = $self->import_init($git, 0, 1);
 345                 $rewrites->[$i] = $im->replace_oids($mime, $replace_map);
 346                 $im->done;
 347         }
 348         $rewrites;
 349 }
 350
 351 sub content_hashes ($) {
 352         my ($mime) = @_;
 353         my @chashes = ( content_hash($mime) );
 354
 355         # We still support Email::MIME, here, and
 356         # Email::MIME->as_string doesn't always round-trip, so we may
 357         # use a second content_hash
 358         my $rt = content_hash(PublicInbox::Eml->new(\($mime->as_string)));
 359         push @chashes, $rt if $chashes[0] ne $rt;
 360         \@chashes;
 361 }
 362
 363 sub content_matches ($$) {
 364         my ($chashes, $existing) = @_;
 365         my $chash = content_hash($existing);
 366         foreach (@$chashes) {
 367                 return 1 if $_ eq $chash
 368         }
 369         0
 370 }
 371
 372 # used for removing or replacing (purging)
 373 sub rewrite_internal ($$;$$$) {
 374         my ($self, $old_eml, $cmt_msg, $new_eml, $sref) = @_;
 375         $self->idx_init;
 376         my ($im, $need_reindex, $replace_map);
 377         if ($sref) {
 378                 $replace_map = {}; # oid => sref
 379                 $need_reindex = [] if $new_eml;
 380         } else {
 381                 $im = $self->importer;
 382         }
 383         my $over = $self->{over};
 384         my $chashes = content_hashes($old_eml);
 385         my $removed = [];
 386         my $mids = mids($old_eml);
 387
 388         # We avoid introducing new blobs into git since the raw content
 389         # can be slightly different, so we do not need the user-supplied
 390         # message now that we have the mids and content_hash
 391         $old_eml = undef;
 392         my $mark;
 393
 394         foreach my $mid (@$mids) {
 395                 my %gone; # num => [ smsg, $mime, raw ]
 396                 my ($id, $prev);
 397                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 398                         my $msg = get_blob($self, $smsg);
 399                         if (!defined($msg)) {
 400                                 warn "broken smsg for $mid\n";
 401                                 next; # continue
 402                         }
 403                         my $orig = $$msg;
 404                         my $cur = PublicInbox::Eml->new($msg);
 405                         if (content_matches($chashes, $cur)) {
 406                                 $gone{$smsg->{num}} = [ $smsg, $cur, \$orig ];
 407                         }
 408                 }
 409                 my $n = scalar keys %gone;
 410                 next unless $n;
 411                 if ($n > 1) {
 412                         warn "BUG: multiple articles linked to <$mid>\n",
 413                                 join(',', sort keys %gone), "\n";
 414                 }
 415                 foreach my $num (keys %gone) {
 416                         my ($smsg, $mime, $orig) = @{$gone{$num}};
 417                         # $removed should only be set once assuming
 418                         # no bugs in our deduplication code:
 419                         $removed = [ undef, $mime, $smsg ];
 420                         my $oid = $smsg->{blob};
 421                         if ($replace_map) {
 422                                 $replace_map->{$oid} = $sref;
 423                         } else {
 424                                 ($mark, undef) = $im->remove($orig, $cmt_msg);
 425                                 $removed->[0] = $mark;
 426                         }
 427                         $orig = undef;
 428                         if ($need_reindex) { # ->replace
 429                                 push @$need_reindex, $smsg;
 430                         } else { # ->purge or ->remove
 431                                 $self->{mm}->num_delete($num);
 432                         }
 433                         unindex_oid_remote($self, $oid, $mid);
 434                 }
 435         }
 436
 437         if (defined $mark) {
 438                 my $cmt = $im->get_mark($mark);
 439                 $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 440         }
 441         if ($replace_map && scalar keys %$replace_map) {
 442                 my $rewrites = _replace_oids($self, $new_eml, $replace_map);
 443                 return { rewrites => $rewrites, need_reindex => $need_reindex };
 444         }
 445         defined($mark) ? $removed : undef;
 446 }
 447
 448 # public (see PublicInbox::Import->remove), but note the 3rd element
 449 # (retval[2]) is not part of the stable API shared with Import->remove
 450 sub remove {
 451         my ($self, $eml, $cmt_msg) = @_;
 452         my $r = $self->{ibx}->with_umask(\&rewrite_internal,
 453                                                 $self, $eml, $cmt_msg);
 454         defined($r) && defined($r->[0]) ? @$r: undef;
 455 }
 456
 457 sub _replace ($$;$$) {
 458         my ($self, $old_eml, $new_eml, $sref) = @_;
 459         my $arg = [ $self, $old_eml, undef, $new_eml, $sref ];
 460         my $rewritten = $self->{ibx}->with_umask(\&rewrite_internal,
 461                         $self, $old_eml, undef, $new_eml, $sref) or return;
 462
 463         my $rewrites = $rewritten->{rewrites};
 464         # ->done is called if there are rewrites since we gc+prune from git
 465         $self->idx_init if @$rewrites;
 466
 467         for my $i (0..$#$rewrites) {
 468                 defined(my $cmt = $rewrites->[$i]) or next;
 469                 $self->{last_commit}->[$i] = $cmt;
 470         }
 471         $rewritten;
 472 }
 473
 474 # public
 475 sub purge {
 476         my ($self, $mime) = @_;
 477         my $rewritten = _replace($self, $mime, undef, \'') or return;
 478         $rewritten->{rewrites}
 479 }
 480
 481 # returns the git object_id of $fh, does not write the object to FS
 482 sub git_hash_raw ($$) {
 483         my ($self, $raw) = @_;
 484         # grab the expected OID we have to reindex:
 485         pipe(my($in, $w)) or die "pipe: $!";
 486         my $git_dir = $self->{ibx}->git->{git_dir};
 487         my $cmd = ['git', "--git-dir=$git_dir", qw(hash-object --stdin)];
 488         my $r = popen_rd($cmd, undef, { 0 => $in });
 489         print $w $$raw or die "print \$w: $!";
 490         close $w or die "close \$w: $!";
 491         local $/ = "\n";
 492         chomp(my $oid = <$r>);
 493         close $r or die "git hash-object failed: $?";
 494         $oid =~ /\A$OID\z/ or die "OID not expected: $oid";
 495         $oid;
 496 }
 497
 498 sub _check_mids_match ($$$) {
 499         my ($old_list, $new_list, $hdrs) = @_;
 500         my %old_mids = map { $_ => 1 } @$old_list;
 501         my %new_mids = map { $_ => 1 } @$new_list;
 502         my @old = keys %old_mids;
 503         my @new = keys %new_mids;
 504         my $err = "$hdrs may not be changed when replacing\n";
 505         die $err if scalar(@old) != scalar(@new);
 506         delete @new_mids{@old};
 507         delete @old_mids{@new};
 508         die $err if (scalar(keys %old_mids) || scalar(keys %new_mids));
 509 }
 510
 511 # Changing Message-IDs or References with ->replace isn't supported.
 512 # The rules for dealing with messages with multiple or conflicting
 513 # Message-IDs are pretty complex and rethreading hasn't been fully
 514 # implemented, yet.
 515 sub check_mids_match ($$) {
 516         my ($old, $new) = @_;
 517         _check_mids_match(mids($old), mids($new), 'Message-ID(s)');
 518         _check_mids_match(references($old), references($new),
 519                         'References/In-Reply-To');
 520 }
 521
 522 # public
 523 sub replace ($$$) {
 524         my ($self, $old_mime, $new_mime) = @_;
 525
 526         check_mids_match($old_mime, $new_mime);
 527
 528         # mutt will always add Content-Length:, Status:, Lines: when editing
 529         PublicInbox::Import::drop_unwanted_headers($new_mime);
 530
 531         my $raw = $new_mime->as_string;
 532         my $expect_oid = git_hash_raw($self, \$raw);
 533         my $rewritten = _replace($self, $old_mime, $new_mime, \$raw) or return;
 534         my $need_reindex = $rewritten->{need_reindex};
 535
 536         # just in case we have bugs in deduplication code:
 537         my $n = scalar(@$need_reindex);
 538         if ($n > 1) {
 539                 my $list = join(', ', map {
 540                                         "$_->{num}: <$_->{mid}>"
 541                                 } @$need_reindex);
 542                 warn <<"";
 543 W: rewritten $n messages matching content of original message (expected: 1).
 544 W: possible bug in public-inbox, NNTP article IDs and Message-IDs follow:
 545 W: $list
 546
 547         }
 548
 549         # make sure we really got the OID:
 550         my ($blob, $type, $bytes) = $self->{ibx}->git->check($expect_oid);
 551         $blob eq $expect_oid or die "BUG: $expect_oid not found after replace";
 552
 553         # don't leak FDs to Xapian:
 554         $self->{ibx}->git->cleanup;
 555
 556         # reindex modified messages:
 557         for my $smsg (@$need_reindex) {
 558                 my $new_smsg = bless {
 559                         blob => $blob,
 560                         raw_bytes => $bytes,
 561                         num => $smsg->{num},
 562                         mid => $smsg->{mid},
 563                 }, 'PublicInbox::Smsg';
 564                 my $sync = { autime => $smsg->{ds}, cotime => $smsg->{ts} };
 565                 $new_smsg->populate($new_mime, $sync);
 566                 do_idx($self, \$raw, $new_mime, $new_smsg);
 567         }
 568         $rewritten->{rewrites};
 569 }
 570
 571 sub last_epoch_commit ($$;$) {
 572         my ($self, $i, $cmt) = @_;
 573         my $v = PublicInbox::Search::SCHEMA_VERSION();
 574         $self->{mm}->last_commit_xap($v, $i, $cmt);
 575 }
 576
 577 sub set_last_commits ($) {
 578         my ($self) = @_;
 579         defined(my $epoch_max = $self->{epoch_max}) or return;
 580         my $last_commit = $self->{last_commit};
 581         foreach my $i (0..$epoch_max) {
 582                 defined(my $cmt = $last_commit->[$i]) or next;
 583                 $last_commit->[$i] = undef;
 584                 last_epoch_commit($self, $i, $cmt);
 585         }
 586 }
 587
 588 sub barrier_init {
 589         my ($self, $n) = @_;
 590         $self->{bnote} or return;
 591         --$n;
 592         my $barrier = { map { $_ => 1 } (0..$n) };
 593 }
 594
 595 sub barrier_wait {
 596         my ($self, $barrier) = @_;
 597         my $bnote = $self->{bnote} or return;
 598         my $r = $bnote->[0];
 599         while (scalar keys %$barrier) {
 600                 defined(my $l = readline($r)) or die "EOF on barrier_wait: $!";
 601                 $l =~ /\Abarrier (\d+)/ or die "bad line on barrier_wait: $l";
 602                 delete $barrier->{$1} or die "bad shard[$1] on barrier wait";
 603         }
 604 }
 605
 606 # public
 607 sub checkpoint ($;$) {
 608         my ($self, $wait) = @_;
 609
 610         if (my $im = $self->{im}) {
 611                 if ($wait) {
 612                         $im->barrier;
 613                 } else {
 614                         $im->checkpoint;
 615                 }
 616         }
 617         my $shards = $self->{idx_shards};
 618         if ($shards) {
 619                 my $dbh = $self->{mm}->{dbh};
 620
 621                 # SQLite msgmap data is second in importance
 622                 $dbh->commit;
 623
 624                 # SQLite overview is third
 625                 $self->{over}->commit_lazy;
 626
 627                 # Now deal with Xapian
 628                 if ($wait) {
 629                         my $barrier = $self->barrier_init(scalar @$shards);
 630
 631                         # each shard needs to issue a barrier command
 632                         $_->remote_barrier for @$shards;
 633
 634                         # wait for each Xapian shard
 635                         $self->barrier_wait($barrier);
 636                 } else {
 637                         $_->remote_commit for @$shards;
 638                 }
 639
 640                 # last_commit is special, don't commit these until
 641                 # remote shards are done:
 642                 $dbh->begin_work;
 643                 set_last_commits($self);
 644                 $dbh->commit;
 645
 646                 $dbh->begin_work;
 647         }
 648         $self->{total_bytes} += $self->{transact_bytes};
 649         $self->{transact_bytes} = 0;
 650 }
 651
 652 # issue a write barrier to ensure all data is visible to other processes
 653 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 654 # public
 655 sub barrier { checkpoint($_[0], 1) };
 656
 657 # public
 658 sub done {
 659         my ($self) = @_;
 660         my $err = '';
 661         if (my $im = delete $self->{im}) {
 662                 eval { $im->done }; # PublicInbox::Import::done
 663                 $err .= "import done: $@\n" if $@;
 664         }
 665         if (!$err) {
 666                 eval { checkpoint($self) };
 667                 $err .= "checkpoint: $@\n" if $@;
 668         }
 669         if (my $mm = delete $self->{mm}) {
 670                 my $m = $err ? 'rollback' : 'commit';
 671                 eval { $mm->{dbh}->$m };
 672                 $err .= "msgmap $m: $@\n" if $@;
 673         }
 674         my $shards = delete $self->{idx_shards};
 675         if ($shards) {
 676                 for (@$shards) {
 677                         eval { $_->remote_close };
 678                         $err .= "shard close: $@\n" if $@;
 679                 }
 680         }
 681         eval { $self->{over}->disconnect };
 682         $err .= "over disconnect: $@\n" if $@;
 683         delete $self->{bnote};
 684         my $nbytes = $self->{total_bytes};
 685         $self->{total_bytes} = 0;
 686         $self->lock_release(!!$nbytes) if $shards;
 687         $self->{ibx}->git->cleanup;
 688         die $err if $err;
 689 }
 690
 691 sub fill_alternates ($$) {
 692         my ($self, $epoch) = @_;
 693
 694         my $pfx = "$self->{ibx}->{inboxdir}/git";
 695         my $all = "$self->{ibx}->{inboxdir}/all.git";
 696         PublicInbox::Import::init_bare($all) unless -d $all;
 697         my $info_dir = "$all/objects/info";
 698         my $alt = "$info_dir/alternates";
 699         my (%alt, $new);
 700         my $mode = 0644;
 701         if (-e $alt) {
 702                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 703                 $mode = (stat($fh))[2] & 07777;
 704
 705                 # we assign a sort score to every alternate and favor
 706                 # the newest (highest numbered) one because loose objects
 707                 # require scanning epochs and only the latest epoch is
 708                 # expected to see loose objects
 709                 my $score;
 710                 my $other = 0; # in case admin adds non-epoch repos
 711                 %alt = map {;
 712                         if (m!\A\Q../../\E([0-9]+)\.git/objects\z!) {
 713                                 $score = $1 + 0;
 714                         } else {
 715                                 $score = --$other;
 716                         }
 717                         $_ => $score;
 718                 } split(/\n+/, do { local $/; <$fh> });
 719         }
 720
 721         foreach my $i (0..$epoch) {
 722                 my $dir = "../../git/$i.git/objects";
 723                 if (!exists($alt{$dir}) && -d "$pfx/$i.git") {
 724                         $alt{$dir} = $i;
 725                         $new = 1;
 726                 }
 727         }
 728         return unless $new;
 729
 730         my ($fh, $tmp) = tempfile('alt-XXXXXXXX', DIR => $info_dir);
 731         print $fh join("\n", sort { $alt{$b} <=> $alt{$a} } keys %alt), "\n"
 732                 or die "print $tmp: $!\n";
 733         chmod($mode, $fh) or die "fchmod $tmp: $!\n";
 734         close $fh or die "close $tmp $!\n";
 735         rename($tmp, $alt) or die "rename $tmp => $alt: $!\n";
 736 }
 737
 738 sub git_init {
 739         my ($self, $epoch) = @_;
 740         my $git_dir = "$self->{ibx}->{inboxdir}/git/$epoch.git";
 741         PublicInbox::Import::init_bare($git_dir);
 742         my @cmd = (qw/git config/, "--file=$git_dir/config",
 743                         'include.path', '../../all.git/config');
 744         PublicInbox::Import::run_die(\@cmd);
 745         fill_alternates($self, $epoch);
 746         $git_dir
 747 }
 748
 749 sub git_dir_latest {
 750         my ($self, $max) = @_;
 751         $$max = -1;
 752         my $pfx = "$self->{ibx}->{inboxdir}/git";
 753         return unless -d $pfx;
 754         my $latest;
 755         opendir my $dh, $pfx or die "opendir $pfx: $!\n";
 756         while (defined(my $git_dir = readdir($dh))) {
 757                 $git_dir =~ m!\A([0-9]+)\.git\z! or next;
 758                 if ($1 > $$max) {
 759                         $$max = $1;
 760                         $latest = "$pfx/$git_dir";
 761                 }
 762         }
 763         $latest;
 764 }
 765
 766 sub importer {
 767         my ($self) = @_;
 768         my $im = $self->{im};
 769         if ($im) {
 770                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 771                         return $im;
 772                 } else {
 773                         $self->{im} = undef;
 774                         $im->done;
 775                         $im = undef;
 776                         $self->checkpoint;
 777                         my $git_dir = $self->git_init(++$self->{epoch_max});
 778                         my $git = PublicInbox::Git->new($git_dir);
 779                         return $self->import_init($git, 0);
 780                 }
 781         }
 782         my $epoch = 0;
 783         my $max;
 784         my $latest = git_dir_latest($self, \$max);
 785         if (defined $latest) {
 786                 my $git = PublicInbox::Git->new($latest);
 787                 my $packed_bytes = $git->packed_bytes;
 788                 my $unpacked_bytes = $packed_bytes / $PACKING_FACTOR;
 789
 790                 if ($unpacked_bytes >= $self->{rotate_bytes}) {
 791                         $epoch = $max + 1;
 792                 } else {
 793                         $self->{epoch_max} = $max;
 794                         return $self->import_init($git, $packed_bytes);
 795                 }
 796         }
 797         $self->{epoch_max} = $epoch;
 798         $latest = $self->git_init($epoch);
 799         $self->import_init(PublicInbox::Git->new($latest), 0);
 800 }
 801
 802 sub import_init {
 803         my ($self, $git, $packed_bytes, $tmp) = @_;
 804         my $im = PublicInbox::Import->new($git, undef, undef, $self->{ibx});
 805         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 806         $im->{lock_path} = undef;
 807         $im->{path_type} = 'v2';
 808         $self->{im} = $im unless $tmp;
 809         $im;
 810 }
 811
 812 # XXX experimental
 813 sub diff ($$$) {
 814         my ($mid, $cur, $new) = @_;
 815
 816         my ($ah, $an) = tempfile('email-cur-XXXXXXXX', TMPDIR => 1);
 817         print $ah $cur->as_string or die "print: $!";
 818         close $ah or die "close: $!";
 819         my ($bh, $bn) = tempfile('email-new-XXXXXXXX', TMPDIR => 1);
 820         PublicInbox::Import::drop_unwanted_headers($new);
 821         print $bh $new->as_string or die "print: $!";
 822         close $bh or die "close: $!";
 823         my $cmd = [ qw(diff -u), $an, $bn ];
 824         print STDERR "# MID conflict <$mid>\n";
 825         my $pid = spawn($cmd, undef, { 1 => 2 });
 826         waitpid($pid, 0) == $pid or die "diff did not finish";
 827         unlink($an, $bn);
 828 }
 829
 830 sub get_blob ($$) {
 831         my ($self, $smsg) = @_;
 832         if (my $im = $self->{im}) {
 833                 my $msg = $im->cat_blob($smsg->{blob});
 834                 return $msg if $msg;
 835         }
 836         # older message, should be in alternates
 837         $self->{ibx}->msg_by_smsg($smsg);
 838 }
 839
 840 sub content_exists ($$$) {
 841         my ($self, $mime, $mid) = @_;
 842         my $over = $self->{over};
 843         my $chashes = content_hashes($mime);
 844         my ($id, $prev);
 845         while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 846                 my $msg = get_blob($self, $smsg);
 847                 if (!defined($msg)) {
 848                         warn "broken smsg for $mid\n";
 849                         next;
 850                 }
 851                 my $cur = PublicInbox::Eml->new($msg);
 852                 return 1 if content_matches($chashes, $cur);
 853
 854                 # XXX DEBUG_DIFF is experimental and may be removed
 855                 diff($mid, $cur, $mime) if $ENV{DEBUG_DIFF};
 856         }
 857         undef;
 858 }
 859
 860 sub atfork_child {
 861         my ($self) = @_;
 862         if (my $shards = $self->{idx_shards}) {
 863                 $_->atfork_child foreach @$shards;
 864         }
 865         if (my $im = $self->{im}) {
 866                 $im->atfork_child;
 867         }
 868         die "unexpected mm" if $self->{mm};
 869         close $self->{bnote}->[0] or die "close bnote[0]: $!\n";
 870         $self->{bnote}->[1];
 871 }
 872
 873 sub reindex_checkpoint ($$) {
 874         my ($self, $sync) = @_;
 875
 876         $self->{ibx}->git->cleanup; # *async_wait
 877         ${$sync->{need_checkpoint}} = 0;
 878         $sync->{mm_tmp}->atfork_prepare;
 879         $self->done; # release lock
 880
 881         if (my $pr = $sync->{-opt}->{-progress}) {
 882                 $pr->(sprintf($sync->{-regen_fmt}, ${$sync->{nr}}));
 883         }
 884
 885         # allow -watch or -mda to write...
 886         $self->idx_init; # reacquire lock
 887         $sync->{mm_tmp}->atfork_parent;
 888 }
 889
 890 sub index_oid { # cat_async callback
 891         my ($bref, $oid, $type, $size, $arg) = @_;
 892         return if $size == 0; # purged
 893         my ($num, $mid0);
 894         my $eml = PublicInbox::Eml->new($$bref);
 895         my $mids = mids($eml);
 896         my $chash = content_hash($eml);
 897         my $self = $arg->{v2w};
 898
 899         if (scalar(@$mids) == 0) {
 900                 warn "E: $oid has no Message-ID, skipping\n";
 901                 return;
 902         }
 903
 904         # {unindexed} is unlikely
 905         if ((my $unindexed = $arg->{unindexed}) && scalar(@$mids) == 1) {
 906                 $num = delete($unindexed->{$mids->[0]});
 907                 if (defined $num) {
 908                         $mid0 = $mids->[0];
 909                         $self->{mm}->mid_set($num, $mid0);
 910                         delete($arg->{unindexed}) if !keys(%$unindexed);
 911                 }
 912         }
 913         if (!defined($num)) { # reuse if reindexing (or duplicates)
 914                 my $over = $self->{over};
 915                 for my $mid (@$mids) {
 916                         ($num, $mid0) = $over->num_mid0_for_oid($oid, $mid);
 917                         last if defined $num;
 918                 }
 919         }
 920         $mid0 //= do { # is this a number we got before?
 921                 $num = $arg->{mm_tmp}->num_for($mids->[0]);
 922                 defined($num) ? $mids->[0] : undef;
 923         };
 924         if (!defined($num)) {
 925                 for (my $i = $#$mids; $i >= 1; $i--) {
 926                         $num = $arg->{mm_tmp}->num_for($mids->[$i]);
 927                         if (defined($num)) {
 928                                 $mid0 = $mids->[$i];
 929                                 last;
 930                         }
 931                 }
 932         }
 933         if (defined($num)) {
 934                 $arg->{mm_tmp}->num_delete($num);
 935         } else { # never seen
 936                 $num = $self->{mm}->mid_insert($mids->[0]);
 937                 if (defined($num)) {
 938                         $mid0 = $mids->[0];
 939                 } else { # rare, try the rest of them, backwards
 940                         for (my $i = $#$mids; $i >= 1; $i--) {
 941                                 $num = $self->{mm}->mid_insert($mids->[$i]);
 942                                 if (defined($num)) {
 943                                         $mid0 = $mids->[$i];
 944                                         last;
 945                                 }
 946                         }
 947                 }
 948         }
 949         if (!defined($num)) {
 950                 warn "E: $oid <", join('> <', @$mids), "> is a duplicate\n";
 951                 return;
 952         }
 953         ++${$arg->{nr}};
 954         my $smsg = bless {
 955                 raw_bytes => $size,
 956                 num => $num,
 957                 blob => $oid,
 958                 mid => $mid0,
 959         }, 'PublicInbox::Smsg';
 960         $smsg->populate($eml, $arg);
 961         if (do_idx($self, $bref, $eml, $smsg)) {
 962                 ${$arg->{need_checkpoint}} = 1;
 963         }
 964 }
 965
 966 # only update last_commit for $i on reindex iff newer than current
 967 sub update_last_commit ($$$$) {
 968         my ($self, $git, $i, $cmt) = @_;
 969         my $last = last_epoch_commit($self, $i);
 970         if (defined $last && is_ancestor($git, $last, $cmt)) {
 971                 my @cmd = (qw(rev-list --count), "$last..$cmt");
 972                 chomp(my $n = $git->qx(@cmd));
 973                 return if $n ne '' && $n == 0;
 974         }
 975         last_epoch_commit($self, $i, $cmt);
 976 }
 977
 978 sub git_dir_n ($$) { "$_[0]->{ibx}->{inboxdir}/git/$_[1].git" }
 979
 980 sub last_commits ($$) {
 981         my ($self, $epoch_max) = @_;
 982         my $heads = [];
 983         for (my $i = $epoch_max; $i >= 0; $i--) {
 984                 $heads->[$i] = last_epoch_commit($self, $i);
 985         }
 986         $heads;
 987 }
 988
 989 # returns a revision range for git-log(1)
 990 sub log_range ($$$$$) {
 991         my ($self, $sync, $git, $i, $tip) = @_;
 992         my $opt = $sync->{-opt};
 993         my $pr = $opt->{-progress} if (($opt->{verbose} || 0) > 1);
 994         my $cur = $sync->{ranges}->[$i] or do {
 995                 $pr->("$i.git indexing all of $tip") if $pr;
 996                 return $tip; # all of it
 997         };
 998
 999         # fast equality check to avoid (v)fork+execve overhead
1000         if ($cur eq $tip) {
1001                 $sync->{ranges}->[$i] = undef;
1002                 return;
1003         }
1004
1005         my $range = "$cur..$tip";
1006         $pr->("$i.git checking contiguity... ") if $pr;
1007         if (is_ancestor($git, $cur, $tip)) { # common case
1008                 $pr->("OK\n") if $pr;
1009                 my $n = $git->qx(qw(rev-list --count), $range);
1010                 chomp($n);
1011                 if ($n == 0) {
1012                         $sync->{ranges}->[$i] = undef;
1013                         $pr->("$i.git has nothing new\n") if $pr;
1014                         return; # nothing to do
1015                 }
1016                 $pr->("$i.git has $n changes since $cur\n") if $pr;
1017         } else {
1018                 $pr->("FAIL\n") if $pr;
1019                 warn <<"";
1020 discontiguous range: $range
1021 Rewritten history? (in $git->{git_dir})
1022
1023                 chomp(my $base = $git->qx('merge-base', $tip, $cur));
1024                 if ($base) {
1025                         $range = "$base..$tip";
1026                         warn "found merge-base: $base\n"
1027                 } else {
1028                         $range = $tip;
1029                         warn "discarding history at $cur\n";
1030                 }
1031                 warn <<"";
1032 reindexing $git->{git_dir} starting at
1033 $range
1034
1035                 $sync->{unindex_range}->{$i} = "$base..$cur";
1036         }
1037         $range;
1038 }
1039
1040 sub sync_prepare ($$$) {
1041         my ($self, $sync, $epoch_max) = @_;
1042         my $pr = $sync->{-opt}->{-progress};
1043         my $regen_max = 0;
1044         my $head = $self->{ibx}->{ref_head} || 'refs/heads/master';
1045
1046         # reindex stops at the current heads and we later rerun index_sync
1047         # without {reindex}
1048         my $reindex_heads = last_commits($self, $epoch_max) if $sync->{reindex};
1049
1050         for (my $i = $epoch_max; $i >= 0; $i--) {
1051                 my $git_dir = git_dir_n($self, $i);
1052                 -d $git_dir or next; # missing epochs are fine
1053                 my $git = PublicInbox::Git->new($git_dir);
1054                 if ($reindex_heads) {
1055                         $head = $reindex_heads->[$i] or next;
1056                 }
1057                 chomp(my $tip = $git->qx(qw(rev-parse -q --verify), $head));
1058
1059                 next if $?; # new repo
1060                 my $range = log_range($self, $sync, $git, $i, $tip) or next;
1061                 # can't use 'rev-list --count' if we use --diff-filter
1062                 $pr->("$i.git counting $range ... ") if $pr;
1063                 # Don't bump num_highwater on --reindex by using {D}.
1064                 # We intentionally do NOT use {D} in the non-reindex case
1065                 # because we want NNTP article number gaps from unindexed
1066                 # messages to show up in mirrors, too.
1067                 $sync->{D} //= $sync->{reindex} ? {} : undef; # OID_BIN => NR
1068                 my $stk = log2stack($sync, $git, $range, $self->{ibx});
1069                 my $nr = $stk ? $stk->num_records : 0;
1070                 $pr->("$nr\n") if $pr;
1071                 $sync->{stacks}->[$i] = $stk if $stk;
1072                 $regen_max += $nr;
1073         }
1074
1075         # XXX this should not happen unless somebody bypasses checks in
1076         # our code and blindly injects "d" file history into git repos
1077         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
1078                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
1079                 my $arg = { v2w => $self };
1080                 my $all = $self->{ibx}->git;
1081                 for my $oid (@leftovers) {
1082                         $oid = unpack('H*', $oid);
1083                         $self->{current_info} = "leftover $oid";
1084                         $all->cat_async($oid, \&unindex_oid, $arg);
1085                 }
1086                 $all->cat_async_wait;
1087         }
1088         return 0 if (!$regen_max && !keys(%{$self->{unindex_range}}));
1089
1090         # reindex should NOT see new commits anymore, if we do,
1091         # it's a problem and we need to notice it via die()
1092         my $pad = length($regen_max) + 1;
1093         $sync->{-regen_fmt} = "% ${pad}u/$regen_max\n";
1094         $sync->{nr} = \(my $nr = 0);
1095         return -1 if $sync->{reindex};
1096         $regen_max + $self->{mm}->num_highwater() || 0;
1097 }
1098
1099 sub unindex_oid_remote ($$$) {
1100         my ($self, $oid, $mid) = @_;
1101         my @removed = $self->{over}->remove_oid($oid, $mid);
1102         for my $num (@removed) {
1103                 my $idx = idx_shard($self, $num % $self->{shards});
1104                 $idx->remote_remove($oid, $num);
1105         }
1106 }
1107
1108 sub unindex_oid ($$;$) { # git->cat_async callback
1109         my ($bref, $oid, $type, $size, $sync) = @_;
1110         my $self = $sync->{v2w};
1111         my $unindexed = $sync->{in_unindex} ? $sync->{unindexed} : undef;
1112         my $mm = $self->{mm};
1113         my $mids = mids(PublicInbox::Eml->new($bref));
1114         undef $$bref;
1115         my $over = $self->{over};
1116         foreach my $mid (@$mids) {
1117                 my %gone;
1118                 my ($id, $prev);
1119                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
1120                         $gone{$smsg->{num}} = 1 if $oid eq $smsg->{blob};
1121                 }
1122                 my $n = scalar(keys(%gone)) or next;
1123                 if ($n > 1) {
1124                         warn "BUG: multiple articles linked to $oid\n",
1125                                 join(',',sort keys %gone), "\n";
1126                 }
1127                 foreach my $num (keys %gone) {
1128                         if ($unindexed) {
1129                                 my $mid0 = $mm->mid_for($num);
1130                                 $unindexed->{$mid0} = $num;
1131                         }
1132                         $mm->num_delete($num);
1133                 }
1134                 unindex_oid_remote($self, $oid, $mid);
1135         }
1136 }
1137
1138 # this is rare, it only happens when we get discontiguous history in
1139 # a mirror because the source used -purge or -edit
1140 sub unindex ($$$$) {
1141         my ($self, $sync, $git, $unindex_range) = @_;
1142         my $unindexed = $sync->{unindexed} //= {}; # $mid0 => $num
1143         my $before = scalar keys %$unindexed;
1144         # order does not matter, here:
1145         my @cmd = qw(log --raw -r
1146                         --no-notes --no-color --no-abbrev --no-renames);
1147         my $fh = $git->popen(@cmd, $unindex_range);
1148         my $all = $self->{ibx}->git;
1149         local $sync->{in_unindex} = 1;
1150         while (<$fh>) {
1151                 /\A:\d{6} 100644 $OID ($OID) [AM]\tm$/o or next;
1152                 $all->cat_async($1, \&unindex_oid, $sync);
1153         }
1154         close $fh or die "git log failed: \$?=$?";
1155         $all->cat_async_wait;
1156
1157         return unless $sync->{-opt}->{prune};
1158         my $after = scalar keys %$unindexed;
1159         return if $before == $after;
1160
1161         # ensure any blob can not longer be accessed via dumb HTTP
1162         PublicInbox::Import::run_die(['git', "--git-dir=$git->{git_dir}",
1163                 qw(-c gc.reflogExpire=now gc --prune=all --quiet)]);
1164 }
1165
1166 sub sync_ranges ($$$) {
1167         my ($self, $sync, $epoch_max) = @_;
1168         my $reindex = $sync->{reindex};
1169
1170         return last_commits($self, $epoch_max) unless $reindex;
1171         return [] if ref($reindex) ne 'HASH';
1172
1173         my $ranges = $reindex->{from}; # arrayref;
1174         if (ref($ranges) ne 'ARRAY') {
1175                 die 'BUG: $reindex->{from} not an ARRAY';
1176         }
1177         $ranges;
1178 }
1179
1180 sub index_epoch ($$$) {
1181         my ($self, $sync, $i) = @_;
1182
1183         my $git_dir = git_dir_n($self, $i);
1184         -d $git_dir or return; # missing epochs are fine
1185         my $git = PublicInbox::Git->new($git_dir);
1186         if (my $unindex_range = delete $sync->{unindex_range}->{$i}) { # rare
1187                 unindex($self, $sync, $git, $unindex_range);
1188         }
1189         defined(my $stk = $sync->{stacks}->[$i]) or return;
1190         $sync->{stacks}->[$i] = undef;
1191         my $all = $self->{ibx}->git;
1192         while (my ($f, $at, $ct, $oid) = $stk->pop_rec) {
1193                 $self->{current_info} = "$i.git $oid";
1194                 if ($f eq 'm') {
1195                         my $arg = { %$sync, autime => $at, cotime => $ct };
1196                         if ($sync->{index_max_size}) {
1197                                 $all->check_async($oid, \&check_size, $arg);
1198                         } else {
1199                                 $all->cat_async($oid, \&index_oid, $arg);
1200                         }
1201                 } elsif ($f eq 'd') {
1202                         $all->cat_async($oid, \&unindex_oid, $sync);
1203                 }
1204                 if (${$sync->{need_checkpoint}}) {
1205                         reindex_checkpoint($self, $sync);
1206                 }
1207         }
1208         $all->check_async_wait;
1209         $all->cat_async_wait;
1210         update_last_commit($self, $git, $i, $stk->{latest_cmt});
1211 }
1212
1213 # public, called by public-inbox-index
1214 sub index_sync {
1215         my ($self, $opt) = @_;
1216         $opt ||= {};
1217         my $pr = $opt->{-progress};
1218         my $epoch_max;
1219         my $latest = git_dir_latest($self, \$epoch_max);
1220         return unless defined $latest;
1221         $self->idx_init($opt); # acquire lock
1222         fill_alternates($self, $epoch_max);
1223         $self->{over}->rethread_prepare($opt);
1224         my $sync = {
1225                 need_checkpoint => \(my $bool = 0),
1226                 unindex_range => {}, # EPOCH => oid_old..oid_new
1227                 reindex => $opt->{reindex},
1228                 -opt => $opt,
1229                 v2w => $self,
1230         };
1231         $sync->{ranges} = sync_ranges($self, $sync, $epoch_max);
1232         if (sync_prepare($self, $sync, $epoch_max)) {
1233                 # tmp_clone seems to fail if inside a transaction, so
1234                 # we rollback here (because we opened {mm} for reading)
1235                 # Note: we do NOT rely on DBI transactions for atomicity;
1236                 # only for batch performance.
1237                 $self->{mm}->{dbh}->rollback;
1238                 $self->{mm}->{dbh}->begin_work;
1239                 $sync->{mm_tmp} =
1240                         $self->{mm}->tmp_clone($self->{ibx}->{inboxdir});
1241         }
1242         if ($sync->{index_max_size} = $self->{ibx}->{index_max_size}) {
1243                 $sync->{index_oid} = \&index_oid;
1244         }
1245         # work forwards through history
1246         index_epoch($self, $sync, $_) for (0..$epoch_max);
1247         $self->{over}->rethread_done($opt);
1248         $self->done;
1249
1250         if (my $nr = $sync->{nr}) {
1251                 my $pr = $sync->{-opt}->{-progress};
1252                 $pr->('all.git '.sprintf($sync->{-regen_fmt}, $$nr)) if $pr;
1253         }
1254
1255         # reindex does not pick up new changes, so we rerun w/o it:
1256         if ($opt->{reindex}) {
1257                 my %again = %$opt;
1258                 $sync = undef;
1259                 delete @again{qw(rethread reindex -skip_lock)};
1260                 index_sync($self, \%again);
1261         }
1262 }
1263
1264 1;