lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 package PublicInbox::V2Writable;
   6 use strict;
   7 use warnings;
   8 use Fcntl qw(:flock :DEFAULT);
   9 use PublicInbox::SearchIdxPart;
  10 use PublicInbox::SearchIdxSkeleton;
  11 use PublicInbox::MIME;
  12 use PublicInbox::Git;
  13 use PublicInbox::Import;
  14
  15 # an estimate of the post-packed size to the raw uncompressed size
  16 my $PACKING_FACTOR = 0.4;
  17
  18 # assume 2 cores if GNU nproc(1) is not available
  19 my $NPROC = int($ENV{NPROC} || `nproc 2>/dev/null` || 2);
  20
  21 sub new {
  22         my ($class, $v2ibx, $creat) = @_;
  23         my $dir = $v2ibx->{mainrepo} or die "no mainrepo in inbox\n";
  24         unless (-d $dir) {
  25                 if ($creat) {
  26                         require File::Path;
  27                         File::Path::mkpath($dir);
  28                 } else {
  29                         die "$dir does not exist\n";
  30                 }
  31         }
  32         my $self = {
  33                 -inbox => $v2ibx,
  34                 im => undef, #  PublicInbox::Import
  35                 xap_rw => undef, # PublicInbox::V2SearchIdx
  36                 xap_ro => undef,
  37                 partitions => $NPROC,
  38                 transact_bytes => 0,
  39                 # limit each repo to 1GB or so
  40                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
  41         };
  42         bless $self, $class
  43 }
  44
  45 # returns undef on duplicate or spam
  46 # mimics Import::add and wraps it for v2
  47 sub add {
  48         my ($self, $mime, $check_cb) = @_;
  49         my $existing = $self->lookup_content($mime);
  50
  51         if ($existing) {
  52                 return undef if $existing->type eq 'mail'; # duplicate
  53         }
  54
  55         my $im = $self->importer;
  56
  57         # im->add returns undef if check_cb fails
  58         my $cmt = $im->add($mime, $check_cb) or return;
  59         $cmt = $im->get_mark($cmt);
  60         my $oid = $im->{last_object_id};
  61         my ($len, $msgref) = @{$im->{last_object}};
  62
  63         $self->idx_init;
  64         my $num = $self->{skel}->index_mm($mime, 1);
  65         my $nparts = $self->{partitions};
  66         my $part = $num % $nparts;
  67         my $idx = $self->idx_part($part);
  68         $idx->index_raw($len, $msgref, $num, $oid);
  69         my $n = $self->{transact_bytes} += $len;
  70         if ($n > (PublicInbox::SearchIdx::BATCH_BYTES * $nparts)) {
  71                 $self->checkpoint;
  72         }
  73
  74         $mime;
  75 }
  76
  77 sub idx_part {
  78         my ($self, $part) = @_;
  79         $self->{idx_parts}->[$part];
  80 }
  81
  82 sub idx_init {
  83         my ($self) = @_;
  84         return if $self->{idx_parts};
  85
  86         # first time initialization, first we create the skeleton pipe:
  87         my $skel = $self->{skel} = PublicInbox::SearchIdxSkeleton->new($self);
  88
  89         # need to create all parts before initializing msgmap FD
  90         my $max = $self->{partitions} - 1;
  91         my $idx = $self->{idx_parts} = [];
  92         for my $i (0..$max) {
  93                 push @$idx, PublicInbox::SearchIdxPart->new($self, $i, $skel);
  94         }
  95
  96         # Now that all subprocesses are up, we can open the FD for SQLite:
  97         $skel->_msgmap_init->{dbh}->begin_work;
  98 }
  99
 100 sub remove {
 101         my ($self, $mime, $msg) = @_;
 102         my $existing = $self->lookup_content($mime) or return;
 103
 104         # don't touch ghosts or already junked messages
 105         return unless $existing->type eq 'mail';
 106
 107         # always write removals to the current (latest) git repo since
 108         # we process chronologically
 109         my $im = $self->importer;
 110         my ($cmt, undef) = $im->remove($mime, $msg);
 111         $cmt = $im->get_mark($cmt);
 112         $self->unindex_msg($existing, $cmt);
 113 }
 114
 115 sub done {
 116         my ($self) = @_;
 117         my $im = $self->{im};
 118         $im->done if $im; # PublicInbox::Import::done
 119         $self->searchidx_checkpoint(0);
 120 }
 121
 122 sub checkpoint {
 123         my ($self) = @_;
 124         my $im = $self->{im};
 125         $im->checkpoint if $im; # PublicInbox::Import::checkpoint
 126         $self->searchidx_checkpoint(1);
 127 }
 128
 129 sub searchidx_checkpoint {
 130         my ($self, $more) = @_;
 131
 132         # order matters, we can only close {skel} after all partitions
 133         # are done because the partitions also write to {skel}
 134         if (my $parts = $self->{idx_parts}) {
 135                 foreach my $idx (@$parts) {
 136                         $idx->remote_commit; # propagates commit to skel
 137                         $idx->remote_close unless $more;
 138                 }
 139                 delete $self->{idx_parts} unless $more;
 140         }
 141
 142         if (my $skel = $self->{skel}) {
 143                 my $dbh = $skel->{mm}->{dbh};
 144                 $dbh->commit;
 145                 if ($more) {
 146                         $dbh->begin_work;
 147                 } else {
 148                         $skel->remote_commit; # XXX should be unnecessary...
 149                         $skel->remote_close;
 150                         delete $self->{skel};
 151                 }
 152         }
 153         $self->{transact_bytes} = 0;
 154 }
 155
 156 sub git_init {
 157         my ($self, $new) = @_;
 158         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 159         my $git_dir = "$pfx/$new.git";
 160         die "$git_dir exists\n" if -e $git_dir;
 161         my @cmd = (qw(git init --bare -q), $git_dir);
 162         PublicInbox::Import::run_die(\@cmd);
 163         @cmd = (qw/git config/, "--file=$git_dir/config",
 164                         'repack.writeBitmaps', 'true');
 165         PublicInbox::Import::run_die(\@cmd);
 166
 167         my $all = "$self->{-inbox}->{mainrepo}/all.git";
 168         unless (-d $all) {
 169                 @cmd = (qw(git init --bare -q), $all);
 170                 PublicInbox::Import::run_die(\@cmd);
 171         }
 172
 173         my $alt = "$all/objects/info/alternates";
 174         my $new_obj_dir = "../../git/$new.git/objects";
 175         my %alts;
 176         if (-e $alt) {
 177                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 178                 %alts = map { chomp; $_ => 1 } (<$fh>);
 179         }
 180         return $git_dir if $alts{$new_obj_dir};
 181         open my $fh, '>>', $alt or die "open >> $alt: $!\n";
 182         print $fh "$new_obj_dir\n" or die "print >> $alt: $!\n";
 183         close $fh or die "close $alt: $!\n";
 184         $git_dir
 185 }
 186
 187 sub importer {
 188         my ($self) = @_;
 189         my $im = $self->{im};
 190         if ($im) {
 191                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 192                         return $im;
 193                 } else {
 194                         $self->{im} = undef;
 195                         $im->done;
 196                         $self->searchidx_checkpoint(1);
 197                         $im = undef;
 198                         my $git_dir = $self->git_init(++$self->{max_git});
 199                         my $git = PublicInbox::Git->new($git_dir);
 200                         return $self->import_init($git, 0);
 201                 }
 202         }
 203         my $latest;
 204         my $max = -1;
 205         my $new = 0;
 206         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 207         if (-d $pfx) {
 208                 foreach my $git_dir (glob("$pfx/*.git")) {
 209                         $git_dir =~ m!/(\d+)\.git\z! or next;
 210                         my $n = $1;
 211                         if ($n > $max) {
 212                                 $max = $n;
 213                                 $latest = $git_dir;
 214                         }
 215                 }
 216         }
 217         if (defined $latest) {
 218                 my $git = PublicInbox::Git->new($latest);
 219                 my $packed_bytes = $git->packed_bytes;
 220                 if ($packed_bytes >= $self->{rotate_bytes}) {
 221                         $new = $max + 1;
 222                 } else {
 223                         $self->{max_git} = $max;
 224                         return $self->import_init($git, $packed_bytes);
 225                 }
 226         }
 227         $self->{max_git} = $new;
 228         $latest = $self->git_init($new);
 229         $self->import_init(PublicInbox::Git->new($latest), 0);
 230 }
 231
 232 sub import_init {
 233         my ($self, $git, $packed_bytes) = @_;
 234         my $im = PublicInbox::Import->new($git, undef, undef, $self->{-inbox});
 235         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 236         $im->{want_object_id} = 1;
 237         $im->{ssoma_lock} = 0;
 238         $im->{path_type} = 'v2';
 239         $self->{im} = $im;
 240 }
 241
 242 sub lookup_content {
 243         undef # TODO
 244 }
 245
 246 sub atfork_child {
 247         my ($self) = @_;
 248         if (my $parts = $self->{idx_parts}) {
 249                 $_->atfork_child foreach @$parts;
 250         }
 251         if (my $im = $self->{im}) {
 252                 $im->atfork_child;
 253         }
 254 }
 255
 256 1;