lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 package PublicInbox::V2Writable;
   6 use strict;
   7 use warnings;
   8 use base qw(PublicInbox::Lock);
   9 use PublicInbox::SearchIdxPart;
  10 use PublicInbox::SearchIdxSkeleton;
  11 use PublicInbox::MIME;
  12 use PublicInbox::Git;
  13 use PublicInbox::Import;
  14 use PublicInbox::MID qw(mids);
  15 use PublicInbox::ContentId qw(content_id content_digest);
  16 use PublicInbox::Inbox;
  17
  18 # an estimate of the post-packed size to the raw uncompressed size
  19 my $PACKING_FACTOR = 0.4;
  20
  21 # assume 2 cores if GNU nproc(1) is not available
  22 sub nproc () {
  23         int($ENV{NPROC} || `nproc 2>/dev/null` || 2);
  24 }
  25
  26 sub new {
  27         my ($class, $v2ibx, $creat) = @_;
  28         my $dir = $v2ibx->{mainrepo} or die "no mainrepo in inbox\n";
  29         unless (-d $dir) {
  30                 if ($creat) {
  31                         require File::Path;
  32                         File::Path::mkpath($dir);
  33                 } else {
  34                         die "$dir does not exist\n";
  35                 }
  36         }
  37
  38         my $nparts = 0;
  39         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
  40
  41         # always load existing partitions in case core count changes:
  42         if (-d $xpfx) {
  43                 foreach my $part (<$xpfx/*>) {
  44                         -d $part && $part =~ m!/\d+\z! or next;
  45                         eval {
  46                                 Search::Xapian::Database->new($part)->close;
  47                                 $nparts++;
  48                         };
  49                 }
  50         }
  51         $nparts = nproc() if ($nparts == 0);
  52
  53         my $self = {
  54                 -inbox => $v2ibx,
  55                 im => undef, #  PublicInbox::Import
  56                 xap_rw => undef, # PublicInbox::V2SearchIdx
  57                 xap_ro => undef,
  58                 partitions => $nparts,
  59                 parallel => 1,
  60                 transact_bytes => 0,
  61                 lock_path => "$dir/inbox.lock",
  62                 # limit each repo to 1GB or so
  63                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
  64         };
  65         bless $self, $class;
  66 }
  67
  68 sub init_inbox {
  69         my ($self, $parallel) = @_;
  70         $self->{parallel} = $parallel;
  71         $self->idx_init;
  72         $self->git_init(0);
  73         $self->done;
  74 }
  75
  76 # returns undef on duplicate or spam
  77 # mimics Import::add and wraps it for v2
  78 sub add {
  79         my ($self, $mime, $check_cb) = @_;
  80
  81         # spam check:
  82         if ($check_cb) {
  83                 $mime = $check_cb->($mime) or return;
  84         }
  85
  86         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
  87         # as does SQLite 3.4.1+ (released in 2007-07-20), and
  88         # Xapian 1.3.2+ (released 2015-03-15).
  89         # For the most part, we can spawn git-fast-import without
  90         # leaking FDs to it...
  91         $self->idx_init;
  92
  93         my $mid0;
  94         my $num = num_for($self, $mime, \$mid0);
  95         defined $num or return; # duplicate
  96         defined $mid0 or die "BUG: $mid0 undefined\n";
  97         my $im = $self->importer;
  98         my $cmt = $im->add($mime);
  99         $cmt = $im->get_mark($cmt);
 100         my ($oid, $len, $msgref) = @{$im->{last_object}};
 101
 102         my $nparts = $self->{partitions};
 103         my $part = $num % $nparts;
 104         my $idx = $self->idx_part($part);
 105         $idx->index_raw($len, $msgref, $num, $oid, $mid0, $mime);
 106         my $n = $self->{transact_bytes} += $len;
 107         if ($n > (PublicInbox::SearchIdx::BATCH_BYTES * $nparts)) {
 108                 $self->checkpoint;
 109         }
 110
 111         $mime;
 112 }
 113
 114 sub num_for {
 115         my ($self, $mime, $mid0) = @_;
 116         my $mids = mids($mime->header_obj);
 117         if (@$mids) {
 118                 my $mid = $mids->[0];
 119                 my $num = $self->{skel}->{mm}->mid_insert($mid);
 120                 if (defined $num) { # common case
 121                         $$mid0 = $mid;
 122                         return $num;
 123                 };
 124
 125                 # crap, Message-ID is already known, hope somebody just resent:
 126                 $self->barrier;
 127                 foreach my $m (@$mids) {
 128                         # read-only lookup now safe to do after above barrier
 129                         my $existing = $self->lookup_content($mime, $m);
 130                         # easy, don't store duplicates
 131                         # note: do not add more diagnostic info here since
 132                         # it gets noisy on public-inbox-watch restarts
 133                         return if $existing;
 134                 }
 135
 136                 # very unlikely:
 137                 warn "<$mid> reused for mismatched content\n";
 138
 139                 # try the rest of the mids
 140                 foreach my $i (1..$#$mids) {
 141                         my $m = $mids->[$i];
 142                         $num = $self->{skel}->{mm}->mid_insert($m);
 143                         if (defined $num) {
 144                                 warn "alternative <$m> for <$mid> found\n";
 145                                 $$mid0 = $m;
 146                                 return $num;
 147                         }
 148                 }
 149         }
 150         # none of the existing Message-IDs are good, generate a new one:
 151         num_for_harder($self, $mime, $mid0);
 152 }
 153
 154 sub num_for_harder {
 155         my ($self, $mime, $mid0) = @_;
 156
 157         my $hdr = $mime->header_obj;
 158         my $dig = content_digest($mime);
 159         $$mid0 = PublicInbox::Import::digest2mid($dig);
 160         my $num = $self->{skel}->{mm}->mid_insert($$mid0);
 161         unless (defined $num) {
 162                 # it's hard to spoof the last Received: header
 163                 my @recvd = $hdr->header_raw('Received');
 164                 $dig->add("Received: $_") foreach (@recvd);
 165                 $$mid0 = PublicInbox::Import::digest2mid($dig);
 166                 $num = $self->{skel}->{mm}->mid_insert($$mid0);
 167
 168                 # fall back to a random Message-ID and give up determinism:
 169                 until (defined($num)) {
 170                         $dig->add(rand);
 171                         $$mid0 = PublicInbox::Import::digest2mid($dig);
 172                         warn "using random Message-ID <$$mid0> as fallback\n";
 173                         $num = $self->{skel}->{mm}->mid_insert($$mid0);
 174                 }
 175         }
 176         my @cur = $hdr->header_raw('Message-Id');
 177         $hdr->header_set('Message-Id', "<$$mid0>", @cur);
 178         $num;
 179 }
 180
 181 sub idx_part {
 182         my ($self, $part) = @_;
 183         $self->{idx_parts}->[$part];
 184 }
 185
 186 # idempotent
 187 sub idx_init {
 188         my ($self) = @_;
 189         return if $self->{idx_parts};
 190         my $ibx = $self->{-inbox};
 191
 192         # do not leak read-only FDs to child processes, we only have these
 193         # FDs for duplicate detection so they should not be
 194         # frequently activated.
 195         delete $ibx->{$_} foreach (qw(git mm search));
 196
 197         $self->lock_acquire;
 198
 199         # first time initialization, first we create the skeleton pipe:
 200         my $skel = $self->{skel} = PublicInbox::SearchIdxSkeleton->new($self);
 201
 202         # need to create all parts before initializing msgmap FD
 203         my $max = $self->{partitions} - 1;
 204         my $idx = $self->{idx_parts} = [];
 205         for my $i (0..$max) {
 206                 push @$idx, PublicInbox::SearchIdxPart->new($self, $i, $skel);
 207         }
 208
 209         # Now that all subprocesses are up, we can open the FD for SQLite:
 210         $skel->_msgmap_init->{dbh}->begin_work;
 211 }
 212
 213 sub remove {
 214         my ($self, $mime, $cmt_msg) = @_;
 215         $self->barrier;
 216         $self->idx_init;
 217         my $im = $self->importer;
 218         my $ibx = $self->{-inbox};
 219         my $srch = $ibx->search;
 220         my $cid = content_id($mime);
 221         my $skel = $self->{skel};
 222         my $parts = $self->{idx_parts};
 223         my $mm = $skel->{mm};
 224         my $removed;
 225         my $mids = mids($mime->header_obj);
 226         foreach my $mid (@$mids) {
 227                 $srch->reopen->each_smsg_by_mid($mid, sub {
 228                         my ($smsg) = @_;
 229                         $smsg->load_expand;
 230                         my $msg = $ibx->msg_by_smsg($smsg);
 231                         if (!defined($msg)) {
 232                                 warn "broken smsg for $mid\n";
 233                                 return 1; # continue
 234                         }
 235                         my $orig = $$msg;
 236                         my $cur = PublicInbox::MIME->new($msg);
 237                         if (content_id($cur) eq $cid) {
 238                                 $mm->num_delete($smsg->num);
 239                                 # $removed should only be set once assuming
 240                                 # no bugs in our deduplication code:
 241                                 $removed = $smsg;
 242                                 $removed->{mime} = $cur;
 243                                 $im->remove(\$orig, $cmt_msg);
 244                                 $orig = undef;
 245                                 $removed->num; # memoize this for callers
 246
 247                                 my $oid = $smsg->{blob};
 248                                 foreach my $idx (@$parts, $skel) {
 249                                         $idx->remote_remove($oid, $mid);
 250                                 }
 251                         }
 252                         1; # continue
 253                 });
 254                 $self->barrier;
 255         }
 256         $removed;
 257 }
 258
 259 sub done {
 260         my ($self) = @_;
 261         my $locked = defined $self->{idx_parts};
 262         my $im = delete $self->{im};
 263         $im->done if $im; # PublicInbox::Import::done
 264         $self->searchidx_checkpoint(0);
 265         $self->lock_release if $locked;
 266 }
 267
 268 sub checkpoint {
 269         my ($self) = @_;
 270         my $im = $self->{im};
 271         $im->checkpoint if $im; # PublicInbox::Import::checkpoint
 272         $self->searchidx_checkpoint(1);
 273 }
 274
 275 # issue a write barrier to ensure all data is visible to other processes
 276 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 277 sub barrier {
 278         my ($self) = @_;
 279
 280         if (my $im = $self->{im}) {
 281                 $im->barrier;
 282         }
 283         my $skel = $self->{skel};
 284         my $parts = $self->{idx_parts};
 285         if ($parts && $skel) {
 286                 my $dbh = $skel->{mm}->{dbh};
 287                 $dbh->commit; # SQLite data is second in importance
 288
 289                 # Now deal with Xapian
 290                 $skel->barrier_init(scalar(@$parts));
 291                 # each partition needs to issue a barrier command to skel:
 292                 $_->remote_barrier foreach @$parts;
 293
 294                 $skel->barrier_wait; # wait for each Xapian partition
 295
 296                 $dbh->begin_work;
 297         }
 298         $self->{transact_bytes} = 0;
 299 }
 300
 301 sub searchidx_checkpoint {
 302         my ($self, $more) = @_;
 303
 304         # order matters, we can only close {skel} after all partitions
 305         # are done because the partitions also write to {skel}
 306         if (my $parts = $self->{idx_parts}) {
 307                 foreach my $idx (@$parts) {
 308                         $idx->remote_commit; # propagates commit to skel
 309                         $idx->remote_close unless $more;
 310                 }
 311                 delete $self->{idx_parts} unless $more;
 312         }
 313
 314         if (my $skel = $self->{skel}) {
 315                 my $dbh = $skel->{mm}->{dbh};
 316                 $dbh->commit;
 317                 if ($more) {
 318                         $dbh->begin_work;
 319                 } else {
 320                         $skel->remote_close;
 321                         delete $self->{skel};
 322                 }
 323         }
 324         $self->{transact_bytes} = 0;
 325 }
 326
 327 sub git_init {
 328         my ($self, $new) = @_;
 329         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 330         my $git_dir = "$pfx/$new.git";
 331         die "$git_dir exists\n" if -e $git_dir;
 332         my @cmd = (qw(git init --bare -q), $git_dir);
 333         PublicInbox::Import::run_die(\@cmd);
 334
 335         my $all = "$self->{-inbox}->{mainrepo}/all.git";
 336         unless (-d $all) {
 337                 @cmd = (qw(git init --bare -q), $all);
 338                 PublicInbox::Import::run_die(\@cmd);
 339                 @cmd = (qw/git config/, "--file=$all/config",
 340                                 'repack.writeBitmaps', 'true');
 341                 PublicInbox::Import::run_die(\@cmd);
 342         }
 343
 344         @cmd = (qw/git config/, "--file=$git_dir/config",
 345                         'include.path', '../../all.git/config');
 346         PublicInbox::Import::run_die(\@cmd);
 347
 348         my $alt = "$all/objects/info/alternates";
 349         my $new_obj_dir = "../../git/$new.git/objects";
 350         my %alts;
 351         if (-e $alt) {
 352                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 353                 %alts = map { chomp; $_ => 1 } (<$fh>);
 354         }
 355         return $git_dir if $alts{$new_obj_dir};
 356         open my $fh, '>>', $alt or die "open >> $alt: $!\n";
 357         print $fh "$new_obj_dir\n" or die "print >> $alt: $!\n";
 358         close $fh or die "close $alt: $!\n";
 359         $git_dir
 360 }
 361
 362 sub git_dir_latest {
 363         my ($self, $max) = @_;
 364         $$max = -1;
 365         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 366         return unless -d $pfx;
 367         my $latest;
 368         opendir my $dh, $pfx or die "opendir $pfx: $!\n";
 369         while (defined(my $git_dir = readdir($dh))) {
 370                 $git_dir =~ m!\A(\d+)\.git\z! or next;
 371                 if ($1 > $$max) {
 372                         $$max = $1;
 373                         $latest = "$pfx/$git_dir";
 374                 }
 375         }
 376         $latest;
 377 }
 378
 379 sub importer {
 380         my ($self) = @_;
 381         my $im = $self->{im};
 382         if ($im) {
 383                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 384                         return $im;
 385                 } else {
 386                         $self->{im} = undef;
 387                         $im->done;
 388                         $self->searchidx_checkpoint(1);
 389                         $im = undef;
 390                         my $git_dir = $self->git_init(++$self->{max_git});
 391                         my $git = PublicInbox::Git->new($git_dir);
 392                         return $self->import_init($git, 0);
 393                 }
 394         }
 395         my $new = 0;
 396         my $max;
 397         my $latest = git_dir_latest($self, \$max);
 398         if (defined $latest) {
 399                 my $git = PublicInbox::Git->new($latest);
 400                 my $packed_bytes = $git->packed_bytes;
 401                 if ($packed_bytes >= $self->{rotate_bytes}) {
 402                         $new = $max + 1;
 403                 } else {
 404                         $self->{max_git} = $max;
 405                         return $self->import_init($git, $packed_bytes);
 406                 }
 407         }
 408         $self->{max_git} = $new;
 409         $latest = $self->git_init($new);
 410         $self->import_init(PublicInbox::Git->new($latest), 0);
 411 }
 412
 413 sub import_init {
 414         my ($self, $git, $packed_bytes) = @_;
 415         my $im = PublicInbox::Import->new($git, undef, undef, $self->{-inbox});
 416         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 417         $im->{want_object_info} = 1;
 418         $im->{lock_path} = undef;
 419         $im->{path_type} = 'v2';
 420         $self->{im} = $im;
 421 }
 422
 423 # XXX experimental
 424 sub diff ($$$) {
 425         my ($mid, $cur, $new) = @_;
 426         use File::Temp qw(tempfile);
 427         use PublicInbox::Spawn qw(spawn);
 428
 429         my ($ah, $an) = tempfile('email-cur-XXXXXXXX');
 430         print $ah $cur->as_string or die "print: $!";
 431         close $ah or die "close: $!";
 432         my ($bh, $bn) = tempfile('email-new-XXXXXXXX');
 433         print $bh $new->as_string or die "print: $!";
 434         close $bh or die "close: $!";
 435         my $cmd = [ qw(diff -u), $an, $bn ];
 436         print STDERR "# MID conflict <$mid>\n";
 437         my $pid = spawn($cmd, undef, { 1 => 2 });
 438         defined $pid or die "diff failed to spawn $!";
 439         waitpid($pid, 0) == $pid or die "diff did not finish";
 440         unlink($an, $bn);
 441 }
 442
 443 sub lookup_content {
 444         my ($self, $mime, $mid) = @_;
 445         my $ibx = $self->{-inbox};
 446
 447         my $srch = $ibx->search->reopen;
 448         my $cid = content_id($mime);
 449         my $found;
 450         $srch->each_smsg_by_mid($mid, sub {
 451                 my ($smsg) = @_;
 452                 $smsg->load_expand;
 453                 my $msg = $ibx->msg_by_smsg($smsg);
 454                 if (!defined($msg)) {
 455                         warn "broken smsg for $mid\n";
 456                         return 1; # continue
 457                 }
 458                 my $cur = PublicInbox::MIME->new($msg);
 459                 if (content_id($cur) eq $cid) {
 460                         $smsg->{mime} = $cur;
 461                         $found = $smsg;
 462                         return 0; # break out of loop
 463                 }
 464
 465                 # XXX DEBUG_DIFF is experimental and may be removed
 466                 diff($mid, $cur, $mime) if $ENV{DEBUG_DIFF};
 467
 468                 1; # continue
 469         });
 470         $found;
 471 }
 472
 473 sub atfork_child {
 474         my ($self) = @_;
 475         my $fh = delete $self->{reindex_pipe};
 476         close $fh if $fh;
 477         if (my $parts = $self->{idx_parts}) {
 478                 $_->atfork_child foreach @$parts;
 479         }
 480         if (my $im = $self->{im}) {
 481                 $im->atfork_child;
 482         }
 483 }
 484
 485 sub mark_deleted {
 486         my ($self, $D, $git, $oid) = @_;
 487         my $msgref = $git->cat_file($oid);
 488         my $mime = PublicInbox::MIME->new($$msgref);
 489         my $mids = mids($mime->header_obj);
 490         my $cid = content_id($mime);
 491         foreach my $mid (@$mids) {
 492                 $D->{$mid.$cid} = 1;
 493         }
 494 }
 495
 496 sub reindex_oid {
 497         my ($self, $mm_tmp, $D, $git, $oid, $regen) = @_;
 498         my $len;
 499         my $msgref = $git->cat_file($oid, \$len);
 500         my $mime = PublicInbox::MIME->new($$msgref);
 501         my $mids = mids($mime->header_obj);
 502         my $cid = content_id($mime);
 503
 504         # get the NNTP article number we used before, highest number wins
 505         # and gets deleted from mm_tmp;
 506         my $mid0;
 507         my $num = -1;
 508         my $del = 0;
 509         foreach my $mid (@$mids) {
 510                 $del += (delete $D->{$mid.$cid} || 0);
 511                 my $n = $mm_tmp->num_for($mid);
 512                 if (defined $n && $n > $num) {
 513                         $mid0 = $mid;
 514                         $num = $n;
 515                 }
 516         }
 517         if (!defined($mid0) && $regen && !$del) {
 518                 $num = $$regen--;
 519                 die "BUG: ran out of article numbers\n" if $num <= 0;
 520                 my $mm = $self->{skel}->{mm};
 521                 foreach my $mid (@$mids) {
 522                         if ($mm->mid_set($num, $mid) == 1) {
 523                                 $mid0 = $mid;
 524                                 last;
 525                         }
 526                 }
 527                 if (!defined($mid0)) {
 528                         my $id = '<' . join('> <', @$mids) . '>';
 529                         warn "Message-Id $id unusable for $num\n";
 530                 }
 531         }
 532
 533         if (!defined($mid0) || $del) {
 534                 if (!defined($mid0) && $del) { # expected for deletes
 535                         $$regen--;
 536                         return
 537                 }
 538
 539                 my $id = '<' . join('> <', @$mids) . '>';
 540                 defined($mid0) or
 541                         warn "Skipping $id, no article number found\n";
 542                 if ($del && defined($mid0)) {
 543                         warn "$id was deleted $del " .
 544                                 "time(s) but mapped to article #$num\n";
 545                 }
 546                 return;
 547
 548         }
 549         $mm_tmp->mid_delete($mid0) or
 550                 die "failed to delete <$mid0> for article #$num\n";
 551
 552         my $nparts = $self->{partitions};
 553         my $part = $num % $nparts;
 554         my $idx = $self->idx_part($part);
 555         $idx->index_raw($len, $msgref, $num, $oid, $mid0, $mime);
 556         my $n = $self->{transact_bytes} += $len;
 557         if ($n > (PublicInbox::SearchIdx::BATCH_BYTES * $nparts)) {
 558                 $git->cleanup;
 559                 $mm_tmp->atfork_prepare;
 560                 $self->done; # release lock
 561                 # allow -watch or -mda to write...
 562                 $self->idx_init; # reacquire lock
 563                 $mm_tmp->atfork_parent;
 564         }
 565 }
 566
 567 sub reindex {
 568         my ($self, $regen) = @_;
 569         my $ibx = $self->{-inbox};
 570         my $pfx = "$ibx->{mainrepo}/git";
 571         my $max_git;
 572         my $latest = git_dir_latest($self, \$max_git);
 573         return unless defined $latest;
 574         my $head = $ibx->{ref_head} || 'refs/heads/master';
 575         $self->idx_init; # acquire lock
 576         my $x40 = qr/[a-f0-9]{40}/;
 577         my $mm_tmp = $self->{skel}->{mm}->tmp_clone;
 578         if (!$regen) {
 579                 my (undef, $max) = $mm_tmp->minmax;
 580                 unless (defined $max) {
 581                         $regen = 1;
 582                         warn
 583 "empty msgmap.sqlite3, regenerating article numbers\n";
 584                 }
 585         }
 586         my $tip; # latest commit out of all git repos
 587         if ($regen) {
 588                 my $regen_max = 0;
 589                 for (my $cur = $max_git; $cur >= 0; $cur--) {
 590                         die "already reindexing!\n" if $self->{reindex_pipe};
 591                         my $git = PublicInbox::Git->new("$pfx/$cur.git");
 592                         chomp($tip = $git->qx('rev-parse', $head)) unless $tip;
 593                         my $h = $cur == $max_git ? $tip : $head;
 594                         my @count = ('rev-list', '--count', $h, '--', 'm');
 595                         $regen_max += $git->qx(@count);
 596                 }
 597                 die "No messages found in $pfx/*.git, bug?\n" unless $regen_max;
 598                 $regen = \$regen_max;
 599         }
 600         my $D = {};
 601         my @cmd = qw(log --raw -r --pretty=tformat:%h
 602                         --no-notes --no-color --no-abbrev);
 603
 604         # if we are regenerating, we must not use a newer tip commit than what
 605         # the regeneration counter used:
 606         $tip ||= $head;
 607
 608         # work backwards through history
 609         for (my $cur = $max_git; $cur >= 0; $cur--) {
 610                 die "already reindexing!\n" if delete $self->{reindex_pipe};
 611                 my $cmt;
 612                 my $git_dir = "$pfx/$cur.git";
 613                 my $git = PublicInbox::Git->new($git_dir);
 614                 my $h = $cur == $max_git ? $tip : $head;
 615                 my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $h);
 616                 while (<$fh>) {
 617                         if (/\A$x40$/o) {
 618                                 chomp($cmt = $_);
 619                         } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o) {
 620                                 $self->reindex_oid($mm_tmp, $D, $git, $1,
 621                                                 $regen);
 622                         } elsif (m!\A:\d{6} 100644 $x40 ($x40) [AM]\t_/D$!o) {
 623                                 $self->mark_deleted($D, $git, $1);
 624                         }
 625                 }
 626                 delete $self->{reindex_pipe};
 627         }
 628         my ($min, $max) = $mm_tmp->minmax;
 629         defined $max and die "leftover article numbers at $min..$max\n";
 630 }
 631
 632 1;