lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 # Used to write to V2 inboxes (see L<public-inbox-v2-format(5)>).
   6 package PublicInbox::V2Writable;
   7 use strict;
   8 use warnings;
   9 use base qw(PublicInbox::Lock);
  10 use PublicInbox::SearchIdxPart;
  11 use PublicInbox::MIME;
  12 use PublicInbox::Git;
  13 use PublicInbox::Import;
  14 use PublicInbox::MID qw(mids);
  15 use PublicInbox::ContentId qw(content_id content_digest);
  16 use PublicInbox::Inbox;
  17 use PublicInbox::OverIdx;
  18 use PublicInbox::Msgmap;
  19 use PublicInbox::Spawn qw(spawn);
  20 use PublicInbox::SearchIdx;
  21 use IO::Handle;
  22
  23 # an estimate of the post-packed size to the raw uncompressed size
  24 my $PACKING_FACTOR = 0.4;
  25
  26 # assume 2 cores if GNU nproc(1) is not available
  27 sub nproc_parts () {
  28         my $n = int($ENV{NPROC} || `nproc 2>/dev/null` || 2);
  29         # subtract for the main process and git-fast-import
  30         $n -= 1;
  31         $n < 1 ? 1 : $n;
  32 }
  33
  34 sub count_partitions ($) {
  35         my ($self) = @_;
  36         my $nparts = 0;
  37         my $xpfx = $self->{xpfx};
  38
  39         # always load existing partitions in case core count changes:
  40         # Also, partition count may change while -watch is running
  41         # due to -compact
  42         if (-d $xpfx) {
  43                 foreach my $part (<$xpfx/*>) {
  44                         -d $part && $part =~ m!/\d+\z! or next;
  45                         eval {
  46                                 Search::Xapian::Database->new($part)->close;
  47                                 $nparts++;
  48                         };
  49                 }
  50         }
  51         $nparts;
  52 }
  53
  54 sub new {
  55         my ($class, $v2ibx, $creat) = @_;
  56         my $dir = $v2ibx->{mainrepo} or die "no mainrepo in inbox\n";
  57         unless (-d $dir) {
  58                 if ($creat) {
  59                         require File::Path;
  60                         File::Path::mkpath($dir);
  61                 } else {
  62                         die "$dir does not exist\n";
  63                 }
  64         }
  65
  66         $v2ibx = PublicInbox::InboxWritable->new($v2ibx);
  67         $v2ibx->umask_prepare;
  68
  69         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
  70         my $self = {
  71                 -inbox => $v2ibx,
  72                 im => undef, #  PublicInbox::Import
  73                 parallel => 1,
  74                 transact_bytes => 0,
  75                 xpfx => $xpfx,
  76                 over => PublicInbox::OverIdx->new("$xpfx/over.sqlite3", 1),
  77                 lock_path => "$dir/inbox.lock",
  78                 # limit each git repo (epoch) to 1GB or so
  79                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
  80                 last_commit => [], # git repo -> commit
  81         };
  82         $self->{partitions} = count_partitions($self) || nproc_parts();
  83         bless $self, $class;
  84 }
  85
  86 sub init_inbox {
  87         my ($self, $parallel, $skip) = @_;
  88         $self->{parallel} = $parallel;
  89         $self->idx_init;
  90         my $epoch_max = -1;
  91         git_dir_latest($self, \$epoch_max);
  92         if (defined $skip && $epoch_max == -1) {
  93                 $epoch_max = $skip;
  94         }
  95         $self->git_init($epoch_max >= 0 ? $epoch_max : 0);
  96         $self->done;
  97 }
  98
  99 # returns undef on duplicate or spam
 100 # mimics Import::add and wraps it for v2
 101 sub add {
 102         my ($self, $mime, $check_cb) = @_;
 103         $self->{-inbox}->with_umask(sub {
 104                 _add($self, $mime, $check_cb)
 105         });
 106 }
 107
 108 sub _add {
 109         my ($self, $mime, $check_cb) = @_;
 110
 111         # spam check:
 112         if ($check_cb) {
 113                 $mime = $check_cb->($mime) or return;
 114         }
 115
 116         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
 117         # as does SQLite 3.4.1+ (released in 2007-07-20), and
 118         # Xapian 1.3.2+ (released 2015-03-15).
 119         # For the most part, we can spawn git-fast-import without
 120         # leaking FDs to it...
 121         $self->idx_init;
 122
 123         my $mid0;
 124         my $num = num_for($self, $mime, \$mid0);
 125         defined $num or return; # duplicate
 126         defined $mid0 or die "BUG: $mid0 undefined\n";
 127         my $im = $self->importer;
 128         my $cmt = $im->add($mime);
 129         $cmt = $im->get_mark($cmt);
 130         $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 131
 132         my ($oid, $len, $msgref) = @{$im->{last_object}};
 133         $self->{over}->add_overview($mime, $len, $num, $oid, $mid0);
 134         my $nparts = $self->{partitions};
 135         my $part = $num % $nparts;
 136         my $idx = $self->idx_part($part);
 137         $idx->index_raw($len, $msgref, $num, $oid, $mid0, $mime);
 138         my $n = $self->{transact_bytes} += $len;
 139         if ($n > (PublicInbox::SearchIdx::BATCH_BYTES * $nparts)) {
 140                 $self->checkpoint;
 141         }
 142
 143         $cmt;
 144 }
 145
 146 sub num_for {
 147         my ($self, $mime, $mid0) = @_;
 148         my $mids = mids($mime->header_obj);
 149         if (@$mids) {
 150                 my $mid = $mids->[0];
 151                 my $num = $self->{mm}->mid_insert($mid);
 152                 if (defined $num) { # common case
 153                         $$mid0 = $mid;
 154                         return $num;
 155                 };
 156
 157                 # crap, Message-ID is already known, hope somebody just resent:
 158                 foreach my $m (@$mids) {
 159                         # read-only lookup now safe to do after above barrier
 160                         my $existing = $self->lookup_content($mime, $m);
 161                         # easy, don't store duplicates
 162                         # note: do not add more diagnostic info here since
 163                         # it gets noisy on public-inbox-watch restarts
 164                         return if $existing;
 165                 }
 166
 167                 # AltId may pre-populate article numbers (e.g. X-Mail-Count
 168                 # or NNTP article number), use that article number if it's
 169                 # not in Over.
 170                 my $altid = $self->{-inbox}->{altid};
 171                 if ($altid && grep(/:file=msgmap\.sqlite3\z/, @$altid)) {
 172                         my $num = $self->{mm}->num_for($mid);
 173
 174                         if (defined $num && !$self->{over}->get_art($num)) {
 175                                 $$mid0 = $mid;
 176                                 return $num;
 177                         }
 178                 }
 179
 180                 # very unlikely:
 181                 warn "<$mid> reused for mismatched content\n";
 182
 183                 # try the rest of the mids
 184                 for(my $i = $#$mids; $i >= 1; $i--) {
 185                         my $m = $mids->[$i];
 186                         $num = $self->{mm}->mid_insert($m);
 187                         if (defined $num) {
 188                                 warn "alternative <$m> for <$mid> found\n";
 189                                 $$mid0 = $m;
 190                                 return $num;
 191                         }
 192                 }
 193         }
 194         # none of the existing Message-IDs are good, generate a new one:
 195         num_for_harder($self, $mime, $mid0);
 196 }
 197
 198 sub num_for_harder {
 199         my ($self, $mime, $mid0) = @_;
 200
 201         my $hdr = $mime->header_obj;
 202         my $dig = content_digest($mime);
 203         $$mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 204         my $num = $self->{mm}->mid_insert($$mid0);
 205         unless (defined $num) {
 206                 # it's hard to spoof the last Received: header
 207                 my @recvd = $hdr->header_raw('Received');
 208                 $dig->add("Received: $_") foreach (@recvd);
 209                 $$mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 210                 $num = $self->{mm}->mid_insert($$mid0);
 211
 212                 # fall back to a random Message-ID and give up determinism:
 213                 until (defined($num)) {
 214                         $dig->add(rand);
 215                         $$mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 216                         warn "using random Message-ID <$$mid0> as fallback\n";
 217                         $num = $self->{mm}->mid_insert($$mid0);
 218                 }
 219         }
 220         PublicInbox::Import::append_mid($hdr, $$mid0);
 221         $num;
 222 }
 223
 224 sub idx_part {
 225         my ($self, $part) = @_;
 226         $self->{idx_parts}->[$part];
 227 }
 228
 229 # idempotent
 230 sub idx_init {
 231         my ($self) = @_;
 232         return if $self->{idx_parts};
 233         my $ibx = $self->{-inbox};
 234
 235         # do not leak read-only FDs to child processes, we only have these
 236         # FDs for duplicate detection so they should not be
 237         # frequently activated.
 238         delete $ibx->{$_} foreach (qw(git mm search));
 239
 240         my $indexlevel = $ibx->{indexlevel};
 241         if ($indexlevel && $indexlevel eq 'basic') {
 242                 $self->{parallel} = 0;
 243         }
 244
 245         if ($self->{parallel}) {
 246                 pipe(my ($r, $w)) or die "pipe failed: $!";
 247                 # pipe for barrier notifications doesn't need to be big,
 248                 # 1031: F_SETPIPE_SZ
 249                 fcntl($w, 1031, 4096) if $^O eq 'linux';
 250                 $self->{bnote} = [ $r, $w ];
 251                 $w->autoflush(1);
 252         }
 253
 254         my $over = $self->{over};
 255         $ibx->umask_prepare;
 256         $ibx->with_umask(sub {
 257                 $self->lock_acquire;
 258                 $over->create;
 259
 260                 # -compact can change partition count while -watch is idle
 261                 my $nparts = count_partitions($self);
 262                 if ($nparts && $nparts != $self->{partitions}) {
 263                         $self->{partitions} = $nparts;
 264                 }
 265
 266                 # need to create all parts before initializing msgmap FD
 267                 my $max = $self->{partitions} - 1;
 268
 269                 # idx_parts must be visible to all forked processes
 270                 my $idx = $self->{idx_parts} = [];
 271                 for my $i (0..$max) {
 272                         push @$idx, PublicInbox::SearchIdxPart->new($self, $i);
 273                 }
 274
 275                 # Now that all subprocesses are up, we can open the FDs
 276                 # for SQLite:
 277                 my $mm = $self->{mm} = PublicInbox::Msgmap->new_file(
 278                         "$self->{-inbox}->{mainrepo}/msgmap.sqlite3", 1);
 279                 $mm->{dbh}->begin_work;
 280         });
 281 }
 282
 283 sub purge_oids {
 284         my ($self, $purge) = @_; # $purge = { $object_id => 1, ... }
 285         $self->done;
 286         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 287         my $purges = [];
 288         my $max = $self->{epoch_max};
 289
 290         unless (defined($max)) {
 291                 defined(my $latest = git_dir_latest($self, \$max)) or return;
 292                 $self->{epoch_max} = $max;
 293         }
 294         foreach my $i (0..$max) {
 295                 my $git_dir = "$pfx/$i.git";
 296                 -d $git_dir or next;
 297                 my $git = PublicInbox::Git->new($git_dir);
 298                 my $im = $self->import_init($git, 0, 1);
 299                 $purges->[$i] = $im->purge_oids($purge);
 300                 $im->done;
 301         }
 302         $purges;
 303 }
 304
 305 sub content_ids ($) {
 306         my ($mime) = @_;
 307         my @cids = ( content_id($mime) );
 308
 309         # Email::MIME->as_string doesn't always round-trip, so we may
 310         # use a second content_id
 311         my $rt = content_id(PublicInbox::MIME->new(\($mime->as_string)));
 312         push @cids, $rt if $cids[0] ne $rt;
 313         \@cids;
 314 }
 315
 316 sub content_matches ($$) {
 317         my ($cids, $existing) = @_;
 318         my $cid = content_id($existing);
 319         foreach (@$cids) {
 320                 return 1 if $_ eq $cid
 321         }
 322         0
 323 }
 324
 325 sub remove_internal {
 326         my ($self, $mime, $cmt_msg, $purge) = @_;
 327         $self->idx_init;
 328         my $im = $self->importer unless $purge;
 329         my $over = $self->{over};
 330         my $cids = content_ids($mime);
 331         my $parts = $self->{idx_parts};
 332         my $mm = $self->{mm};
 333         my $removed;
 334         my $mids = mids($mime->header_obj);
 335
 336         # We avoid introducing new blobs into git since the raw content
 337         # can be slightly different, so we do not need the user-supplied
 338         # message now that we have the mids and content_id
 339         $mime = undef;
 340         my $mark;
 341
 342         foreach my $mid (@$mids) {
 343                 my %gone;
 344                 my ($id, $prev);
 345                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 346                         my $msg = get_blob($self, $smsg);
 347                         if (!defined($msg)) {
 348                                 warn "broken smsg for $mid\n";
 349                                 next; # continue
 350                         }
 351                         my $orig = $$msg;
 352                         my $cur = PublicInbox::MIME->new($msg);
 353                         if (content_matches($cids, $cur)) {
 354                                 $smsg->{mime} = $cur;
 355                                 $gone{$smsg->{num}} = [ $smsg, \$orig ];
 356                         }
 357                 }
 358                 my $n = scalar keys %gone;
 359                 next unless $n;
 360                 if ($n > 1) {
 361                         warn "BUG: multiple articles linked to <$mid>\n",
 362                                 join(',', sort keys %gone), "\n";
 363                 }
 364                 foreach my $num (keys %gone) {
 365                         my ($smsg, $orig) = @{$gone{$num}};
 366                         $mm->num_delete($num);
 367                         # $removed should only be set once assuming
 368                         # no bugs in our deduplication code:
 369                         $removed = $smsg;
 370                         my $oid = $smsg->{blob};
 371                         if ($purge) {
 372                                 $purge->{$oid} = 1;
 373                         } else {
 374                                 ($mark, undef) = $im->remove($orig, $cmt_msg);
 375                         }
 376                         $orig = undef;
 377                         $self->unindex_oid_remote($oid, $mid);
 378                 }
 379         }
 380
 381         if (defined $mark) {
 382                 my $cmt = $im->get_mark($mark);
 383                 $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 384         }
 385         if ($purge && scalar keys %$purge) {
 386                 return purge_oids($self, $purge);
 387         }
 388         $removed;
 389 }
 390
 391 sub remove {
 392         my ($self, $mime, $cmt_msg) = @_;
 393         $self->{-inbox}->with_umask(sub {
 394                 remove_internal($self, $mime, $cmt_msg);
 395         });
 396 }
 397
 398 sub purge {
 399         my ($self, $mime) = @_;
 400         my $purges = $self->{-inbox}->with_umask(sub {
 401                 remove_internal($self, $mime, undef, {});
 402         }) or return;
 403         $self->idx_init if @$purges; # ->done is called on purges
 404         for my $i (0..$#$purges) {
 405                 defined(my $cmt = $purges->[$i]) or next;
 406                 $self->{last_commit}->[$i] = $cmt;
 407         }
 408         $purges;
 409 }
 410
 411 sub last_commit_part ($$;$) {
 412         my ($self, $i, $cmt) = @_;
 413         my $v = PublicInbox::Search::SCHEMA_VERSION();
 414         $self->{mm}->last_commit_xap($v, $i, $cmt);
 415 }
 416
 417 sub set_last_commits ($) {
 418         my ($self) = @_;
 419         defined(my $epoch_max = $self->{epoch_max}) or return;
 420         my $last_commit = $self->{last_commit};
 421         foreach my $i (0..$epoch_max) {
 422                 defined(my $cmt = $last_commit->[$i]) or next;
 423                 $last_commit->[$i] = undef;
 424                 last_commit_part($self, $i, $cmt);
 425         }
 426 }
 427
 428 sub barrier_init {
 429         my ($self, $n) = @_;
 430         $self->{bnote} or return;
 431         --$n;
 432         my $barrier = { map { $_ => 1 } (0..$n) };
 433 }
 434
 435 sub barrier_wait {
 436         my ($self, $barrier) = @_;
 437         my $bnote = $self->{bnote} or return;
 438         my $r = $bnote->[0];
 439         while (scalar keys %$barrier) {
 440                 defined(my $l = $r->getline) or die "EOF on barrier_wait: $!";
 441                 $l =~ /\Abarrier (\d+)/ or die "bad line on barrier_wait: $l";
 442                 delete $barrier->{$1} or die "bad part[$1] on barrier wait";
 443         }
 444 }
 445
 446 sub checkpoint ($;$) {
 447         my ($self, $wait) = @_;
 448
 449         if (my $im = $self->{im}) {
 450                 if ($wait) {
 451                         $im->barrier;
 452                 } else {
 453                         $im->checkpoint;
 454                 }
 455         }
 456         my $parts = $self->{idx_parts};
 457         if ($parts) {
 458                 my $dbh = $self->{mm}->{dbh};
 459
 460                 # SQLite msgmap data is second in importance
 461                 $dbh->commit;
 462
 463                 # SQLite overview is third
 464                 $self->{over}->commit_lazy;
 465
 466                 # Now deal with Xapian
 467                 if ($wait) {
 468                         my $barrier = $self->barrier_init(scalar @$parts);
 469
 470                         # each partition needs to issue a barrier command
 471                         $_->remote_barrier for @$parts;
 472
 473                         # wait for each Xapian partition
 474                         $self->barrier_wait($barrier);
 475                 } else {
 476                         $_->remote_commit for @$parts;
 477                 }
 478
 479                 # last_commit is special, don't commit these until
 480                 # remote partitions are done:
 481                 $dbh->begin_work;
 482                 set_last_commits($self);
 483                 $dbh->commit;
 484
 485                 $dbh->begin_work;
 486         }
 487         $self->{transact_bytes} = 0;
 488 }
 489
 490 # issue a write barrier to ensure all data is visible to other processes
 491 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 492 sub barrier { checkpoint($_[0], 1) };
 493
 494 sub done {
 495         my ($self) = @_;
 496         my $im = delete $self->{im};
 497         $im->done if $im; # PublicInbox::Import::done
 498         checkpoint($self);
 499         my $mm = delete $self->{mm};
 500         $mm->{dbh}->commit if $mm;
 501         my $parts = delete $self->{idx_parts};
 502         if ($parts) {
 503                 $_->remote_close for @$parts;
 504         }
 505         $self->{over}->disconnect;
 506         delete $self->{bnote};
 507         $self->{transact_bytes} = 0;
 508         $self->lock_release if $parts;
 509         $self->{-inbox}->git->cleanup;
 510 }
 511
 512 sub fill_alternates ($$) {
 513         my ($self, $epoch) = @_;
 514
 515         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 516         my $all = "$self->{-inbox}->{mainrepo}/all.git";
 517         my @cmd;
 518         unless (-d $all) {
 519                 @cmd = (qw(git init --bare -q), $all);
 520                 PublicInbox::Import::run_die(\@cmd);
 521                 @cmd = (qw/git config/, "--file=$all/config",
 522                                 'repack.writeBitmaps', 'true');
 523                 PublicInbox::Import::run_die(\@cmd);
 524         }
 525         @cmd = (qw/git config/, "--file=$pfx/$epoch.git/config",
 526                         'include.path', '../../all.git/config');
 527         PublicInbox::Import::run_die(\@cmd);
 528
 529         my $alt = "$all/objects/info/alternates";
 530         my %alts;
 531         my @add;
 532         if (-e $alt) {
 533                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 534                 %alts = map { chomp; $_ => 1 } (<$fh>);
 535         }
 536         foreach my $i (0..$epoch) {
 537                 my $dir = "../../git/$i.git/objects";
 538                 push @add, $dir if !$alts{$dir} && -d "$pfx/$i.git";
 539         }
 540         return unless @add;
 541         open my $fh, '>>', $alt or die "open >> $alt: $!\n";
 542         foreach my $dir (@add) {
 543                 print $fh "$dir\n" or die "print >> $alt: $!\n";
 544         }
 545         close $fh or die "close $alt: $!\n";
 546 }
 547
 548 sub git_init {
 549         my ($self, $epoch) = @_;
 550         my $git_dir = "$self->{-inbox}->{mainrepo}/git/$epoch.git";
 551         my @cmd = (qw(git init --bare -q), $git_dir);
 552         PublicInbox::Import::run_die(\@cmd);
 553         fill_alternates($self, $epoch);
 554         $git_dir
 555 }
 556
 557 sub git_dir_latest {
 558         my ($self, $max) = @_;
 559         $$max = -1;
 560         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 561         return unless -d $pfx;
 562         my $latest;
 563         opendir my $dh, $pfx or die "opendir $pfx: $!\n";
 564         while (defined(my $git_dir = readdir($dh))) {
 565                 $git_dir =~ m!\A(\d+)\.git\z! or next;
 566                 if ($1 > $$max) {
 567                         $$max = $1;
 568                         $latest = "$pfx/$git_dir";
 569                 }
 570         }
 571         $latest;
 572 }
 573
 574 sub importer {
 575         my ($self) = @_;
 576         my $im = $self->{im};
 577         if ($im) {
 578                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 579                         return $im;
 580                 } else {
 581                         $self->{im} = undef;
 582                         $im->done;
 583                         $im = undef;
 584                         $self->checkpoint;
 585                         my $git_dir = $self->git_init(++$self->{epoch_max});
 586                         my $git = PublicInbox::Git->new($git_dir);
 587                         return $self->import_init($git, 0);
 588                 }
 589         }
 590         my $epoch = 0;
 591         my $max;
 592         my $latest = git_dir_latest($self, \$max);
 593         if (defined $latest) {
 594                 my $git = PublicInbox::Git->new($latest);
 595                 my $packed_bytes = $git->packed_bytes;
 596                 my $unpacked_bytes = $packed_bytes / $PACKING_FACTOR;
 597
 598                 if ($unpacked_bytes >= $self->{rotate_bytes}) {
 599                         $epoch = $max + 1;
 600                 } else {
 601                         $self->{epoch_max} = $max;
 602                         return $self->import_init($git, $packed_bytes);
 603                 }
 604         }
 605         $self->{epoch_max} = $epoch;
 606         $latest = $self->git_init($epoch);
 607         $self->import_init(PublicInbox::Git->new($latest), 0);
 608 }
 609
 610 sub import_init {
 611         my ($self, $git, $packed_bytes, $tmp) = @_;
 612         my $im = PublicInbox::Import->new($git, undef, undef, $self->{-inbox});
 613         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 614         $im->{want_object_info} = 1;
 615         $im->{lock_path} = undef;
 616         $im->{path_type} = 'v2';
 617         $self->{im} = $im unless $tmp;
 618         $im;
 619 }
 620
 621 # XXX experimental
 622 sub diff ($$$) {
 623         my ($mid, $cur, $new) = @_;
 624         use File::Temp qw(tempfile);
 625
 626         my ($ah, $an) = tempfile('email-cur-XXXXXXXX', TMPDIR => 1);
 627         print $ah $cur->as_string or die "print: $!";
 628         close $ah or die "close: $!";
 629         my ($bh, $bn) = tempfile('email-new-XXXXXXXX', TMPDIR => 1);
 630         PublicInbox::Import::drop_unwanted_headers($new);
 631         print $bh $new->as_string or die "print: $!";
 632         close $bh or die "close: $!";
 633         my $cmd = [ qw(diff -u), $an, $bn ];
 634         print STDERR "# MID conflict <$mid>\n";
 635         my $pid = spawn($cmd, undef, { 1 => 2 });
 636         defined $pid or die "diff failed to spawn $!";
 637         waitpid($pid, 0) == $pid or die "diff did not finish";
 638         unlink($an, $bn);
 639 }
 640
 641 sub get_blob ($$) {
 642         my ($self, $smsg) = @_;
 643         if (my $im = $self->{im}) {
 644                 my $msg = $im->cat_blob($smsg->{blob});
 645                 return $msg if $msg;
 646         }
 647         # older message, should be in alternates
 648         my $ibx = $self->{-inbox};
 649         $ibx->msg_by_smsg($smsg);
 650 }
 651
 652 sub lookup_content {
 653         my ($self, $mime, $mid) = @_;
 654         my $over = $self->{over};
 655         my $cids = content_ids($mime);
 656         my ($id, $prev);
 657         while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 658                 my $msg = get_blob($self, $smsg);
 659                 if (!defined($msg)) {
 660                         warn "broken smsg for $mid\n";
 661                         next;
 662                 }
 663                 my $cur = PublicInbox::MIME->new($msg);
 664                 if (content_matches($cids, $cur)) {
 665                         $smsg->{mime} = $cur;
 666                         return $smsg;
 667                 }
 668
 669
 670                 # XXX DEBUG_DIFF is experimental and may be removed
 671                 diff($mid, $cur, $mime) if $ENV{DEBUG_DIFF};
 672         }
 673         undef;
 674 }
 675
 676 sub atfork_child {
 677         my ($self) = @_;
 678         my $fh = delete $self->{reindex_pipe};
 679         close $fh if $fh;
 680         if (my $parts = $self->{idx_parts}) {
 681                 $_->atfork_child foreach @$parts;
 682         }
 683         if (my $im = $self->{im}) {
 684                 $im->atfork_child;
 685         }
 686         die "unexpected mm" if $self->{mm};
 687         close $self->{bnote}->[0] or die "close bnote[0]: $!\n";
 688         $self->{bnote}->[1];
 689 }
 690
 691 sub mark_deleted {
 692         my ($self, $D, $git, $oid) = @_;
 693         my $msgref = $git->cat_file($oid);
 694         my $mime = PublicInbox::MIME->new($$msgref);
 695         my $mids = mids($mime->header_obj);
 696         my $cid = content_id($mime);
 697         foreach my $mid (@$mids) {
 698                 $D->{"$mid\0$cid"} = $oid;
 699         }
 700 }
 701
 702 sub reindex_oid {
 703         my ($self, $mm_tmp, $D, $git, $oid, $regen, $reindex) = @_;
 704         my $len;
 705         my $msgref = $git->cat_file($oid, \$len);
 706         my $mime = PublicInbox::MIME->new($$msgref);
 707         my $mids = mids($mime->header_obj);
 708         my $cid = content_id($mime);
 709
 710         # get the NNTP article number we used before, highest number wins
 711         # and gets deleted from mm_tmp;
 712         my $mid0;
 713         my $num = -1;
 714         my $del = 0;
 715         foreach my $mid (@$mids) {
 716                 $del += delete($D->{"$mid\0$cid"}) ? 1 : 0;
 717                 my $n = $mm_tmp->num_for($mid);
 718                 if (defined $n && $n > $num) {
 719                         $mid0 = $mid;
 720                         $num = $n;
 721                         $self->{mm}->mid_set($num, $mid0);
 722                 }
 723         }
 724         if (!defined($mid0) && $regen && !$del) {
 725                 $num = $$regen--;
 726                 die "BUG: ran out of article numbers\n" if $num <= 0;
 727                 my $mm = $self->{mm};
 728                 foreach my $mid (reverse @$mids) {
 729                         if ($mm->mid_set($num, $mid) == 1) {
 730                                 $mid0 = $mid;
 731                                 last;
 732                         }
 733                 }
 734                 if (!defined($mid0)) {
 735                         my $id = '<' . join('> <', @$mids) . '>';
 736                         warn "Message-ID $id unusable for $num\n";
 737                         foreach my $mid (@$mids) {
 738                                 defined(my $n = $mm->num_for($mid)) or next;
 739                                 warn "#$n previously mapped for <$mid>\n";
 740                         }
 741                 }
 742         }
 743
 744         if (!defined($mid0) || $del) {
 745                 if (!defined($mid0) && $del) { # expected for deletes
 746                         $num = $$regen--;
 747                         $self->{mm}->num_highwater($num) unless $reindex;
 748                         return
 749                 }
 750
 751                 my $id = '<' . join('> <', @$mids) . '>';
 752                 defined($mid0) or
 753                         warn "Skipping $id, no article number found\n";
 754                 if ($del && defined($mid0)) {
 755                         warn "$id was deleted $del " .
 756                                 "time(s) but mapped to article #$num\n";
 757                 }
 758                 return;
 759
 760         }
 761         $mm_tmp->mid_delete($mid0) or
 762                 die "failed to delete <$mid0> for article #$num\n";
 763
 764         $self->{over}->add_overview($mime, $len, $num, $oid, $mid0);
 765         my $nparts = $self->{partitions};
 766         my $part = $num % $nparts;
 767         my $idx = $self->idx_part($part);
 768         $idx->index_raw($len, $msgref, $num, $oid, $mid0, $mime);
 769         my $n = $self->{transact_bytes} += $len;
 770         if ($n > (PublicInbox::SearchIdx::BATCH_BYTES * $nparts)) {
 771                 $git->cleanup;
 772                 $mm_tmp->atfork_prepare;
 773                 $self->done; # release lock
 774                 # allow -watch or -mda to write...
 775                 $self->idx_init; # reacquire lock
 776                 $mm_tmp->atfork_parent;
 777         }
 778 }
 779
 780 # only update last_commit for $i on reindex iff newer than current
 781 sub update_last_commit {
 782         my ($self, $git, $i, $cmt) = @_;
 783         my $last = last_commit_part($self, $i);
 784         if (defined $last && is_ancestor($git, $last, $cmt)) {
 785                 my @cmd = (qw(rev-list --count), "$last..$cmt");
 786                 chomp(my $n = $git->qx(@cmd));
 787                 return if $n ne '' && $n == 0;
 788         }
 789         last_commit_part($self, $i, $cmt);
 790 }
 791
 792 sub git_dir_n ($$) { "$_[0]->{-inbox}->{mainrepo}/git/$_[1].git" }
 793
 794 sub last_commits {
 795         my ($self, $epoch_max) = @_;
 796         my $heads = [];
 797         for (my $i = $epoch_max; $i >= 0; $i--) {
 798                 $heads->[$i] = last_commit_part($self, $i);
 799         }
 800         $heads;
 801 }
 802
 803 *is_ancestor = *PublicInbox::SearchIdx::is_ancestor;
 804
 805 sub index_prepare {
 806         my ($self, $opts, $epoch_max, $ranges) = @_;
 807         my $regen_max = 0;
 808         my $head = $self->{-inbox}->{ref_head} || 'refs/heads/master';
 809         for (my $i = $epoch_max; $i >= 0; $i--) {
 810                 die "already indexing!\n" if $self->{index_pipe};
 811                 my $git_dir = git_dir_n($self, $i);
 812                 -d $git_dir or next; # missing parts are fine
 813                 my $git = PublicInbox::Git->new($git_dir);
 814                 chomp(my $tip = $git->qx(qw(rev-parse -q --verify), $head));
 815                 next if $?; # new repo
 816                 my $range;
 817                 if (defined(my $cur = $ranges->[$i])) {
 818                         $range = "$cur..$tip";
 819                         if (is_ancestor($git, $cur, $tip)) { # common case
 820                                 my $n = $git->qx(qw(rev-list --count), $range);
 821                                 chomp($n);
 822                                 if ($n == 0) {
 823                                         $ranges->[$i] = undef;
 824                                         next;
 825                                 }
 826                         } else {
 827                                 warn <<"";
 828 discontiguous range: $range
 829 Rewritten history? (in $git_dir)
 830
 831                                 my $base = $git->qx('merge-base', $tip, $cur);
 832                                 chomp $base;
 833                                 if ($base) {
 834                                         $range = "$base..$tip";
 835                                         warn "found merge-base: $base\n"
 836                                 } else {
 837                                         $range = $tip;
 838                                         warn <<"";
 839 discarding history at $cur
 840
 841                                 }
 842                                 warn <<"";
 843 reindexing $git_dir starting at
 844 $range
 845
 846                                 $self->{"unindex-range.$i"} = "$base..$cur";
 847                         }
 848                 } else {
 849                         $range = $tip; # all of it
 850                 }
 851                 $ranges->[$i] = $range;
 852
 853                 # can't use 'rev-list --count' if we use --diff-filter
 854                 my $fh = $git->popen(qw(log --pretty=tformat:%H
 855                                 --no-notes --no-color --no-renames
 856                                 --diff-filter=AM), $range, '--', 'm');
 857                 ++$regen_max while <$fh>;
 858         }
 859         \$regen_max;
 860 }
 861
 862 sub unindex_oid_remote {
 863         my ($self, $oid, $mid) = @_;
 864         $_->remote_remove($oid, $mid) foreach @{$self->{idx_parts}};
 865         $self->{over}->remove_oid($oid, $mid);
 866 }
 867
 868 sub unindex_oid {
 869         my ($self, $git, $oid) = @_;
 870         my $msgref = $git->cat_file($oid);
 871         my $mime = PublicInbox::MIME->new($msgref);
 872         my $mids = mids($mime->header_obj);
 873         $mime = $msgref = undef;
 874         my $over = $self->{over};
 875         foreach my $mid (@$mids) {
 876                 my %gone;
 877                 my ($id, $prev);
 878                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 879                         $gone{$smsg->{num}} = 1 if $oid eq $smsg->{blob};
 880                         1; # continue
 881                 }
 882                 my $n = scalar keys %gone;
 883                 next unless $n;
 884                 if ($n > 1) {
 885                         warn "BUG: multiple articles linked to $oid\n",
 886                                 join(',',sort keys %gone), "\n";
 887                 }
 888                 foreach my $num (keys %gone) {
 889                         $self->{unindexed}->{$_}++;
 890                         $self->{mm}->num_delete($num);
 891                 }
 892                 $self->unindex_oid_remote($oid, $mid);
 893         }
 894 }
 895
 896 my $x40 = qr/[a-f0-9]{40}/;
 897 sub unindex {
 898         my ($self, $opts, $git, $unindex_range) = @_;
 899         my $un = $self->{unindexed} ||= {}; # num => removal count
 900         my $before = scalar keys %$un;
 901         my @cmd = qw(log --raw -r
 902                         --no-notes --no-color --no-abbrev --no-renames);
 903         my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $unindex_range);
 904         while (<$fh>) {
 905                 /\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o or next;
 906                 $self->unindex_oid($git, $1);
 907         }
 908         delete $self->{reindex_pipe};
 909         $fh = undef;
 910
 911         return unless $opts->{prune};
 912         my $after = scalar keys %$un;
 913         return if $before == $after;
 914
 915         # ensure any blob can not longer be accessed via dumb HTTP
 916         PublicInbox::Import::run_die(['git', "--git-dir=$git->{git_dir}",
 917                 qw(-c gc.reflogExpire=now gc --prune=all)]);
 918 }
 919
 920 sub index_sync {
 921         my ($self, $opts) = @_;
 922         $opts ||= {};
 923         my $epoch_max;
 924         my $latest = git_dir_latest($self, \$epoch_max);
 925         return unless defined $latest;
 926         $self->idx_init; # acquire lock
 927         my $mm_tmp = $self->{mm}->tmp_clone;
 928         my $reindex = $opts->{reindex};
 929         my $ranges = $reindex ? [] : $self->last_commits($epoch_max);
 930
 931         my $high = $self->{mm}->num_highwater();
 932         my $regen = $self->index_prepare($opts, $epoch_max, $ranges);
 933         $$regen += $high if $high;
 934         my $D = {}; # "$mid\0$cid" => $oid
 935         my @cmd = qw(log --raw -r --pretty=tformat:%H
 936                         --no-notes --no-color --no-abbrev --no-renames);
 937
 938         # work backwards through history
 939         my $last_commit = [];
 940         for (my $i = $epoch_max; $i >= 0; $i--) {
 941                 my $git_dir = git_dir_n($self, $i);
 942                 die "already reindexing!\n" if delete $self->{reindex_pipe};
 943                 -d $git_dir or next; # missing parts are fine
 944                 my $git = PublicInbox::Git->new($git_dir);
 945                 my $unindex = delete $self->{"unindex-range.$i"};
 946                 $self->unindex($opts, $git, $unindex) if $unindex;
 947                 defined(my $range = $ranges->[$i]) or next;
 948                 my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $range);
 949                 my $cmt;
 950                 while (<$fh>) {
 951                         if (/\A$x40$/o && !defined($cmt)) {
 952                                 chomp($cmt = $_);
 953                         } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o) {
 954                                 $self->reindex_oid($mm_tmp, $D, $git, $1,
 955                                                 $regen, $reindex);
 956                         } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\td$/o) {
 957                                 $self->mark_deleted($D, $git, $1);
 958                         }
 959                 }
 960                 $fh = undef;
 961                 delete $self->{reindex_pipe};
 962                 $self->update_last_commit($git, $i, $cmt) if defined $cmt;
 963         }
 964
 965         # unindex is required for leftovers if "deletes" affect messages
 966         # in a previous fetch+index window:
 967         if (scalar keys %$D) {
 968                 my $git = $self->{-inbox}->git;
 969                 $self->unindex_oid($git, $_) for values %$D;
 970                 $git->cleanup;
 971         }
 972         $self->done;
 973 }
 974
 975 1;