lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 # Used to write to V2 inboxes (see L<public-inbox-v2-format(5)>).
   6 package PublicInbox::V2Writable;
   7 use strict;
   8 use warnings;
   9 use base qw(PublicInbox::Lock);
  10 use 5.010_001;
  11 use PublicInbox::SearchIdxShard;
  12 use PublicInbox::Eml;
  13 use PublicInbox::Git;
  14 use PublicInbox::Import;
  15 use PublicInbox::MID qw(mids references);
  16 use PublicInbox::ContentHash qw(content_hash content_digest);
  17 use PublicInbox::Inbox;
  18 use PublicInbox::OverIdx;
  19 use PublicInbox::Msgmap;
  20 use PublicInbox::Spawn qw(spawn popen_rd);
  21 use PublicInbox::SearchIdx;
  22 use PublicInbox::MultiMidQueue;
  23 use IO::Handle; # ->autoflush
  24 use File::Temp qw(tempfile);
  25
  26 # an estimate of the post-packed size to the raw uncompressed size
  27 my $PACKING_FACTOR = 0.4;
  28
  29 # SATA storage lags behind what CPUs are capable of, so relying on
  30 # nproc(1) can be misleading and having extra Xapian shards is a
  31 # waste of FDs and space.  It can also lead to excessive IO latency
  32 # and slow things down.  Users on NVME or other fast storage can
  33 # use the NPROC env or switches in our script/public-inbox-* programs
  34 # to increase Xapian shards
  35 our $NPROC_MAX_DEFAULT = 4;
  36
  37 sub detect_nproc () {
  38         for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
  39                 `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
  40         }
  41
  42         # getconf(1) is POSIX, but *NPROCESSORS* vars are not
  43         for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
  44                 `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
  45         }
  46
  47         # should we bother with `sysctl hw.ncpu`?  Those only give
  48         # us total processor count, not online processor count.
  49         undef
  50 }
  51
  52 sub nproc_shards ($) {
  53         my ($creat_opt) = @_;
  54         my $n = $creat_opt->{nproc} if ref($creat_opt) eq 'HASH';
  55         $n //= $ENV{NPROC};
  56         if (!$n) {
  57                 # assume 2 cores if not detectable or zero
  58                 state $NPROC_DETECTED = detect_nproc() || 2;
  59                 $n = $NPROC_DETECTED;
  60                 $n = $NPROC_MAX_DEFAULT if $n > $NPROC_MAX_DEFAULT;
  61         }
  62
  63         # subtract for the main process and git-fast-import
  64         $n -= 1;
  65         $n < 1 ? 1 : $n;
  66 }
  67
  68 sub count_shards ($) {
  69         my ($self) = @_;
  70         my $n = 0;
  71         my $xpfx = $self->{xpfx};
  72
  73         # always load existing shards in case core count changes:
  74         # Also, shard count may change while -watch is running
  75         # due to "xcpdb --reshard"
  76         if (-d $xpfx) {
  77                 my $XapianDatabase;
  78                 foreach my $shard (<$xpfx/*>) {
  79                         -d $shard && $shard =~ m!/[0-9]+\z! or next;
  80                         $XapianDatabase //= do {
  81                                 require PublicInbox::Search;
  82                                 PublicInbox::Search::load_xapian();
  83                                 $PublicInbox::Search::X{Database};
  84                         };
  85                         eval {
  86                                 $XapianDatabase->new($shard)->close;
  87                                 $n++;
  88                         };
  89                 }
  90         }
  91         $n;
  92 }
  93
  94 sub new {
  95         # $creat may be any true value, or 0/undef.  A hashref is true,
  96         # and $creat->{nproc} may be set to an integer
  97         my ($class, $v2ibx, $creat) = @_;
  98         $v2ibx = PublicInbox::InboxWritable->new($v2ibx);
  99         my $dir = $v2ibx->assert_usable_dir;
 100         unless (-d $dir) {
 101                 if ($creat) {
 102                         require File::Path;
 103                         File::Path::mkpath($dir);
 104                 } else {
 105                         die "$dir does not exist\n";
 106                 }
 107         }
 108         $v2ibx->umask_prepare;
 109
 110         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
 111         my $self = {
 112                 -inbox => $v2ibx,
 113                 im => undef, #  PublicInbox::Import
 114                 parallel => 1,
 115                 transact_bytes => 0,
 116                 current_info => '',
 117                 xpfx => $xpfx,
 118                 over => PublicInbox::OverIdx->new("$xpfx/over.sqlite3", 1),
 119                 lock_path => "$dir/inbox.lock",
 120                 # limit each git repo (epoch) to 1GB or so
 121                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
 122                 last_commit => [], # git repo -> commit
 123         };
 124         $self->{shards} = count_shards($self) || nproc_shards($creat);
 125         $self->{index_max_size} = $v2ibx->{index_max_size};
 126         bless $self, $class;
 127 }
 128
 129 # public (for now?)
 130 sub init_inbox {
 131         my ($self, $shards, $skip_epoch, $skip_artnum) = @_;
 132         if (defined $shards) {
 133                 $self->{parallel} = 0 if $shards == 0;
 134                 $self->{shards} = $shards if $shards > 0;
 135         }
 136         $self->idx_init;
 137         $self->{mm}->skip_artnum($skip_artnum) if defined $skip_artnum;
 138         my $epoch_max = -1;
 139         git_dir_latest($self, \$epoch_max);
 140         if (defined $skip_epoch && $epoch_max == -1) {
 141                 $epoch_max = $skip_epoch;
 142         }
 143         $self->git_init($epoch_max >= 0 ? $epoch_max : 0);
 144         $self->done;
 145 }
 146
 147 # returns undef on duplicate or spam
 148 # mimics Import::add and wraps it for v2
 149 sub add {
 150         my ($self, $mime, $check_cb) = @_;
 151         $self->{-inbox}->with_umask(sub {
 152                 _add($self, $mime, $check_cb)
 153         });
 154 }
 155
 156 # indexes a message, returns true if checkpointing is needed
 157 sub do_idx ($$$$) {
 158         my ($self, $msgref, $mime, $smsg) = @_;
 159         $smsg->{bytes} = $smsg->{raw_bytes} +
 160                         PublicInbox::SearchIdx::crlf_adjust($$msgref);
 161         $self->{over}->add_overview($mime, $smsg);
 162         my $idx = idx_shard($self, $smsg->{num} % $self->{shards});
 163         $idx->index_raw($msgref, $mime, $smsg);
 164         my $n = $self->{transact_bytes} += $smsg->{raw_bytes};
 165         $n >= ($PublicInbox::SearchIdx::BATCH_BYTES * $self->{shards});
 166 }
 167
 168 sub _add {
 169         my ($self, $mime, $check_cb) = @_;
 170
 171         # spam check:
 172         if ($check_cb) {
 173                 $mime = $check_cb->($mime) or return;
 174         }
 175
 176         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
 177         # as does SQLite 3.4.1+ (released in 2007-07-20), and
 178         # Xapian 1.3.2+ (released 2015-03-15).
 179         # For the most part, we can spawn git-fast-import without
 180         # leaking FDs to it...
 181         $self->idx_init;
 182
 183         my ($num, $mid0) = v2_num_for($self, $mime);
 184         defined $num or return; # duplicate
 185         defined $mid0 or die "BUG: \$mid0 undefined\n";
 186         my $im = $self->importer;
 187         my $smsg = bless { mid => $mid0, num => $num }, 'PublicInbox::Smsg';
 188         my $cmt = $im->add($mime, undef, $smsg); # sets $smsg->{ds|ts|blob}
 189         $cmt = $im->get_mark($cmt);
 190         $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 191
 192         my $msgref = delete $smsg->{-raw_email};
 193         if (do_idx($self, $msgref, $mime, $smsg)) {
 194                 $self->checkpoint;
 195         }
 196
 197         $cmt;
 198 }
 199
 200 sub v2_num_for {
 201         my ($self, $mime) = @_;
 202         my $mids = mids($mime->header_obj);
 203         if (@$mids) {
 204                 my $mid = $mids->[0];
 205                 my $num = $self->{mm}->mid_insert($mid);
 206                 if (defined $num) { # common case
 207                         return ($num, $mid);
 208                 }
 209
 210                 # crap, Message-ID is already known, hope somebody just resent:
 211                 foreach my $m (@$mids) {
 212                         # read-only lookup now safe to do after above barrier
 213                         # easy, don't store duplicates
 214                         # note: do not add more diagnostic info here since
 215                         # it gets noisy on public-inbox-watch restarts
 216                         return () if content_exists($self, $mime, $m);
 217                 }
 218
 219                 # AltId may pre-populate article numbers (e.g. X-Mail-Count
 220                 # or NNTP article number), use that article number if it's
 221                 # not in Over.
 222                 my $altid = $self->{-inbox}->{altid};
 223                 if ($altid && grep(/:file=msgmap\.sqlite3\z/, @$altid)) {
 224                         my $num = $self->{mm}->num_for($mid);
 225
 226                         if (defined $num && !$self->{over}->get_art($num)) {
 227                                 return ($num, $mid);
 228                         }
 229                 }
 230
 231                 # very unlikely:
 232                 warn "<$mid> reused for mismatched content\n";
 233
 234                 # try the rest of the mids
 235                 for(my $i = $#$mids; $i >= 1; $i--) {
 236                         my $m = $mids->[$i];
 237                         $num = $self->{mm}->mid_insert($m);
 238                         if (defined $num) {
 239                                 warn "alternative <$m> for <$mid> found\n";
 240                                 return ($num, $m);
 241                         }
 242                 }
 243         }
 244         # none of the existing Message-IDs are good, generate a new one:
 245         v2_num_for_harder($self, $mime);
 246 }
 247
 248 sub v2_num_for_harder {
 249         my ($self, $mime) = @_;
 250
 251         my $hdr = $mime->header_obj;
 252         my $dig = content_digest($mime);
 253         my $mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 254         my $num = $self->{mm}->mid_insert($mid0);
 255         unless (defined $num) {
 256                 # it's hard to spoof the last Received: header
 257                 my @recvd = $hdr->header_raw('Received');
 258                 $dig->add("Received: $_") foreach (@recvd);
 259                 $mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 260                 $num = $self->{mm}->mid_insert($mid0);
 261
 262                 # fall back to a random Message-ID and give up determinism:
 263                 until (defined($num)) {
 264                         $dig->add(rand);
 265                         $mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 266                         warn "using random Message-ID <$mid0> as fallback\n";
 267                         $num = $self->{mm}->mid_insert($mid0);
 268                 }
 269         }
 270         PublicInbox::Import::append_mid($hdr, $mid0);
 271         ($num, $mid0);
 272 }
 273
 274 sub idx_shard {
 275         my ($self, $shard_i) = @_;
 276         $self->{idx_shards}->[$shard_i];
 277 }
 278
 279 # idempotent
 280 sub idx_init {
 281         my ($self, $opt) = @_;
 282         return if $self->{idx_shards};
 283         my $ibx = $self->{-inbox};
 284
 285         # do not leak read-only FDs to child processes, we only have these
 286         # FDs for duplicate detection so they should not be
 287         # frequently activated.
 288         delete $ibx->{$_} foreach (qw(git mm search));
 289
 290         my $indexlevel = $ibx->{indexlevel};
 291         if ($indexlevel && $indexlevel eq 'basic') {
 292                 $self->{parallel} = 0;
 293         }
 294
 295         if ($self->{parallel}) {
 296                 pipe(my ($r, $w)) or die "pipe failed: $!";
 297                 # pipe for barrier notifications doesn't need to be big,
 298                 # 1031: F_SETPIPE_SZ
 299                 fcntl($w, 1031, 4096) if $^O eq 'linux';
 300                 $self->{bnote} = [ $r, $w ];
 301                 $w->autoflush(1);
 302         }
 303
 304         my $over = $self->{over};
 305         $ibx->umask_prepare;
 306         $ibx->with_umask(sub {
 307                 $self->lock_acquire unless ($opt && $opt->{-skip_lock});
 308                 $over->create;
 309
 310                 # xcpdb can change shard count while -watch is idle
 311                 my $nshards = count_shards($self);
 312                 if ($nshards && $nshards != $self->{shards}) {
 313                         $self->{shards} = $nshards;
 314                 }
 315
 316                 # need to create all shards before initializing msgmap FD
 317                 my $max = $self->{shards} - 1;
 318
 319                 # idx_shards must be visible to all forked processes
 320                 my $idx = $self->{idx_shards} = [];
 321                 for my $i (0..$max) {
 322                         push @$idx, PublicInbox::SearchIdxShard->new($self, $i);
 323                 }
 324
 325                 # Now that all subprocesses are up, we can open the FDs
 326                 # for SQLite:
 327                 my $mm = $self->{mm} = PublicInbox::Msgmap->new_file(
 328                         "$self->{-inbox}->{inboxdir}/msgmap.sqlite3", 1);
 329                 $mm->{dbh}->begin_work;
 330         });
 331 }
 332
 333 # returns an array mapping [ epoch => latest_commit ]
 334 # latest_commit may be undef if nothing was done to that epoch
 335 # $replace_map = { $object_id => $strref, ... }
 336 sub _replace_oids ($$$) {
 337         my ($self, $mime, $replace_map) = @_;
 338         $self->done;
 339         my $pfx = "$self->{-inbox}->{inboxdir}/git";
 340         my $rewrites = []; # epoch => commit
 341         my $max = $self->{epoch_max};
 342
 343         unless (defined($max)) {
 344                 defined(my $latest = git_dir_latest($self, \$max)) or return;
 345                 $self->{epoch_max} = $max;
 346         }
 347
 348         foreach my $i (0..$max) {
 349                 my $git_dir = "$pfx/$i.git";
 350                 -d $git_dir or next;
 351                 my $git = PublicInbox::Git->new($git_dir);
 352                 my $im = $self->import_init($git, 0, 1);
 353                 $rewrites->[$i] = $im->replace_oids($mime, $replace_map);
 354                 $im->done;
 355         }
 356         $rewrites;
 357 }
 358
 359 sub content_hashes ($) {
 360         my ($mime) = @_;
 361         my @chashes = ( content_hash($mime) );
 362
 363         # We still support Email::MIME, here, and
 364         # Email::MIME->as_string doesn't always round-trip, so we may
 365         # use a second content_hash
 366         my $rt = content_hash(PublicInbox::Eml->new(\($mime->as_string)));
 367         push @chashes, $rt if $chashes[0] ne $rt;
 368         \@chashes;
 369 }
 370
 371 sub content_matches ($$) {
 372         my ($chashes, $existing) = @_;
 373         my $chash = content_hash($existing);
 374         foreach (@$chashes) {
 375                 return 1 if $_ eq $chash
 376         }
 377         0
 378 }
 379
 380 # used for removing or replacing (purging)
 381 sub rewrite_internal ($$;$$$) {
 382         my ($self, $old_mime, $cmt_msg, $new_mime, $sref) = @_;
 383         $self->idx_init;
 384         my ($im, $need_reindex, $replace_map);
 385         if ($sref) {
 386                 $replace_map = {}; # oid => sref
 387                 $need_reindex = [] if $new_mime;
 388         } else {
 389                 $im = $self->importer;
 390         }
 391         my $over = $self->{over};
 392         my $chashes = content_hashes($old_mime);
 393         my @removed;
 394         my $mids = mids($old_mime->header_obj);
 395
 396         # We avoid introducing new blobs into git since the raw content
 397         # can be slightly different, so we do not need the user-supplied
 398         # message now that we have the mids and content_hash
 399         $old_mime = undef;
 400         my $mark;
 401
 402         foreach my $mid (@$mids) {
 403                 my %gone; # num => [ smsg, $mime, raw ]
 404                 my ($id, $prev);
 405                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 406                         my $msg = get_blob($self, $smsg);
 407                         if (!defined($msg)) {
 408                                 warn "broken smsg for $mid\n";
 409                                 next; # continue
 410                         }
 411                         my $orig = $$msg;
 412                         my $cur = PublicInbox::Eml->new($msg);
 413                         if (content_matches($chashes, $cur)) {
 414                                 $gone{$smsg->{num}} = [ $smsg, $cur, \$orig ];
 415                         }
 416                 }
 417                 my $n = scalar keys %gone;
 418                 next unless $n;
 419                 if ($n > 1) {
 420                         warn "BUG: multiple articles linked to <$mid>\n",
 421                                 join(',', sort keys %gone), "\n";
 422                 }
 423                 foreach my $num (keys %gone) {
 424                         my ($smsg, $mime, $orig) = @{$gone{$num}};
 425                         # @removed should only be set once assuming
 426                         # no bugs in our deduplication code:
 427                         @removed = (undef, $mime, $smsg);
 428                         my $oid = $smsg->{blob};
 429                         if ($replace_map) {
 430                                 $replace_map->{$oid} = $sref;
 431                         } else {
 432                                 ($mark, undef) = $im->remove($orig, $cmt_msg);
 433                                 $removed[0] = $mark;
 434                         }
 435                         $orig = undef;
 436                         if ($need_reindex) { # ->replace
 437                                 push @$need_reindex, $smsg;
 438                         } else { # ->purge or ->remove
 439                                 $self->{mm}->num_delete($num);
 440                         }
 441                         unindex_oid_remote($self, $oid, $mid);
 442                 }
 443         }
 444
 445         if (defined $mark) {
 446                 my $cmt = $im->get_mark($mark);
 447                 $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 448         }
 449         if ($replace_map && scalar keys %$replace_map) {
 450                 my $rewrites = _replace_oids($self, $new_mime, $replace_map);
 451                 return { rewrites => $rewrites, need_reindex => $need_reindex };
 452         }
 453         defined($mark) ? @removed : undef;
 454 }
 455
 456 # public (see PublicInbox::Import->remove), but note the 3rd element
 457 # (retval[2]) is not part of the stable API shared with Import->remove
 458 sub remove {
 459         my ($self, $mime, $cmt_msg) = @_;
 460         my @ret;
 461         $self->{-inbox}->with_umask(sub {
 462                 @ret = rewrite_internal($self, $mime, $cmt_msg);
 463         });
 464         defined($ret[0]) ? @ret : undef;
 465 }
 466
 467 sub _replace ($$;$$) {
 468         my ($self, $old_mime, $new_mime, $sref) = @_;
 469         my $rewritten = $self->{-inbox}->with_umask(sub {
 470                 rewrite_internal($self, $old_mime, undef, $new_mime, $sref);
 471         }) or return;
 472
 473         my $rewrites = $rewritten->{rewrites};
 474         # ->done is called if there are rewrites since we gc+prune from git
 475         $self->idx_init if @$rewrites;
 476
 477         for my $i (0..$#$rewrites) {
 478                 defined(my $cmt = $rewrites->[$i]) or next;
 479                 $self->{last_commit}->[$i] = $cmt;
 480         }
 481         $rewritten;
 482 }
 483
 484 # public
 485 sub purge {
 486         my ($self, $mime) = @_;
 487         my $rewritten = _replace($self, $mime, undef, \'') or return;
 488         $rewritten->{rewrites}
 489 }
 490
 491 # returns the git object_id of $fh, does not write the object to FS
 492 sub git_hash_raw ($$) {
 493         my ($self, $raw) = @_;
 494         # grab the expected OID we have to reindex:
 495         open my $tmp_fh, '+>', undef or die "failed to open tmp: $!";
 496         $tmp_fh->autoflush(1);
 497         print $tmp_fh $$raw or die "print \$tmp_fh: $!";
 498         sysseek($tmp_fh, 0, 0) or die "seek failed: $!";
 499
 500         my $git_dir = $self->{-inbox}->git->{git_dir};
 501         my $cmd = ['git', "--git-dir=$git_dir", qw(hash-object --stdin)];
 502         my $r = popen_rd($cmd, undef, { 0 => $tmp_fh });
 503         local $/ = "\n";
 504         chomp(my $oid = <$r>);
 505         close $r or die "git hash-object failed: $?";
 506         $oid =~ /\A[a-f0-9]{40}\z/ or die "OID not expected: $oid";
 507         $oid;
 508 }
 509
 510 sub _check_mids_match ($$$) {
 511         my ($old_list, $new_list, $hdrs) = @_;
 512         my %old_mids = map { $_ => 1 } @$old_list;
 513         my %new_mids = map { $_ => 1 } @$new_list;
 514         my @old = keys %old_mids;
 515         my @new = keys %new_mids;
 516         my $err = "$hdrs may not be changed when replacing\n";
 517         die $err if scalar(@old) != scalar(@new);
 518         delete @new_mids{@old};
 519         delete @old_mids{@new};
 520         die $err if (scalar(keys %old_mids) || scalar(keys %new_mids));
 521 }
 522
 523 # Changing Message-IDs or References with ->replace isn't supported.
 524 # The rules for dealing with messages with multiple or conflicting
 525 # Message-IDs are pretty complex and rethreading hasn't been fully
 526 # implemented, yet.
 527 sub check_mids_match ($$) {
 528         my ($old_mime, $new_mime) = @_;
 529         my $old = $old_mime->header_obj;
 530         my $new = $new_mime->header_obj;
 531         _check_mids_match(mids($old), mids($new), 'Message-ID(s)');
 532         _check_mids_match(references($old), references($new),
 533                         'References/In-Reply-To');
 534 }
 535
 536 # public
 537 sub replace ($$$) {
 538         my ($self, $old_mime, $new_mime) = @_;
 539
 540         check_mids_match($old_mime, $new_mime);
 541
 542         # mutt will always add Content-Length:, Status:, Lines: when editing
 543         PublicInbox::Import::drop_unwanted_headers($new_mime);
 544
 545         my $raw = $new_mime->as_string;
 546         my $expect_oid = git_hash_raw($self, \$raw);
 547         my $rewritten = _replace($self, $old_mime, $new_mime, \$raw) or return;
 548         my $need_reindex = $rewritten->{need_reindex};
 549
 550         # just in case we have bugs in deduplication code:
 551         my $n = scalar(@$need_reindex);
 552         if ($n > 1) {
 553                 my $list = join(', ', map {
 554                                         "$_->{num}: <$_->{mid}>"
 555                                 } @$need_reindex);
 556                 warn <<"";
 557 W: rewritten $n messages matching content of original message (expected: 1).
 558 W: possible bug in public-inbox, NNTP article IDs and Message-IDs follow:
 559 W: $list
 560
 561         }
 562
 563         # make sure we really got the OID:
 564         my ($blob, $type, $bytes) = $self->{-inbox}->git->check($expect_oid);
 565         $blob eq $expect_oid or die "BUG: $expect_oid not found after replace";
 566
 567         # don't leak FDs to Xapian:
 568         $self->{-inbox}->git->cleanup;
 569
 570         # reindex modified messages:
 571         for my $smsg (@$need_reindex) {
 572                 my $new_smsg = bless {
 573                         blob => $blob,
 574                         raw_bytes => $bytes,
 575                         num => $smsg->{num},
 576                         mid => $smsg->{mid},
 577                 }, 'PublicInbox::Smsg';
 578                 my $v2w = { autime => $smsg->{ds}, cotime => $smsg->{ts} };
 579                 $new_smsg->populate($new_mime, $v2w);
 580                 do_idx($self, \$raw, $new_mime, $new_smsg);
 581         }
 582         $rewritten->{rewrites};
 583 }
 584
 585 sub last_epoch_commit ($$;$) {
 586         my ($self, $i, $cmt) = @_;
 587         my $v = PublicInbox::Search::SCHEMA_VERSION();
 588         $self->{mm}->last_commit_xap($v, $i, $cmt);
 589 }
 590
 591 sub set_last_commits ($) {
 592         my ($self) = @_;
 593         defined(my $epoch_max = $self->{epoch_max}) or return;
 594         my $last_commit = $self->{last_commit};
 595         foreach my $i (0..$epoch_max) {
 596                 defined(my $cmt = $last_commit->[$i]) or next;
 597                 $last_commit->[$i] = undef;
 598                 last_epoch_commit($self, $i, $cmt);
 599         }
 600 }
 601
 602 sub barrier_init {
 603         my ($self, $n) = @_;
 604         $self->{bnote} or return;
 605         --$n;
 606         my $barrier = { map { $_ => 1 } (0..$n) };
 607 }
 608
 609 sub barrier_wait {
 610         my ($self, $barrier) = @_;
 611         my $bnote = $self->{bnote} or return;
 612         my $r = $bnote->[0];
 613         while (scalar keys %$barrier) {
 614                 defined(my $l = readline($r)) or die "EOF on barrier_wait: $!";
 615                 $l =~ /\Abarrier (\d+)/ or die "bad line on barrier_wait: $l";
 616                 delete $barrier->{$1} or die "bad shard[$1] on barrier wait";
 617         }
 618 }
 619
 620 # public
 621 sub checkpoint ($;$) {
 622         my ($self, $wait) = @_;
 623
 624         if (my $im = $self->{im}) {
 625                 if ($wait) {
 626                         $im->barrier;
 627                 } else {
 628                         $im->checkpoint;
 629                 }
 630         }
 631         my $shards = $self->{idx_shards};
 632         if ($shards) {
 633                 my $dbh = $self->{mm}->{dbh};
 634
 635                 # SQLite msgmap data is second in importance
 636                 $dbh->commit;
 637
 638                 # SQLite overview is third
 639                 $self->{over}->commit_lazy;
 640
 641                 # Now deal with Xapian
 642                 if ($wait) {
 643                         my $barrier = $self->barrier_init(scalar @$shards);
 644
 645                         # each shard needs to issue a barrier command
 646                         $_->remote_barrier for @$shards;
 647
 648                         # wait for each Xapian shard
 649                         $self->barrier_wait($barrier);
 650                 } else {
 651                         $_->remote_commit for @$shards;
 652                 }
 653
 654                 # last_commit is special, don't commit these until
 655                 # remote shards are done:
 656                 $dbh->begin_work;
 657                 set_last_commits($self);
 658                 $dbh->commit;
 659
 660                 $dbh->begin_work;
 661         }
 662         $self->{transact_bytes} = 0;
 663 }
 664
 665 # issue a write barrier to ensure all data is visible to other processes
 666 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 667 # public
 668 sub barrier { checkpoint($_[0], 1) };
 669
 670 # public
 671 sub done {
 672         my ($self) = @_;
 673         my $im = delete $self->{im};
 674         $im->done if $im; # PublicInbox::Import::done
 675         checkpoint($self);
 676         my $mm = delete $self->{mm};
 677         $mm->{dbh}->commit if $mm;
 678         my $shards = delete $self->{idx_shards};
 679         if ($shards) {
 680                 $_->remote_close for @$shards;
 681         }
 682         $self->{over}->disconnect;
 683         delete $self->{bnote};
 684         $self->{transact_bytes} = 0;
 685         $self->lock_release if $shards;
 686         $self->{-inbox}->git->cleanup;
 687 }
 688
 689 sub fill_alternates ($$) {
 690         my ($self, $epoch) = @_;
 691
 692         my $pfx = "$self->{-inbox}->{inboxdir}/git";
 693         my $all = "$self->{-inbox}->{inboxdir}/all.git";
 694
 695         unless (-d $all) {
 696                 PublicInbox::Import::init_bare($all);
 697         }
 698         my $info_dir = "$all/objects/info";
 699         my $alt = "$info_dir/alternates";
 700         my (%alt, $new);
 701         my $mode = 0644;
 702         if (-e $alt) {
 703                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 704                 $mode = (stat($fh))[2] & 07777;
 705
 706                 # we assign a sort score to every alternate and favor
 707                 # the newest (highest numbered) one when we
 708                 my $score;
 709                 my $other = 0; # in case admin adds non-epoch repos
 710                 %alt = map {;
 711                         if (m!\A\Q../../\E([0-9]+)\.git/objects\z!) {
 712                                 $score = $1 + 0;
 713                         } else {
 714                                 $score = --$other;
 715                         }
 716                         $_ => $score;
 717                 } split(/\n+/, do { local $/; <$fh> });
 718         }
 719
 720         foreach my $i (0..$epoch) {
 721                 my $dir = "../../git/$i.git/objects";
 722                 if (!exists($alt{$dir}) && -d "$pfx/$i.git") {
 723                         $alt{$dir} = $i;
 724                         $new = 1;
 725                 }
 726         }
 727         return unless $new;
 728
 729         my ($fh, $tmp) = tempfile('alt-XXXXXXXX', DIR => $info_dir);
 730         print $fh join("\n", sort { $alt{$b} <=> $alt{$a} } keys %alt), "\n"
 731                 or die "print $tmp: $!\n";
 732         chmod($mode, $fh) or die "fchmod $tmp: $!\n";
 733         close $fh or die "close $tmp $!\n";
 734         rename($tmp, $alt) or die "rename $tmp => $alt: $!\n";
 735 }
 736
 737 sub git_init {
 738         my ($self, $epoch) = @_;
 739         my $git_dir = "$self->{-inbox}->{inboxdir}/git/$epoch.git";
 740         PublicInbox::Import::init_bare($git_dir);
 741         my @cmd = (qw/git config/, "--file=$git_dir/config",
 742                         'include.path', '../../all.git/config');
 743         PublicInbox::Import::run_die(\@cmd);
 744         fill_alternates($self, $epoch);
 745         $git_dir
 746 }
 747
 748 sub git_dir_latest {
 749         my ($self, $max) = @_;
 750         $$max = -1;
 751         my $pfx = "$self->{-inbox}->{inboxdir}/git";
 752         return unless -d $pfx;
 753         my $latest;
 754         opendir my $dh, $pfx or die "opendir $pfx: $!\n";
 755         while (defined(my $git_dir = readdir($dh))) {
 756                 $git_dir =~ m!\A([0-9]+)\.git\z! or next;
 757                 if ($1 > $$max) {
 758                         $$max = $1;
 759                         $latest = "$pfx/$git_dir";
 760                 }
 761         }
 762         $latest;
 763 }
 764
 765 sub importer {
 766         my ($self) = @_;
 767         my $im = $self->{im};
 768         if ($im) {
 769                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 770                         return $im;
 771                 } else {
 772                         $self->{im} = undef;
 773                         $im->done;
 774                         $im = undef;
 775                         $self->checkpoint;
 776                         my $git_dir = $self->git_init(++$self->{epoch_max});
 777                         my $git = PublicInbox::Git->new($git_dir);
 778                         return $self->import_init($git, 0);
 779                 }
 780         }
 781         my $epoch = 0;
 782         my $max;
 783         my $latest = git_dir_latest($self, \$max);
 784         if (defined $latest) {
 785                 my $git = PublicInbox::Git->new($latest);
 786                 my $packed_bytes = $git->packed_bytes;
 787                 my $unpacked_bytes = $packed_bytes / $PACKING_FACTOR;
 788
 789                 if ($unpacked_bytes >= $self->{rotate_bytes}) {
 790                         $epoch = $max + 1;
 791                 } else {
 792                         $self->{epoch_max} = $max;
 793                         return $self->import_init($git, $packed_bytes);
 794                 }
 795         }
 796         $self->{epoch_max} = $epoch;
 797         $latest = $self->git_init($epoch);
 798         $self->import_init(PublicInbox::Git->new($latest), 0);
 799 }
 800
 801 sub import_init {
 802         my ($self, $git, $packed_bytes, $tmp) = @_;
 803         my $im = PublicInbox::Import->new($git, undef, undef, $self->{-inbox});
 804         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 805         $im->{lock_path} = undef;
 806         $im->{path_type} = 'v2';
 807         $self->{im} = $im unless $tmp;
 808         $im;
 809 }
 810
 811 # XXX experimental
 812 sub diff ($$$) {
 813         my ($mid, $cur, $new) = @_;
 814
 815         my ($ah, $an) = tempfile('email-cur-XXXXXXXX', TMPDIR => 1);
 816         print $ah $cur->as_string or die "print: $!";
 817         close $ah or die "close: $!";
 818         my ($bh, $bn) = tempfile('email-new-XXXXXXXX', TMPDIR => 1);
 819         PublicInbox::Import::drop_unwanted_headers($new);
 820         print $bh $new->as_string or die "print: $!";
 821         close $bh or die "close: $!";
 822         my $cmd = [ qw(diff -u), $an, $bn ];
 823         print STDERR "# MID conflict <$mid>\n";
 824         my $pid = spawn($cmd, undef, { 1 => 2 });
 825         waitpid($pid, 0) == $pid or die "diff did not finish";
 826         unlink($an, $bn);
 827 }
 828
 829 sub get_blob ($$) {
 830         my ($self, $smsg) = @_;
 831         if (my $im = $self->{im}) {
 832                 my $msg = $im->cat_blob($smsg->{blob});
 833                 return $msg if $msg;
 834         }
 835         # older message, should be in alternates
 836         my $ibx = $self->{-inbox};
 837         $ibx->msg_by_smsg($smsg);
 838 }
 839
 840 sub content_exists ($$$) {
 841         my ($self, $mime, $mid) = @_;
 842         my $over = $self->{over};
 843         my $chashes = content_hashes($mime);
 844         my ($id, $prev);
 845         while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 846                 my $msg = get_blob($self, $smsg);
 847                 if (!defined($msg)) {
 848                         warn "broken smsg for $mid\n";
 849                         next;
 850                 }
 851                 my $cur = PublicInbox::Eml->new($msg);
 852                 return 1 if content_matches($chashes, $cur);
 853
 854                 # XXX DEBUG_DIFF is experimental and may be removed
 855                 diff($mid, $cur, $mime) if $ENV{DEBUG_DIFF};
 856         }
 857         undef;
 858 }
 859
 860 sub atfork_child {
 861         my ($self) = @_;
 862         my $fh = delete $self->{reindex_pipe};
 863         close $fh if $fh;
 864         if (my $shards = $self->{idx_shards}) {
 865                 $_->atfork_child foreach @$shards;
 866         }
 867         if (my $im = $self->{im}) {
 868                 $im->atfork_child;
 869         }
 870         die "unexpected mm" if $self->{mm};
 871         close $self->{bnote}->[0] or die "close bnote[0]: $!\n";
 872         $self->{bnote}->[1];
 873 }
 874
 875 sub mark_deleted ($$$$) {
 876         my ($self, $sync, $git, $oid) = @_;
 877         return if PublicInbox::SearchIdx::too_big($self, $git, $oid);
 878         my $msgref = $git->cat_file($oid);
 879         my $mime = PublicInbox::Eml->new($$msgref);
 880         my $mids = mids($mime->header_obj);
 881         my $chash = content_hash($mime);
 882         foreach my $mid (@$mids) {
 883                 $sync->{D}->{"$mid\0$chash"} = $oid;
 884         }
 885 }
 886
 887 sub reindex_checkpoint ($$$) {
 888         my ($self, $sync, $git) = @_;
 889
 890         $git->cleanup;
 891         $sync->{mm_tmp}->atfork_prepare;
 892         $self->done; # release lock
 893
 894         if (my $pr = $sync->{-opt}->{-progress}) {
 895                 my ($bn) = (split('/', $git->{git_dir}))[-1];
 896                 $pr->("$bn ".sprintf($sync->{-regen_fmt}, $sync->{nr}));
 897         }
 898
 899         # allow -watch or -mda to write...
 900         $self->idx_init; # reacquire lock
 901         $sync->{mm_tmp}->atfork_parent;
 902 }
 903
 904 # only for a few odd messages with multiple Message-IDs
 905 sub reindex_oid_m ($$$$;$) {
 906         my ($self, $sync, $git, $oid, $regen_num) = @_;
 907         $self->{current_info} = "multi_mid $oid";
 908         my ($num, $mid0, $len);
 909         my $msgref = $git->cat_file($oid, \$len);
 910         my $mime = PublicInbox::Eml->new($$msgref);
 911         my $mids = mids($mime->header_obj);
 912         my $chash = content_hash($mime);
 913         die "BUG: reindex_oid_m called for <=1 mids" if scalar(@$mids) <= 1;
 914
 915         for my $mid (reverse @$mids) {
 916                 delete($sync->{D}->{"$mid\0$chash"}) and
 917                         die "BUG: reindex_oid should handle <$mid> delete";
 918         }
 919         my $over = $self->{over};
 920         for my $mid (reverse @$mids) {
 921                 ($num, $mid0) = $over->num_mid0_for_oid($oid, $mid);
 922                 next unless defined $num;
 923                 if (defined($regen_num) && $regen_num != $num) {
 924                         die "BUG: regen(#$regen_num) != over(#$num)";
 925                 }
 926         }
 927         unless (defined($num)) {
 928                 for my $mid (reverse @$mids) {
 929                         # is this a number we got before?
 930                         my $n = $sync->{mm_tmp}->num_for($mid);
 931                         next unless defined $n;
 932                         next if defined($regen_num) && $regen_num != $n;
 933                         ($num, $mid0) = ($n, $mid);
 934                         last;
 935                 }
 936         }
 937         if (defined($num)) {
 938                 $sync->{mm_tmp}->num_delete($num);
 939         } elsif (defined $regen_num) {
 940                 $num = $regen_num;
 941                 for my $mid (reverse @$mids) {
 942                         $self->{mm}->mid_set($num, $mid) == 1 or next;
 943                         $mid0 = $mid;
 944                         last;
 945                 }
 946                 unless (defined $mid0) {
 947                         warn "E: cannot regen #$num\n";
 948                         return;
 949                 }
 950         } else { # fixup bugs in old mirrors on reindex
 951                 for my $mid (reverse @$mids) {
 952                         $num = $self->{mm}->mid_insert($mid);
 953                         next unless defined $num;
 954                         $mid0 = $mid;
 955                         last;
 956                 }
 957                 if (defined $mid0) {
 958                         if ($sync->{reindex}) {
 959                                 warn "reindex added #$num <$mid0>\n";
 960                         }
 961                 } else {
 962                         warn "E: cannot find article #\n";
 963                         return;
 964                 }
 965         }
 966         $sync->{nr}++;
 967         my $smsg = bless {
 968                 raw_bytes => $len,
 969                 num => $num,
 970                 blob => $oid,
 971                 mid => $mid0,
 972         }, 'PublicInbox::Smsg';
 973         $smsg->populate($mime, $self);
 974         if (do_idx($self, $msgref, $mime, $smsg)) {
 975                 reindex_checkpoint($self, $sync, $git);
 976         }
 977 }
 978
 979 sub check_unindexed ($$$) {
 980         my ($self, $num, $mid0) = @_;
 981         my $unindexed = $self->{unindexed} // {};
 982         my $n = delete($unindexed->{$mid0});
 983         defined $n or return;
 984         if ($n != $num) {
 985                 die "BUG: unindexed $n != $num <$mid0>\n";
 986         } else {
 987                 $self->{mm}->mid_set($num, $mid0);
 988         }
 989 }
 990
 991 sub multi_mid_q_push ($$$) {
 992         my ($self, $sync, $oid) = @_;
 993         my $multi_mid = $sync->{multi_mid} //= PublicInbox::MultiMidQueue->new;
 994         if ($sync->{reindex}) { # no regen on reindex
 995                 $multi_mid->push_oid($oid, $self);
 996         } else {
 997                 my $num = $sync->{regen}--;
 998                 die "BUG: ran out of article numbers" if $num <= 0;
 999                 $multi_mid->set_oid($num, $oid, $self);
1000         }
1001 }
1002
1003 sub reindex_oid ($$$$) {
1004         my ($self, $sync, $git, $oid) = @_;
1005         return if PublicInbox::SearchIdx::too_big($self, $git, $oid);
1006         my ($num, $mid0, $len);
1007         my $msgref = $git->cat_file($oid, \$len);
1008         return if $len == 0; # purged
1009         my $mime = PublicInbox::Eml->new($$msgref);
1010         my $mids = mids($mime->header_obj);
1011         my $chash = content_hash($mime);
1012
1013         if (scalar(@$mids) == 0) {
1014                 warn "E: $oid has no Message-ID, skipping\n";
1015                 return;
1016         } elsif (scalar(@$mids) == 1) {
1017                 my $mid = $mids->[0];
1018
1019                 # was the file previously marked as deleted?, skip if so
1020                 if (delete($sync->{D}->{"$mid\0$chash"})) {
1021                         if (!$sync->{reindex}) {
1022                                 $num = $sync->{regen}--;
1023                                 $self->{mm}->num_highwater($num);
1024                         }
1025                         return;
1026                 }
1027
1028                 # is this a number we got before?
1029                 $num = $sync->{mm_tmp}->num_for($mid);
1030                 if (defined $num) {
1031                         $mid0 = $mid;
1032                         check_unindexed($self, $num, $mid0);
1033                 } else {
1034                         $num = $sync->{regen}--;
1035                         die "BUG: ran out of article numbers" if $num <= 0;
1036                         if ($self->{mm}->mid_set($num, $mid) != 1) {
1037                                 warn "E: unable to assign $num => <$mid>\n";
1038                                 return;
1039                         }
1040                         $mid0 = $mid;
1041                 }
1042         } else { # multiple MIDs are a weird case:
1043                 my $del = 0;
1044                 for (@$mids) {
1045                         $del += delete($sync->{D}->{"$_\0$chash"}) // 0;
1046                 }
1047                 if ($del) {
1048                         unindex_oid_remote($self, $oid, $_) for @$mids;
1049                         # do not delete from {mm_tmp}, since another
1050                         # single-MID message may use it.
1051                 } else { # handle them at the end:
1052                         multi_mid_q_push($self, $sync, $oid);
1053                 }
1054                 return;
1055         }
1056         $sync->{mm_tmp}->mid_delete($mid0) or
1057                 die "failed to delete <$mid0> for article #$num\n";
1058         $sync->{nr}++;
1059         my $smsg = bless {
1060                 raw_bytes => $len,
1061                 num => $num,
1062                 blob => $oid,
1063                 mid => $mid0,
1064         }, 'PublicInbox::Smsg';
1065         $smsg->populate($mime, $self);
1066         if (do_idx($self, $msgref, $mime, $smsg)) {
1067                 reindex_checkpoint($self, $sync, $git);
1068         }
1069 }
1070
1071 # only update last_commit for $i on reindex iff newer than current
1072 sub update_last_commit ($$$$) {
1073         my ($self, $git, $i, $cmt) = @_;
1074         my $last = last_epoch_commit($self, $i);
1075         if (defined $last && is_ancestor($git, $last, $cmt)) {
1076                 my @cmd = (qw(rev-list --count), "$last..$cmt");
1077                 chomp(my $n = $git->qx(@cmd));
1078                 return if $n ne '' && $n == 0;
1079         }
1080         last_epoch_commit($self, $i, $cmt);
1081 }
1082
1083 sub git_dir_n ($$) { "$_[0]->{-inbox}->{inboxdir}/git/$_[1].git" }
1084
1085 sub last_commits ($$) {
1086         my ($self, $epoch_max) = @_;
1087         my $heads = [];
1088         for (my $i = $epoch_max; $i >= 0; $i--) {
1089                 $heads->[$i] = last_epoch_commit($self, $i);
1090         }
1091         $heads;
1092 }
1093
1094 *is_ancestor = *PublicInbox::SearchIdx::is_ancestor;
1095
1096 # returns a revision range for git-log(1)
1097 sub log_range ($$$$$) {
1098         my ($self, $sync, $git, $i, $tip) = @_;
1099         my $opt = $sync->{-opt};
1100         my $pr = $opt->{-progress} if (($opt->{verbose} || 0) > 1);
1101         my $cur = $sync->{ranges}->[$i] or do {
1102                 $pr->("$i.git indexing all of $tip") if $pr;
1103                 return $tip; # all of it
1104         };
1105
1106         # fast equality check to avoid (v)fork+execve overhead
1107         if ($cur eq $tip) {
1108                 $sync->{ranges}->[$i] = undef;
1109                 return;
1110         }
1111
1112         my $range = "$cur..$tip";
1113         $pr->("$i.git checking contiguity... ") if $pr;
1114         if (is_ancestor($git, $cur, $tip)) { # common case
1115                 $pr->("OK\n") if $pr;
1116                 my $n = $git->qx(qw(rev-list --count), $range);
1117                 chomp($n);
1118                 if ($n == 0) {
1119                         $sync->{ranges}->[$i] = undef;
1120                         $pr->("$i.git has nothing new\n") if $pr;
1121                         return; # nothing to do
1122                 }
1123                 $pr->("$i.git has $n changes since $cur\n") if $pr;
1124         } else {
1125                 $pr->("FAIL\n") if $pr;
1126                 warn <<"";
1127 discontiguous range: $range
1128 Rewritten history? (in $git->{git_dir})
1129
1130                 chomp(my $base = $git->qx('merge-base', $tip, $cur));
1131                 if ($base) {
1132                         $range = "$base..$tip";
1133                         warn "found merge-base: $base\n"
1134                 } else {
1135                         $range = $tip;
1136                         warn "discarding history at $cur\n";
1137                 }
1138                 warn <<"";
1139 reindexing $git->{git_dir} starting at
1140 $range
1141
1142                 $sync->{unindex_range}->{$i} = "$base..$cur";
1143         }
1144         $range;
1145 }
1146
1147 sub sync_prepare ($$$) {
1148         my ($self, $sync, $epoch_max) = @_;
1149         my $pr = $sync->{-opt}->{-progress};
1150         my $regen_max = 0;
1151         my $head = $self->{-inbox}->{ref_head} || 'refs/heads/master';
1152
1153         # reindex stops at the current heads and we later rerun index_sync
1154         # without {reindex}
1155         my $reindex_heads = last_commits($self, $epoch_max) if $sync->{reindex};
1156
1157         for (my $i = $epoch_max; $i >= 0; $i--) {
1158                 die 'BUG: already indexing!' if $self->{reindex_pipe};
1159                 my $git_dir = git_dir_n($self, $i);
1160                 -d $git_dir or next; # missing epochs are fine
1161                 my $git = PublicInbox::Git->new($git_dir);
1162                 if ($reindex_heads) {
1163                         $head = $reindex_heads->[$i] or next;
1164                 }
1165                 chomp(my $tip = $git->qx(qw(rev-parse -q --verify), $head));
1166
1167                 next if $?; # new repo
1168                 my $range = log_range($self, $sync, $git, $i, $tip) or next;
1169                 $sync->{ranges}->[$i] = $range;
1170
1171                 # can't use 'rev-list --count' if we use --diff-filter
1172                 $pr->("$i.git counting $range ... ") if $pr;
1173                 my $n = 0;
1174                 my $fh = $git->popen(qw(log --pretty=tformat:%H
1175                                 --no-notes --no-color --no-renames
1176                                 --diff-filter=AM), $range, '--', 'm');
1177                 ++$n while <$fh>;
1178                 close $fh or die "git log failed: \$?=$?";
1179                 $pr->("$n\n") if $pr;
1180                 $regen_max += $n;
1181         }
1182
1183         return 0 if (!$regen_max && !keys(%{$self->{unindex_range}}));
1184
1185         # reindex should NOT see new commits anymore, if we do,
1186         # it's a problem and we need to notice it via die()
1187         my $pad = length($regen_max) + 1;
1188         $sync->{-regen_fmt} = "% ${pad}u/$regen_max\n";
1189         $sync->{nr} = 0;
1190         return -1 if $sync->{reindex};
1191         $regen_max + $self->{mm}->num_highwater() || 0;
1192 }
1193
1194 sub unindex_oid_remote ($$$) {
1195         my ($self, $oid, $mid) = @_;
1196         $_->remote_remove($oid, $mid) foreach @{$self->{idx_shards}};
1197         $self->{over}->remove_oid($oid, $mid);
1198 }
1199
1200 sub unindex_oid ($$$;$) {
1201         my ($self, $git, $oid, $unindexed) = @_;
1202         my $mm = $self->{mm};
1203         my $msgref = $git->cat_file($oid);
1204         my $mime = PublicInbox::Eml->new($msgref);
1205         my $mids = mids($mime->header_obj);
1206         $mime = $msgref = undef;
1207         my $over = $self->{over};
1208         foreach my $mid (@$mids) {
1209                 my %gone;
1210                 my ($id, $prev);
1211                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
1212                         $gone{$smsg->{num}} = 1 if $oid eq $smsg->{blob};
1213                         1; # continue
1214                 }
1215                 my $n = scalar keys %gone;
1216                 next unless $n;
1217                 if ($n > 1) {
1218                         warn "BUG: multiple articles linked to $oid\n",
1219                                 join(',',sort keys %gone), "\n";
1220                 }
1221                 foreach my $num (keys %gone) {
1222                         if ($unindexed) {
1223                                 my $mid0 = $mm->mid_for($num);
1224                                 $unindexed->{$mid0} = $num;
1225                         }
1226                         $mm->num_delete($num);
1227                 }
1228                 unindex_oid_remote($self, $oid, $mid);
1229         }
1230 }
1231
1232 my $x40 = qr/[a-f0-9]{40}/;
1233 sub unindex ($$$$) {
1234         my ($self, $sync, $git, $unindex_range) = @_;
1235         my $unindexed = $self->{unindexed} ||= {}; # $mid0 => $num
1236         my $before = scalar keys %$unindexed;
1237         # order does not matter, here:
1238         my @cmd = qw(log --raw -r
1239                         --no-notes --no-color --no-abbrev --no-renames);
1240         my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $unindex_range);
1241         while (<$fh>) {
1242                 /\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o or next;
1243                 unindex_oid($self, $git, $1, $unindexed);
1244         }
1245         delete $self->{reindex_pipe};
1246         close $fh or die "git log failed: \$?=$?";
1247
1248         return unless $sync->{-opt}->{prune};
1249         my $after = scalar keys %$unindexed;
1250         return if $before == $after;
1251
1252         # ensure any blob can not longer be accessed via dumb HTTP
1253         PublicInbox::Import::run_die(['git', "--git-dir=$git->{git_dir}",
1254                 qw(-c gc.reflogExpire=now gc --prune=all --quiet)]);
1255 }
1256
1257 sub sync_ranges ($$$) {
1258         my ($self, $sync, $epoch_max) = @_;
1259         my $reindex = $sync->{reindex};
1260
1261         return last_commits($self, $epoch_max) unless $reindex;
1262         return [] if ref($reindex) ne 'HASH';
1263
1264         my $ranges = $reindex->{from}; # arrayref;
1265         if (ref($ranges) ne 'ARRAY') {
1266                 die 'BUG: $reindex->{from} not an ARRAY';
1267         }
1268         $ranges;
1269 }
1270
1271 sub index_epoch ($$$) {
1272         my ($self, $sync, $i) = @_;
1273
1274         my $git_dir = git_dir_n($self, $i);
1275         die 'BUG: already reindexing!' if $self->{reindex_pipe};
1276         -d $git_dir or return; # missing epochs are fine
1277         fill_alternates($self, $i);
1278         my $git = PublicInbox::Git->new($git_dir);
1279         if (my $unindex_range = delete $sync->{unindex_range}->{$i}) {
1280                 unindex($self, $sync, $git, $unindex_range);
1281         }
1282         defined(my $range = $sync->{ranges}->[$i]) or return;
1283         if (my $pr = $sync->{-opt}->{-progress}) {
1284                 $pr->("$i.git indexing $range\n");
1285         }
1286
1287         my @cmd = qw(log --raw -r --pretty=tformat:%H.%at.%ct
1288                         --no-notes --no-color --no-abbrev --no-renames);
1289         my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $range);
1290         my $cmt;
1291         while (<$fh>) {
1292                 chomp;
1293                 $self->{current_info} = "$i.git $_";
1294                 if (/\A($x40)\.([0-9]+)\.([0-9]+)$/o) {
1295                         $cmt //= $1;
1296                         $self->{autime} = $2;
1297                         $self->{cotime} = $3;
1298                 } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o) {
1299                         reindex_oid($self, $sync, $git, $1);
1300                 } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\td$/o) {
1301                         mark_deleted($self, $sync, $git, $1);
1302                 }
1303         }
1304         close $fh or die "git log failed: \$?=$?";
1305         delete @$self{qw(reindex_pipe autime cotime)};
1306         update_last_commit($self, $git, $i, $cmt) if defined $cmt;
1307 }
1308
1309 # public, called by public-inbox-index
1310 sub index_sync {
1311         my ($self, $opt) = @_;
1312         $opt ||= {};
1313         my $pr = $opt->{-progress};
1314         my $epoch_max;
1315         my $latest = git_dir_latest($self, \$epoch_max);
1316         return unless defined $latest;
1317         $self->idx_init($opt); # acquire lock
1318         my $sync = {
1319                 D => {}, # "$mid\0$chash" => $oid
1320                 unindex_range => {}, # EPOCH => oid_old..oid_new
1321                 reindex => $opt->{reindex},
1322                 -opt => $opt
1323         };
1324         $sync->{ranges} = sync_ranges($self, $sync, $epoch_max);
1325         $sync->{regen} = sync_prepare($self, $sync, $epoch_max);
1326
1327         if ($sync->{regen}) {
1328                 # tmp_clone seems to fail if inside a transaction, so
1329                 # we rollback here (because we opened {mm} for reading)
1330                 # Note: we do NOT rely on DBI transactions for atomicity;
1331                 # only for batch performance.
1332                 $self->{mm}->{dbh}->rollback;
1333                 $self->{mm}->{dbh}->begin_work;
1334                 $sync->{mm_tmp} = $self->{mm}->tmp_clone;
1335         }
1336
1337         # work backwards through history
1338         for (my $i = $epoch_max; $i >= 0; $i--) {
1339                 index_epoch($self, $sync, $i);
1340         }
1341
1342         # unindex is required for leftovers if "deletes" affect messages
1343         # in a previous fetch+index window:
1344         my $git;
1345         if (my @leftovers = values %{delete $sync->{D}}) {
1346                 $git = $self->{-inbox}->git;
1347                 for my $oid (@leftovers) {
1348                         $self->{current_info} = "leftover $oid";
1349                         unindex_oid($self, $git, $oid);
1350                 }
1351         }
1352         if (my $multi_mid = delete $sync->{multi_mid}) {
1353                 $git //= $self->{-inbox}->git;
1354                 my $min = $multi_mid->{min};
1355                 my $max = $multi_mid->{max};
1356                 if ($sync->{reindex}) {
1357                         # we may need to create new Message-IDs if mirrors
1358                         # were initially indexed with old versions
1359                         for (my $i = $max; $i >= $min; $i--) {
1360                                 my $oid;
1361                                 $oid = $multi_mid->get_oid($i, $self) or next;
1362                                 next unless defined $oid;
1363                                 reindex_oid_m($self, $sync, $git, $oid);
1364                         }
1365                 } else { # regen on initial index
1366                         for my $num ($min..$max) {
1367                                 my $oid;
1368                                 $oid = $multi_mid->get_oid($num, $self) or next;
1369                                 reindex_oid_m($self, $sync, $git, $oid, $num);
1370                         }
1371                 }
1372         }
1373         $git->cleanup if $git;
1374         $self->done;
1375
1376         if (my $nr = $sync->{nr}) {
1377                 my $pr = $sync->{-opt}->{-progress};
1378                 $pr->('all.git '.sprintf($sync->{-regen_fmt}, $nr)) if $pr;
1379         }
1380
1381         # reindex does not pick up new changes, so we rerun w/o it:
1382         if ($opt->{reindex}) {
1383                 my %again = %$opt;
1384                 $sync = undef;
1385                 delete @again{qw(reindex -skip_lock)};
1386                 index_sync($self, \%again);
1387         }
1388 }
1389
1390 1;