lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 # Used to write to V2 inboxes (see L<public-inbox-v2-format(5)>).
   6 package PublicInbox::V2Writable;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::Lock);
  10 use PublicInbox::SearchIdxShard;
  11 use PublicInbox::Eml;
  12 use PublicInbox::Git;
  13 use PublicInbox::Import;
  14 use PublicInbox::MID qw(mids references);
  15 use PublicInbox::ContentHash qw(content_hash content_digest);
  16 use PublicInbox::InboxWritable;
  17 use PublicInbox::OverIdx;
  18 use PublicInbox::Msgmap;
  19 use PublicInbox::Spawn qw(spawn popen_rd);
  20 use PublicInbox::SearchIdx qw(log2stack crlf_adjust is_ancestor check_size);
  21 use IO::Handle; # ->autoflush
  22 use File::Temp ();
  23
  24 my $OID = qr/[a-f0-9]{40,}/;
  25 # an estimate of the post-packed size to the raw uncompressed size
  26 my $PACKING_FACTOR = 0.4;
  27
  28 # SATA storage lags behind what CPUs are capable of, so relying on
  29 # nproc(1) can be misleading and having extra Xapian shards is a
  30 # waste of FDs and space.  It can also lead to excessive IO latency
  31 # and slow things down.  Users on NVME or other fast storage can
  32 # use the NPROC env or switches in our script/public-inbox-* programs
  33 # to increase Xapian shards
  34 our $NPROC_MAX_DEFAULT = 4;
  35
  36 sub detect_nproc () {
  37         # getconf(1) is POSIX, but *NPROCESSORS* vars are not
  38         for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
  39                 `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
  40         }
  41         for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
  42                 `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
  43         }
  44
  45         # should we bother with `sysctl hw.ncpu`?  Those only give
  46         # us total processor count, not online processor count.
  47         undef
  48 }
  49
  50 sub nproc_shards ($) {
  51         my ($creat_opt) = @_;
  52         my $n = $creat_opt->{nproc} if ref($creat_opt) eq 'HASH';
  53         $n //= $ENV{NPROC};
  54         if (!$n) {
  55                 # assume 2 cores if not detectable or zero
  56                 state $NPROC_DETECTED = detect_nproc() || 2;
  57                 $n = $NPROC_DETECTED;
  58                 $n = $NPROC_MAX_DEFAULT if $n > $NPROC_MAX_DEFAULT;
  59         }
  60
  61         # subtract for the main process and git-fast-import
  62         $n -= 1;
  63         $n < 1 ? 1 : $n;
  64 }
  65
  66 sub count_shards ($) {
  67         my ($self) = @_;
  68         # always load existing shards in case core count changes:
  69         # Also, shard count may change while -watch is running
  70         my $srch = $self->{ibx}->search or return 0;
  71         delete $self->{ibx}->{search};
  72         $srch->{nshard} // 0
  73 }
  74
  75 sub new {
  76         # $creat may be any true value, or 0/undef.  A hashref is true,
  77         # and $creat->{nproc} may be set to an integer
  78         my ($class, $v2ibx, $creat) = @_;
  79         $v2ibx = PublicInbox::InboxWritable->new($v2ibx);
  80         my $dir = $v2ibx->assert_usable_dir;
  81         unless (-d $dir) {
  82                 if ($creat) {
  83                         require File::Path;
  84                         File::Path::mkpath($dir);
  85                 } else {
  86                         die "$dir does not exist\n";
  87                 }
  88         }
  89         $v2ibx->umask_prepare;
  90
  91         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
  92         my $self = {
  93                 ibx => $v2ibx,
  94                 im => undef, #  PublicInbox::Import
  95                 parallel => 1,
  96                 transact_bytes => 0,
  97                 total_bytes => 0,
  98                 current_info => '',
  99                 xpfx => $xpfx,
 100                 oidx => PublicInbox::OverIdx->new("$xpfx/over.sqlite3"),
 101                 lock_path => "$dir/inbox.lock",
 102                 # limit each git repo (epoch) to 1GB or so
 103                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
 104                 last_commit => [], # git epoch -> commit
 105         };
 106         $self->{oidx}->{-no_fsync} = 1 if $v2ibx->{-no_fsync};
 107         $self->{shards} = count_shards($self) || nproc_shards($creat);
 108         bless $self, $class;
 109 }
 110
 111 # public (for now?)
 112 sub init_inbox {
 113         my ($self, $shards, $skip_epoch, $skip_artnum) = @_;
 114         if (defined $shards) {
 115                 $self->{parallel} = 0 if $shards == 0;
 116                 $self->{shards} = $shards if $shards > 0;
 117         }
 118         $self->idx_init;
 119         $self->{mm}->skip_artnum($skip_artnum) if defined $skip_artnum;
 120         my $epoch_max = -1;
 121         git_dir_latest($self, \$epoch_max);
 122         if (defined $skip_epoch && $epoch_max == -1) {
 123                 $epoch_max = $skip_epoch;
 124         }
 125         $self->git_init($epoch_max >= 0 ? $epoch_max : 0);
 126         $self->done;
 127 }
 128
 129 # returns undef on duplicate or spam
 130 # mimics Import::add and wraps it for v2
 131 sub add {
 132         my ($self, $eml, $check_cb) = @_;
 133         $self->{ibx}->with_umask(\&_add, $self, $eml, $check_cb);
 134 }
 135
 136 # indexes a message, returns true if checkpointing is needed
 137 sub do_idx ($$$$) {
 138         my ($self, $msgref, $mime, $smsg) = @_;
 139         $smsg->{bytes} = $smsg->{raw_bytes} + crlf_adjust($$msgref);
 140         $self->{oidx}->add_overview($mime, $smsg);
 141         my $idx = idx_shard($self, $smsg->{num} % $self->{shards});
 142         $idx->index_raw($msgref, $mime, $smsg);
 143         my $n = $self->{transact_bytes} += $smsg->{raw_bytes};
 144         $n >= $self->{batch_bytes};
 145 }
 146
 147 sub _add {
 148         my ($self, $mime, $check_cb) = @_;
 149
 150         # spam check:
 151         if ($check_cb) {
 152                 $mime = $check_cb->($mime, $self->{ibx}) or return;
 153         }
 154
 155         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
 156         # as does SQLite 3.4.1+ (released in 2007-07-20), and
 157         # Xapian 1.3.2+ (released 2015-03-15).
 158         # For the most part, we can spawn git-fast-import without
 159         # leaking FDs to it...
 160         $self->idx_init;
 161
 162         my ($num, $mid0) = v2_num_for($self, $mime);
 163         defined $num or return; # duplicate
 164         defined $mid0 or die "BUG: \$mid0 undefined\n";
 165         my $im = $self->importer;
 166         my $smsg = bless { mid => $mid0, num => $num }, 'PublicInbox::Smsg';
 167         my $cmt = $im->add($mime, undef, $smsg); # sets $smsg->{ds|ts|blob}
 168         $cmt = $im->get_mark($cmt);
 169         $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 170
 171         my $msgref = delete $smsg->{-raw_email};
 172         if (do_idx($self, $msgref, $mime, $smsg)) {
 173                 $self->checkpoint;
 174         }
 175
 176         $cmt;
 177 }
 178
 179 sub v2_num_for {
 180         my ($self, $mime) = @_;
 181         my $mids = mids($mime);
 182         if (@$mids) {
 183                 my $mid = $mids->[0];
 184                 my $num = $self->{mm}->mid_insert($mid);
 185                 if (defined $num) { # common case
 186                         return ($num, $mid);
 187                 }
 188
 189                 # crap, Message-ID is already known, hope somebody just resent:
 190                 foreach my $m (@$mids) {
 191                         # read-only lookup now safe to do after above barrier
 192                         # easy, don't store duplicates
 193                         # note: do not add more diagnostic info here since
 194                         # it gets noisy on public-inbox-watch restarts
 195                         return () if content_exists($self, $mime, $m);
 196                 }
 197
 198                 # AltId may pre-populate article numbers (e.g. X-Mail-Count
 199                 # or NNTP article number), use that article number if it's
 200                 # not in Over.
 201                 my $altid = $self->{ibx}->{altid};
 202                 if ($altid && grep(/:file=msgmap\.sqlite3\z/, @$altid)) {
 203                         my $num = $self->{mm}->num_for($mid);
 204
 205                         if (defined $num && !$self->{oidx}->get_art($num)) {
 206                                 return ($num, $mid);
 207                         }
 208                 }
 209
 210                 # very unlikely:
 211                 warn "<$mid> reused for mismatched content\n";
 212
 213                 # try the rest of the mids
 214                 for(my $i = $#$mids; $i >= 1; $i--) {
 215                         my $m = $mids->[$i];
 216                         $num = $self->{mm}->mid_insert($m);
 217                         if (defined $num) {
 218                                 warn "alternative <$m> for <$mid> found\n";
 219                                 return ($num, $m);
 220                         }
 221                 }
 222         }
 223         # none of the existing Message-IDs are good, generate a new one:
 224         v2_num_for_harder($self, $mime);
 225 }
 226
 227 sub v2_num_for_harder {
 228         my ($self, $eml) = @_;
 229
 230         my $dig = content_digest($eml);
 231         my $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 232         my $num = $self->{mm}->mid_insert($mid0);
 233         unless (defined $num) {
 234                 # it's hard to spoof the last Received: header
 235                 my @recvd = $eml->header_raw('Received');
 236                 $dig->add("Received: $_") foreach (@recvd);
 237                 $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 238                 $num = $self->{mm}->mid_insert($mid0);
 239
 240                 # fall back to a random Message-ID and give up determinism:
 241                 until (defined($num)) {
 242                         $dig->add(rand);
 243                         $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 244                         warn "using random Message-ID <$mid0> as fallback\n";
 245                         $num = $self->{mm}->mid_insert($mid0);
 246                 }
 247         }
 248         PublicInbox::Import::append_mid($eml, $mid0);
 249         ($num, $mid0);
 250 }
 251
 252 sub idx_shard {
 253         my ($self, $shard_i) = @_;
 254         $self->{idx_shards}->[$shard_i];
 255 }
 256
 257 sub _idx_init { # with_umask callback
 258         my ($self, $opt) = @_;
 259         $self->lock_acquire unless $opt && $opt->{-skip_lock};
 260         $self->{oidx}->create;
 261
 262         # xcpdb can change shard count while -watch is idle
 263         my $nshards = count_shards($self);
 264         $self->{shards} = $nshards if $nshards && $nshards != $self->{shards};
 265         $self->{batch_bytes} = $opt->{batch_size} //
 266                                 $PublicInbox::SearchIdx::BATCH_BYTES;
 267         $self->{batch_bytes} *= $self->{shards} if $self->{parallel};
 268
 269         # need to create all shards before initializing msgmap FD
 270         # idx_shards must be visible to all forked processes
 271         my $max = $self->{shards} - 1;
 272         my $idx = $self->{idx_shards} = [];
 273         push @$idx, PublicInbox::SearchIdxShard->new($self, $_) for (0..$max);
 274         my $ibx = $self->{ibx} or return; # ExtIdxSearch
 275
 276         # Now that all subprocesses are up, we can open the FDs
 277         # for SQLite:
 278         my $mm = $self->{mm} = PublicInbox::Msgmap->new_file(
 279                                 "$ibx->{inboxdir}/msgmap.sqlite3",
 280                                 $ibx->{-no_fsync} ? 2 : 1);
 281         $mm->{dbh}->begin_work;
 282 }
 283
 284 sub parallel_init ($$) {
 285         my ($self, $indexlevel) = @_;
 286         if (($indexlevel // 'full') eq 'basic') {
 287                 $self->{parallel} = 0;
 288         } else {
 289                 pipe(my ($r, $w)) or die "pipe failed: $!";
 290                 # pipe for barrier notifications doesn't need to be big,
 291                 # 1031: F_SETPIPE_SZ
 292                 fcntl($w, 1031, 4096) if $^O eq 'linux';
 293                 $self->{bnote} = [ $r, $w ];
 294                 $w->autoflush(1);
 295         }
 296 }
 297
 298 # idempotent
 299 sub idx_init {
 300         my ($self, $opt) = @_;
 301         return if $self->{idx_shards};
 302         my $ibx = $self->{ibx};
 303
 304         # do not leak read-only FDs to child processes, we only have these
 305         # FDs for duplicate detection so they should not be
 306         # frequently activated.
 307         delete @$ibx{qw(mm search)};
 308         $ibx->git->cleanup;
 309
 310         parallel_init($self, $ibx->{indexlevel});
 311         $ibx->umask_prepare;
 312         $ibx->with_umask(\&_idx_init, $self, $opt);
 313 }
 314
 315 # returns an array mapping [ epoch => latest_commit ]
 316 # latest_commit may be undef if nothing was done to that epoch
 317 # $replace_map = { $object_id => $strref, ... }
 318 sub _replace_oids ($$$) {
 319         my ($self, $mime, $replace_map) = @_;
 320         $self->done;
 321         my $pfx = "$self->{ibx}->{inboxdir}/git";
 322         my $rewrites = []; # epoch => commit
 323         my $max = $self->{epoch_max};
 324
 325         unless (defined($max)) {
 326                 defined(my $latest = git_dir_latest($self, \$max)) or return;
 327                 $self->{epoch_max} = $max;
 328         }
 329
 330         foreach my $i (0..$max) {
 331                 my $git_dir = "$pfx/$i.git";
 332                 -d $git_dir or next;
 333                 my $git = PublicInbox::Git->new($git_dir);
 334                 my $im = $self->import_init($git, 0, 1);
 335                 $rewrites->[$i] = $im->replace_oids($mime, $replace_map);
 336                 $im->done;
 337         }
 338         $rewrites;
 339 }
 340
 341 sub content_hashes ($) {
 342         my ($mime) = @_;
 343         my @chashes = ( content_hash($mime) );
 344
 345         # We still support Email::MIME, here, and
 346         # Email::MIME->as_string doesn't always round-trip, so we may
 347         # use a second content_hash
 348         my $rt = content_hash(PublicInbox::Eml->new(\($mime->as_string)));
 349         push @chashes, $rt if $chashes[0] ne $rt;
 350         \@chashes;
 351 }
 352
 353 sub content_matches ($$) {
 354         my ($chashes, $existing) = @_;
 355         my $chash = content_hash($existing);
 356         foreach (@$chashes) {
 357                 return 1 if $_ eq $chash
 358         }
 359         0
 360 }
 361
 362 # used for removing or replacing (purging)
 363 sub rewrite_internal ($$;$$$) {
 364         my ($self, $old_eml, $cmt_msg, $new_eml, $sref) = @_;
 365         $self->idx_init;
 366         my ($im, $need_reindex, $replace_map);
 367         if ($sref) {
 368                 $replace_map = {}; # oid => sref
 369                 $need_reindex = [] if $new_eml;
 370         } else {
 371                 $im = $self->importer;
 372         }
 373         my $oidx = $self->{oidx};
 374         my $chashes = content_hashes($old_eml);
 375         my $removed = [];
 376         my $mids = mids($old_eml);
 377
 378         # We avoid introducing new blobs into git since the raw content
 379         # can be slightly different, so we do not need the user-supplied
 380         # message now that we have the mids and content_hash
 381         $old_eml = undef;
 382         my $mark;
 383
 384         foreach my $mid (@$mids) {
 385                 my %gone; # num => [ smsg, $mime, raw ]
 386                 my ($id, $prev);
 387                 while (my $smsg = $oidx->next_by_mid($mid, \$id, \$prev)) {
 388                         my $msg = get_blob($self, $smsg);
 389                         if (!defined($msg)) {
 390                                 warn "broken smsg for $mid\n";
 391                                 next; # continue
 392                         }
 393                         my $orig = $$msg;
 394                         my $cur = PublicInbox::Eml->new($msg);
 395                         if (content_matches($chashes, $cur)) {
 396                                 $gone{$smsg->{num}} = [ $smsg, $cur, \$orig ];
 397                         }
 398                 }
 399                 my $n = scalar keys %gone;
 400                 next unless $n;
 401                 if ($n > 1) {
 402                         warn "BUG: multiple articles linked to <$mid>\n",
 403                                 join(',', sort keys %gone), "\n";
 404                 }
 405                 foreach my $num (keys %gone) {
 406                         my ($smsg, $mime, $orig) = @{$gone{$num}};
 407                         # $removed should only be set once assuming
 408                         # no bugs in our deduplication code:
 409                         $removed = [ undef, $mime, $smsg ];
 410                         my $oid = $smsg->{blob};
 411                         if ($replace_map) {
 412                                 $replace_map->{$oid} = $sref;
 413                         } else {
 414                                 ($mark, undef) = $im->remove($orig, $cmt_msg);
 415                                 $removed->[0] = $mark;
 416                         }
 417                         $orig = undef;
 418                         if ($need_reindex) { # ->replace
 419                                 push @$need_reindex, $smsg;
 420                         } else { # ->purge or ->remove
 421                                 $self->{mm}->num_delete($num);
 422                         }
 423                         unindex_oid_remote($self, $oid, $mid);
 424                 }
 425         }
 426
 427         if (defined $mark) {
 428                 my $cmt = $im->get_mark($mark);
 429                 $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 430         }
 431         if ($replace_map && scalar keys %$replace_map) {
 432                 my $rewrites = _replace_oids($self, $new_eml, $replace_map);
 433                 return { rewrites => $rewrites, need_reindex => $need_reindex };
 434         }
 435         defined($mark) ? $removed : undef;
 436 }
 437
 438 # public (see PublicInbox::Import->remove), but note the 3rd element
 439 # (retval[2]) is not part of the stable API shared with Import->remove
 440 sub remove {
 441         my ($self, $eml, $cmt_msg) = @_;
 442         my $r = $self->{ibx}->with_umask(\&rewrite_internal,
 443                                                 $self, $eml, $cmt_msg);
 444         defined($r) && defined($r->[0]) ? @$r: undef;
 445 }
 446
 447 sub _replace ($$;$$) {
 448         my ($self, $old_eml, $new_eml, $sref) = @_;
 449         my $arg = [ $self, $old_eml, undef, $new_eml, $sref ];
 450         my $rewritten = $self->{ibx}->with_umask(\&rewrite_internal,
 451                         $self, $old_eml, undef, $new_eml, $sref) or return;
 452
 453         my $rewrites = $rewritten->{rewrites};
 454         # ->done is called if there are rewrites since we gc+prune from git
 455         $self->idx_init if @$rewrites;
 456
 457         for my $i (0..$#$rewrites) {
 458                 defined(my $cmt = $rewrites->[$i]) or next;
 459                 $self->{last_commit}->[$i] = $cmt;
 460         }
 461         $rewritten;
 462 }
 463
 464 # public
 465 sub purge {
 466         my ($self, $mime) = @_;
 467         my $rewritten = _replace($self, $mime, undef, \'') or return;
 468         $rewritten->{rewrites}
 469 }
 470
 471 # returns the git object_id of $fh, does not write the object to FS
 472 sub git_hash_raw ($$) {
 473         my ($self, $raw) = @_;
 474         # grab the expected OID we have to reindex:
 475         pipe(my($in, $w)) or die "pipe: $!";
 476         my $git_dir = $self->git->{git_dir};
 477         my $cmd = ['git', "--git-dir=$git_dir", qw(hash-object --stdin)];
 478         my $r = popen_rd($cmd, undef, { 0 => $in });
 479         print $w $$raw or die "print \$w: $!";
 480         close $w or die "close \$w: $!";
 481         local $/ = "\n";
 482         chomp(my $oid = <$r>);
 483         close $r or die "git hash-object failed: $?";
 484         $oid =~ /\A$OID\z/ or die "OID not expected: $oid";
 485         $oid;
 486 }
 487
 488 sub _check_mids_match ($$$) {
 489         my ($old_list, $new_list, $hdrs) = @_;
 490         my %old_mids = map { $_ => 1 } @$old_list;
 491         my %new_mids = map { $_ => 1 } @$new_list;
 492         my @old = keys %old_mids;
 493         my @new = keys %new_mids;
 494         my $err = "$hdrs may not be changed when replacing\n";
 495         die $err if scalar(@old) != scalar(@new);
 496         delete @new_mids{@old};
 497         delete @old_mids{@new};
 498         die $err if (scalar(keys %old_mids) || scalar(keys %new_mids));
 499 }
 500
 501 # Changing Message-IDs or References with ->replace isn't supported.
 502 # The rules for dealing with messages with multiple or conflicting
 503 # Message-IDs are pretty complex and rethreading hasn't been fully
 504 # implemented, yet.
 505 sub check_mids_match ($$) {
 506         my ($old, $new) = @_;
 507         _check_mids_match(mids($old), mids($new), 'Message-ID(s)');
 508         _check_mids_match(references($old), references($new),
 509                         'References/In-Reply-To');
 510 }
 511
 512 # public
 513 sub replace ($$$) {
 514         my ($self, $old_mime, $new_mime) = @_;
 515
 516         check_mids_match($old_mime, $new_mime);
 517
 518         # mutt will always add Content-Length:, Status:, Lines: when editing
 519         PublicInbox::Import::drop_unwanted_headers($new_mime);
 520
 521         my $raw = $new_mime->as_string;
 522         my $expect_oid = git_hash_raw($self, \$raw);
 523         my $rewritten = _replace($self, $old_mime, $new_mime, \$raw) or return;
 524         my $need_reindex = $rewritten->{need_reindex};
 525
 526         # just in case we have bugs in deduplication code:
 527         my $n = scalar(@$need_reindex);
 528         if ($n > 1) {
 529                 my $list = join(', ', map {
 530                                         "$_->{num}: <$_->{mid}>"
 531                                 } @$need_reindex);
 532                 warn <<"";
 533 W: rewritten $n messages matching content of original message (expected: 1).
 534 W: possible bug in public-inbox, NNTP article IDs and Message-IDs follow:
 535 W: $list
 536
 537         }
 538
 539         # make sure we really got the OID:
 540         my ($blob, $type, $bytes) = $self->git->check($expect_oid);
 541         $blob eq $expect_oid or die "BUG: $expect_oid not found after replace";
 542
 543         # don't leak FDs to Xapian:
 544         $self->git->cleanup;
 545
 546         # reindex modified messages:
 547         for my $smsg (@$need_reindex) {
 548                 my $new_smsg = bless {
 549                         blob => $blob,
 550                         raw_bytes => $bytes,
 551                         num => $smsg->{num},
 552                         mid => $smsg->{mid},
 553                 }, 'PublicInbox::Smsg';
 554                 my $sync = { autime => $smsg->{ds}, cotime => $smsg->{ts} };
 555                 $new_smsg->populate($new_mime, $sync);
 556                 do_idx($self, \$raw, $new_mime, $new_smsg);
 557         }
 558         $rewritten->{rewrites};
 559 }
 560
 561 sub last_epoch_commit ($$;$) {
 562         my ($self, $i, $cmt) = @_;
 563         my $v = PublicInbox::Search::SCHEMA_VERSION();
 564         $self->{mm}->last_commit_xap($v, $i, $cmt);
 565 }
 566
 567 sub set_last_commits ($) {
 568         my ($self) = @_;
 569         defined(my $epoch_max = $self->{epoch_max}) or return;
 570         my $last_commit = $self->{last_commit};
 571         foreach my $i (0..$epoch_max) {
 572                 defined(my $cmt = $last_commit->[$i]) or next;
 573                 $last_commit->[$i] = undef;
 574                 last_epoch_commit($self, $i, $cmt);
 575         }
 576 }
 577
 578 sub barrier_init {
 579         my ($self, $n) = @_;
 580         $self->{bnote} or return;
 581         --$n;
 582         my $barrier = { map { $_ => 1 } (0..$n) };
 583 }
 584
 585 sub barrier_wait {
 586         my ($self, $barrier) = @_;
 587         my $bnote = $self->{bnote} or return;
 588         my $r = $bnote->[0];
 589         while (scalar keys %$barrier) {
 590                 defined(my $l = readline($r)) or die "EOF on barrier_wait: $!";
 591                 $l =~ /\Abarrier (\d+)/ or die "bad line on barrier_wait: $l";
 592                 delete $barrier->{$1} or die "bad shard[$1] on barrier wait";
 593         }
 594 }
 595
 596 # public
 597 sub checkpoint ($;$) {
 598         my ($self, $wait) = @_;
 599
 600         if (my $im = $self->{im}) {
 601                 if ($wait) {
 602                         $im->barrier;
 603                 } else {
 604                         $im->checkpoint;
 605                 }
 606         }
 607         my $shards = $self->{idx_shards};
 608         if ($shards) {
 609                 my $dbh = $self->{mm}->{dbh};
 610
 611                 # SQLite msgmap data is second in importance
 612                 $dbh->commit;
 613
 614                 # SQLite overview is third
 615                 $self->{oidx}->commit_lazy;
 616
 617                 # Now deal with Xapian
 618                 if ($wait) {
 619                         my $barrier = $self->barrier_init(scalar @$shards);
 620
 621                         # each shard needs to issue a barrier command
 622                         $_->shard_barrier for @$shards;
 623
 624                         # wait for each Xapian shard
 625                         $self->barrier_wait($barrier);
 626                 } else {
 627                         $_->shard_commit for @$shards;
 628                 }
 629
 630                 # last_commit is special, don't commit these until
 631                 # remote shards are done:
 632                 $dbh->begin_work;
 633                 set_last_commits($self);
 634                 $dbh->commit;
 635
 636                 $dbh->begin_work;
 637         }
 638         $self->{total_bytes} += $self->{transact_bytes};
 639         $self->{transact_bytes} = 0;
 640 }
 641
 642 # issue a write barrier to ensure all data is visible to other processes
 643 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 644 # public
 645 sub barrier { checkpoint($_[0], 1) };
 646
 647 # true if locked and active
 648 sub active { !!$_[0]->{im} }
 649
 650 # public
 651 sub done {
 652         my ($self) = @_;
 653         my $err = '';
 654         if (my $im = delete $self->{im}) {
 655                 eval { $im->done }; # PublicInbox::Import::done
 656                 $err .= "import done: $@\n" if $@;
 657         }
 658         if (!$err) {
 659                 eval { checkpoint($self) };
 660                 $err .= "checkpoint: $@\n" if $@;
 661         }
 662         if (my $mm = delete $self->{mm}) {
 663                 my $m = $err ? 'rollback' : 'commit';
 664                 eval { $mm->{dbh}->$m };
 665                 $err .= "msgmap $m: $@\n" if $@;
 666         }
 667         my $shards = delete $self->{idx_shards};
 668         if ($shards) {
 669                 for (@$shards) {
 670                         eval { $_->shard_close };
 671                         $err .= "shard close: $@\n" if $@;
 672                 }
 673         }
 674         eval { $self->{oidx}->dbh_close };
 675         $err .= "over close: $@\n" if $@;
 676         delete $self->{bnote};
 677         my $nbytes = $self->{total_bytes};
 678         $self->{total_bytes} = 0;
 679         $self->lock_release(!!$nbytes) if $shards;
 680         $self->git->cleanup;
 681         die $err if $err;
 682 }
 683
 684 sub fill_alternates ($$) {
 685         my ($self, $epoch) = @_;
 686
 687         my $pfx = "$self->{ibx}->{inboxdir}/git";
 688         my $all = "$self->{ibx}->{inboxdir}/all.git";
 689         PublicInbox::Import::init_bare($all) unless -d $all;
 690         my $info_dir = "$all/objects/info";
 691         my $alt = "$info_dir/alternates";
 692         my (%alt, $new);
 693         my $mode = 0644;
 694         if (-e $alt) {
 695                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 696                 $mode = (stat($fh))[2] & 07777;
 697
 698                 # we assign a sort score to every alternate and favor
 699                 # the newest (highest numbered) one because loose objects
 700                 # require scanning epochs and only the latest epoch is
 701                 # expected to see loose objects
 702                 my $score;
 703                 my $other = 0; # in case admin adds non-epoch repos
 704                 %alt = map {;
 705                         if (m!\A\Q../../\E([0-9]+)\.git/objects\z!) {
 706                                 $score = $1 + 0;
 707                         } else {
 708                                 $score = --$other;
 709                         }
 710                         $_ => $score;
 711                 } split(/\n+/, do { local $/; <$fh> });
 712         }
 713
 714         foreach my $i (0..$epoch) {
 715                 my $dir = "../../git/$i.git/objects";
 716                 if (!exists($alt{$dir}) && -d "$pfx/$i.git") {
 717                         $alt{$dir} = $i;
 718                         $new = 1;
 719                 }
 720         }
 721         return unless $new;
 722
 723         my $fh = File::Temp->new(TEMPLATE => 'alt-XXXXXXXX', DIR => $info_dir);
 724         my $tmp = $fh->filename;
 725         print $fh join("\n", sort { $alt{$b} <=> $alt{$a} } keys %alt), "\n"
 726                 or die "print $tmp: $!\n";
 727         chmod($mode, $fh) or die "fchmod $tmp: $!\n";
 728         close $fh or die "close $tmp $!\n";
 729         rename($tmp, $alt) or die "rename $tmp => $alt: $!\n";
 730         $fh->unlink_on_destroy(0);
 731 }
 732
 733 sub git_init {
 734         my ($self, $epoch) = @_;
 735         my $git_dir = "$self->{ibx}->{inboxdir}/git/$epoch.git";
 736         PublicInbox::Import::init_bare($git_dir);
 737         my @cmd = (qw/git config/, "--file=$git_dir/config",
 738                         'include.path', '../../all.git/config');
 739         PublicInbox::Import::run_die(\@cmd);
 740         fill_alternates($self, $epoch);
 741         $git_dir
 742 }
 743
 744 sub git_dir_latest {
 745         my ($self, $max) = @_;
 746         $$max = -1;
 747         my $pfx = "$self->{ibx}->{inboxdir}/git";
 748         return unless -d $pfx;
 749         my $latest;
 750         opendir my $dh, $pfx or die "opendir $pfx: $!\n";
 751         while (defined(my $git_dir = readdir($dh))) {
 752                 $git_dir =~ m!\A([0-9]+)\.git\z! or next;
 753                 if ($1 > $$max) {
 754                         $$max = $1;
 755                         $latest = "$pfx/$git_dir";
 756                 }
 757         }
 758         $latest;
 759 }
 760
 761 sub importer {
 762         my ($self) = @_;
 763         my $im = $self->{im};
 764         if ($im) {
 765                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 766                         return $im;
 767                 } else {
 768                         $self->{im} = undef;
 769                         $im->done;
 770                         $im = undef;
 771                         $self->checkpoint;
 772                         my $git_dir = $self->git_init(++$self->{epoch_max});
 773                         my $git = PublicInbox::Git->new($git_dir);
 774                         return $self->import_init($git, 0);
 775                 }
 776         }
 777         my $epoch = 0;
 778         my $max;
 779         my $latest = git_dir_latest($self, \$max);
 780         if (defined $latest) {
 781                 my $git = PublicInbox::Git->new($latest);
 782                 my $packed_bytes = $git->packed_bytes;
 783                 my $unpacked_bytes = $packed_bytes / $PACKING_FACTOR;
 784
 785                 if ($unpacked_bytes >= $self->{rotate_bytes}) {
 786                         $epoch = $max + 1;
 787                 } else {
 788                         $self->{epoch_max} = $max;
 789                         return $self->import_init($git, $packed_bytes);
 790                 }
 791         }
 792         $self->{epoch_max} = $epoch;
 793         $latest = $self->git_init($epoch);
 794         $self->import_init(PublicInbox::Git->new($latest), 0);
 795 }
 796
 797 sub import_init {
 798         my ($self, $git, $packed_bytes, $tmp) = @_;
 799         my $im = PublicInbox::Import->new($git, undef, undef, $self->{ibx});
 800         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 801         $im->{lock_path} = undef;
 802         $im->{path_type} = 'v2';
 803         $self->{im} = $im unless $tmp;
 804         $im;
 805 }
 806
 807 # XXX experimental
 808 sub diff ($$$) {
 809         my ($mid, $cur, $new) = @_;
 810
 811         my $ah = File::Temp->new(TEMPLATE => 'email-cur-XXXXXXXX', TMPDIR => 1);
 812         print $ah $cur->as_string or die "print: $!";
 813         $ah->flush or die "flush: $!";
 814         PublicInbox::Import::drop_unwanted_headers($new);
 815         my $bh = File::Temp->new(TEMPLATE => 'email-new-XXXXXXXX', TMPDIR => 1);
 816         print $bh $new->as_string or die "print: $!";
 817         $bh->flush or die "flush: $!";
 818         my $cmd = [ qw(diff -u), $ah->filename, $bh->filename ];
 819         print STDERR "# MID conflict <$mid>\n";
 820         my $pid = spawn($cmd, undef, { 1 => 2 });
 821         waitpid($pid, 0) == $pid or die "diff did not finish";
 822 }
 823
 824 sub get_blob ($$) {
 825         my ($self, $smsg) = @_;
 826         if (my $im = $self->{im}) {
 827                 my $msg = $im->cat_blob($smsg->{blob});
 828                 return $msg if $msg;
 829         }
 830         # older message, should be in alternates
 831         $self->{ibx}->msg_by_smsg($smsg);
 832 }
 833
 834 sub content_exists ($$$) {
 835         my ($self, $mime, $mid) = @_;
 836         my $oidx = $self->{oidx};
 837         my $chashes = content_hashes($mime);
 838         my ($id, $prev);
 839         while (my $smsg = $oidx->next_by_mid($mid, \$id, \$prev)) {
 840                 my $msg = get_blob($self, $smsg);
 841                 if (!defined($msg)) {
 842                         warn "broken smsg for $mid\n";
 843                         next;
 844                 }
 845                 my $cur = PublicInbox::Eml->new($msg);
 846                 return 1 if content_matches($chashes, $cur);
 847
 848                 # XXX DEBUG_DIFF is experimental and may be removed
 849                 diff($mid, $cur, $mime) if $ENV{DEBUG_DIFF};
 850         }
 851         undef;
 852 }
 853
 854 sub atfork_child {
 855         my ($self) = @_;
 856         if (my $shards = $self->{idx_shards}) {
 857                 $_->atfork_child foreach @$shards;
 858         }
 859         if (my $im = $self->{im}) {
 860                 $im->atfork_child;
 861         }
 862         die "unexpected mm" if $self->{mm};
 863         close $self->{bnote}->[0] or die "close bnote[0]: $!\n";
 864         $self->{bnote}->[1];
 865 }
 866
 867 sub reindex_checkpoint ($$) {
 868         my ($self, $sync) = @_;
 869
 870         $self->git->cleanup; # *async_wait
 871         ${$sync->{need_checkpoint}} = 0;
 872         my $mm_tmp = $sync->{mm_tmp};
 873         $mm_tmp->atfork_prepare if $mm_tmp;
 874         $self->done; # release lock
 875
 876         if (my $pr = $sync->{-opt}->{-progress}) {
 877                 $pr->(sprintf($sync->{-regen_fmt}, ${$sync->{nr}}));
 878         }
 879
 880         # allow -watch or -mda to write...
 881         $self->idx_init($sync->{-opt}); # reacquire lock
 882         $mm_tmp->atfork_parent if $mm_tmp;
 883 }
 884
 885 sub index_oid { # cat_async callback
 886         my ($bref, $oid, $type, $size, $arg) = @_;
 887         return if $size == 0; # purged
 888         my ($num, $mid0);
 889         my $eml = PublicInbox::Eml->new($$bref);
 890         my $mids = mids($eml);
 891         my $chash = content_hash($eml);
 892         my $self = $arg->{v2w};
 893
 894         if (scalar(@$mids) == 0) {
 895                 warn "E: $oid has no Message-ID, skipping\n";
 896                 return;
 897         }
 898
 899         # {unindexed} is unlikely
 900         if ((my $unindexed = $arg->{unindexed}) && scalar(@$mids) == 1) {
 901                 $num = delete($unindexed->{$mids->[0]});
 902                 if (defined $num) {
 903                         $mid0 = $mids->[0];
 904                         $self->{mm}->mid_set($num, $mid0);
 905                         delete($arg->{unindexed}) if !keys(%$unindexed);
 906                 }
 907         }
 908         if (!defined($num)) { # reuse if reindexing (or duplicates)
 909                 my $oidx = $self->{oidx};
 910                 for my $mid (@$mids) {
 911                         ($num, $mid0) = $oidx->num_mid0_for_oid($oid, $mid);
 912                         last if defined $num;
 913                 }
 914         }
 915         $mid0 //= do { # is this a number we got before?
 916                 $num = $arg->{mm_tmp}->num_for($mids->[0]);
 917                 defined($num) ? $mids->[0] : undef;
 918         };
 919         if (!defined($num)) {
 920                 for (my $i = $#$mids; $i >= 1; $i--) {
 921                         $num = $arg->{mm_tmp}->num_for($mids->[$i]);
 922                         if (defined($num)) {
 923                                 $mid0 = $mids->[$i];
 924                                 last;
 925                         }
 926                 }
 927         }
 928         if (defined($num)) {
 929                 $arg->{mm_tmp}->num_delete($num);
 930         } else { # never seen
 931                 $num = $self->{mm}->mid_insert($mids->[0]);
 932                 if (defined($num)) {
 933                         $mid0 = $mids->[0];
 934                 } else { # rare, try the rest of them, backwards
 935                         for (my $i = $#$mids; $i >= 1; $i--) {
 936                                 $num = $self->{mm}->mid_insert($mids->[$i]);
 937                                 if (defined($num)) {
 938                                         $mid0 = $mids->[$i];
 939                                         last;
 940                                 }
 941                         }
 942                 }
 943         }
 944         if (!defined($num)) {
 945                 warn "E: $oid <", join('> <', @$mids), "> is a duplicate\n";
 946                 return;
 947         }
 948         ++${$arg->{nr}};
 949         my $smsg = bless {
 950                 raw_bytes => $size,
 951                 num => $num,
 952                 blob => $oid,
 953                 mid => $mid0,
 954         }, 'PublicInbox::Smsg';
 955         $smsg->populate($eml, $arg);
 956         if (do_idx($self, $bref, $eml, $smsg)) {
 957                 ${$arg->{need_checkpoint}} = 1;
 958         }
 959 }
 960
 961 # only update last_commit for $i on reindex iff newer than current
 962 sub update_last_commit {
 963         my ($self, $git, $i, $cmt) = @_;
 964         my $last = last_epoch_commit($self, $i);
 965         if (defined $last && is_ancestor($git, $last, $cmt)) {
 966                 my @cmd = (qw(rev-list --count), "$last..$cmt");
 967                 chomp(my $n = $git->qx(@cmd));
 968                 return if $n ne '' && $n == 0;
 969         }
 970         last_epoch_commit($self, $i, $cmt);
 971 }
 972
 973 sub git_dir_n ($$) { "$_[0]->{ibx}->{inboxdir}/git/$_[1].git" }
 974
 975 sub last_commits ($$) {
 976         my ($self, $epoch_max) = @_;
 977         my $heads = [];
 978         for (my $i = $epoch_max; $i >= 0; $i--) {
 979                 $heads->[$i] = last_epoch_commit($self, $i);
 980         }
 981         $heads;
 982 }
 983
 984 # returns a revision range for git-log(1)
 985 sub log_range ($$$$$) {
 986         my ($self, $sync, $git, $i, $tip) = @_;
 987         my $opt = $sync->{-opt};
 988         my $pr = $opt->{-progress} if (($opt->{verbose} || 0) > 1);
 989         my $cur = $sync->{ranges}->[$i] or do {
 990                 $pr->("$i.git indexing all of $tip\n") if $pr;
 991                 return $tip; # all of it
 992         };
 993
 994         # fast equality check to avoid (v)fork+execve overhead
 995         if ($cur eq $tip) {
 996                 $sync->{ranges}->[$i] = undef;
 997                 return;
 998         }
 999
1000         my $range = "$cur..$tip";
1001         $pr->("$i.git checking contiguity... ") if $pr;
1002         if (is_ancestor($git, $cur, $tip)) { # common case
1003                 $pr->("OK\n") if $pr;
1004                 my $n = $git->qx(qw(rev-list --count), $range);
1005                 chomp($n);
1006                 if ($n == 0) {
1007                         $sync->{ranges}->[$i] = undef;
1008                         $pr->("$i.git has nothing new\n") if $pr;
1009                         return; # nothing to do
1010                 }
1011                 $pr->("$i.git has $n changes since $cur\n") if $pr;
1012         } else {
1013                 $pr->("FAIL\n") if $pr;
1014                 warn <<"";
1015 discontiguous range: $range
1016 Rewritten history? (in $git->{git_dir})
1017
1018                 chomp(my $base = $git->qx('merge-base', $tip, $cur));
1019                 if ($base) {
1020                         $range = "$base..$tip";
1021                         warn "found merge-base: $base\n"
1022                 } else {
1023                         $range = $tip;
1024                         warn "discarding history at $cur\n";
1025                 }
1026                 warn <<"";
1027 reindexing $git->{git_dir} starting at
1028 $range
1029
1030                 $sync->{unindex_range}->{$i} = "$base..$cur";
1031         }
1032         $range;
1033 }
1034
1035 sub sync_prepare ($$$) {
1036         my ($self, $sync, $epoch_max) = @_;
1037         my $pr = $sync->{-opt}->{-progress};
1038         my $regen_max = 0;
1039         my $head = $self->{ibx}->{ref_head} || 'HEAD';
1040
1041         # reindex stops at the current heads and we later rerun index_sync
1042         # without {reindex}
1043         my $reindex_heads = $self->last_commits($epoch_max) if $sync->{reindex};
1044
1045         for (my $i = $epoch_max; $i >= 0; $i--) {
1046                 my $git_dir = git_dir_n($self, $i);
1047                 -d $git_dir or next; # missing epochs are fine
1048                 my $git = PublicInbox::Git->new($git_dir);
1049                 if ($reindex_heads) {
1050                         $head = $reindex_heads->[$i] or next;
1051                 }
1052                 chomp(my $tip = $git->qx(qw(rev-parse -q --verify), $head));
1053
1054                 next if $?; # new repo
1055                 my $range = log_range($self, $sync, $git, $i, $tip) or next;
1056                 # can't use 'rev-list --count' if we use --diff-filter
1057                 $pr->("$i.git counting $range ... ") if $pr;
1058                 # Don't bump num_highwater on --reindex by using {D}.
1059                 # We intentionally do NOT use {D} in the non-reindex case
1060                 # because we want NNTP article number gaps from unindexed
1061                 # messages to show up in mirrors, too.
1062                 $sync->{D} //= $sync->{reindex} ? {} : undef; # OID_BIN => NR
1063                 my $stk = log2stack($sync, $git, $range, $self->{ibx});
1064                 my $nr = $stk ? $stk->num_records : 0;
1065                 $pr->("$nr\n") if $pr;
1066                 $sync->{stacks}->[$i] = $stk if $stk;
1067                 $regen_max += $nr;
1068         }
1069
1070         # XXX this should not happen unless somebody bypasses checks in
1071         # our code and blindly injects "d" file history into git repos
1072         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
1073                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
1074                 my $arg = { v2w => $self };
1075                 for my $oid (@leftovers) {
1076                         $oid = unpack('H*', $oid);
1077                         $self->{current_info} = "leftover $oid";
1078                         $self->git->cat_async($oid, \&unindex_oid, $arg);
1079                 }
1080                 $self->git->cat_async_wait;
1081         }
1082         if (!$regen_max) {
1083                 $sync->{-regen_fmt} = "%u/?\n";
1084                 return 0;
1085         }
1086
1087         # reindex should NOT see new commits anymore, if we do,
1088         # it's a problem and we need to notice it via die()
1089         my $pad = length($regen_max) + 1;
1090         $sync->{-regen_fmt} = "% ${pad}u/$regen_max\n";
1091         $sync->{nr} = \(my $nr = 0);
1092         return -1 if $sync->{reindex};
1093         $regen_max + $self->{mm}->num_highwater() || 0;
1094 }
1095
1096 sub unindex_oid_remote ($$$) {
1097         my ($self, $oid, $mid) = @_;
1098         my @removed = $self->{oidx}->remove_oid($oid, $mid);
1099         for my $num (@removed) {
1100                 my $idx = idx_shard($self, $num % $self->{shards});
1101                 $idx->shard_remove($oid, $num);
1102         }
1103 }
1104
1105 sub unindex_oid ($$;$) { # git->cat_async callback
1106         my ($bref, $oid, $type, $size, $sync) = @_;
1107         my $self = $sync->{v2w};
1108         my $unindexed = $sync->{in_unindex} ? $sync->{unindexed} : undef;
1109         my $mm = $self->{mm};
1110         my $mids = mids(PublicInbox::Eml->new($bref));
1111         undef $$bref;
1112         my $oidx = $self->{oidx};
1113         foreach my $mid (@$mids) {
1114                 my %gone;
1115                 my ($id, $prev);
1116                 while (my $smsg = $oidx->next_by_mid($mid, \$id, \$prev)) {
1117                         $gone{$smsg->{num}} = 1 if $oid eq $smsg->{blob};
1118                 }
1119                 my $n = scalar(keys(%gone)) or next;
1120                 if ($n > 1) {
1121                         warn "BUG: multiple articles linked to $oid\n",
1122                                 join(',',sort keys %gone), "\n";
1123                 }
1124                 foreach my $num (keys %gone) {
1125                         if ($unindexed) {
1126                                 my $mid0 = $mm->mid_for($num);
1127                                 $unindexed->{$mid0} = $num;
1128                         }
1129                         $mm->num_delete($num);
1130                 }
1131                 unindex_oid_remote($self, $oid, $mid);
1132         }
1133 }
1134
1135 sub git { $_[0]->{ibx}->git }
1136
1137 # this is rare, it only happens when we get discontiguous history in
1138 # a mirror because the source used -purge or -edit
1139 sub unindex ($$$$) {
1140         my ($self, $sync, $git, $unindex_range) = @_;
1141         my $unindexed = $sync->{unindexed} //= {}; # $mid0 => $num
1142         my $before = scalar keys %$unindexed;
1143         # order does not matter, here:
1144         my @cmd = qw(log --raw -r
1145                         --no-notes --no-color --no-abbrev --no-renames);
1146         my $fh = $git->popen(@cmd, $unindex_range);
1147         local $sync->{in_unindex} = 1;
1148         while (<$fh>) {
1149                 /\A:\d{6} 100644 $OID ($OID) [AM]\tm$/o or next;
1150                 $self->git->cat_async($1, \&unindex_oid, $sync);
1151         }
1152         close $fh or die "git log failed: \$?=$?";
1153         $self->git->cat_async_wait;
1154
1155         return unless $sync->{-opt}->{prune};
1156         my $after = scalar keys %$unindexed;
1157         return if $before == $after;
1158
1159         # ensure any blob can not longer be accessed via dumb HTTP
1160         PublicInbox::Import::run_die(['git', "--git-dir=$git->{git_dir}",
1161                 qw(-c gc.reflogExpire=now gc --prune=all --quiet)]);
1162 }
1163
1164 sub sync_ranges ($$$) {
1165         my ($self, $sync, $epoch_max) = @_;
1166         my $reindex = $sync->{reindex};
1167
1168         return last_commits($self, $epoch_max) unless $reindex;
1169         return [] if ref($reindex) ne 'HASH';
1170
1171         my $ranges = $reindex->{from}; # arrayref;
1172         if (ref($ranges) ne 'ARRAY') {
1173                 die 'BUG: $reindex->{from} not an ARRAY';
1174         }
1175         $ranges;
1176 }
1177
1178 sub index_xap_only { # git->cat_async callback
1179         my ($bref, $oid, $type, $size, $smsg) = @_;
1180         my $self = $smsg->{v2w};
1181         my $idx = idx_shard($self, $smsg->{num} % $self->{shards});
1182         $smsg->{raw_bytes} = $size;
1183         $idx->index_raw($bref, undef, $smsg);
1184         $self->{transact_bytes} += $size;
1185 }
1186
1187 sub index_xap_step ($$$;$) {
1188         my ($self, $sync, $beg, $step) = @_;
1189         my $end = $sync->{art_end};
1190         return if $beg > $end; # nothing to do
1191
1192         $step //= $self->{shards};
1193         my $ibx = $self->{ibx};
1194         if (my $pr = $sync->{-opt}->{-progress}) {
1195                 $pr->("Xapian indexlevel=$ibx->{indexlevel} ".
1196                         "$beg..$end (% $step)\n");
1197         }
1198         for (my $num = $beg; $num <= $end; $num += $step) {
1199                 my $smsg = $ibx->over->get_art($num) or next;
1200                 $smsg->{v2w} = $self;
1201                 $ibx->git->cat_async($smsg->{blob}, \&index_xap_only, $smsg);
1202                 if ($self->{transact_bytes} >= $self->{batch_bytes}) {
1203                         ${$sync->{nr}} = $num;
1204                         reindex_checkpoint($self, $sync);
1205                 }
1206         }
1207 }
1208
1209 sub index_epoch ($$$) {
1210         my ($self, $sync, $i) = @_;
1211
1212         my $git_dir = git_dir_n($self, $i);
1213         -d $git_dir or return; # missing epochs are fine
1214         my $git = PublicInbox::Git->new($git_dir);
1215         if (my $unindex_range = delete $sync->{unindex_range}->{$i}) { # rare
1216                 unindex($self, $sync, $git, $unindex_range);
1217         }
1218         defined(my $stk = $sync->{stacks}->[$i]) or return;
1219         $sync->{stacks}->[$i] = undef;
1220         my $all = $self->git;
1221         while (my ($f, $at, $ct, $oid) = $stk->pop_rec) {
1222                 $self->{current_info} = "$i.git $oid";
1223                 if ($f eq 'm') {
1224                         my $arg = { %$sync, autime => $at, cotime => $ct };
1225                         if ($sync->{max_size}) {
1226                                 $all->check_async($oid, \&check_size, $arg);
1227                         } else {
1228                                 $all->cat_async($oid, \&index_oid, $arg);
1229                         }
1230                 } elsif ($f eq 'd') {
1231                         $all->cat_async($oid, \&unindex_oid, $sync);
1232                 }
1233                 if (${$sync->{need_checkpoint}}) {
1234                         reindex_checkpoint($self, $sync);
1235                 }
1236         }
1237         $all->async_wait_all;
1238         $self->update_last_commit($git, $i, $stk->{latest_cmt});
1239 }
1240
1241 sub xapian_only {
1242         my ($self, $opt, $sync, $art_beg) = @_;
1243         my $seq = $opt->{sequential_shard};
1244         $art_beg //= 0;
1245         local $self->{parallel} = 0 if $seq;
1246         $self->idx_init($opt); # acquire lock
1247         if (my $art_end = $self->{ibx}->mm->max) {
1248                 $sync //= {
1249                         need_checkpoint => \(my $bool = 0),
1250                         -opt => $opt,
1251                         v2w => $self,
1252                         nr => \(my $nr = 0),
1253                         -regen_fmt => "%u/?\n",
1254                 };
1255                 $sync->{art_end} = $art_end;
1256                 if ($seq || !$self->{parallel}) {
1257                         my $shard_end = $self->{shards} - 1;
1258                         for my $i (0..$shard_end) {
1259                                 index_xap_step($self, $sync, $art_beg + $i);
1260                                 if ($i != $shard_end) {
1261                                         reindex_checkpoint($self, $sync);
1262                                 }
1263                         }
1264                 } else { # parallel (maybe)
1265                         index_xap_step($self, $sync, $art_beg, 1);
1266                 }
1267         }
1268         $self->git->cat_async_wait;
1269         $self->done;
1270 }
1271
1272 # public, called by public-inbox-index
1273 sub index_sync {
1274         my ($self, $opt) = @_;
1275         $opt //= {};
1276         return xapian_only($self, $opt) if $opt->{xapian_only};
1277
1278         my $pr = $opt->{-progress};
1279         my $epoch_max;
1280         my $latest = git_dir_latest($self, \$epoch_max);
1281         return unless defined $latest;
1282
1283         my $seq = $opt->{sequential_shard};
1284         my $art_beg; # the NNTP article number we start xapian_only at
1285         my $idxlevel = $self->{ibx}->{indexlevel};
1286         local $self->{ibx}->{indexlevel} = 'basic' if $seq;
1287
1288         $self->idx_init($opt); # acquire lock
1289         fill_alternates($self, $epoch_max);
1290         $self->{oidx}->rethread_prepare($opt);
1291         my $sync = {
1292                 need_checkpoint => \(my $bool = 0),
1293                 unindex_range => {}, # EPOCH => oid_old..oid_new
1294                 reindex => $opt->{reindex},
1295                 -opt => $opt,
1296                 v2w => $self,
1297         };
1298         $sync->{ranges} = sync_ranges($self, $sync, $epoch_max);
1299         if (sync_prepare($self, $sync, $epoch_max)) {
1300                 # tmp_clone seems to fail if inside a transaction, so
1301                 # we rollback here (because we opened {mm} for reading)
1302                 # Note: we do NOT rely on DBI transactions for atomicity;
1303                 # only for batch performance.
1304                 $self->{mm}->{dbh}->rollback;
1305                 $self->{mm}->{dbh}->begin_work;
1306                 $sync->{mm_tmp} =
1307                         $self->{mm}->tmp_clone($self->{ibx}->{inboxdir});
1308
1309                 # xapian_only works incrementally w/o --reindex
1310                 if ($seq && !$opt->{reindex}) {
1311                         $art_beg = $sync->{mm_tmp}->max;
1312                         $art_beg++ if defined($art_beg);
1313                 }
1314         }
1315         if ($sync->{max_size} = $opt->{max_size}) {
1316                 $sync->{index_oid} = \&index_oid;
1317         }
1318         # work forwards through history
1319         index_epoch($self, $sync, $_) for (0..$epoch_max);
1320         $self->{oidx}->rethread_done($opt);
1321         $self->done;
1322
1323         if (my $nr = $sync->{nr}) {
1324                 my $pr = $sync->{-opt}->{-progress};
1325                 $pr->('all.git '.sprintf($sync->{-regen_fmt}, $$nr)) if $pr;
1326         }
1327
1328         # deal with Xapian shards sequentially
1329         if ($seq && delete($sync->{mm_tmp})) {
1330                 $self->{ibx}->{indexlevel} = $idxlevel;
1331                 xapian_only($self, $opt, $sync, $art_beg);
1332         }
1333
1334         # --reindex on the command-line
1335         if ($opt->{reindex} && !ref($opt->{reindex}) && $idxlevel ne 'basic') {
1336                 $self->lock_acquire;
1337                 my $s0 = PublicInbox::SearchIdx->new($self->{ibx}, 0, 0);
1338                 if (my $xdb = $s0->idx_acquire) {
1339                         my $n = $xdb->get_metadata('has_threadid');
1340                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
1341                 }
1342                 $s0->idx_release;
1343                 $self->lock_release;
1344         }
1345
1346         # reindex does not pick up new changes, so we rerun w/o it:
1347         if ($opt->{reindex}) {
1348                 my %again = %$opt;
1349                 $sync = undef;
1350                 delete @again{qw(rethread reindex -skip_lock)};
1351                 index_sync($self, \%again);
1352         }
1353 }
1354
1355 1;