lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 package PublicInbox::V2Writable;
   6 use strict;
   7 use warnings;
   8 use Fcntl qw(:flock :DEFAULT);
   9 use PublicInbox::SearchIdxPart;
  10 use PublicInbox::SearchIdxThread;
  11 use PublicInbox::MIME;
  12 use PublicInbox::Git;
  13 use PublicInbox::Import;
  14 use Email::MIME::ContentType;
  15 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  16
  17 # an estimate of the post-packed size to the raw uncompressed size
  18 my $PACKING_FACTOR = 0.4;
  19
  20 # assume 2 cores if GNU nproc(1) is not available
  21 my $NPROC = int($ENV{NPROC} || `nproc 2>/dev/null` || 2);
  22
  23 sub new {
  24         my ($class, $v2ibx, $creat) = @_;
  25         my $dir = $v2ibx->{mainrepo} or die "no mainrepo in inbox\n";
  26         unless (-d $dir) {
  27                 if ($creat) {
  28                         require File::Path;
  29                         File::Path::mkpath($dir);
  30                 } else {
  31                         die "$dir does not exist\n";
  32                 }
  33         }
  34         my $self = {
  35                 -inbox => $v2ibx,
  36                 im => undef, #  PublicInbox::Import
  37                 xap_rw => undef, # PublicInbox::V2SearchIdx
  38                 xap_ro => undef,
  39                 partitions => $NPROC,
  40                 transact_bytes => 0,
  41                 # limit each repo to 1GB or so
  42                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
  43         };
  44         bless $self, $class
  45 }
  46
  47 # returns undef on duplicate or spam
  48 # mimics Import::add and wraps it for v2
  49 sub add {
  50         my ($self, $mime, $check_cb) = @_;
  51         my $existing = $self->lookup_content($mime);
  52
  53         if ($existing) {
  54                 return undef if $existing->type eq 'mail'; # duplicate
  55         }
  56
  57         my $im = $self->importer;
  58
  59         # im->add returns undef if check_cb fails
  60         my $cmt = $im->add($mime, $check_cb) or return;
  61         $cmt = $im->get_mark($cmt);
  62         my $oid = $im->{last_object_id};
  63         my ($len, $msgref) = @{$im->{last_object}};
  64
  65         $self->idx_init;
  66         my $num = $self->{all}->index_mm($mime, 1);
  67         my $nparts = $self->{partitions};
  68         my $part = $num % $nparts;
  69         my $idx = $self->idx_part($part);
  70         $idx->index_raw($len, $msgref, $num, $oid);
  71         my $n = $self->{transact_bytes} += $len;
  72         if ($n > (PublicInbox::SearchIdx::BATCH_BYTES * $nparts)) {
  73                 $self->checkpoint;
  74         }
  75
  76         $mime;
  77 }
  78
  79 sub idx_part {
  80         my ($self, $part) = @_;
  81         $self->{idx_parts}->[$part];
  82 }
  83
  84 sub idx_init {
  85         my ($self) = @_;
  86         return if $self->{idx_parts};
  87
  88         # first time initialization, first we create the threader pipe:
  89         my $all = $self->{all} = PublicInbox::SearchIdxThread->new($self);
  90
  91         # need to create all parts before initializing msgmap FD
  92         my $max = $self->{partitions} - 1;
  93         my $idx = $self->{idx_parts} = [];
  94         for my $i (0..$max) {
  95                 push @$idx, PublicInbox::SearchIdxPart->new($self, $i, $all);
  96         }
  97
  98         # Now that all subprocesses are up, we can open the FD for SQLite:
  99         $all->_msgmap_init->{dbh}->begin_work;
 100 }
 101
 102 sub remove {
 103         my ($self, $mime, $msg) = @_;
 104         my $existing = $self->lookup_content($mime) or return;
 105
 106         # don't touch ghosts or already junked messages
 107         return unless $existing->type eq 'mail';
 108
 109         # always write removals to the current (latest) git repo since
 110         # we process chronologically
 111         my $im = $self->importer;
 112         my ($cmt, undef) = $im->remove($mime, $msg);
 113         $cmt = $im->get_mark($cmt);
 114         $self->unindex_msg($existing, $cmt);
 115 }
 116
 117 sub done {
 118         my ($self) = @_;
 119         my $im = $self->{im};
 120         $im->done if $im; # PublicInbox::Import::done
 121         $self->searchidx_checkpoint(0);
 122 }
 123
 124 sub checkpoint {
 125         my ($self) = @_;
 126         my $im = $self->{im};
 127         $im->checkpoint if $im; # PublicInbox::Import::checkpoint
 128         $self->searchidx_checkpoint(1);
 129 }
 130
 131 sub searchidx_checkpoint {
 132         my ($self, $more) = @_;
 133
 134         # order matters, we can only close {all} after all partitions
 135         # are done because the partitions also write to {all}
 136
 137         if (my $parts = $self->{idx_parts}) {
 138                 foreach my $idx (@$parts) {
 139                         $idx->remote_commit;
 140                         $idx->remote_close unless $more;
 141                 }
 142                 delete $self->{idx_parts} unless $more;
 143         }
 144
 145         if (my $all = $self->{all}) {
 146                 $all->{mm}->{dbh}->commit;
 147                 if ($more) {
 148                         $all->{mm}->{dbh}->begin_work;
 149                 }
 150                 $all->remote_commit;
 151                 $all->remote_close unless $more;
 152                 delete $self->{all} unless $more;
 153         }
 154         $self->{transact_bytes} = 0;
 155 }
 156
 157 sub git_init {
 158         my ($self, $new) = @_;
 159         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 160         my $git_dir = "$pfx/$new.git";
 161         die "$git_dir exists\n" if -e $git_dir;
 162         my @cmd = (qw(git init --bare -q), $git_dir);
 163         PublicInbox::Import::run_die(\@cmd);
 164         @cmd = (qw/git config/, "--file=$git_dir/config",
 165                         'repack.writeBitmaps', 'true');
 166         PublicInbox::Import::run_die(\@cmd);
 167
 168         my $all = "$self->{-inbox}->{mainrepo}/all.git";
 169         unless (-d $all) {
 170                 @cmd = (qw(git init --bare -q), $all);
 171                 PublicInbox::Import::run_die(\@cmd);
 172         }
 173
 174         my $alt = "$all/objects/info/alternates";
 175         my $new_obj_dir = "../../git/$new.git/objects";
 176         my %alts;
 177         if (-e $alt) {
 178                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 179                 %alts = map { chomp; $_ => 1 } (<$fh>);
 180         }
 181         return $git_dir if $alts{$new_obj_dir};
 182         open my $fh, '>>', $alt or die "open >> $alt: $!\n";
 183         print $fh "$new_obj_dir\n" or die "print >> $alt: $!\n";
 184         close $fh or die "close $alt: $!\n";
 185         $git_dir
 186 }
 187
 188 sub importer {
 189         my ($self) = @_;
 190         my $im = $self->{im};
 191         if ($im) {
 192                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 193                         return $im;
 194                 } else {
 195                         $self->{im} = undef;
 196                         $im->done;
 197                         $self->searchidx_checkpoint(1);
 198                         $im = undef;
 199                         my $git_dir = $self->git_init(++$self->{max_git});
 200                         my $git = PublicInbox::Git->new($git_dir);
 201                         return $self->import_init($git, 0);
 202                 }
 203         }
 204         my $latest;
 205         my $max = -1;
 206         my $new = 0;
 207         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 208         if (-d $pfx) {
 209                 foreach my $git_dir (glob("$pfx/*.git")) {
 210                         $git_dir =~ m!/(\d+)\.git\z! or next;
 211                         my $n = $1;
 212                         if ($n > $max) {
 213                                 $max = $n;
 214                                 $latest = $git_dir;
 215                         }
 216                 }
 217         }
 218         if (defined $latest) {
 219                 my $git = PublicInbox::Git->new($latest);
 220                 my $packed_bytes = $git->packed_bytes;
 221                 if ($packed_bytes >= $self->{rotate_bytes}) {
 222                         $new = $max + 1;
 223                 } else {
 224                         $self->{max_git} = $max;
 225                         return $self->import_init($git, $packed_bytes);
 226                 }
 227         }
 228         $self->{max_git} = $new;
 229         $latest = $self->git_init($new);
 230         $self->import_init(PublicInbox::Git->new($latest), 0);
 231 }
 232
 233 sub import_init {
 234         my ($self, $git, $packed_bytes) = @_;
 235         my $im = PublicInbox::Import->new($git, undef, undef, $self->{-inbox});
 236         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 237         $im->{want_object_id} = 1;
 238         $im->{ssoma_lock} = 0;
 239         $im->{path_type} = 'v2';
 240         $self->{im} = $im;
 241 }
 242
 243 sub lookup_content {
 244         undef # TODO
 245 }
 246
 247 sub atfork_child {
 248         my ($self) = @_;
 249         if (my $parts = $self->{idx_parts}) {
 250                 $_->atfork_child foreach @$parts;
 251         }
 252         if (my $im = $self->{im}) {
 253                 $im->atfork_child;
 254         }
 255 }
 256
 257 1;