lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 # Used to write to V2 inboxes (see L<public-inbox-v2-format(5)>).
   6 package PublicInbox::V2Writable;
   7 use strict;
   8 use warnings;
   9 use base qw(PublicInbox::Lock);
  10 use PublicInbox::SearchIdxPart;
  11 use PublicInbox::MIME;
  12 use PublicInbox::Git;
  13 use PublicInbox::Import;
  14 use PublicInbox::MID qw(mids);
  15 use PublicInbox::ContentId qw(content_id content_digest);
  16 use PublicInbox::Inbox;
  17 use PublicInbox::OverIdx;
  18 use PublicInbox::Msgmap;
  19 use PublicInbox::Spawn qw(spawn);
  20 use PublicInbox::SearchIdx;
  21 use IO::Handle;
  22
  23 # an estimate of the post-packed size to the raw uncompressed size
  24 my $PACKING_FACTOR = 0.4;
  25
  26 # assume 2 cores if GNU nproc(1) is not available
  27 sub nproc_parts () {
  28         my $n = int($ENV{NPROC} || `nproc 2>/dev/null` || 2);
  29         # subtract for the main process and git-fast-import
  30         $n -= 1;
  31         $n < 1 ? 1 : $n;
  32 }
  33
  34 sub count_partitions ($) {
  35         my ($self) = @_;
  36         my $nparts = 0;
  37         my $xpfx = $self->{xpfx};
  38
  39         # always load existing partitions in case core count changes:
  40         # Also, partition count may change while -watch is running
  41         # due to -compact
  42         if (-d $xpfx) {
  43                 foreach my $part (<$xpfx/*>) {
  44                         -d $part && $part =~ m!/\d+\z! or next;
  45                         eval {
  46                                 Search::Xapian::Database->new($part)->close;
  47                                 $nparts++;
  48                         };
  49                 }
  50         }
  51         $nparts;
  52 }
  53
  54 sub new {
  55         my ($class, $v2ibx, $creat) = @_;
  56         my $dir = $v2ibx->{mainrepo} or die "no mainrepo in inbox\n";
  57         unless (-d $dir) {
  58                 if ($creat) {
  59                         require File::Path;
  60                         File::Path::mkpath($dir);
  61                 } else {
  62                         die "$dir does not exist\n";
  63                 }
  64         }
  65
  66         $v2ibx = PublicInbox::InboxWritable->new($v2ibx);
  67         $v2ibx->umask_prepare;
  68
  69         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
  70         my $self = {
  71                 -inbox => $v2ibx,
  72                 im => undef, #  PublicInbox::Import
  73                 parallel => 1,
  74                 transact_bytes => 0,
  75                 xpfx => $xpfx,
  76                 over => PublicInbox::OverIdx->new("$xpfx/over.sqlite3", 1),
  77                 lock_path => "$dir/inbox.lock",
  78                 # limit each git repo (epoch) to 1GB or so
  79                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
  80                 last_commit => [], # git repo -> commit
  81         };
  82         $self->{partitions} = count_partitions($self) || nproc_parts();
  83         bless $self, $class;
  84 }
  85
  86 sub init_inbox {
  87         my ($self, $parallel, $skip) = @_;
  88         $self->{parallel} = $parallel;
  89         $self->idx_init;
  90         my $epoch_max = -1;
  91         git_dir_latest($self, \$epoch_max);
  92         if (defined $skip && $epoch_max == -1) {
  93                 $epoch_max = $skip;
  94         }
  95         $self->git_init($epoch_max >= 0 ? $epoch_max : 0);
  96         $self->done;
  97 }
  98
  99 # returns undef on duplicate or spam
 100 # mimics Import::add and wraps it for v2
 101 sub add {
 102         my ($self, $mime, $check_cb) = @_;
 103         $self->{-inbox}->with_umask(sub {
 104                 _add($self, $mime, $check_cb)
 105         });
 106 }
 107
 108 sub _add {
 109         my ($self, $mime, $check_cb) = @_;
 110
 111         # spam check:
 112         if ($check_cb) {
 113                 $mime = $check_cb->($mime) or return;
 114         }
 115
 116         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
 117         # as does SQLite 3.4.1+ (released in 2007-07-20), and
 118         # Xapian 1.3.2+ (released 2015-03-15).
 119         # For the most part, we can spawn git-fast-import without
 120         # leaking FDs to it...
 121         $self->idx_init;
 122
 123         my $mid0;
 124         my $num = num_for($self, $mime, \$mid0);
 125         defined $num or return; # duplicate
 126         defined $mid0 or die "BUG: $mid0 undefined\n";
 127         my $im = $self->importer;
 128         my $cmt = $im->add($mime);
 129         $cmt = $im->get_mark($cmt);
 130         $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 131
 132         my ($oid, $len, $msgref) = @{$im->{last_object}};
 133         $self->{over}->add_overview($mime, $len, $num, $oid, $mid0);
 134         my $nparts = $self->{partitions};
 135         my $part = $num % $nparts;
 136         my $idx = $self->idx_part($part);
 137         $idx->index_raw($len, $msgref, $num, $oid, $mid0, $mime);
 138         my $n = $self->{transact_bytes} += $len;
 139         if ($n > (PublicInbox::SearchIdx::BATCH_BYTES * $nparts)) {
 140                 $self->checkpoint;
 141         }
 142
 143         $cmt;
 144 }
 145
 146 sub num_for {
 147         my ($self, $mime, $mid0) = @_;
 148         my $mids = mids($mime->header_obj);
 149         if (@$mids) {
 150                 my $mid = $mids->[0];
 151                 my $num = $self->{mm}->mid_insert($mid);
 152                 if (defined $num) { # common case
 153                         $$mid0 = $mid;
 154                         return $num;
 155                 };
 156
 157                 # crap, Message-ID is already known, hope somebody just resent:
 158                 foreach my $m (@$mids) {
 159                         # read-only lookup now safe to do after above barrier
 160                         my $existing = $self->lookup_content($mime, $m);
 161                         # easy, don't store duplicates
 162                         # note: do not add more diagnostic info here since
 163                         # it gets noisy on public-inbox-watch restarts
 164                         return if $existing;
 165                 }
 166
 167                 # AltId may pre-populate article numbers (e.g. X-Mail-Count
 168                 # or NNTP article number), use that article number if it's
 169                 # not in Over.
 170                 my $altid = $self->{-inbox}->{altid};
 171                 if ($altid && grep(/:file=msgmap\.sqlite3\z/, @$altid)) {
 172                         my $num = $self->{mm}->num_for($mid);
 173
 174                         if (defined $num && !$self->{over}->get_art($num)) {
 175                                 $$mid0 = $mid;
 176                                 return $num;
 177                         }
 178                 }
 179
 180                 # very unlikely:
 181                 warn "<$mid> reused for mismatched content\n";
 182
 183                 # try the rest of the mids
 184                 for(my $i = $#$mids; $i >= 1; $i--) {
 185                         my $m = $mids->[$i];
 186                         $num = $self->{mm}->mid_insert($m);
 187                         if (defined $num) {
 188                                 warn "alternative <$m> for <$mid> found\n";
 189                                 $$mid0 = $m;
 190                                 return $num;
 191                         }
 192                 }
 193         }
 194         # none of the existing Message-IDs are good, generate a new one:
 195         num_for_harder($self, $mime, $mid0);
 196 }
 197
 198 sub num_for_harder {
 199         my ($self, $mime, $mid0) = @_;
 200
 201         my $hdr = $mime->header_obj;
 202         my $dig = content_digest($mime);
 203         $$mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 204         my $num = $self->{mm}->mid_insert($$mid0);
 205         unless (defined $num) {
 206                 # it's hard to spoof the last Received: header
 207                 my @recvd = $hdr->header_raw('Received');
 208                 $dig->add("Received: $_") foreach (@recvd);
 209                 $$mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 210                 $num = $self->{mm}->mid_insert($$mid0);
 211
 212                 # fall back to a random Message-ID and give up determinism:
 213                 until (defined($num)) {
 214                         $dig->add(rand);
 215                         $$mid0 = PublicInbox::Import::digest2mid($dig, $hdr);
 216                         warn "using random Message-ID <$$mid0> as fallback\n";
 217                         $num = $self->{mm}->mid_insert($$mid0);
 218                 }
 219         }
 220         PublicInbox::Import::append_mid($hdr, $$mid0);
 221         $num;
 222 }
 223
 224 sub idx_part {
 225         my ($self, $part) = @_;
 226         $self->{idx_parts}->[$part];
 227 }
 228
 229 # idempotent
 230 sub idx_init {
 231         my ($self) = @_;
 232         return if $self->{idx_parts};
 233         my $ibx = $self->{-inbox};
 234
 235         # do not leak read-only FDs to child processes, we only have these
 236         # FDs for duplicate detection so they should not be
 237         # frequently activated.
 238         delete $ibx->{$_} foreach (qw(git mm search));
 239
 240         my $indexlevel = $ibx->{indexlevel};
 241         if ($indexlevel && $indexlevel eq 'basic') {
 242                 $self->{parallel} = 0;
 243         }
 244
 245         if ($self->{parallel}) {
 246                 pipe(my ($r, $w)) or die "pipe failed: $!";
 247                 # pipe for barrier notifications doesn't need to be big,
 248                 # 1031: F_SETPIPE_SZ
 249                 fcntl($w, 1031, 4096) if $^O eq 'linux';
 250                 $self->{bnote} = [ $r, $w ];
 251                 $w->autoflush(1);
 252         }
 253
 254         my $over = $self->{over};
 255         $ibx->umask_prepare;
 256         $ibx->with_umask(sub {
 257                 $self->lock_acquire;
 258                 $over->create;
 259
 260                 # -compact can change partition count while -watch is idle
 261                 my $nparts = count_partitions($self);
 262                 if ($nparts && $nparts != $self->{partitions}) {
 263                         $self->{partitions} = $nparts;
 264                 }
 265
 266                 # need to create all parts before initializing msgmap FD
 267                 my $max = $self->{partitions} - 1;
 268
 269                 # idx_parts must be visible to all forked processes
 270                 my $idx = $self->{idx_parts} = [];
 271                 for my $i (0..$max) {
 272                         push @$idx, PublicInbox::SearchIdxPart->new($self, $i);
 273                 }
 274
 275                 # Now that all subprocesses are up, we can open the FDs
 276                 # for SQLite:
 277                 my $mm = $self->{mm} = PublicInbox::Msgmap->new_file(
 278                         "$self->{-inbox}->{mainrepo}/msgmap.sqlite3", 1);
 279                 $mm->{dbh}->begin_work;
 280         });
 281 }
 282
 283 sub purge_oids {
 284         my ($self, $purge) = @_; # $purge = { $object_id => 1, ... }
 285         $self->done;
 286         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 287         my $purges = [];
 288         foreach my $i (0..$self->{epoch_max}) {
 289                 my $git = PublicInbox::Git->new("$pfx/$i.git");
 290                 my $im = $self->import_init($git, 0, 1);
 291                 $purges->[$i] = $im->purge_oids($purge);
 292         }
 293         $purges;
 294 }
 295
 296 sub content_ids ($) {
 297         my ($mime) = @_;
 298         my @cids = ( content_id($mime) );
 299
 300         # Email::MIME->as_string doesn't always round-trip, so we may
 301         # use a second content_id
 302         my $rt = content_id(PublicInbox::MIME->new(\($mime->as_string)));
 303         push @cids, $rt if $cids[0] ne $rt;
 304         \@cids;
 305 }
 306
 307 sub content_matches ($$) {
 308         my ($cids, $existing) = @_;
 309         my $cid = content_id($existing);
 310         foreach (@$cids) {
 311                 return 1 if $_ eq $cid
 312         }
 313         0
 314 }
 315
 316 sub remove_internal {
 317         my ($self, $mime, $cmt_msg, $purge) = @_;
 318         $self->idx_init;
 319         my $im = $self->importer unless $purge;
 320         my $over = $self->{over};
 321         my $cids = content_ids($mime);
 322         my $parts = $self->{idx_parts};
 323         my $mm = $self->{mm};
 324         my $removed;
 325         my $mids = mids($mime->header_obj);
 326
 327         # We avoid introducing new blobs into git since the raw content
 328         # can be slightly different, so we do not need the user-supplied
 329         # message now that we have the mids and content_id
 330         $mime = undef;
 331         my $mark;
 332
 333         foreach my $mid (@$mids) {
 334                 my %gone;
 335                 my ($id, $prev);
 336                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 337                         my $msg = get_blob($self, $smsg);
 338                         if (!defined($msg)) {
 339                                 warn "broken smsg for $mid\n";
 340                                 next; # continue
 341                         }
 342                         my $orig = $$msg;
 343                         my $cur = PublicInbox::MIME->new($msg);
 344                         if (content_matches($cids, $cur)) {
 345                                 $smsg->{mime} = $cur;
 346                                 $gone{$smsg->{num}} = [ $smsg, \$orig ];
 347                         }
 348                 }
 349                 my $n = scalar keys %gone;
 350                 next unless $n;
 351                 if ($n > 1) {
 352                         warn "BUG: multiple articles linked to <$mid>\n",
 353                                 join(',', sort keys %gone), "\n";
 354                 }
 355                 foreach my $num (keys %gone) {
 356                         my ($smsg, $orig) = @{$gone{$num}};
 357                         $mm->num_delete($num);
 358                         # $removed should only be set once assuming
 359                         # no bugs in our deduplication code:
 360                         $removed = $smsg;
 361                         my $oid = $smsg->{blob};
 362                         if ($purge) {
 363                                 $purge->{$oid} = 1;
 364                         } else {
 365                                 ($mark, undef) = $im->remove($orig, $cmt_msg);
 366                         }
 367                         $orig = undef;
 368                         $self->unindex_oid_remote($oid, $mid);
 369                 }
 370         }
 371
 372         if (defined $mark) {
 373                 my $cmt = $im->get_mark($mark);
 374                 $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 375         }
 376         if ($purge && scalar keys %$purge) {
 377                 return purge_oids($self, $purge);
 378         }
 379         $removed;
 380 }
 381
 382 sub remove {
 383         my ($self, $mime, $cmt_msg) = @_;
 384         $self->{-inbox}->with_umask(sub {
 385                 remove_internal($self, $mime, $cmt_msg);
 386         });
 387 }
 388
 389 sub purge {
 390         my ($self, $mime) = @_;
 391         my $purges = $self->{-inbox}->with_umask(sub {
 392                 remove_internal($self, $mime, undef, {});
 393         });
 394         $self->idx_init if @$purges; # ->done is called on purges
 395         for my $i (0..$#$purges) {
 396                 defined(my $cmt = $purges->[$i]) or next;
 397                 $self->{last_commit}->[$i] = $cmt;
 398         }
 399         $purges;
 400 }
 401
 402 sub last_commit_part ($$;$) {
 403         my ($self, $i, $cmt) = @_;
 404         my $v = PublicInbox::Search::SCHEMA_VERSION();
 405         $self->{mm}->last_commit_xap($v, $i, $cmt);
 406 }
 407
 408 sub set_last_commits ($) {
 409         my ($self) = @_;
 410         defined(my $epoch_max = $self->{epoch_max}) or return;
 411         my $last_commit = $self->{last_commit};
 412         foreach my $i (0..$epoch_max) {
 413                 defined(my $cmt = $last_commit->[$i]) or next;
 414                 $last_commit->[$i] = undef;
 415                 last_commit_part($self, $i, $cmt);
 416         }
 417 }
 418
 419 sub barrier_init {
 420         my ($self, $n) = @_;
 421         $self->{bnote} or return;
 422         --$n;
 423         my $barrier = { map { $_ => 1 } (0..$n) };
 424 }
 425
 426 sub barrier_wait {
 427         my ($self, $barrier) = @_;
 428         my $bnote = $self->{bnote} or return;
 429         my $r = $bnote->[0];
 430         while (scalar keys %$barrier) {
 431                 defined(my $l = $r->getline) or die "EOF on barrier_wait: $!";
 432                 $l =~ /\Abarrier (\d+)/ or die "bad line on barrier_wait: $l";
 433                 delete $barrier->{$1} or die "bad part[$1] on barrier wait";
 434         }
 435 }
 436
 437 sub checkpoint ($;$) {
 438         my ($self, $wait) = @_;
 439
 440         if (my $im = $self->{im}) {
 441                 if ($wait) {
 442                         $im->barrier;
 443                 } else {
 444                         $im->checkpoint;
 445                 }
 446         }
 447         my $parts = $self->{idx_parts};
 448         if ($parts) {
 449                 my $dbh = $self->{mm}->{dbh};
 450
 451                 # SQLite msgmap data is second in importance
 452                 $dbh->commit;
 453
 454                 # SQLite overview is third
 455                 $self->{over}->commit_lazy;
 456
 457                 # Now deal with Xapian
 458                 if ($wait) {
 459                         my $barrier = $self->barrier_init(scalar @$parts);
 460
 461                         # each partition needs to issue a barrier command
 462                         $_->remote_barrier for @$parts;
 463
 464                         # wait for each Xapian partition
 465                         $self->barrier_wait($barrier);
 466                 } else {
 467                         $_->remote_commit for @$parts;
 468                 }
 469
 470                 # last_commit is special, don't commit these until
 471                 # remote partitions are done:
 472                 $dbh->begin_work;
 473                 set_last_commits($self);
 474                 $dbh->commit;
 475
 476                 $dbh->begin_work;
 477         }
 478         $self->{transact_bytes} = 0;
 479 }
 480
 481 # issue a write barrier to ensure all data is visible to other processes
 482 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 483 sub barrier { checkpoint($_[0], 1) };
 484
 485 sub done {
 486         my ($self) = @_;
 487         my $im = delete $self->{im};
 488         $im->done if $im; # PublicInbox::Import::done
 489         checkpoint($self);
 490         my $mm = delete $self->{mm};
 491         $mm->{dbh}->commit if $mm;
 492         my $parts = delete $self->{idx_parts};
 493         if ($parts) {
 494                 $_->remote_close for @$parts;
 495         }
 496         $self->{over}->disconnect;
 497         delete $self->{bnote};
 498         $self->{transact_bytes} = 0;
 499         $self->lock_release if $parts;
 500 }
 501
 502 sub git_init {
 503         my ($self, $epoch) = @_;
 504         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 505         my $git_dir = "$pfx/$epoch.git";
 506         my @cmd = (qw(git init --bare -q), $git_dir);
 507         PublicInbox::Import::run_die(\@cmd);
 508
 509         my $all = "$self->{-inbox}->{mainrepo}/all.git";
 510         unless (-d $all) {
 511                 @cmd = (qw(git init --bare -q), $all);
 512                 PublicInbox::Import::run_die(\@cmd);
 513                 @cmd = (qw/git config/, "--file=$all/config",
 514                                 'repack.writeBitmaps', 'true');
 515                 PublicInbox::Import::run_die(\@cmd);
 516         }
 517
 518         @cmd = (qw/git config/, "--file=$git_dir/config",
 519                         'include.path', '../../all.git/config');
 520         PublicInbox::Import::run_die(\@cmd);
 521
 522         my $alt = "$all/objects/info/alternates";
 523         my %alts;
 524         my @add;
 525         if (-e $alt) {
 526                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 527                 %alts = map { chomp; $_ => 1 } (<$fh>);
 528         }
 529         foreach my $i (0..$epoch) {
 530                 my $dir = "../../git/$i.git/objects";
 531                 push @add, $dir if !$alts{$dir} && -d "$pfx/$i.git";
 532         }
 533         return $git_dir unless @add;
 534         open my $fh, '>>', $alt or die "open >> $alt: $!\n";
 535         foreach my $dir (@add) {
 536                 print $fh "$dir\n" or die "print >> $alt: $!\n";
 537         }
 538         close $fh or die "close $alt: $!\n";
 539         $git_dir
 540 }
 541
 542 sub git_dir_latest {
 543         my ($self, $max) = @_;
 544         $$max = -1;
 545         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 546         return unless -d $pfx;
 547         my $latest;
 548         opendir my $dh, $pfx or die "opendir $pfx: $!\n";
 549         while (defined(my $git_dir = readdir($dh))) {
 550                 $git_dir =~ m!\A(\d+)\.git\z! or next;
 551                 if ($1 > $$max) {
 552                         $$max = $1;
 553                         $latest = "$pfx/$git_dir";
 554                 }
 555         }
 556         $latest;
 557 }
 558
 559 sub importer {
 560         my ($self) = @_;
 561         my $im = $self->{im};
 562         if ($im) {
 563                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 564                         return $im;
 565                 } else {
 566                         $self->{im} = undef;
 567                         $im->done;
 568                         $im = undef;
 569                         $self->checkpoint;
 570                         my $git_dir = $self->git_init(++$self->{epoch_max});
 571                         my $git = PublicInbox::Git->new($git_dir);
 572                         return $self->import_init($git, 0);
 573                 }
 574         }
 575         my $epoch = 0;
 576         my $max;
 577         my $latest = git_dir_latest($self, \$max);
 578         if (defined $latest) {
 579                 my $git = PublicInbox::Git->new($latest);
 580                 my $packed_bytes = $git->packed_bytes;
 581                 if ($packed_bytes >= $self->{rotate_bytes}) {
 582                         $epoch = $max + 1;
 583                 } else {
 584                         $self->{epoch_max} = $max;
 585                         return $self->import_init($git, $packed_bytes);
 586                 }
 587         }
 588         $self->{epoch_max} = $epoch;
 589         $latest = $self->git_init($epoch);
 590         $self->import_init(PublicInbox::Git->new($latest), 0);
 591 }
 592
 593 sub import_init {
 594         my ($self, $git, $packed_bytes, $tmp) = @_;
 595         my $im = PublicInbox::Import->new($git, undef, undef, $self->{-inbox});
 596         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 597         $im->{want_object_info} = 1;
 598         $im->{lock_path} = undef;
 599         $im->{path_type} = 'v2';
 600         $self->{im} = $im unless $tmp;
 601         $im;
 602 }
 603
 604 # XXX experimental
 605 sub diff ($$$) {
 606         my ($mid, $cur, $new) = @_;
 607         use File::Temp qw(tempfile);
 608
 609         my ($ah, $an) = tempfile('email-cur-XXXXXXXX', TMPDIR => 1);
 610         print $ah $cur->as_string or die "print: $!";
 611         close $ah or die "close: $!";
 612         my ($bh, $bn) = tempfile('email-new-XXXXXXXX', TMPDIR => 1);
 613         PublicInbox::Import::drop_unwanted_headers($new);
 614         print $bh $new->as_string or die "print: $!";
 615         close $bh or die "close: $!";
 616         my $cmd = [ qw(diff -u), $an, $bn ];
 617         print STDERR "# MID conflict <$mid>\n";
 618         my $pid = spawn($cmd, undef, { 1 => 2 });
 619         defined $pid or die "diff failed to spawn $!";
 620         waitpid($pid, 0) == $pid or die "diff did not finish";
 621         unlink($an, $bn);
 622 }
 623
 624 sub get_blob ($$) {
 625         my ($self, $smsg) = @_;
 626         if (my $im = $self->{im}) {
 627                 my $msg = $im->cat_blob($smsg->{blob});
 628                 return $msg if $msg;
 629         }
 630         # older message, should be in alternates
 631         my $ibx = $self->{-inbox};
 632         $ibx->msg_by_smsg($smsg);
 633 }
 634
 635 sub lookup_content {
 636         my ($self, $mime, $mid) = @_;
 637         my $over = $self->{over};
 638         my $cids = content_ids($mime);
 639         my ($id, $prev);
 640         while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 641                 my $msg = get_blob($self, $smsg);
 642                 if (!defined($msg)) {
 643                         warn "broken smsg for $mid\n";
 644                         next;
 645                 }
 646                 my $cur = PublicInbox::MIME->new($msg);
 647                 if (content_matches($cids, $cur)) {
 648                         $smsg->{mime} = $cur;
 649                         return $smsg;
 650                 }
 651
 652
 653                 # XXX DEBUG_DIFF is experimental and may be removed
 654                 diff($mid, $cur, $mime) if $ENV{DEBUG_DIFF};
 655         }
 656         undef;
 657 }
 658
 659 sub atfork_child {
 660         my ($self) = @_;
 661         my $fh = delete $self->{reindex_pipe};
 662         close $fh if $fh;
 663         if (my $parts = $self->{idx_parts}) {
 664                 $_->atfork_child foreach @$parts;
 665         }
 666         if (my $im = $self->{im}) {
 667                 $im->atfork_child;
 668         }
 669         die "unexpected mm" if $self->{mm};
 670         close $self->{bnote}->[0] or die "close bnote[0]: $!\n";
 671         $self->{bnote}->[1];
 672 }
 673
 674 sub mark_deleted {
 675         my ($self, $D, $git, $oid) = @_;
 676         my $msgref = $git->cat_file($oid);
 677         my $mime = PublicInbox::MIME->new($$msgref);
 678         my $mids = mids($mime->header_obj);
 679         my $cid = content_id($mime);
 680         foreach my $mid (@$mids) {
 681                 $D->{"$mid\0$cid"} = $oid;
 682         }
 683 }
 684
 685 sub reindex_oid {
 686         my ($self, $mm_tmp, $D, $git, $oid, $regen, $reindex) = @_;
 687         my $len;
 688         my $msgref = $git->cat_file($oid, \$len);
 689         my $mime = PublicInbox::MIME->new($$msgref);
 690         my $mids = mids($mime->header_obj);
 691         my $cid = content_id($mime);
 692
 693         # get the NNTP article number we used before, highest number wins
 694         # and gets deleted from mm_tmp;
 695         my $mid0;
 696         my $num = -1;
 697         my $del = 0;
 698         foreach my $mid (@$mids) {
 699                 $del += delete($D->{"$mid\0$cid"}) ? 1 : 0;
 700                 my $n = $mm_tmp->num_for($mid);
 701                 if (defined $n && $n > $num) {
 702                         $mid0 = $mid;
 703                         $num = $n;
 704                         $self->{mm}->mid_set($num, $mid0);
 705                 }
 706         }
 707         if (!defined($mid0) && $regen && !$del) {
 708                 $num = $$regen--;
 709                 die "BUG: ran out of article numbers\n" if $num <= 0;
 710                 my $mm = $self->{mm};
 711                 foreach my $mid (reverse @$mids) {
 712                         if ($mm->mid_set($num, $mid) == 1) {
 713                                 $mid0 = $mid;
 714                                 last;
 715                         }
 716                 }
 717                 if (!defined($mid0)) {
 718                         my $id = '<' . join('> <', @$mids) . '>';
 719                         warn "Message-ID $id unusable for $num\n";
 720                         foreach my $mid (@$mids) {
 721                                 defined(my $n = $mm->num_for($mid)) or next;
 722                                 warn "#$n previously mapped for <$mid>\n";
 723                         }
 724                 }
 725         }
 726
 727         if (!defined($mid0) || $del) {
 728                 if (!defined($mid0) && $del) { # expected for deletes
 729                         $num = $$regen--;
 730                         $self->{mm}->num_highwater($num) unless $reindex;
 731                         return
 732                 }
 733
 734                 my $id = '<' . join('> <', @$mids) . '>';
 735                 defined($mid0) or
 736                         warn "Skipping $id, no article number found\n";
 737                 if ($del && defined($mid0)) {
 738                         warn "$id was deleted $del " .
 739                                 "time(s) but mapped to article #$num\n";
 740                 }
 741                 return;
 742
 743         }
 744         $mm_tmp->mid_delete($mid0) or
 745                 die "failed to delete <$mid0> for article #$num\n";
 746
 747         $self->{over}->add_overview($mime, $len, $num, $oid, $mid0);
 748         my $nparts = $self->{partitions};
 749         my $part = $num % $nparts;
 750         my $idx = $self->idx_part($part);
 751         $idx->index_raw($len, $msgref, $num, $oid, $mid0, $mime);
 752         my $n = $self->{transact_bytes} += $len;
 753         if ($n > (PublicInbox::SearchIdx::BATCH_BYTES * $nparts)) {
 754                 $git->cleanup;
 755                 $mm_tmp->atfork_prepare;
 756                 $self->done; # release lock
 757                 # allow -watch or -mda to write...
 758                 $self->idx_init; # reacquire lock
 759                 $mm_tmp->atfork_parent;
 760         }
 761 }
 762
 763 # only update last_commit for $i on reindex iff newer than current
 764 sub update_last_commit {
 765         my ($self, $git, $i, $cmt) = @_;
 766         my $last = last_commit_part($self, $i);
 767         if (defined $last && is_ancestor($git, $last, $cmt)) {
 768                 my @cmd = (qw(rev-list --count), "$last..$cmt");
 769                 chomp(my $n = $git->qx(@cmd));
 770                 return if $n ne '' && $n == 0;
 771         }
 772         last_commit_part($self, $i, $cmt);
 773 }
 774
 775 sub git_dir_n ($$) { "$_[0]->{-inbox}->{mainrepo}/git/$_[1].git" }
 776
 777 sub last_commits {
 778         my ($self, $epoch_max) = @_;
 779         my $heads = [];
 780         for (my $i = $epoch_max; $i >= 0; $i--) {
 781                 $heads->[$i] = last_commit_part($self, $i);
 782         }
 783         $heads;
 784 }
 785
 786 *is_ancestor = *PublicInbox::SearchIdx::is_ancestor;
 787
 788 sub index_prepare {
 789         my ($self, $opts, $epoch_max, $ranges) = @_;
 790         my $regen_max = 0;
 791         my $head = $self->{-inbox}->{ref_head} || 'refs/heads/master';
 792         for (my $i = $epoch_max; $i >= 0; $i--) {
 793                 die "already indexing!\n" if $self->{index_pipe};
 794                 my $git_dir = git_dir_n($self, $i);
 795                 -d $git_dir or next; # missing parts are fine
 796                 my $git = PublicInbox::Git->new($git_dir);
 797                 chomp(my $tip = $git->qx(qw(rev-parse -q --verify), $head));
 798                 next if $?; # new repo
 799                 my $range;
 800                 if (defined(my $cur = $ranges->[$i])) {
 801                         $range = "$cur..$tip";
 802                         if (is_ancestor($git, $cur, $tip)) { # common case
 803                                 my $n = $git->qx(qw(rev-list --count), $range);
 804                                 chomp($n);
 805                                 if ($n == 0) {
 806                                         $ranges->[$i] = undef;
 807                                         next;
 808                                 }
 809                         } else {
 810                                 warn <<"";
 811 discontiguous range: $range
 812 Rewritten history? (in $git_dir)
 813
 814                                 my $base = $git->qx('merge-base', $tip, $cur);
 815                                 chomp $base;
 816                                 if ($base) {
 817                                         $range = "$base..$tip";
 818                                         warn "found merge-base: $base\n"
 819                                 } else {
 820                                         $range = $tip;
 821                                         warn <<"";
 822 discarding history at $cur
 823
 824                                 }
 825                                 warn <<"";
 826 reindexing $git_dir starting at
 827 $range
 828
 829                                 $self->{"unindex-range.$i"} = "$base..$cur";
 830                         }
 831                 } else {
 832                         $range = $tip; # all of it
 833                 }
 834                 $ranges->[$i] = $range;
 835
 836                 # can't use 'rev-list --count' if we use --diff-filter
 837                 my $fh = $git->popen(qw(log --pretty=tformat:%H
 838                                 --no-notes --no-color --no-renames
 839                                 --diff-filter=AM), $range, '--', 'm');
 840                 ++$regen_max while <$fh>;
 841         }
 842         \$regen_max;
 843 }
 844
 845 sub unindex_oid_remote {
 846         my ($self, $oid, $mid) = @_;
 847         $_->remote_remove($oid, $mid) foreach @{$self->{idx_parts}};
 848         $self->{over}->remove_oid($oid, $mid);
 849 }
 850
 851 sub unindex_oid {
 852         my ($self, $git, $oid) = @_;
 853         my $msgref = $git->cat_file($oid);
 854         my $mime = PublicInbox::MIME->new($msgref);
 855         my $mids = mids($mime->header_obj);
 856         $mime = $msgref = undef;
 857         my $over = $self->{over};
 858         foreach my $mid (@$mids) {
 859                 my %gone;
 860                 my ($id, $prev);
 861                 while (my $smsg = $over->next_by_mid($mid, \$id, \$prev)) {
 862                         $gone{$smsg->{num}} = 1 if $oid eq $smsg->{blob};
 863                         1; # continue
 864                 }
 865                 my $n = scalar keys %gone;
 866                 next unless $n;
 867                 if ($n > 1) {
 868                         warn "BUG: multiple articles linked to $oid\n",
 869                                 join(',',sort keys %gone), "\n";
 870                 }
 871                 foreach my $num (keys %gone) {
 872                         $self->{unindexed}->{$_}++;
 873                         $self->{mm}->num_delete($num);
 874                 }
 875                 $self->unindex_oid_remote($oid, $mid);
 876         }
 877 }
 878
 879 my $x40 = qr/[a-f0-9]{40}/;
 880 sub unindex {
 881         my ($self, $opts, $git, $unindex_range) = @_;
 882         my $un = $self->{unindexed} ||= {}; # num => removal count
 883         my $before = scalar keys %$un;
 884         my @cmd = qw(log --raw -r
 885                         --no-notes --no-color --no-abbrev --no-renames);
 886         my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $unindex_range);
 887         while (<$fh>) {
 888                 /\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o or next;
 889                 $self->unindex_oid($git, $1);
 890         }
 891         delete $self->{reindex_pipe};
 892         $fh = undef;
 893
 894         return unless $opts->{prune};
 895         my $after = scalar keys %$un;
 896         return if $before == $after;
 897
 898         # ensure any blob can not longer be accessed via dumb HTTP
 899         PublicInbox::Import::run_die(['git', "--git-dir=$git->{git_dir}",
 900                 qw(-c gc.reflogExpire=now gc --prune=all)]);
 901 }
 902
 903 sub index_sync {
 904         my ($self, $opts) = @_;
 905         $opts ||= {};
 906         my $epoch_max;
 907         my $latest = git_dir_latest($self, \$epoch_max);
 908         return unless defined $latest;
 909         $self->idx_init; # acquire lock
 910         my $mm_tmp = $self->{mm}->tmp_clone;
 911         my $reindex = $opts->{reindex};
 912         my $ranges = $reindex ? [] : $self->last_commits($epoch_max);
 913
 914         my $high = $self->{mm}->num_highwater();
 915         my $regen = $self->index_prepare($opts, $epoch_max, $ranges);
 916         $$regen += $high if $high;
 917         my $D = {}; # "$mid\0$cid" => $oid
 918         my @cmd = qw(log --raw -r --pretty=tformat:%H
 919                         --no-notes --no-color --no-abbrev --no-renames);
 920
 921         # work backwards through history
 922         my $last_commit = [];
 923         for (my $i = $epoch_max; $i >= 0; $i--) {
 924                 my $git_dir = git_dir_n($self, $i);
 925                 die "already reindexing!\n" if delete $self->{reindex_pipe};
 926                 -d $git_dir or next; # missing parts are fine
 927                 my $git = PublicInbox::Git->new($git_dir);
 928                 my $unindex = delete $self->{"unindex-range.$i"};
 929                 $self->unindex($opts, $git, $unindex) if $unindex;
 930                 defined(my $range = $ranges->[$i]) or next;
 931                 my $fh = $self->{reindex_pipe} = $git->popen(@cmd, $range);
 932                 my $cmt;
 933                 while (<$fh>) {
 934                         if (/\A$x40$/o && !defined($cmt)) {
 935                                 chomp($cmt = $_);
 936                         } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\tm$/o) {
 937                                 $self->reindex_oid($mm_tmp, $D, $git, $1,
 938                                                 $regen, $reindex);
 939                         } elsif (/\A:\d{6} 100644 $x40 ($x40) [AM]\td$/o) {
 940                                 $self->mark_deleted($D, $git, $1);
 941                         }
 942                 }
 943                 $fh = undef;
 944                 delete $self->{reindex_pipe};
 945                 $self->update_last_commit($git, $i, $cmt) if defined $cmt;
 946         }
 947
 948         # unindex is required for leftovers if "deletes" affect messages
 949         # in a previous fetch+index window:
 950         if (scalar keys %$D) {
 951                 my $git = $self->{-inbox}->git;
 952                 $self->unindex_oid($git, $_) for values %$D;
 953                 $git->cleanup;
 954         }
 955         $self->done;
 956 }
 957
 958 1;