lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 package PublicInbox::V2Writable;
   6 use strict;
   7 use warnings;
   8 use Fcntl qw(:flock :DEFAULT);
   9 use PublicInbox::SearchIdxPart;
  10 use PublicInbox::SearchIdxSkeleton;
  11 use PublicInbox::MIME;
  12 use PublicInbox::Git;
  13 use PublicInbox::Import;
  14 use PublicInbox::MID qw(mids);
  15 use PublicInbox::ContentId qw(content_id content_digest);
  16 use PublicInbox::Inbox;
  17
  18 # an estimate of the post-packed size to the raw uncompressed size
  19 my $PACKING_FACTOR = 0.4;
  20
  21 # assume 2 cores if GNU nproc(1) is not available
  22 sub nproc () {
  23         int($ENV{NPROC} || `nproc 2>/dev/null` || 2);
  24 }
  25
  26 sub new {
  27         my ($class, $v2ibx, $creat) = @_;
  28         my $dir = $v2ibx->{mainrepo} or die "no mainrepo in inbox\n";
  29         unless (-d $dir) {
  30                 if ($creat) {
  31                         require File::Path;
  32                         File::Path::mkpath($dir);
  33                 } else {
  34                         die "$dir does not exist\n";
  35                 }
  36         }
  37
  38         my $nparts = 0;
  39         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
  40
  41         # always load existing partitions in case core count changes:
  42         if (-d $xpfx) {
  43                 foreach my $part (<$xpfx/*>) {
  44                         -d $part && $part =~ m!/\d+\z! or next;
  45                         eval {
  46                                 Search::Xapian::Database->new($part)->close;
  47                                 $nparts++;
  48                         };
  49                 }
  50         }
  51         $nparts = nproc() if ($nparts == 0);
  52
  53         my $self = {
  54                 -inbox => $v2ibx,
  55                 im => undef, #  PublicInbox::Import
  56                 xap_rw => undef, # PublicInbox::V2SearchIdx
  57                 xap_ro => undef,
  58                 partitions => $nparts,
  59                 transact_bytes => 0,
  60                 # limit each repo to 1GB or so
  61                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
  62         };
  63         bless $self, $class
  64 }
  65
  66 # returns undef on duplicate or spam
  67 # mimics Import::add and wraps it for v2
  68 sub add {
  69         my ($self, $mime, $check_cb) = @_;
  70
  71         # spam check:
  72         if ($check_cb) {
  73                 $mime = $check_cb->($mime) or return;
  74         }
  75
  76         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
  77         # as does SQLite 3.4.1+ (released in 2007-07-20), and
  78         # Xapian 1.3.2+ (released 2015-03-15).
  79         # For the most part, we can spawn git-fast-import without
  80         # leaking FDs to it...
  81         $self->idx_init;
  82
  83         my $mid0;
  84         my $num = num_for($self, $mime, \$mid0);
  85         defined $num or return; # duplicate
  86         defined $mid0 or die "BUG: $mid0 undefined\n";
  87         my $im = $self->importer;
  88         my $cmt = $im->add($mime);
  89         $cmt = $im->get_mark($cmt);
  90         my ($oid, $len, $msgref) = @{$im->{last_object}};
  91
  92         my $nparts = $self->{partitions};
  93         my $part = $num % $nparts;
  94         my $idx = $self->idx_part($part);
  95         $idx->index_raw($len, $msgref, $num, $oid, $mid0);
  96         my $n = $self->{transact_bytes} += $len;
  97         if ($n > (PublicInbox::SearchIdx::BATCH_BYTES * $nparts)) {
  98                 $self->checkpoint;
  99         }
 100
 101         $mime;
 102 }
 103
 104 sub num_for {
 105         my ($self, $mime, $mid0) = @_;
 106         my $mids = mids($mime->header_obj);
 107         if (@$mids) {
 108                 my $mid = $mids->[0];
 109                 my $num = $self->{skel}->{mm}->mid_insert($mid);
 110                 if (defined $num) { # common case
 111                         $$mid0 = $mid;
 112                         return $num;
 113                 };
 114
 115                 # crap, Message-ID is already known, hope somebody just resent:
 116                 $self->barrier;
 117                 foreach my $m (@$mids) {
 118                         # read-only lookup now safe to do after above barrier
 119                         my $existing = $self->lookup_content($mime, $m);
 120                         if ($existing) {
 121                                 warn "<$m> resent\n";
 122                                 return; # easy, don't store duplicates
 123                         }
 124                 }
 125
 126                 # very unlikely:
 127                 warn "<$mid> reused for mismatched content\n";
 128
 129                 # try the rest of the mids
 130                 foreach my $i (1..$#$mids) {
 131                         my $m = $mids->[$i];
 132                         $num = $self->{skel}->{mm}->mid_insert($m);
 133                         if (defined $num) {
 134                                 warn "alternative <$m> for <$mid> found\n";
 135                                 $$mid0 = $m;
 136                                 return $num;
 137                         }
 138                 }
 139         }
 140         # none of the existing Message-IDs are good, generate a new one:
 141         num_for_harder($self, $mime, $mid0);
 142 }
 143
 144 sub num_for_harder {
 145         my ($self, $mime, $mid0) = @_;
 146
 147         my $hdr = $mime->header_obj;
 148         my $dig = content_digest($mime);
 149         $$mid0 = $dig->clone->hexdigest . '@localhost';
 150         my $num = $self->{skel}->{mm}->mid_insert($$mid0);
 151         unless (defined $num) {
 152                 # it's hard to spoof the last Received: header
 153                 my @recvd = $hdr->header_raw('Received');
 154                 $dig->add("Received: $_") foreach (@recvd);
 155                 $$mid0 = $dig->clone->hexdigest . '@localhost';
 156                 $num = $self->{skel}->{mm}->mid_insert($$mid0);
 157
 158                 # fall back to a random Message-ID and give up determinism:
 159                 until (defined($num)) {
 160                         $dig->add(rand);
 161                         $$mid0 = $dig->clone->hexdigest . '@localhost';
 162                         warn "using random Message-ID <$$mid0> as fallback\n";
 163                         $num = $self->{skel}->{mm}->mid_insert($$mid0);
 164                 }
 165         }
 166         my @cur = $hdr->header_raw('Message-Id');
 167         $hdr->header_set('Message-Id', "<$$mid0>", @cur);
 168         $num;
 169 }
 170
 171 sub idx_part {
 172         my ($self, $part) = @_;
 173         $self->{idx_parts}->[$part];
 174 }
 175
 176 # idempotent
 177 sub idx_init {
 178         my ($self) = @_;
 179         return if $self->{idx_parts};
 180         my $ibx = $self->{-inbox};
 181
 182         # do not leak read-only FDs to child processes, we only have these
 183         # FDs for duplicate detection so they should not be
 184         # frequently activated.
 185         delete $ibx->{$_} foreach (qw(git mm search));
 186
 187         # first time initialization, first we create the skeleton pipe:
 188         my $skel = $self->{skel} = PublicInbox::SearchIdxSkeleton->new($self);
 189
 190         # need to create all parts before initializing msgmap FD
 191         my $max = $self->{partitions} - 1;
 192         my $idx = $self->{idx_parts} = [];
 193         for my $i (0..$max) {
 194                 push @$idx, PublicInbox::SearchIdxPart->new($self, $i, $skel);
 195         }
 196
 197         # Now that all subprocesses are up, we can open the FD for SQLite:
 198         $skel->_msgmap_init->{dbh}->begin_work;
 199 }
 200
 201 sub remove {
 202         my ($self, $mime, $msg) = @_;
 203         my $existing = $self->lookup_content($mime) or return;
 204
 205         # don't touch ghosts or already junked messages
 206         return unless $existing->type eq 'mail';
 207
 208         # always write removals to the current (latest) git repo since
 209         # we process chronologically
 210         my $im = $self->importer;
 211         my ($cmt, undef) = $im->remove($mime, $msg);
 212         $cmt = $im->get_mark($cmt);
 213         $self->unindex_msg($existing, $cmt);
 214 }
 215
 216 sub done {
 217         my ($self) = @_;
 218         my $im = delete $self->{im};
 219         $im->done if $im; # PublicInbox::Import::done
 220         $self->searchidx_checkpoint(0);
 221 }
 222
 223 sub checkpoint {
 224         my ($self) = @_;
 225         my $im = $self->{im};
 226         $im->checkpoint if $im; # PublicInbox::Import::checkpoint
 227         $self->searchidx_checkpoint(1);
 228 }
 229
 230 # issue a write barrier to ensure all data is visible to other processes
 231 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 232 sub barrier {
 233         my ($self) = @_;
 234
 235         # For safety, we ensure git checkpoint is complete before because
 236         # the data in git is still more important than what is in Xapian.
 237         # Performance may be gained by delaying ->progress call but we
 238         # lose safety
 239         if (my $im = $self->{im}) {
 240                 $im->checkpoint;
 241                 $im->progress('checkpoint');
 242         }
 243         my $skel = $self->{skel};
 244         my $parts = $self->{idx_parts};
 245         if ($parts && $skel) {
 246                 my $dbh = $skel->{mm}->{dbh};
 247                 $dbh->commit; # SQLite data is second in importance
 248
 249                 # Now deal with Xapian
 250                 $skel->barrier_init(scalar(@$parts));
 251                 # each partition needs to issue a barrier command to skel:
 252                 $_->barrier foreach @$parts;
 253
 254                 $skel->barrier_wait; # wait for each Xapian partition
 255
 256                 $dbh->begin_work;
 257         }
 258         $self->{transact_bytes} = 0;
 259 }
 260
 261 sub searchidx_checkpoint {
 262         my ($self, $more) = @_;
 263
 264         # order matters, we can only close {skel} after all partitions
 265         # are done because the partitions also write to {skel}
 266         if (my $parts = $self->{idx_parts}) {
 267                 foreach my $idx (@$parts) {
 268                         $idx->remote_commit; # propagates commit to skel
 269                         $idx->remote_close unless $more;
 270                 }
 271                 delete $self->{idx_parts} unless $more;
 272         }
 273
 274         if (my $skel = $self->{skel}) {
 275                 my $dbh = $skel->{mm}->{dbh};
 276                 $dbh->commit;
 277                 if ($more) {
 278                         $dbh->begin_work;
 279                 } else {
 280                         $skel->remote_close;
 281                         delete $self->{skel};
 282                 }
 283         }
 284         $self->{transact_bytes} = 0;
 285 }
 286
 287 sub git_init {
 288         my ($self, $new) = @_;
 289         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 290         my $git_dir = "$pfx/$new.git";
 291         die "$git_dir exists\n" if -e $git_dir;
 292         my @cmd = (qw(git init --bare -q), $git_dir);
 293         PublicInbox::Import::run_die(\@cmd);
 294
 295         my $all = "$self->{-inbox}->{mainrepo}/all.git";
 296         unless (-d $all) {
 297                 @cmd = (qw(git init --bare -q), $all);
 298                 PublicInbox::Import::run_die(\@cmd);
 299                 @cmd = (qw/git config/, "--file=$all/config",
 300                                 'repack.writeBitmaps', 'true');
 301                 PublicInbox::Import::run_die(\@cmd);
 302         }
 303
 304         @cmd = (qw/git config/, "--file=$git_dir/config",
 305                         'include.path', '../../all.git/config');
 306         PublicInbox::Import::run_die(\@cmd);
 307
 308         my $alt = "$all/objects/info/alternates";
 309         my $new_obj_dir = "../../git/$new.git/objects";
 310         my %alts;
 311         if (-e $alt) {
 312                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 313                 %alts = map { chomp; $_ => 1 } (<$fh>);
 314         }
 315         return $git_dir if $alts{$new_obj_dir};
 316         open my $fh, '>>', $alt or die "open >> $alt: $!\n";
 317         print $fh "$new_obj_dir\n" or die "print >> $alt: $!\n";
 318         close $fh or die "close $alt: $!\n";
 319         $git_dir
 320 }
 321
 322 sub importer {
 323         my ($self) = @_;
 324         my $im = $self->{im};
 325         if ($im) {
 326                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 327                         return $im;
 328                 } else {
 329                         $self->{im} = undef;
 330                         $im->done;
 331                         $self->searchidx_checkpoint(1);
 332                         $im = undef;
 333                         my $git_dir = $self->git_init(++$self->{max_git});
 334                         my $git = PublicInbox::Git->new($git_dir);
 335                         return $self->import_init($git, 0);
 336                 }
 337         }
 338         my $latest;
 339         my $max = -1;
 340         my $new = 0;
 341         my $pfx = "$self->{-inbox}->{mainrepo}/git";
 342         if (-d $pfx) {
 343                 foreach my $git_dir (glob("$pfx/*.git")) {
 344                         $git_dir =~ m!/(\d+)\.git\z! or next;
 345                         my $n = $1;
 346                         if ($n > $max) {
 347                                 $max = $n;
 348                                 $latest = $git_dir;
 349                         }
 350                 }
 351         }
 352         if (defined $latest) {
 353                 my $git = PublicInbox::Git->new($latest);
 354                 my $packed_bytes = $git->packed_bytes;
 355                 if ($packed_bytes >= $self->{rotate_bytes}) {
 356                         $new = $max + 1;
 357                 } else {
 358                         $self->{max_git} = $max;
 359                         return $self->import_init($git, $packed_bytes);
 360                 }
 361         }
 362         $self->{max_git} = $new;
 363         $latest = $self->git_init($new);
 364         $self->import_init(PublicInbox::Git->new($latest), 0);
 365 }
 366
 367 sub import_init {
 368         my ($self, $git, $packed_bytes) = @_;
 369         my $im = PublicInbox::Import->new($git, undef, undef, $self->{-inbox});
 370         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 371         $im->{want_object_info} = 1;
 372         $im->{ssoma_lock} = 0;
 373         $im->{path_type} = 'v2';
 374         $self->{im} = $im;
 375 }
 376
 377 sub lookup_content {
 378         my ($self, $mime, $mid) = @_;
 379         my $ibx = $self->{-inbox};
 380
 381         my $srch = $ibx->search->reopen;
 382         my $cid = content_id($mime);
 383         my $found;
 384         $srch->each_smsg_by_mid($mid, sub {
 385                 my ($smsg) = @_;
 386                 $smsg->load_expand;
 387                 my $msg = $ibx->msg_by_smsg($smsg);
 388                 if (!defined($msg)) {
 389                         warn "broken smsg for $mid\n";
 390                         return 1; # continue
 391                 }
 392                 my $cur = PublicInbox::MIME->new($msg);
 393                 if (content_id($cur) eq $cid) {
 394                         $smsg->{mime} = $cur;
 395                         $found = $smsg;
 396                         return 0; # break out of loop
 397                 }
 398                 1; # continue
 399         });
 400         $found;
 401 }
 402
 403 sub atfork_child {
 404         my ($self) = @_;
 405         if (my $parts = $self->{idx_parts}) {
 406                 $_->atfork_child foreach @$parts;
 407         }
 408         if (my $im = $self->{im}) {
 409                 $im->atfork_child;
 410         }
 411 }
 412
 413 1;