lib/PublicInbox/V2Writable.pm

   1 # Copyright (C) 2018-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # This interface wraps and mimics PublicInbox::Import
   5 # Used to write to V2 inboxes (see L<public-inbox-v2-format(5)>).
   6 package PublicInbox::V2Writable;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(PublicInbox::Lock);
  10 use PublicInbox::SearchIdxShard;
  11 use PublicInbox::Eml;
  12 use PublicInbox::Git;
  13 use PublicInbox::Import;
  14 use PublicInbox::MID qw(mids references);
  15 use PublicInbox::ContentHash qw(content_hash content_digest);
  16 use PublicInbox::InboxWritable;
  17 use PublicInbox::OverIdx;
  18 use PublicInbox::Msgmap;
  19 use PublicInbox::Spawn qw(spawn popen_rd run_die);
  20 use PublicInbox::SearchIdx qw(log2stack crlf_adjust is_ancestor check_size
  21         is_bad_blob);
  22 use IO::Handle; # ->autoflush
  23 use File::Temp ();
  24
  25 my $OID = qr/[a-f0-9]{40,}/;
  26 # an estimate of the post-packed size to the raw uncompressed size
  27 our $PACKING_FACTOR = 0.4;
  28
  29 # SATA storage lags behind what CPUs are capable of, so relying on
  30 # nproc(1) can be misleading and having extra Xapian shards is a
  31 # waste of FDs and space.  It can also lead to excessive IO latency
  32 # and slow things down.  Users on NVME or other fast storage can
  33 # use the NPROC env or switches in our script/public-inbox-* programs
  34 # to increase Xapian shards
  35 our $NPROC_MAX_DEFAULT = 4;
  36
  37 sub detect_nproc () {
  38         # getconf(1) is POSIX, but *NPROCESSORS* vars are not
  39         for (qw(_NPROCESSORS_ONLN NPROCESSORS_ONLN)) {
  40                 `getconf $_ 2>/dev/null` =~ /^(\d+)$/ and return $1;
  41         }
  42         for my $nproc (qw(nproc gnproc)) { # GNU coreutils nproc
  43                 `$nproc 2>/dev/null` =~ /^(\d+)$/ and return $1;
  44         }
  45
  46         # should we bother with `sysctl hw.ncpu`?  Those only give
  47         # us total processor count, not online processor count.
  48         undef
  49 }
  50
  51 sub nproc_shards ($) {
  52         my ($creat_opt) = @_;
  53         my $n = $creat_opt->{nproc} if ref($creat_opt) eq 'HASH';
  54         $n //= $ENV{NPROC};
  55         if (!$n) {
  56                 # assume 2 cores if not detectable or zero
  57                 state $NPROC_DETECTED = detect_nproc() || 2;
  58                 $n = $NPROC_DETECTED;
  59                 $n = $NPROC_MAX_DEFAULT if $n > $NPROC_MAX_DEFAULT;
  60         }
  61
  62         # subtract for the main process and git-fast-import
  63         $n -= 1;
  64         $n < 1 ? 1 : $n;
  65 }
  66
  67 sub count_shards ($) {
  68         my ($self) = @_;
  69         if (my $ibx = $self->{ibx}) {
  70                 # always load existing shards in case core count changes:
  71                 # Also, shard count may change while -watch is running
  72                 my $srch = $ibx->search or return 0;
  73                 delete $ibx->{search};
  74                 $srch->{nshard} // 0
  75         } else { # ExtSearchIdx
  76                 $self->{nshard} ||= scalar($self->xdb_shards_flat);
  77         }
  78 }
  79
  80 sub new {
  81         # $creat may be any true value, or 0/undef.  A hashref is true,
  82         # and $creat->{nproc} may be set to an integer
  83         my ($class, $v2ibx, $creat) = @_;
  84         $v2ibx = PublicInbox::InboxWritable->new($v2ibx);
  85         my $dir = $v2ibx->assert_usable_dir;
  86         unless (-d $dir) {
  87                 if ($creat) {
  88                         require File::Path;
  89                         File::Path::mkpath($dir);
  90                 } else {
  91                         die "$dir does not exist\n";
  92                 }
  93         }
  94         my $xpfx = "$dir/xap" . PublicInbox::Search::SCHEMA_VERSION;
  95         my $self = {
  96                 ibx => $v2ibx,
  97                 im => undef, #  PublicInbox::Import
  98                 parallel => 1,
  99                 transact_bytes => 0,
 100                 total_bytes => 0,
 101                 current_info => '',
 102                 xpfx => $xpfx,
 103                 oidx => PublicInbox::OverIdx->new("$xpfx/over.sqlite3"),
 104                 lock_path => "$dir/inbox.lock",
 105                 # limit each git repo (epoch) to 1GB or so
 106                 rotate_bytes => int((1024 * 1024 * 1024) / $PACKING_FACTOR),
 107                 last_commit => [], # git epoch -> commit
 108         };
 109         $self->{oidx}->{-no_fsync} = 1 if $v2ibx->{-no_fsync};
 110         $self->{shards} = count_shards($self) || nproc_shards($creat);
 111         bless $self, $class;
 112 }
 113
 114 # public (for now?)
 115 sub init_inbox {
 116         my ($self, $shards, $skip_epoch, $skip_artnum) = @_;
 117         if (defined $shards) {
 118                 $self->{parallel} = 0 if $shards == 0;
 119                 $self->{shards} = $shards if $shards > 0;
 120         }
 121         $self->idx_init;
 122         $self->{mm}->skip_artnum($skip_artnum) if defined $skip_artnum;
 123         my $max = $self->{ibx}->max_git_epoch;
 124         $max = $skip_epoch if (defined($skip_epoch) && !defined($max));
 125         $self->git_init($max // 0);
 126         $self->done;
 127 }
 128
 129 # returns undef on duplicate or spam
 130 # mimics Import::add and wraps it for v2
 131 sub add {
 132         my ($self, $eml, $check_cb) = @_;
 133         $self->{ibx}->with_umask(\&_add, $self, $eml, $check_cb);
 134 }
 135
 136 sub idx_shard ($$) {
 137         my ($self, $num) = @_;
 138         $self->{idx_shards}->[$num % scalar(@{$self->{idx_shards}})];
 139 }
 140
 141 # indexes a message, returns true if checkpointing is needed
 142 sub do_idx ($$$$) {
 143         my ($self, $msgref, $mime, $smsg) = @_;
 144         $smsg->{bytes} = $smsg->{raw_bytes} + crlf_adjust($$msgref);
 145         $self->{oidx}->add_overview($mime, $smsg);
 146         my $idx = idx_shard($self, $smsg->{num});
 147         $idx->index_raw($msgref, $mime, $smsg);
 148         my $n = $self->{transact_bytes} += $smsg->{raw_bytes};
 149         $n >= $self->{batch_bytes};
 150 }
 151
 152 sub _add {
 153         my ($self, $mime, $check_cb) = @_;
 154
 155         # spam check:
 156         if ($check_cb) {
 157                 $mime = $check_cb->($mime, $self->{ibx}) or return;
 158         }
 159
 160         # All pipes (> $^F) known to Perl 5.6+ have FD_CLOEXEC set,
 161         # as does SQLite 3.4.1+ (released in 2007-07-20), and
 162         # Xapian 1.3.2+ (released 2015-03-15).
 163         # For the most part, we can spawn git-fast-import without
 164         # leaking FDs to it...
 165         $self->idx_init;
 166
 167         my ($num, $mid0) = v2_num_for($self, $mime);
 168         defined $num or return; # duplicate
 169         defined $mid0 or die "BUG: \$mid0 undefined\n";
 170         my $im = $self->importer;
 171         my $smsg = bless { mid => $mid0, num => $num }, 'PublicInbox::Smsg';
 172         my $cmt = $im->add($mime, undef, $smsg); # sets $smsg->{ds|ts|blob}
 173         $cmt = $im->get_mark($cmt);
 174         $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 175
 176         my $msgref = delete $smsg->{-raw_email};
 177         if (do_idx($self, $msgref, $mime, $smsg)) {
 178                 $self->checkpoint;
 179         }
 180
 181         $cmt;
 182 }
 183
 184 sub v2_num_for {
 185         my ($self, $mime) = @_;
 186         my $mids = mids($mime);
 187         if (@$mids) {
 188                 my $mid = $mids->[0];
 189                 my $num = $self->{mm}->mid_insert($mid);
 190                 if (defined $num) { # common case
 191                         return ($num, $mid);
 192                 }
 193
 194                 # crap, Message-ID is already known, hope somebody just resent:
 195                 foreach my $m (@$mids) {
 196                         # read-only lookup now safe to do after above barrier
 197                         # easy, don't store duplicates
 198                         # note: do not add more diagnostic info here since
 199                         # it gets noisy on public-inbox-watch restarts
 200                         return () if content_exists($self, $mime, $m);
 201                 }
 202
 203                 # AltId may pre-populate article numbers (e.g. X-Mail-Count
 204                 # or NNTP article number), use that article number if it's
 205                 # not in Over.
 206                 my $altid = $self->{ibx}->{altid};
 207                 if ($altid && grep(/:file=msgmap\.sqlite3\z/, @$altid)) {
 208                         my $num = $self->{mm}->num_for($mid);
 209
 210                         if (defined $num && !$self->{oidx}->get_art($num)) {
 211                                 return ($num, $mid);
 212                         }
 213                 }
 214
 215                 # very unlikely:
 216                 warn "<$mid> reused for mismatched content\n";
 217
 218                 # try the rest of the mids
 219                 for(my $i = $#$mids; $i >= 1; $i--) {
 220                         my $m = $mids->[$i];
 221                         $num = $self->{mm}->mid_insert($m);
 222                         if (defined $num) {
 223                                 warn "alternative <$m> for <$mid> found\n";
 224                                 return ($num, $m);
 225                         }
 226                 }
 227         }
 228         # none of the existing Message-IDs are good, generate a new one:
 229         v2_num_for_harder($self, $mime);
 230 }
 231
 232 sub v2_num_for_harder {
 233         my ($self, $eml) = @_;
 234
 235         my $dig = content_digest($eml);
 236         my $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 237         my $num = $self->{mm}->mid_insert($mid0);
 238         unless (defined $num) {
 239                 # it's hard to spoof the last Received: header
 240                 my @recvd = $eml->header_raw('Received');
 241                 $dig->add("Received: $_") foreach (@recvd);
 242                 $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 243                 $num = $self->{mm}->mid_insert($mid0);
 244
 245                 # fall back to a random Message-ID and give up determinism:
 246                 until (defined($num)) {
 247                         $dig->add(rand);
 248                         $mid0 = PublicInbox::Import::digest2mid($dig, $eml);
 249                         warn "using random Message-ID <$mid0> as fallback\n";
 250                         $num = $self->{mm}->mid_insert($mid0);
 251                 }
 252         }
 253         PublicInbox::Import::append_mid($eml, $mid0);
 254         ($num, $mid0);
 255 }
 256
 257 sub _idx_init { # with_umask callback
 258         my ($self, $opt) = @_;
 259         $self->lock_acquire unless $opt && $opt->{-skip_lock};
 260         $self->{oidx}->create;
 261
 262         # xcpdb can change shard count while -watch is idle
 263         my $nshards = count_shards($self);
 264         $self->{shards} = $nshards if $nshards && $nshards != $self->{shards};
 265         $self->{batch_bytes} = $opt->{batch_size} //
 266                                 $PublicInbox::SearchIdx::BATCH_BYTES;
 267
 268         # need to create all shards before initializing msgmap FD
 269         # idx_shards must be visible to all forked processes
 270         my $max = $self->{shards} - 1;
 271         my $idx = $self->{idx_shards} = [];
 272         push @$idx, PublicInbox::SearchIdxShard->new($self, $_) for (0..$max);
 273
 274         # SearchIdxShard may do their own flushing, so don't scale
 275         # until after forking
 276         $self->{batch_bytes} *= $self->{shards} if $self->{parallel};
 277
 278         my $ibx = $self->{ibx} or return; # ExtIdxSearch
 279
 280         # Now that all subprocesses are up, we can open the FDs
 281         # for SQLite:
 282         my $mm = $self->{mm} = PublicInbox::Msgmap->new_file(
 283                                 "$ibx->{inboxdir}/msgmap.sqlite3",
 284                                 $ibx->{-no_fsync} ? 2 : 1);
 285         $mm->{dbh}->begin_work;
 286 }
 287
 288 sub parallel_init ($$) {
 289         my ($self, $indexlevel) = @_;
 290         $self->{parallel} = 0 if ($indexlevel // 'full') eq 'basic';
 291 }
 292
 293 # idempotent
 294 sub idx_init {
 295         my ($self, $opt) = @_;
 296         return if $self->{idx_shards};
 297         my $ibx = $self->{ibx};
 298
 299         # do not leak read-only FDs to child processes, we only have these
 300         # FDs for duplicate detection so they should not be
 301         # frequently activated.
 302         delete @$ibx{qw(mm search)};
 303         $ibx->git->cleanup;
 304
 305         parallel_init($self, $ibx->{indexlevel});
 306         $ibx->with_umask(\&_idx_init, $self, $opt);
 307 }
 308
 309 # returns an array mapping [ epoch => latest_commit ]
 310 # latest_commit may be undef if nothing was done to that epoch
 311 # $replace_map = { $object_id => $strref, ... }
 312 sub _replace_oids ($$$) {
 313         my ($self, $mime, $replace_map) = @_;
 314         $self->done;
 315         my $ibx = $self->{ibx};
 316         my $pfx = "$ibx->{inboxdir}/git";
 317         my $rewrites = []; # epoch => commit
 318         my $max = $self->{epoch_max} //= $ibx->max_git_epoch // return;
 319
 320         foreach my $i (0..$max) {
 321                 my $git_dir = "$pfx/$i.git";
 322                 -d $git_dir or next;
 323                 my $git = PublicInbox::Git->new($git_dir);
 324                 my $im = $self->import_init($git, 0, 1);
 325                 $rewrites->[$i] = $im->replace_oids($mime, $replace_map);
 326                 $im->done;
 327         }
 328         $rewrites;
 329 }
 330
 331 sub content_hashes ($) {
 332         my ($mime) = @_;
 333         my @chashes = ( content_hash($mime) );
 334
 335         # We still support Email::MIME, here, and
 336         # Email::MIME->as_string doesn't always round-trip, so we may
 337         # use a second content_hash
 338         my $rt = content_hash(PublicInbox::Eml->new(\($mime->as_string)));
 339         push @chashes, $rt if $chashes[0] ne $rt;
 340         \@chashes;
 341 }
 342
 343 sub content_matches ($$) {
 344         my ($chashes, $existing) = @_;
 345         my $chash = content_hash($existing);
 346         foreach (@$chashes) {
 347                 return 1 if $_ eq $chash
 348         }
 349         0
 350 }
 351
 352 # used for removing or replacing (purging)
 353 sub rewrite_internal ($$;$$$) {
 354         my ($self, $old_eml, $cmt_msg, $new_eml, $sref) = @_;
 355         $self->idx_init;
 356         my ($im, $need_reindex, $replace_map);
 357         if ($sref) {
 358                 $replace_map = {}; # oid => sref
 359                 $need_reindex = [] if $new_eml;
 360         } else {
 361                 $im = $self->importer;
 362         }
 363         my $oidx = $self->{oidx};
 364         my $chashes = content_hashes($old_eml);
 365         my $removed = [];
 366         my $mids = mids($old_eml);
 367
 368         # We avoid introducing new blobs into git since the raw content
 369         # can be slightly different, so we do not need the user-supplied
 370         # message now that we have the mids and content_hash
 371         $old_eml = undef;
 372         my $mark;
 373
 374         foreach my $mid (@$mids) {
 375                 my %gone; # num => [ smsg, $mime, raw ]
 376                 my ($id, $prev);
 377                 while (my $smsg = $oidx->next_by_mid($mid, \$id, \$prev)) {
 378                         my $msg = get_blob($self, $smsg);
 379                         if (!defined($msg)) {
 380                                 warn "broken smsg for $mid\n";
 381                                 next; # continue
 382                         }
 383                         my $orig = $$msg;
 384                         my $cur = PublicInbox::Eml->new($msg);
 385                         if (content_matches($chashes, $cur)) {
 386                                 $gone{$smsg->{num}} = [ $smsg, $cur, \$orig ];
 387                         }
 388                 }
 389                 my $n = scalar keys %gone;
 390                 next unless $n;
 391                 if ($n > 1) {
 392                         warn "BUG: multiple articles linked to <$mid>\n",
 393                                 join(',', sort keys %gone), "\n";
 394                 }
 395                 foreach my $num (keys %gone) {
 396                         my ($smsg, $mime, $orig) = @{$gone{$num}};
 397                         # $removed should only be set once assuming
 398                         # no bugs in our deduplication code:
 399                         $removed = [ undef, $mime, $smsg ];
 400                         my $oid = $smsg->{blob};
 401                         if ($replace_map) {
 402                                 $replace_map->{$oid} = $sref;
 403                         } else {
 404                                 ($mark, undef) = $im->remove($orig, $cmt_msg);
 405                                 $removed->[0] = $mark;
 406                         }
 407                         $orig = undef;
 408                         if ($need_reindex) { # ->replace
 409                                 push @$need_reindex, $smsg;
 410                         } else { # ->purge or ->remove
 411                                 $self->{mm}->num_delete($num);
 412                         }
 413                         unindex_oid_aux($self, $oid, $mid);
 414                 }
 415         }
 416
 417         if (defined $mark) {
 418                 my $cmt = $im->get_mark($mark);
 419                 $self->{last_commit}->[$self->{epoch_max}] = $cmt;
 420         }
 421         if ($replace_map && scalar keys %$replace_map) {
 422                 my $rewrites = _replace_oids($self, $new_eml, $replace_map);
 423                 return { rewrites => $rewrites, need_reindex => $need_reindex };
 424         }
 425         defined($mark) ? $removed : undef;
 426 }
 427
 428 # public (see PublicInbox::Import->remove), but note the 3rd element
 429 # (retval[2]) is not part of the stable API shared with Import->remove
 430 sub remove {
 431         my ($self, $eml, $cmt_msg) = @_;
 432         my $r = $self->{ibx}->with_umask(\&rewrite_internal,
 433                                                 $self, $eml, $cmt_msg);
 434         defined($r) && defined($r->[0]) ? @$r: undef;
 435 }
 436
 437 sub _replace ($$;$$) {
 438         my ($self, $old_eml, $new_eml, $sref) = @_;
 439         my $arg = [ $self, $old_eml, undef, $new_eml, $sref ];
 440         my $rewritten = $self->{ibx}->with_umask(\&rewrite_internal,
 441                         $self, $old_eml, undef, $new_eml, $sref) or return;
 442
 443         my $rewrites = $rewritten->{rewrites};
 444         # ->done is called if there are rewrites since we gc+prune from git
 445         $self->idx_init if @$rewrites;
 446
 447         for my $i (0..$#$rewrites) {
 448                 defined(my $cmt = $rewrites->[$i]) or next;
 449                 $self->{last_commit}->[$i] = $cmt;
 450         }
 451         $rewritten;
 452 }
 453
 454 # public
 455 sub purge {
 456         my ($self, $mime) = @_;
 457         my $rewritten = _replace($self, $mime, undef, \'') or return;
 458         $rewritten->{rewrites}
 459 }
 460
 461 # returns the git object_id of $fh, does not write the object to FS
 462 sub git_hash_raw ($$) {
 463         my ($self, $raw) = @_;
 464         # grab the expected OID we have to reindex:
 465         pipe(my($in, $w)) or die "pipe: $!";
 466         my $git_dir = $self->git->{git_dir};
 467         my $cmd = ['git', "--git-dir=$git_dir", qw(hash-object --stdin)];
 468         my $r = popen_rd($cmd, undef, { 0 => $in });
 469         print $w $$raw or die "print \$w: $!";
 470         close $w or die "close \$w: $!";
 471         local $/ = "\n";
 472         chomp(my $oid = <$r>);
 473         close $r or die "git hash-object failed: $?";
 474         $oid =~ /\A$OID\z/ or die "OID not expected: $oid";
 475         $oid;
 476 }
 477
 478 sub _check_mids_match ($$$) {
 479         my ($old_list, $new_list, $hdrs) = @_;
 480         my %old_mids = map { $_ => 1 } @$old_list;
 481         my %new_mids = map { $_ => 1 } @$new_list;
 482         my @old = keys %old_mids;
 483         my @new = keys %new_mids;
 484         my $err = "$hdrs may not be changed when replacing\n";
 485         die $err if scalar(@old) != scalar(@new);
 486         delete @new_mids{@old};
 487         delete @old_mids{@new};
 488         die $err if (scalar(keys %old_mids) || scalar(keys %new_mids));
 489 }
 490
 491 # Changing Message-IDs or References with ->replace isn't supported.
 492 # The rules for dealing with messages with multiple or conflicting
 493 # Message-IDs are pretty complex and rethreading hasn't been fully
 494 # implemented, yet.
 495 sub check_mids_match ($$) {
 496         my ($old, $new) = @_;
 497         _check_mids_match(mids($old), mids($new), 'Message-ID(s)');
 498         _check_mids_match(references($old), references($new),
 499                         'References/In-Reply-To');
 500 }
 501
 502 # public
 503 sub replace ($$$) {
 504         my ($self, $old_mime, $new_mime) = @_;
 505
 506         check_mids_match($old_mime, $new_mime);
 507
 508         # mutt will always add Content-Length:, Status:, Lines: when editing
 509         PublicInbox::Import::drop_unwanted_headers($new_mime);
 510
 511         my $raw = $new_mime->as_string;
 512         my $expect_oid = git_hash_raw($self, \$raw);
 513         my $rewritten = _replace($self, $old_mime, $new_mime, \$raw) or return;
 514         my $need_reindex = $rewritten->{need_reindex};
 515
 516         # just in case we have bugs in deduplication code:
 517         my $n = scalar(@$need_reindex);
 518         if ($n > 1) {
 519                 my $list = join(', ', map {
 520                                         "$_->{num}: <$_->{mid}>"
 521                                 } @$need_reindex);
 522                 warn <<"";
 523 W: rewritten $n messages matching content of original message (expected: 1).
 524 W: possible bug in public-inbox, NNTP article IDs and Message-IDs follow:
 525 W: $list
 526
 527         }
 528
 529         # make sure we really got the OID:
 530         my ($blob, $type, $bytes) = $self->git->check($expect_oid);
 531         $blob eq $expect_oid or die "BUG: $expect_oid not found after replace";
 532
 533         # don't leak FDs to Xapian:
 534         $self->git->cleanup;
 535
 536         # reindex modified messages:
 537         for my $smsg (@$need_reindex) {
 538                 my $new_smsg = bless {
 539                         blob => $blob,
 540                         raw_bytes => $bytes,
 541                         num => $smsg->{num},
 542                         mid => $smsg->{mid},
 543                 }, 'PublicInbox::Smsg';
 544                 my $sync = { autime => $smsg->{ds}, cotime => $smsg->{ts} };
 545                 $new_smsg->populate($new_mime, $sync);
 546                 do_idx($self, \$raw, $new_mime, $new_smsg);
 547         }
 548         $rewritten->{rewrites};
 549 }
 550
 551 sub last_epoch_commit ($$;$) {
 552         my ($self, $i, $cmt) = @_;
 553         my $v = PublicInbox::Search::SCHEMA_VERSION();
 554         $self->{mm}->last_commit_xap($v, $i, $cmt);
 555 }
 556
 557 sub set_last_commits ($) { # this is NOT for ExtSearchIdx
 558         my ($self) = @_;
 559         defined(my $epoch_max = $self->{epoch_max}) or return;
 560         my $last_commit = $self->{last_commit};
 561         foreach my $i (0..$epoch_max) {
 562                 defined(my $cmt = $last_commit->[$i]) or next;
 563                 $last_commit->[$i] = undef;
 564                 last_epoch_commit($self, $i, $cmt);
 565         }
 566 }
 567
 568 # public
 569 sub checkpoint ($;$) {
 570         my ($self, $wait) = @_;
 571
 572         if (my $im = $self->{im}) {
 573                 if ($wait) {
 574                         $im->barrier;
 575                 } else {
 576                         $im->checkpoint;
 577                 }
 578         }
 579         my $shards = $self->{idx_shards};
 580         if ($shards) {
 581                 my $mm = $self->{mm};
 582                 my $dbh = $mm->{dbh} if $mm;
 583
 584                 # SQLite msgmap data is second in importance
 585                 $dbh->commit if $dbh;
 586
 587                 # SQLite overview is third
 588                 $self->{oidx}->commit_lazy;
 589
 590                 # Now deal with Xapian
 591
 592                 # start commit_txn_lazy asynchronously on all parallel shards
 593                 # (non-parallel waits here)
 594                 $_->ipc_do('commit_txn_lazy') for @$shards;
 595
 596                 # transactions started on parallel shards,
 597                 # wait for them by issuing an echo command (echo can only
 598                 # run after commit_txn_lazy is done)
 599                 if ($wait && $self->{parallel}) {
 600                         my $i = 0;
 601                         for my $shard (@$shards) {
 602                                 my $echo = $shard->ipc_do('echo', $i);
 603                                 $echo == $i or die <<"";
 604 shard[$i] bad echo:$echo != $i waiting for txn commit
 605
 606                                 ++$i;
 607                         }
 608                 }
 609
 610                 my $midx = $self->{midx}; # misc index
 611                 $midx->commit_txn if $midx;
 612
 613                 # last_commit is special, don't commit these until
 614                 # Xapian shards are done:
 615                 $dbh->begin_work if $dbh;
 616                 set_last_commits($self);
 617                 if ($dbh) {
 618                         $dbh->commit;
 619                         $dbh->begin_work;
 620                 }
 621                 $midx->begin_txn if $midx;
 622         }
 623         $self->{total_bytes} += $self->{transact_bytes};
 624         $self->{transact_bytes} = 0;
 625 }
 626
 627 # issue a write barrier to ensure all data is visible to other processes
 628 # and read-only ops.  Order of data importance is: git > SQLite > Xapian
 629 # public
 630 sub barrier { checkpoint($_[0], 1) };
 631
 632 # true if locked and active
 633 sub active { !!$_[0]->{im} }
 634
 635 # public
 636 sub done {
 637         my ($self) = @_;
 638         my $err = '';
 639         if (my $im = delete $self->{im}) {
 640                 eval { $im->done }; # PublicInbox::Import::done
 641                 $err .= "import done: $@\n" if $@;
 642         }
 643         if (!$err) {
 644                 eval { checkpoint($self) };
 645                 $err .= "checkpoint: $@\n" if $@;
 646         }
 647         if (my $mm = delete $self->{mm}) {
 648                 my $m = $err ? 'rollback' : 'commit';
 649                 eval { $mm->{dbh}->$m };
 650                 $err .= "msgmap $m: $@\n" if $@;
 651         }
 652         my $shards = delete $self->{idx_shards};
 653         if ($shards) {
 654                 for (@$shards) {
 655                         eval { $_->shard_close };
 656                         $err .= "shard close: $@\n" if $@;
 657                 }
 658         }
 659         eval { $self->{oidx}->dbh_close };
 660         $err .= "over close: $@\n" if $@;
 661         delete $self->{midx};
 662         my $nbytes = $self->{total_bytes};
 663         $self->{total_bytes} = 0;
 664         $self->lock_release(!!$nbytes) if $shards;
 665         $self->git->cleanup;
 666         die $err if $err;
 667 }
 668
 669 sub write_alternates ($$$) {
 670         my ($info_dir, $mode, $out) = @_;
 671         my $fh = File::Temp->new(TEMPLATE => 'alt-XXXXXXXX', DIR => $info_dir);
 672         my $tmp = $fh->filename;
 673         print $fh @$out or die "print $tmp: $!\n";
 674         chmod($mode, $fh) or die "fchmod $tmp: $!\n";
 675         close $fh or die "close $tmp $!\n";
 676         my $alt = "$info_dir/alternates";
 677         rename($tmp, $alt) or die "rename $tmp => $alt: $!\n";
 678         $fh->unlink_on_destroy(0);
 679 }
 680
 681 sub fill_alternates ($$) {
 682         my ($self, $epoch) = @_;
 683
 684         my $pfx = "$self->{ibx}->{inboxdir}/git";
 685         my $all = "$self->{ibx}->{inboxdir}/all.git";
 686         PublicInbox::Import::init_bare($all) unless -d $all;
 687         my $info_dir = "$all/objects/info";
 688         my $alt = "$info_dir/alternates";
 689         my (%alt, $new);
 690         my $mode = 0644;
 691         if (-e $alt) {
 692                 open(my $fh, '<', $alt) or die "open < $alt: $!\n";
 693                 $mode = (stat($fh))[2] & 07777;
 694
 695                 # we assign a sort score to every alternate and favor
 696                 # the newest (highest numbered) one because loose objects
 697                 # require scanning epochs and only the latest epoch is
 698                 # expected to see loose objects
 699                 my $score;
 700                 my $other = 0; # in case admin adds non-epoch repos
 701                 %alt = map {;
 702                         if (m!\A\Q../../\E([0-9]+)\.git/objects\z!) {
 703                                 $score = $1 + 0;
 704                         } else {
 705                                 $score = --$other;
 706                         }
 707                         $_ => $score;
 708                 } split(/\n+/, do { local $/; <$fh> });
 709         }
 710
 711         foreach my $i (0..$epoch) {
 712                 my $dir = "../../git/$i.git/objects";
 713                 if (!exists($alt{$dir}) && -d "$pfx/$i.git") {
 714                         $alt{$dir} = $i;
 715                         $new = 1;
 716                 }
 717         }
 718         return unless $new;
 719         write_alternates($info_dir, $mode,
 720                 [join("\n", sort { $alt{$b} <=> $alt{$a} } keys %alt), "\n"]);
 721 }
 722
 723 sub git_init {
 724         my ($self, $epoch) = @_;
 725         my $git_dir = "$self->{ibx}->{inboxdir}/git/$epoch.git";
 726         PublicInbox::Import::init_bare($git_dir);
 727         run_die([qw(git config), "--file=$git_dir/config",
 728                 qw(include.path ../../all.git/config)]);
 729         fill_alternates($self, $epoch);
 730         $git_dir
 731 }
 732
 733 sub importer {
 734         my ($self) = @_;
 735         my $im = $self->{im};
 736         if ($im) {
 737                 if ($im->{bytes_added} < $self->{rotate_bytes}) {
 738                         return $im;
 739                 } else {
 740                         $self->{im} = undef;
 741                         $im->done;
 742                         $im = undef;
 743                         $self->checkpoint;
 744                         my $git_dir = $self->git_init(++$self->{epoch_max});
 745                         my $git = PublicInbox::Git->new($git_dir);
 746                         return $self->import_init($git, 0);
 747                 }
 748         }
 749         my $epoch = 0;
 750         my $max;
 751         my $latest = $self->{ibx}->git_dir_latest(\$max);
 752         if (defined $latest) {
 753                 my $git = PublicInbox::Git->new($latest);
 754                 my $packed_bytes = $git->packed_bytes;
 755                 my $unpacked_bytes = $packed_bytes / $PACKING_FACTOR;
 756
 757                 if ($unpacked_bytes >= $self->{rotate_bytes}) {
 758                         $epoch = $max + 1;
 759                 } else {
 760                         $self->{epoch_max} = $max;
 761                         return $self->import_init($git, $packed_bytes);
 762                 }
 763         }
 764         $self->{epoch_max} = $epoch;
 765         $latest = $self->git_init($epoch);
 766         $self->import_init(PublicInbox::Git->new($latest), 0);
 767 }
 768
 769 sub import_init {
 770         my ($self, $git, $packed_bytes, $tmp) = @_;
 771         my $im = PublicInbox::Import->new($git, undef, undef, $self->{ibx});
 772         $im->{bytes_added} = int($packed_bytes / $PACKING_FACTOR);
 773         $im->{lock_path} = undef;
 774         $im->{path_type} = 'v2';
 775         $self->{im} = $im unless $tmp;
 776         $im;
 777 }
 778
 779 # XXX experimental
 780 sub diff ($$$) {
 781         my ($mid, $cur, $new) = @_;
 782
 783         my $ah = File::Temp->new(TEMPLATE => 'email-cur-XXXXXXXX', TMPDIR => 1);
 784         print $ah $cur->as_string or die "print: $!";
 785         $ah->flush or die "flush: $!";
 786         PublicInbox::Import::drop_unwanted_headers($new);
 787         my $bh = File::Temp->new(TEMPLATE => 'email-new-XXXXXXXX', TMPDIR => 1);
 788         print $bh $new->as_string or die "print: $!";
 789         $bh->flush or die "flush: $!";
 790         my $cmd = [ qw(diff -u), $ah->filename, $bh->filename ];
 791         print STDERR "# MID conflict <$mid>\n";
 792         my $pid = spawn($cmd, undef, { 1 => 2 });
 793         waitpid($pid, 0) == $pid or die "diff did not finish";
 794 }
 795
 796 sub get_blob ($$) {
 797         my ($self, $smsg) = @_;
 798         if (my $im = $self->{im}) {
 799                 my $msg = $im->cat_blob($smsg->{blob});
 800                 return $msg if $msg;
 801         }
 802         # older message, should be in alternates
 803         $self->{ibx}->msg_by_smsg($smsg);
 804 }
 805
 806 sub content_exists ($$$) {
 807         my ($self, $mime, $mid) = @_;
 808         my $oidx = $self->{oidx};
 809         my $chashes = content_hashes($mime);
 810         my ($id, $prev);
 811         while (my $smsg = $oidx->next_by_mid($mid, \$id, \$prev)) {
 812                 my $msg = get_blob($self, $smsg);
 813                 if (!defined($msg)) {
 814                         warn "broken smsg for $mid\n";
 815                         next;
 816                 }
 817                 my $cur = PublicInbox::Eml->new($msg);
 818                 return 1 if content_matches($chashes, $cur);
 819
 820                 # XXX DEBUG_DIFF is experimental and may be removed
 821                 diff($mid, $cur, $mime) if $ENV{DEBUG_DIFF};
 822         }
 823         undef;
 824 }
 825
 826 sub atfork_child {
 827         my ($self) = @_;
 828         if (my $older_siblings = $self->{idx_shards}) {
 829                 $_->shard_atfork_child for @$older_siblings;
 830         }
 831         if (my $im = $self->{im}) {
 832                 $im->atfork_child;
 833         }
 834         die "BUG: unexpected mm" if $self->{mm};
 835 }
 836
 837 sub reindex_checkpoint ($$) {
 838         my ($self, $sync) = @_;
 839
 840         $self->git->async_wait_all;
 841         $self->update_last_commit($sync);
 842         ${$sync->{need_checkpoint}} = 0;
 843         my $mm_tmp = $sync->{mm_tmp};
 844         $mm_tmp->atfork_prepare if $mm_tmp;
 845         die 'BUG: {im} during reindex' if $self->{im};
 846         if ($self->{ibx_map} && !$sync->{checkpoint_unlocks}) {
 847                 checkpoint($self, 1); # no need to release lock on pure index
 848         } else {
 849                 $self->done; # release lock
 850         }
 851
 852         if (my $pr = $sync->{-regen_fmt} ? $sync->{-opt}->{-progress} : undef) {
 853                 $pr->(sprintf($sync->{-regen_fmt}, ${$sync->{nr}}));
 854         }
 855
 856         # allow -watch or -mda to write...
 857         $self->idx_init($sync->{-opt}); # reacquire lock
 858         if (my $intvl = $sync->{check_intvl}) { # eidx
 859                 $sync->{next_check} = PublicInbox::DS::now() + $intvl;
 860         }
 861         $mm_tmp->atfork_parent if $mm_tmp;
 862 }
 863
 864 sub index_finalize ($$) {
 865         my ($arg, $index) = @_;
 866         ++$arg->{self}->{nidx};
 867         if (defined(my $cur = $arg->{cur_cmt})) {
 868                 ${$arg->{latest_cmt}} = $cur;
 869         } elsif ($index) {
 870                 die 'BUG: {cur_cmt} missing';
 871         } # else { unindexing @leftovers doesn't set {cur_cmt}
 872 }
 873
 874 sub index_oid { # cat_async callback
 875         my ($bref, $oid, $type, $size, $arg) = @_;
 876         is_bad_blob($oid, $type, $size, $arg->{oid}) and
 877                 return index_finalize($arg, 1); # size == 0 purged returns here
 878         my $self = $arg->{self};
 879         local $self->{current_info} = "$self->{current_info} $oid";
 880         my ($num, $mid0);
 881         my $eml = PublicInbox::Eml->new($$bref);
 882         my $mids = mids($eml);
 883         my $chash = content_hash($eml);
 884
 885         if (scalar(@$mids) == 0) {
 886                 warn "E: $oid has no Message-ID, skipping\n";
 887                 return;
 888         }
 889
 890         # {unindexed} is unlikely
 891         if ((my $unindexed = $arg->{unindexed}) && scalar(@$mids) == 1) {
 892                 $num = delete($unindexed->{$mids->[0]});
 893                 if (defined $num) {
 894                         $mid0 = $mids->[0];
 895                         $self->{mm}->mid_set($num, $mid0);
 896                         delete($arg->{unindexed}) if !keys(%$unindexed);
 897                 }
 898         }
 899         if (!defined($num)) { # reuse if reindexing (or duplicates)
 900                 my $oidx = $self->{oidx};
 901                 for my $mid (@$mids) {
 902                         ($num, $mid0) = $oidx->num_mid0_for_oid($oid, $mid);
 903                         last if defined $num;
 904                 }
 905         }
 906         $mid0 //= do { # is this a number we got before?
 907                 $num = $arg->{mm_tmp}->num_for($mids->[0]);
 908                 defined($num) ? $mids->[0] : undef;
 909         };
 910         if (!defined($num)) {
 911                 for (my $i = $#$mids; $i >= 1; $i--) {
 912                         $num = $arg->{mm_tmp}->num_for($mids->[$i]);
 913                         if (defined($num)) {
 914                                 $mid0 = $mids->[$i];
 915                                 last;
 916                         }
 917                 }
 918         }
 919         if (defined($num)) {
 920                 $arg->{mm_tmp}->num_delete($num);
 921         } else { # never seen
 922                 $num = $self->{mm}->mid_insert($mids->[0]);
 923                 if (defined($num)) {
 924                         $mid0 = $mids->[0];
 925                 } else { # rare, try the rest of them, backwards
 926                         for (my $i = $#$mids; $i >= 1; $i--) {
 927                                 $num = $self->{mm}->mid_insert($mids->[$i]);
 928                                 if (defined($num)) {
 929                                         $mid0 = $mids->[$i];
 930                                         last;
 931                                 }
 932                         }
 933                 }
 934         }
 935         if (!defined($num)) {
 936                 warn "E: $oid <", join('> <', @$mids), "> is a duplicate\n";
 937                 return;
 938         }
 939         ++${$arg->{nr}};
 940         my $smsg = bless {
 941                 raw_bytes => $size,
 942                 num => $num,
 943                 blob => $oid,
 944                 mid => $mid0,
 945         }, 'PublicInbox::Smsg';
 946         $smsg->populate($eml, $arg);
 947         if (do_idx($self, $bref, $eml, $smsg)) {
 948                 ${$arg->{need_checkpoint}} = 1;
 949         }
 950         index_finalize($arg, 1);
 951 }
 952
 953 # only update last_commit for $i on reindex iff newer than current
 954 sub update_last_commit {
 955         my ($self, $sync, $stk) = @_;
 956         my $unit = $sync->{unit} // return;
 957         my $latest_cmt = $stk ? $stk->{latest_cmt} : ${$sync->{latest_cmt}};
 958         defined($latest_cmt) or return;
 959         my $last = last_epoch_commit($self, $unit->{epoch});
 960         if (defined $last && is_ancestor($self->git, $last, $latest_cmt)) {
 961                 my @cmd = (qw(rev-list --count), "$last..$latest_cmt");
 962                 chomp(my $n = $unit->{git}->qx(@cmd));
 963                 return if $n ne '' && $n == 0;
 964         }
 965         last_epoch_commit($self, $unit->{epoch}, $latest_cmt);
 966 }
 967
 968 sub last_commits {
 969         my ($self, $sync) = @_;
 970         my $heads = [];
 971         for (my $i = $sync->{epoch_max}; $i >= 0; $i--) {
 972                 $heads->[$i] = last_epoch_commit($self, $i);
 973         }
 974         $heads;
 975 }
 976
 977 # returns a revision range for git-log(1)
 978 sub log_range ($$$) {
 979         my ($sync, $unit, $tip) = @_;
 980         my $opt = $sync->{-opt};
 981         my $pr = $opt->{-progress} if (($opt->{verbose} || 0) > 1);
 982         my $i = $unit->{epoch};
 983         my $cur = $sync->{ranges}->[$i] or do {
 984                 $pr->("$i.git indexing all of $tip\n") if $pr;
 985                 return $tip; # all of it
 986         };
 987
 988         # fast equality check to avoid (v)fork+execve overhead
 989         if ($cur eq $tip) {
 990                 $sync->{ranges}->[$i] = undef;
 991                 return;
 992         }
 993
 994         my $range = "$cur..$tip";
 995         $pr->("$i.git checking contiguity... ") if $pr;
 996         my $git = $unit->{git};
 997         if (is_ancestor($sync->{self}->git, $cur, $tip)) { # common case
 998                 $pr->("OK\n") if $pr;
 999                 my $n = $git->qx(qw(rev-list --count), $range);
1000                 chomp($n);
1001                 if ($n == 0) {
1002                         $sync->{ranges}->[$i] = undef;
1003                         $pr->("$i.git has nothing new\n") if $pr;
1004                         return; # nothing to do
1005                 }
1006                 $pr->("$i.git has $n changes since $cur\n") if $pr;
1007         } else {
1008                 $pr->("FAIL\n") if $pr;
1009                 warn <<"";
1010 discontiguous range: $range
1011 Rewritten history? (in $git->{git_dir})
1012
1013                 chomp(my $base = $git->qx('merge-base', $tip, $cur));
1014                 if ($base) {
1015                         $range = "$base..$tip";
1016                         warn "found merge-base: $base\n"
1017                 } else {
1018                         $range = $tip;
1019                         warn "discarding history at $cur\n";
1020                 }
1021                 warn <<"";
1022 reindexing $git->{git_dir}
1023 starting at $range
1024
1025                 # $cur^0 may no longer exist if pruned by git
1026                 if ($git->qx(qw(rev-parse -q --verify), "$cur^0")) {
1027                         $unit->{unindex_range} = "$base..$cur";
1028                 } elsif ($base && $git->qx(qw(rev-parse -q --verify), $base)) {
1029                         $unit->{unindex_range} = "$base..";
1030                 } else {
1031                         warn "W: unable to unindex before $range\n";
1032                 }
1033         }
1034         $range;
1035 }
1036
1037 # overridden by ExtSearchIdx
1038 sub artnum_max { $_[0]->{mm}->num_highwater }
1039
1040 sub sync_prepare ($$) {
1041         my ($self, $sync) = @_;
1042         $sync->{ranges} = sync_ranges($self, $sync);
1043         my $pr = $sync->{-opt}->{-progress};
1044         my $regen_max = 0;
1045         my $head = $sync->{ibx}->{ref_head} || 'HEAD';
1046         my $pfx;
1047         if ($pr) {
1048                 ($pfx) = ($sync->{ibx}->{inboxdir} =~ m!([^/]+)\z!g);
1049                 $pfx //= $sync->{ibx}->{inboxdir};
1050         }
1051
1052         my $reindex_heads;
1053         if ($self->{ibx_map}) {
1054                 # ExtSearchIdx won't index messages unless they're in
1055                 # over.sqlite3 for a given inbox, so don't read beyond
1056                 # what's in the per-inbox index.
1057                 $reindex_heads = [];
1058                 my $v = PublicInbox::Search::SCHEMA_VERSION;
1059                 my $mm = $sync->{ibx}->mm;
1060                 for my $i (0..$sync->{epoch_max}) {
1061                         $reindex_heads->[$i] = $mm->last_commit_xap($v, $i);
1062                 }
1063         } elsif ($sync->{reindex}) { # V2 inbox
1064                 # reindex stops at the current heads and we later
1065                 # rerun index_sync without {reindex}
1066                 $reindex_heads = $self->last_commits($sync);
1067         }
1068         if ($sync->{max_size} = $sync->{-opt}->{max_size}) {
1069                 $sync->{index_oid} = $self->can('index_oid');
1070         }
1071         my $git_pfx = "$sync->{ibx}->{inboxdir}/git";
1072         for (my $i = $sync->{epoch_max}; $i >= 0; $i--) {
1073                 my $git_dir = "$git_pfx/$i.git";
1074                 -d $git_dir or next; # missing epochs are fine
1075                 my $git = PublicInbox::Git->new($git_dir);
1076                 my $unit = { git => $git, epoch => $i };
1077                 my $tip;
1078                 if ($reindex_heads) {
1079                         $tip = $head = $reindex_heads->[$i] or next;
1080                 } else {
1081                         $tip = $git->qx(qw(rev-parse -q --verify), $head);
1082                         next if $?; # new repo
1083                         chomp $tip;
1084                 }
1085                 my $range = log_range($sync, $unit, $tip) or next;
1086                 # can't use 'rev-list --count' if we use --diff-filter
1087                 $pr->("$pfx $i.git counting $range ... ") if $pr;
1088                 # Don't bump num_highwater on --reindex by using {D}.
1089                 # We intentionally do NOT use {D} in the non-reindex case
1090                 # because we want NNTP article number gaps from unindexed
1091                 # messages to show up in mirrors, too.
1092                 $sync->{D} //= $sync->{reindex} ? {} : undef; # OID_BIN => NR
1093                 my $stk = log2stack($sync, $git, $range);
1094                 return 0 if $sync->{quit};
1095                 my $nr = $stk ? $stk->num_records : 0;
1096                 $pr->("$nr\n") if $pr;
1097                 $unit->{stack} = $stk; # may be undef
1098                 unshift @{$sync->{todo}}, $unit;
1099                 $regen_max += $nr;
1100         }
1101         return 0 if $sync->{quit};
1102
1103         # XXX this should not happen unless somebody bypasses checks in
1104         # our code and blindly injects "d" file history into git repos
1105         if (my @leftovers = keys %{delete($sync->{D}) // {}}) {
1106                 warn('W: unindexing '.scalar(@leftovers)." leftovers\n");
1107                 local $self->{current_info} = 'leftover ';
1108                 my $unindex_oid = $self->can('unindex_oid');
1109                 for my $oid (@leftovers) {
1110                         last if $sync->{quit};
1111                         $oid = unpack('H*', $oid);
1112                         my $req = { %$sync, oid => $oid };
1113                         $self->git->cat_async($oid, $unindex_oid, $req);
1114                 }
1115                 $self->git->cat_async_wait;
1116         }
1117         return 0 if $sync->{quit};
1118         if (!$regen_max) {
1119                 $sync->{-regen_fmt} = "%u/?\n";
1120                 return 0;
1121         }
1122
1123         # reindex should NOT see new commits anymore, if we do,
1124         # it's a problem and we need to notice it via die()
1125         my $pad = length($regen_max) + 1;
1126         $sync->{-regen_fmt} = "% ${pad}u/$regen_max\n";
1127         $sync->{nr} = \(my $nr = 0);
1128         return -1 if $sync->{reindex};
1129         $regen_max + $self->artnum_max || 0;
1130 }
1131
1132 sub unindex_oid_aux ($$$) {
1133         my ($self, $oid, $mid) = @_;
1134         my @removed = $self->{oidx}->remove_oid($oid, $mid);
1135         for my $num (@removed) {
1136                 my $idx = idx_shard($self, $num);
1137                 $idx->shard_remove($num);
1138         }
1139 }
1140
1141 sub unindex_oid ($$;$) { # git->cat_async callback
1142         my ($bref, $oid, $type, $size, $arg) = @_;
1143         is_bad_blob($oid, $type, $size, $arg->{oid}) and
1144                 return index_finalize($arg, 0);
1145         my $self = $arg->{self};
1146         local $self->{current_info} = "$self->{current_info} $oid";
1147         my $unindexed = $arg->{in_unindex} ? $arg->{unindexed} : undef;
1148         my $mm = $self->{mm};
1149         my $mids = mids(PublicInbox::Eml->new($bref));
1150         undef $$bref;
1151         my $oidx = $self->{oidx};
1152         foreach my $mid (@$mids) {
1153                 my %gone;
1154                 my ($id, $prev);
1155                 while (my $smsg = $oidx->next_by_mid($mid, \$id, \$prev)) {
1156                         $gone{$smsg->{num}} = 1 if $oid eq $smsg->{blob};
1157                 }
1158                 my $n = scalar(keys(%gone)) or next;
1159                 if ($n > 1) {
1160                         warn "BUG: multiple articles linked to $oid\n",
1161                                 join(',',sort keys %gone), "\n";
1162                 }
1163                 foreach my $num (keys %gone) {
1164                         if ($unindexed) {
1165                                 my $mid0 = $mm->mid_for($num);
1166                                 $unindexed->{$mid0} = $num;
1167                         }
1168                         $mm->num_delete($num);
1169                 }
1170                 unindex_oid_aux($self, $oid, $mid);
1171         }
1172         index_finalize($arg, 0);
1173 }
1174
1175 sub git { $_[0]->{ibx}->git }
1176
1177 # this is rare, it only happens when we get discontiguous history in
1178 # a mirror because the source used -purge or -edit
1179 sub unindex_todo ($$$) {
1180         my ($self, $sync, $unit) = @_;
1181         my $unindex_range = delete($unit->{unindex_range}) // return;
1182         my $unindexed = $sync->{unindexed} //= {}; # $mid0 => $num
1183         my $before = scalar keys %$unindexed;
1184         # order does not matter, here:
1185         my $fh = $unit->{git}->popen(qw(log --raw -r --no-notes --no-color
1186                                 --no-abbrev --no-renames), $unindex_range);
1187         local $sync->{in_unindex} = 1;
1188         my $unindex_oid = $self->can('unindex_oid');
1189         while (<$fh>) {
1190                 /\A:\d{6} 100644 $OID ($OID) [AM]\tm$/o or next;
1191                 $self->git->cat_async($1, $unindex_oid, { %$sync, oid => $1 });
1192         }
1193         close $fh or die "git log failed: \$?=$?";
1194         $self->git->cat_async_wait;
1195
1196         return unless $sync->{-opt}->{prune};
1197         my $after = scalar keys %$unindexed;
1198         return if $before == $after;
1199
1200         # ensure any blob can not longer be accessed via dumb HTTP
1201         run_die(['git', "--git-dir=$unit->{git}->{git_dir}",
1202                 qw(-c gc.reflogExpire=now gc --prune=all --quiet)]);
1203 }
1204
1205 sub sync_ranges ($$) {
1206         my ($self, $sync) = @_;
1207         my $reindex = $sync->{reindex};
1208         return $self->last_commits($sync) unless $reindex;
1209         return [] if ref($reindex) ne 'HASH';
1210
1211         my $ranges = $reindex->{from}; # arrayref;
1212         if (ref($ranges) ne 'ARRAY') {
1213                 die 'BUG: $reindex->{from} not an ARRAY';
1214         }
1215         $ranges;
1216 }
1217
1218 sub index_xap_only { # git->cat_async callback
1219         my ($bref, $oid, $type, $size, $smsg) = @_;
1220         my $self = $smsg->{self};
1221         my $idx = idx_shard($self, $smsg->{num});
1222         $smsg->{raw_bytes} = $size;
1223         $idx->index_raw($bref, undef, $smsg);
1224         $self->{transact_bytes} += $size;
1225 }
1226
1227 sub index_xap_step ($$$;$) {
1228         my ($self, $sync, $beg, $step) = @_;
1229         my $end = $sync->{art_end};
1230         return if $beg > $end; # nothing to do
1231
1232         $step //= $self->{shards};
1233         my $ibx = $self->{ibx};
1234         if (my $pr = $sync->{-opt}->{-progress}) {
1235                 $pr->("Xapian indexlevel=$ibx->{indexlevel} ".
1236                         "$beg..$end (% $step)\n");
1237         }
1238         for (my $num = $beg; $num <= $end; $num += $step) {
1239                 last if $sync->{quit};
1240                 my $smsg = $ibx->over->get_art($num) or next;
1241                 $smsg->{self} = $self;
1242                 $ibx->git->cat_async($smsg->{blob}, \&index_xap_only, $smsg);
1243                 if ($self->{transact_bytes} >= $self->{batch_bytes}) {
1244                         ${$sync->{nr}} = $num;
1245                         reindex_checkpoint($self, $sync);
1246                 }
1247         }
1248 }
1249
1250 sub index_todo ($$$) {
1251         my ($self, $sync, $unit) = @_;
1252         return if $sync->{quit};
1253         unindex_todo($self, $sync, $unit);
1254         my $stk = delete($unit->{stack}) or return;
1255         my $all = $self->git;
1256         my $index_oid = $self->can('index_oid');
1257         my $unindex_oid = $self->can('unindex_oid');
1258         my $pfx;
1259         if ($unit->{git}->{git_dir} =~ m!/([^/]+)/git/([0-9]+\.git)\z!) {
1260                 $pfx = "$1 $2"; # v2
1261         } else { # v1
1262                 ($pfx) = ($unit->{git}->{git_dir} =~ m!/([^/]+)\z!g);
1263                 $pfx //= $unit->{git}->{git_dir};
1264         }
1265         local $self->{current_info} = "$pfx ";
1266         local $sync->{latest_cmt} = \(my $latest_cmt);
1267         local $sync->{unit} = $unit;
1268         while (my ($f, $at, $ct, $oid, $cmt) = $stk->pop_rec) {
1269                 if ($sync->{quit}) {
1270                         warn "waiting to quit...\n";
1271                         $all->async_wait_all;
1272                         $self->update_last_commit($sync);
1273                         return;
1274                 }
1275                 my $req = {
1276                         %$sync,
1277                         autime => $at,
1278                         cotime => $ct,
1279                         oid => $oid,
1280                         cur_cmt => $cmt
1281                 };
1282                 if ($f eq 'm') {
1283                         if ($sync->{max_size}) {
1284                                 $all->check_async($oid, \&check_size, $req);
1285                         } else {
1286                                 $all->cat_async($oid, $index_oid, $req);
1287                         }
1288                 } elsif ($f eq 'd') {
1289                         $all->cat_async($oid, $unindex_oid, $req);
1290                 }
1291                 if (${$sync->{need_checkpoint}}) {
1292                         reindex_checkpoint($self, $sync);
1293                 }
1294         }
1295         $all->async_wait_all;
1296         $self->update_last_commit($sync, $stk);
1297 }
1298
1299 sub xapian_only {
1300         my ($self, $opt, $sync, $art_beg) = @_;
1301         my $seq = $opt->{sequential_shard};
1302         $art_beg //= 0;
1303         local $self->{parallel} = 0 if $seq;
1304         $self->idx_init($opt); # acquire lock
1305         if (my $art_end = $self->{ibx}->mm->max) {
1306                 $sync //= {
1307                         need_checkpoint => \(my $bool = 0),
1308                         -opt => $opt,
1309                         self => $self,
1310                         nr => \(my $nr = 0),
1311                         -regen_fmt => "%u/?\n",
1312                 };
1313                 $sync->{art_end} = $art_end;
1314                 if ($seq || !$self->{parallel}) {
1315                         my $shard_end = $self->{shards} - 1;
1316                         for my $i (0..$shard_end) {
1317                                 last if $sync->{quit};
1318                                 index_xap_step($self, $sync, $art_beg + $i);
1319                                 if ($i != $shard_end) {
1320                                         reindex_checkpoint($self, $sync);
1321                                 }
1322                         }
1323                 } else { # parallel (maybe)
1324                         index_xap_step($self, $sync, $art_beg, 1);
1325                 }
1326         }
1327         $self->git->cat_async_wait;
1328         $self->done;
1329 }
1330
1331 # public, called by public-inbox-index
1332 sub index_sync {
1333         my ($self, $opt) = @_;
1334         $opt //= {};
1335         return xapian_only($self, $opt) if $opt->{xapian_only};
1336
1337         my $epoch_max;
1338         my $latest = $self->{ibx}->git_dir_latest(\$epoch_max) // return;
1339         if ($opt->{'fast-noop'}) { # nanosecond (st_ctim) comparison
1340                 use Time::HiRes qw(stat);
1341                 if (my @mm = stat("$self->{ibx}->{inboxdir}/msgmap.sqlite3")) {
1342                         my $c = $mm[10]; # 10 = ctime (nsec NV)
1343                         my @hd = stat("$latest/refs/heads");
1344                         my @pr = stat("$latest/packed-refs");
1345                         return if $c > ($hd[10] // 0) && $c > ($pr[10] // 0);
1346                 }
1347         }
1348
1349         my $pr = $opt->{-progress};
1350         my $seq = $opt->{sequential_shard};
1351         my $art_beg; # the NNTP article number we start xapian_only at
1352         my $idxlevel = $self->{ibx}->{indexlevel};
1353         local $self->{ibx}->{indexlevel} = 'basic' if $seq;
1354
1355         $self->idx_init($opt); # acquire lock
1356         fill_alternates($self, $epoch_max);
1357         $self->{oidx}->rethread_prepare($opt);
1358         my $sync = {
1359                 need_checkpoint => \(my $bool = 0),
1360                 reindex => $opt->{reindex},
1361                 -opt => $opt,
1362                 self => $self,
1363                 ibx => $self->{ibx},
1364                 epoch_max => $epoch_max,
1365         };
1366         my $quit = PublicInbox::SearchIdx::quit_cb($sync);
1367         local $SIG{QUIT} = $quit;
1368         local $SIG{INT} = $quit;
1369         local $SIG{TERM} = $quit;
1370
1371         if (sync_prepare($self, $sync)) {
1372                 # tmp_clone seems to fail if inside a transaction, so
1373                 # we rollback here (because we opened {mm} for reading)
1374                 # Note: we do NOT rely on DBI transactions for atomicity;
1375                 # only for batch performance.
1376                 $self->{mm}->{dbh}->rollback;
1377                 $self->{mm}->{dbh}->begin_work;
1378                 $sync->{mm_tmp} =
1379                         $self->{mm}->tmp_clone($self->{ibx}->{inboxdir});
1380
1381                 # xapian_only works incrementally w/o --reindex
1382                 if ($seq && !$opt->{reindex}) {
1383                         $art_beg = $sync->{mm_tmp}->max || -1;
1384                         $art_beg++;
1385                 }
1386         }
1387         # work forwards through history
1388         index_todo($self, $sync, $_) for @{delete($sync->{todo}) // []};
1389         $self->{oidx}->rethread_done($opt) unless $sync->{quit};
1390         $self->done;
1391
1392         if (my $nr = $sync->{nr}) {
1393                 my $pr = $sync->{-opt}->{-progress};
1394                 $pr->('all.git '.sprintf($sync->{-regen_fmt}, $$nr)) if $pr;
1395         }
1396
1397         my $quit_warn;
1398         # deal with Xapian shards sequentially
1399         if ($seq && delete($sync->{mm_tmp})) {
1400                 if ($sync->{quit}) {
1401                         $quit_warn = 1;
1402                 } else {
1403                         $self->{ibx}->{indexlevel} = $idxlevel;
1404                         xapian_only($self, $opt, $sync, $art_beg);
1405                         $quit_warn = 1 if $sync->{quit};
1406                 }
1407         }
1408
1409         # --reindex on the command-line
1410         if (!$sync->{quit} && $opt->{reindex} &&
1411                         !ref($opt->{reindex}) && $idxlevel ne 'basic') {
1412                 $self->lock_acquire;
1413                 my $s0 = PublicInbox::SearchIdx->new($self->{ibx}, 0, 0);
1414                 if (my $xdb = $s0->idx_acquire) {
1415                         my $n = $xdb->get_metadata('has_threadid');
1416                         $xdb->set_metadata('has_threadid', '1') if $n ne '1';
1417                 }
1418                 $s0->idx_release;
1419                 $self->lock_release;
1420         }
1421
1422         # reindex does not pick up new changes, so we rerun w/o it:
1423         if ($opt->{reindex} && !$sync->{quit}) {
1424                 my %again = %$opt;
1425                 $sync = undef;
1426                 delete @again{qw(rethread reindex -skip_lock)};
1427                 index_sync($self, \%again);
1428                 $opt->{quit} = $again{quit}; # propagate to caller
1429         }
1430         warn <<EOF if $quit_warn;
1431 W: interrupted, --xapian-only --reindex required upon restart
1432 EOF
1433 }
1434
1435 1;